Programming Exercises

24. *Hint*: Use ODS statements and options to turn certain portions of the output into data and to control page breaks.

*Answer*:

LIBNAME sasdata 'c:\MySASLib';

\*\* Part a);

ODS TRACE ON;

PROC FREQ DATA = sasdata.earthquakes;

WHERE Magnitude >= 7.0;

TABLES State / MISSING;

\*\* Part b);

ODS OUTPUT OneWayFreqs = statecount;

TITLE1 'Counts of Major to Great Earthquakes';

TITLE2 'By State';

RUN;

ODS TRACE OFF;

\*\* Part c);

ODS PDF STYLE = ANALYSIS FILE =

'c:\MyPDFFiles\EQSummary.pdf'

STARTPAGE = NO;

ODS NOPROCTITLE;

PROC PRINT DATA = statecount NOOBS;

WHERE Frequency >= 2;

VAR State Frequency;

\*\* The TITLE statements only need to be specified once

since the output for parts c) and d) will appear on

the same page;

TITLE1 'Frequency of Major Earthquakes by State';

TITLE2 'and';

TITLE3 'Listing of Major to Great Earthquakes';

TITLE4 'Since 2000';

RUN;

\*\* Part d);

PROC PRINT DATA = sasdata.earthquakes NOOBS;

WHERE Year >= 2000 AND Magnitude >= 7.0;

VAR Year State Magnitude;

RUN;

ODS PDF CLOSE;

(sections 5.1, 5.2, 5.3, 5.7)

25. *Hint*: Be sure to put your ODS statements where they will capture the results of both procedures. In the SAS windowing environment, once all the destinations are closed, you may want to reopen the default destination, or exit SAS to reset the destination.

*Answer*:

LIBNAME sasdata 'c:\MySASLib';

\*\* Part b);

ODS LISTING FILE =

'c:\MyTextFiles\CrayonsReport.txt';

\*\* Part c);

ODS HTML FILE =

'c:\MyHTMLFiles\CrayonsReport.html';

\*\* Part d);

ODS RTF FILE =

'c:\MyRTFFiles\CrayonsReport.rtf';

\*\* Part e);

ODS PDF FILE =

'c:\MyPDFFiles\CrayonsReport.pdf';

\*\* Part a);

PROC FREQ DATA = sasdata.crayons;

TABLES Issued;

TITLE 'Crayola Crayon Counts';

RUN;

PROC PRINT DATA = sasdata.crayons;

VAR Color Hex Issued;

TITLE 'Listing of Crayola Crayons';

RUN;

\*\* Part b);

ODS LISTING CLOSE;

\*\* Part c);

ODS HTML CLOSE;

\*\* Part d);

ODS RTF CLOSE;

\*\* Part e);

ODS PDF CLOSE;

(sections 5.4, 5.5, 5.6, 5.7)

26. *Hint*: Consider using a WHERE statement to select the desired applicants. The various styles for shading may require more than one VAR statement. In the SAS windowing environment, once all the destinations are closed, you may want to reopen the default destination, or exit SAS to reset the destination.

*Answer*:

LIBNAME sasdata 'c:\MySASLib';

\*\* Part a);

PROC FREQ DATA = sasdata.applications;

\*\* Part b);

WHERE StartDate < '30APR2014'D AND

(CheckBoxes CONTAINS '1' AND

CheckBoxes CONTAINS '4' AND

CheckBoxes CONTAINS '6');

TABLES TypeSpeed CheckBoxes DesiredPay;

TITLE1 HEIGHT = 18PT 'REDUCED Applicant Pool';

TITLE2 'Applicants Who Can Start By End of April,';

TITLE3 'Know Microsoft Word, Can Work Full-Time,';

TITLE4 'and Live Locally';

RUN;

\*\* Part d);

ODS HTML FILE = 'c:\MyHTMLFiles\Applicants.html';

ODS RTF FILE = 'c:\MyRTFFiles\ApplicantListing.rtf';

