Sub loop\_worksheets()

' Create a loop that will run the function in all sheets

Dim ws As Worksheet

Application.ScreenUpdating = False

For Each ws In Worksheets

ws.Select

Call Stocks

Call GreatChanges

Next ws

Application.ScreenUpdating = True

End Sub

Sub Stocks()

' Create variables

Dim ticker As String

Dim next\_ticker As String

Dim LastRow As Long

Dim position As Long

Dim yearly\_change As Double

Dim vol As Double

Dim year\_open As Double

Dim year\_close As Double

Dim RowFirst As Double

Dim RowLast As Double

Dim percent As Double

' Create summary table headers

Range("J1").Value = "Ticker"

Range("K1").Value = "Yearly Change"

Range("L1").Value = "Percent Change"

Range("M1").Value = "Total Stock Volume"

Range("J1:M1").Columns.AutoFit

' List the tickers in the summary table

' Determine the last row with content

LastRow = Cells(Rows.Count, 1).End(xlUp).Row

' Set a starting position

position = 2

' Loop through the <ticker> column

For i = 2 To LastRow

ticker = Cells(i, 1).Value

next\_ticker = Cells(i + 1, 1).Value

' Put each unique ticker

If ticker <> next\_ticker Then

Cells(position, 10).Value = ticker

' Calculate volume per ticker

vol = WorksheetFunction.SumIf(Range("A2:A" & LastRow), ticker, Range("G2:G" & LastRow))

Cells(position, 13).Value = vol

' Determine the row numbers of first and last entries for the year

RowFirst = Range("A1:A" & LastRow).Find(What:=ticker, LookAt:=xlWhole, SearchDirection:=xlNext, MatchCase:=False).Row

RowLast = Range("A1:A" & LastRow).Find(What:=ticker, LookAt:=xlWhole, SearchDirection:=xlPrevious, MatchCase:=False).Row

' Determine stock value on first day opening and last day closing

year\_open = Cells(RowFirst, 3).Value

year\_close = Cells(RowLast, 6).Value

yearly\_change = year\_close - year\_open

' Determine year change

Cells(position, 11).Value = yearly\_change

' Determine percent change

If year\_open > 0 Then

percent = yearly\_change / year\_open

Cells(position, 12).Value = percent

Cells(position, 12).NumberFormat = "0.00%"

ElseIf year\_open <= 0 Then

Cells(position, 12).Value = "NA"

End If

' Highlight the cells for yearly\_change as follows:

' red = negative change; green = positive change

If yearly\_change < 0 Then

Cells(position, 11).Interior.ColorIndex = 3

ElseIf yearly\_change > 0 Then

Cells(position, 11).Interior.ColorIndex = 4

End If

position = position + 1

End If

Next i

End Sub

Sub GreatChanges()

' Create new variables

Dim gt\_in As Double ' greatest increase

Dim gt\_dc As Double ' greatest decrease

Dim gt\_vol As Double 'greatest total volume

' Create table containing greatest changes

Range("P2").Value = "Greatest % Increase"

Range("P3").Value = "Greatest % Decrease"

Range("P4").Value = "Greatest Total Volume"

Range("Q1").Value = "Ticker"

Range("R1").Value = "Value"

Range("P1:Q4").Columns.AutoFit

' Find the values

gt\_in = Application.WorksheetFunction.Max(Columns("L"))

gt\_dc = Application.WorksheetFunction.Min(Columns("L"))

gt\_vol = Application.WorksheetFunction.Max(Columns("M"))

Cells(2, 18).Value = gt\_in

Cells(3, 18).Value = gt\_dc

Cells(4, 18).Value = gt\_vol

Range("R2:R3").NumberFormat = "0.00%"

' Find the last row

LastRow = Cells(Rows.Count, 10).End(xlUp).Row

' Loop through the column to find the corresponding ticker

For j = 1 To LastRow

' Find the corresponding ticker

If Cells(j, 12).Value = gt\_in Then

Cells(2, 17).Value = Cells(j, 10).Value

End If

If Cells(j, 12).Value = gt\_dc Then

Cells(3, 17).Value = Cells(j, 10).Value

End If

If Cells(j, 13).Value = gt\_vol Then

Cells(4, 17).Value = Cells(j, 10).Value

End If

Next j

End Sub