Programming Exercises

13. *Hint:* Make sure that the character data with embedded commas are enclosed in double quotation marks.

*Answer:*

LIBNAME sasdata 'c:\MySASLib';

\*\* Part a);

\*\* The code for part a) is the result of using the

Export Wizard;

PROC EXPORT DATA= sasdata.cartalk

OUTFILE= "c:\MyRawData\CT1.csv"

DBMS=CSV REPLACE;

PUTNAMES=YES;

RUN;

\*\* Part b);

PROC EXPORT DATA = sasdata.cartalk

OUTFILE = 'c:\MyRawData\CT2.csv'

REPLACE;

RUN;

\*\* Part c);

DATA \_NULL\_;

SET sasdata.cartalk;

FILE 'c:\MyRawData\CT3.csv' DSD DLM = ',';

PUT Episode Title AirDate Description;

RUN;

\*\* Part d);

\*\* The data files created with the Export Wizard and

PROC EXPORT contain variable names for the first row,

while the data file created with the DATA step does

not. All of the data files use double quotation marks

on data that contain commas. They also do not have

formatted dates for AirDate;

\*\* Part e);

\*\* The code from the Export Wizard is very

similar to the user-written PROC EXPORT, with the

exception that a PUTNAMES= statement is automatically

added to the Export Wizard code. The DATA step is

very different from PROC EXPORT. The main

difference with the DATA step is that a PUT

statement is used to specify each variable;

(sections 10.2, 10.3, 10.5)

14. *Hint:* Detailed information about the continent names and years appears in the variable labels. To create this file, you may need multiple PROC steps, but you do not need multiple DATA steps.

*Answer:*

LIBNAME sasdata 'c:\MySASLib';

\*\* Parts a) and c);

DATA er\_miss er\_nmiss;

SET sasdata.exchangerate;

IF Y1 = . THEN OUTPUT er\_miss;

ELSE IF Y1 ~= . THEN OUTPUT er\_nmiss;

\*\* Part b);

FORMAT Y1 Y2 Y3 Y4 COMMA9.2;

RUN;

\*\* Part a);

\*\* The DBMS identifier and file extension you use may

vary depending on your operating system and version

of Microsoft Excel;

PROC EXPORT DATA = er\_miss

OUTFILE = 'c:\MyRawData\ExchRate.xlsx'

DBMS = XLSX

REPLACE;

SHEET = 'Recent Missing';

RUN;

\*\* Part c);

PROC EXPORT DATA = er\_nmiss (WHERE = (Continent = 'AF'))

OUTFILE = 'c:\MyRawData\ExchRate.xlsx'

DBMS = XLSX

REPLACE;

SHEET = 'Africa';

RUN;

PROC EXPORT DATA = er\_nmiss (WHERE = (Continent = 'AS'))

OUTFILE = 'c:\MyRawData\ExchRate.xlsx'

DBMS = XLSX

REPLACE;

SHEET = 'Asia';

RUN;

PROC EXPORT DATA = er\_nmiss (WHERE = (Continent = 'EU'))

OUTFILE = 'c:\MyRawData\ExchRate.xlsx'

DBMS = XLSX

REPLACE;

SHEET = 'Europe';

RUN;

PROC EXPORT DATA = er\_nmiss (WHERE = (Continent = 'NA'))

OUTFILE = 'c:\MyRawData\ExchRate.xlsx'

DBMS = XLSX

REPLACE;

SHEET = 'North America';

RUN;

PROC EXPORT DATA = er\_nmiss (WHERE = (Continent = 'SA'))

OUTFILE = 'c:\MyRawData\ExchRate.xlsx'

DBMS = XLSX

REPLACE;

SHEET = 'South America';

RUN;

PROC EXPORT DATA = er\_nmiss (WHERE = (Continent = 'OC'))

OUTFILE = 'c:\MyRawData\ExchRate.xlsx'

DBMS = XLSX

REPLACE;

SHEET = 'Australia Oceania';

RUN;

\*\* There are no data in the file for this continent but

it is specifed as being included in the raw data

file;

PROC EXPORT DATA = er\_nmiss (WHERE = (Continent = 'AN'))

OUTFILE = 'c:\MyRawData\ExchRate.xlsx'

DBMS = XLSX

REPLACE;

SHEET = 'Antarctica';

RUN;

(section 10.4)

15. *Hint:* Be sure to check the variable types and formats. Consider using different PUT statements depending on the value for appointment date. Think about how you can display just the first letter of a name without creating a new variable.

*Answer:*

LIBNAME sasdata 'c:\MySASLib';

\*\* Part b);

PROC SORT DATA = sasdata.advising OUT = advising;

BY apptdate ID;

RUN;

\*\* Part a);

DATA \_NULL\_;

SET advising;

FILE 'c:\MyRawData\Expt.dat';

\*\* Part c);

IF ApptDate = . THEN PUT 'XX/XX/XXXX' +1 @;

ELSE IF ApptDate ~= . THEN PUT ApptDate @;

PUT First Last ID;

\*\* Parts c) and d);

FORMAT ApptDate MMDDYY10. First $1.;

RUN;

(sections 10.1, 10.5)

16. *Hint:* Look for a system option to display missing numeric data as blanks.

*Answer:*

LIBNAME sasdata 'c:\MySASLib';

\*\* Part c);

OPTIONS MISSING = ' ';

\*\* Part a);

\*\* Various combinations of HTML or CHTML with .xls or

.xlsx can be used here;

ODS CHTML FILE = 'c:\MyRawData\APdata.xls';

\*\* Parts a) and b);

PROC PRINT DATA = sasdata.aptest LABEL NOOBS;

VAR State NumSchools TotalPassedPct FemalePassedPct

Spending SalaryWages;

\*\* Part c);

FORMAT Spending SalaryWages DOLLAR10.2;

TITLE;

RUN;

ODS CHTML CLOSE;

(section 10.6)