【实验6.10】

实验内容：

1. 完成硬件测试环境；
2. 编写程序对微机系统的串口进行自发自收外环测试，发送采用查询方式，接收采用中断方式；
3. 数据发送从键盘键入，接收数据屏幕显示。

**实验代码：**

.586

DATA SEGMENT USE16

OLD0B DD ?

FLAG DB 0

DATA ENDS

CODE SEGMENT USE16

ASSUME CS:CODE ,DS:DATA

BEG: MOV AX,DATA

MOV DS,AX

CLI ;关中断

CALL I8250 ;初始化编程

CALL I8259

CALL RD0B ;读写中断向量

CALL WR0B

STI

SCANT: CMP FLAG ,-1

JE RETURN ;接收到ESC则结束该程序

MOV DX,2FDH

IN AL,DX ;读取通信状态

TEST AL,20H

JZ SCANT

MOV AH,1 ;查询键盘的缓冲区是否有字

INT 16H

JZ SCANT

MOV AH,0H ;调用BIOS无回显输入

INT 16H

AND AL,7FH

MOV DX,2F8H

OUT DX,AL

CMP AL,1BH

JNE SCANT

TWAIT: MOV DX,2FDH ;读取通信线状态寄存器

IN AL,DX

TEST AL,40H

JZ TWAIT

RETURN: CALL RESET

MOV AH,4CH

INT 21H

RECEIVE PROC

PUSH AX ;保护现场

PUSH DX

PUSH DS

MOV AX,DATA

MOV DS,AX

MOV DX,2F8H

IN AL,DX

AND AL,7FH

CMP AL,1BH ;判断是否为结束字符

JE NEXT

MOV AH,2

MOV DL,AL

INT 21H

JMP EXIT

NEXT: MOV FLAG, -1

EXIT: MOV AL,20H

OUT 20H,AL

POP DS

POP DX

POP AX

IRET

RECEIVE ENDP

I8250 PROC ;辅助串口初始化

MOV DX,2FBH

MOV AL,80H

OUT DX,AL

MOV DX,2F9H

MOV AL,0

OUT DX,AL

MOV DX,2F8H

MOV AL,60H

OUT DX,AL

MOV DX,2FBH

MOV AL,03H

OUT DX,AL

MOV DX,2F9H

MOV AL,01H

OUT DX,AL ;允许中断

MOV DX,2FCH

MOV AL,18H

OUT DX,AL

RET

I8250 ENDP

I8259 PROC ;开放辅8259串口中断

IN AL,21H

AND AL,11110111B

OUT 21H,AL

RET

I8259 ENDP

RD0B PROC ;读取中断向量

MOV AX,350BH

INT 21H

MOV WORD PTR OLD0B,BX

MOV WORD PTR OLD0B+2, ES

RET

RD0B ENDP

WR0B PROC ;写中断向量

PUSH DS

MOV AX,CODE

MOV DS,AX

MOV DX,OFFSET RECEIVE

MOV AX,250BH

INT 21H

POP DS

RET

WR0B ENDP

RESET PROC ;恢复中断向量

IN AL,21H

OR AL,00001000B

OUT 21H,AL

MOV AX,250BH

MOV DX, WORD PTR OLD0B

MOV DS, WORD PTR OLD0B+2

INT 21H

RET

RESET ENDP

CODE ENDS

END BEG