ODS NOPROCTITLE;

\*\* Part c);

PROC FORMAT;

VALUE typing 0 -< 40 = 'Slow'

40 -< 80 = 'Medium'

80 - HIGH = 'Fast';

RUN;

PROC SORT DATA = sasdata.applications OUT = appsort;

BY TypeSpeed;

RUN;

PROC PRINT DATA = appsort NOOBS;

WHERE StartDate < '30APR2014'D AND

(CheckBoxes CONTAINS '1' AND

CheckBoxes CONTAINS '4' AND

CheckBoxes CONTAINS '6');

\*\* Part e);

VAR Applicant StartDate / STYLE(DATA) =

{BACKGROUND = GRAY};

VAR DesiredPay / STYLE(DATA) = {BACKGROUND = GREEN

FOREGROUND = WHITE

FONT\_WEIGHT = BOLD};

BY TypeSpeed;

FORMAT TypeSpeed typing. StartDate mmddyy8.;

TITLE1 HEIGHT = 18PT 'FOR INTERNAL REVIEW';

TITLE2 'Applicants That Can Start By End of April,';

TITLE3 'Know Microsoft Word, Can Work Full-Time,';

TITLE4 'and Live Locally';

RUN;

ODS RTF CLOSE;

ODS HTML CLOSE;

(sections 5.5, 5.6, 5.8)

27. *Hint*: Review the codes specified in the variable labels in the SAS data set. Consider reformatting the data values with meaningful code descriptions so that they will appear cleaner in the output. Find an ODS statement option that will eliminate default titles for each table.

*Answer*:

LIBNAME sasdata 'c:\MySASLib';

\*\* Part d);

ODS RTF FILE = 'c:\MyRTFFiles\LoanSummary.rtf'

COLUMNS = 2 BODYTITLE;

ODS NOPROCTITLE;

\*\* Part a);

PROC FORMAT;

VALUE brch 1 = 'LIV925'

2 = 'SV408'

3 = 'SLO805'

4 = 'GLN626'

5 = 'COR760';

VALUE yesno 0 = 'No'

1 = 'Yes';

RUN;

PROC FREQ DATA = sasdata.loanapp;

WHERE PercentDown < 0.05;

TABLES Branch\*LoanApproved / NOPERCENT NOCOL;

FORMAT Branch brch. LoanApproved yesno.;

LABEL Branch = 'Branch'

LoanApproved = 'Loan Approved';

\*\* Part c);

TITLE1 JUSTIFY = LEFT HEIGHT = 0.25IN FONT = Arial

'Loan Approval by Branch';

TITLE2 JUSTIFY = LEFT HEIGHT = 0.20IN FONT = Arial

'For Loans with <5% Down';

RUN;

\*\* Part b);

PROC TABULATE DATA = sasdata.loanapp

STYLE = {JUST = CENTER};

WHERE LoanApproved = 1;

CLASS Branch;

VAR LoanAmt Price CreditScore;

TABLE Branch = 'Branch', N = ' '\*LoanAmt = 'N'

MEAN = 'Mean' \*

(LoanAmt = 'Loan Amount' \*

FORMAT = DOLLAR11.2

Price = 'Home Price' \*

FORMAT = DOLLAR11.2)

MEDIAN = 'Median' \* CreditScore \*

FORMAT = 3.;

FORMAT Branch brch.;

\*\* Part c);

TITLE1 JUSTIFY = LEFT HEIGHT = 0.25IN FONT = Arial

'Average Loan Amount and Price by Branch';

TITLE2 JUSTIFY = LEFT HEIGHT = 0.20IN FONT = Arial

'For Approved Loans';

RUN;

\*\* Part d);

ODS RTF CLOSE;

(sections 5.6, 5.8, 5.11)

28. *Hint*: The data have already been analyzed and consolidated and just need to be formatted for presentation.

*Answer*:

LIBNAME sasdata 'c:\MySASLib';

\*\* Part a);

PROC FORMAT;

VALUE grp 1 = '0.60mm+'

2 = '<0.60mm';

VALUE tx 0 = 'Placebo'

1 = 'Vitamin E';

VALUE bld LOW -< 0.05 = 'BOLD';

VALUE ita LOW -< 0.05 = 'ITALIC';

RUN;

\*\* Part e);

ODS PDF FILE =

'c:\MyPDFFiles\VitaminE.pdf';

\*\* In some operating environments it may be

necessary to specify the FONT\_FACE for the DATA

portion of the table in order for the bold and

italics to appear;

PROC PRINT DATA = sasdata.pvalues NOOBS LABEL

STYLE(HEADER) = {JUST = CENTER};

FORMAT Strata grp. Treatment tx. Mean

LowerCLMean UpperCLMean 6.3;

\*\* Part b);

LABEL Strata = 'Strata'

Treatment = 'Treatment Group';

\*\* Part c);

VAR Treatment Strata Mean LowerCLMean UpperCLMean /

STYLE(DATA) = {JUST = CENTER};

\*\* Parts c) and d);

VAR Probt /

STYLE(DATA) = {FONT\_WEIGHT = bld.

FONT\_STYLE = ita. JUST = CENTER};

TITLE1 'Difference in Plaque Thickness';

TITLE2 'Before and After Treatment';

RUN;

ODS PDF CLOSE;

(sections 5.9, 5.12, 5.13)

29. *Hint*: The best procedures to carry out each task may vary.

*Answer*:

LIBNAME sasdata 'c:\MySASLib';

\*\* Part a);

PROC SORT DATA = sasdata.grades OUT = sortgrades;

BY Course\_Section Exam3;

RUN;

PROC PRINT DATA = sortgrades;

VAR Course\_Section ID Exam1 - Exam3;

TITLE1 JUSTIFY = CENTER HEIGHT = 14PT

'Course-Section Exam Scores';

\*\* Using FONT= will turn off the bolding for the

second title;

TITLE2 JUSTIFY = CENTER FONT = Arial

'Sorted by Third Exam';

RUN;

\*\* Part b);

PROC FORMAT;

VALUE rng 0 -< 0.60 = 'red'

0.60 -< 0.80 = 'yellow'

0.80 - HIGH = 'green';

RUN;

PROC REPORT DATA = sasdata.grades NOWINDOWS;

\*\* Parts b) and c);

COLUMN Course\_Section ID Exam1 Exam2 Exam3 Average;

DEFINE Exam1 / STYLE(COLUMN) = {BACKGROUND = LIGHTGRAY

FOREGROUND = rng.};

DEFINE Exam2 / STYLE(COLUMN) = {BACKGROUND = LIGHTGRAY

FOREGROUND = rng.};

DEFINE Exam3 / STYLE(COLUMN) = {BACKGROUND = LIGHTGRAY

FOREGROUND = rng.};

DEFINE Average / COMPUTED STYLE(COLUMN) =

{BACKGROUND = rng.};

COMPUTE Average;

Average = MEAN(Exam1.SUM,Exam2.SUM,Exam3.SUM);

ENDCOMP;

TITLE1 'Highlighted Student Listing';

TITLE2 'with Average Score';

RUN;

\*\* Part d);

PROC FORMAT;

VALUE hgh 0.80 - HIGH = 'pink';

RUN;

PROC TABULATE DATA = sasdata.grades FORMAT = 5.3;

CLASS Course\_Section ;

VAR Exam1 - Exam3;

TABLE Course\_Section,

MEAN \* Exam1 \* {STYLE = {BACKGROUND = hgh.}}

MEAN \* Exam2 \* {STYLE = {BACKGROUND = hgh.}}

MEAN \* Exam3 \* {STYLE = {BACKGROUND = hgh.}};

TITLE1 'Highlighted Average Exam Scores';

TITLE2 'by Course-Section';

RUN;

(sections 5.8, 5.10, 5.11, 5.12, 5.13)