\ forthHaiku 範例 2015/11/03 陳爽

\ 反斜線空格後 文字忽略 當作註解

\ 左右刮號之間 文字忽略 也作註解

( 例00 紅光亮度 0

\ 註 非認定的文字及數字 皆為 0

z \ )

( 例01 紅光亮度 1

1 \ )

( 例02 紅光亮度 0.5

.5 \ )

( 例03 紅光亮度隨 x 從左 0 到右 1

x \ )

( 例04 紅光亮度隨 y 從下 0 到上 1

y \ )

( 例05 紅光亮度隨 x+y 從 0 到 1

\ 註 數值 大於 1 其亮度 為 1

x y + \ )

( 例06 紅光亮度隨 x-y 從 0 到 1

\ 註 數值 小於 0 其亮度 為 0

x y - \ )

( 例07 紅光亮度 x<y 左上區 1

\ 註 紅光亮度 x>y 右下區 0

x y < \ )

( 例08 紅光亮度 x+y<1 左下區 1

\ 註 紅光亮度 x+y>1 右上區 0

x y + 1 < \ )

: cx .5 ; : cy .5 ; : p0 cx cy ;

: 2pi pi pi + ;

: r \ 中心 到 x,y 距離

x cx - 2 \*\* y cy - 2 \*\* + sqrt ;

( 例09 .5 半徑 圓

r .5 < \ )

: 內 ( r v -- 區 ) < ; \ r<v 區

( 例10 .3 半徑 圓

r .3 內 \ )

: 外 ( r v -- 區 ) > ; \ r>v 區

( 例11 .3 半徑 洞

r .3 外 \ )

: 間 ( x L U -- 區 ) \ x 在 L U 間

>r over r> < >r > r> and ;

( 例12 .3 到 .4 半徑的圈

r .3 .4 間 \ )

: a \ 中心 到 x,y 角度

y cy - x cx - atan2 2pi / 1 mod ;

( 例13 0 ~ 36 度 角

\ 註 值 1 對應 360度

a .1 < \ )

( 例14 改以 36 度 為 角 的起點

\ 註 值 1 對應 360度

a .1 - 1 mod \ )

: 中圓 ( v -- 圓 ) r > ;

( 例15 .3 半徑的 中心圓

.3 中圓 \ )

: 中洞 ( v -- 洞 ) r < ;

( 例16 .3 半徑的 中心洞

.3 中洞 \ )

: 線徑 .01 ;

: 線 ( r v d - 線 ) \ r=v線, d粗細

>r - abs r> < ;

( 例17 .3 半徑的 中心圈

r .3 線徑 2 / 線 \ )

: 中圈 ( v -- 圈 )

r 線徑 2 / 線 ;

( 例18 .3 半徑的 中心圈

.3 中圈 \ )

: 反 ( v -- 1-v ) \ 亮度 0 1 反轉

1 swap - ;

( 例19 亮度 從 左 1 到 右 0

x 反 \ )

: 暈 ( r v -- 暈 ) \ r=v暈

- .2 \*\* 反 ;

( 例20 半徑 .3 有光暈的圈

r .3 暈 \ )

: 層 ( v n -- v ) \ v 的 n 層 對應

dup >r \* dup 1 mod - r> 1 - / ;

( 例21 亮度 左 0 到 右 1 分 10 層

x 10 層 \ )

( 例22 亮度 隨角 0 到 1 分 8 層

a 8 層 \ )

: 層格 ( x y n -- v )

\ x,y 的 n\*n 層格 對應

dup >r 層 swap r> 層 + 2 / ;

( 例23 沿 x y 變亮度 各分 8 層

x y 8 層格 \ )

( 例24 沿 a r 變亮度 各分 8 層

a r 8 層格 \ )

: 摺 ( v n -- v ) \ v 的 n 摺 對應

\* 1 mod ;

( 例25 x 分 5 區 亮度各從 0 到 1

x 5 摺 \ )

( 例26 x+y 分 5 區 亮度各從 0 到 1

x y + 2 / 5 摺 \ )

( 例27 r a 各自 經特別摺法後 比較

r 9 \*\* 599 \* a 4 摺 > \ )

( 例28 r a 各分 5 區 各取 <

r 1.19 摺 a 1.333 摺 > \ )

( 例29 r a 各 8 區亮度 各從 0 到 1

r 8 摺 a 8 摺 < \ )

: 摺格 ( x y n -- v )

\ x,y 的 n\*n 摺格 對應值

dup >r 摺 swap r@ 摺 \*

r@ 2 \* r> / \* ;

( 例30 x y 各 8 區亮度 都從 0 到 1

x y 8 摺格 \ )

( 例31 r a 各 8 區亮度 都從 0 到 1

r a 8 摺格 \ )

: 移 ( x n -- v ) - ; \ x=0 移 n

( 例32 x .1 移 使值域變 -.1 到 .9

: x x .1 移 ;

x 0 < \ )

: 放 ( x n -- v ) \* ; \ x區放n倍

( 例33 x 2 放 使值域變 0 到 2

: x x 2 放 ;

x .2 < \ )

: 縮 ( x n -- v ) / ; \ x區縮n倍

( 例34 x 2 縮 使值域變 0 到 .5

: x x 2 縮 ;

x .05 < \ )

( 例35 另類表示 x .4 .6 間

x cx 移 abs .1 內 \ )

: 矩 ( x0 y0 w h -- 矩 )

2 / >r y rot 移 abs r> < >r

2 / swap x 移 abs > r> and ;

( 例36 .4 寬 .3 高 p0 的 矩形

: p0 .5 .5 ; p0 .4 .3 矩 \ )

: 方 ( x0 y0 d -- 方 ) dup 矩 ;

( 例37 邊長 .4 在中心的 方形

: p0 .5 .5 ; p0 .4 方 \ )

: 距 ( x0 y0 -- 距 ) \ p0 到 p 距

y - 2 \*\* swap x - 2 \*\* + sqrt ;

( 例38 在 p0 的 .4 半徑 圓

: p0 .5 .5 ; p0 距 .4 內 \ )

: 角 ( x0 y0 -- 角 ) \ p0 到 p 角

y swap - swap x swap - atan2

2pi / 1 mod ;

( 例39 在 p0 的 36度 角

: p0 .5 .5 ; p0 角 .1 內 \ )

: 垂直線 ( x1 -- 線 )

x 線徑 2 / 線 ;

( 例40 在 x=.3 的 垂直線

.3 垂直線 \ )

: 水平線 ( y1 -- 線 )

y 線徑 2 / 線 ;

( 例41 在 y=.6 的 水平線

.6 水平線 \ )

: 兩點斜率 ( p1 p2 -- 斜率 )

rot - ( x1 x2 y2-y1 )

-rot - ( y2-y1 x1-x2 ) / ;

: y軸截點 ( x1 y1 斜率 -- y軸截點 )

rot \* + ;

( 例42 過 y軸截點 指定斜率 的 線

: p1 .2 .1 ; : p2 .8 .9 ;

p1 p1 p2 兩點斜率

dup >r

y軸截點 r@ x \* - y

線徑 2 /

r> 2 \*\* 1 + sqrt \*

線 \ )

: 兩點線 ( p1 p2 -- 線 )

>r over r> ( p1 x2 y1 y2 )

- >r ( p1 x2 ; -dy )

>r over r> ( p1 x1 x2 ; -dy )

swap - ( p1 dx ; -dy ) dup

If \ dx<>0 非 垂直線 也非 一個點

r> swap ( p1 -dy dx )

/ ( p1 斜率 ) dup >r

y軸截點 r@ x \* - y

線徑 2 / r> 2 \*\* 1 + sqrt \* 線

else ( p1 dx ; -dy )

drop r> ( p1 -dy )

if drop ( x1 ) 垂直線

else ( p1 )

水平線 swap ( 線 x1 )

垂直線 \* \ 交點

then

then ;

( 例43 兩點線 垂直線 水平線 兩交點

: x1 .1 ; : y1 .4 ;

: x2 .6 ; : y2 .8 ;

: p1 x1 y1 ; : p2 x2 y2 ;

: p3 x1 y2 ; : p4 x2 y1 ;

0

p1 p2 兩點線 +

0

p1 p3 兩點線 +

\ x1 垂直線 +

p2 p4 兩點線 +

\ x2 垂直線 +

p1 p4 兩點線 +

\ y1 水平線 +

p2 p3 兩點線 +

\ y2 水平線 +

0

p1 p1 兩點線 +

p2 p2 兩點線 + \ )

: 點角向 ( x1 y1 a -- 圖 )

.25 - \ 向上

1 mod

2pi \* \ 值域 -pi 到 pi

>r y - swap x - atan2 r> +

pi + cos ;

: 點角線 ( x0 y0 a -- 圖 )

.25 - \ 向上

1 mod

2pi \* \ 值域 -pi 到 pi

>r

2dup r@ 點角向

-rot swap \ m y0 x0

r@ sin x rot - \* \ m y0 fx

swap \ m fx y0

r> cos y rot - \* \ m fx fy

+ abs 1 - 線粗 2 / - 15000 \*\*

\* ;

( A. 圓圈洞 與 紅綠藍透

.1 中圓 \ 半徑 0.1 中心圓 R

.2 中圈 \ 半徑 0.2 中心圈 G

.3 中洞 \ 半徑 0.3 中心洞 B

.4 中圓 \ 半徑 0.4 中心圓 A

\ 建議: 數值 測試區間 0.0 到 0.5 )

( B. 距角內外間反

\ 距 \ 點 到 任意位置 距離

\ 角 \ 點 到 任意位置 角度

p0 距 .2 內 \ 半徑 0.2 中心圓 R

p0 距 .3 外 \ 半徑 0.3 中心洞 G

p0 角 0 .1 間 \ 角度 -180 到 36 B

.4 中洞 反 \ 半徑 0.4 中心圓 A

\ 註1 洞 反 即是 圓, 圓 反 即是 洞

\ 註2 紅藍重疊變 紫, 綠藍重疊變 青

\ 建議: p0 距 測試區間 0.0 到 0.5

\ 建議: p0 角 測試區間 0.0 到 1.0 )

( C. xy 間方

\ x 左右 0 到 1

\ y 下上 0 到 1

p0 .2 方 \ 紅 cx,cy 心 .2 方

x .3 .7 間 \ 綠

y .3 .7 間 \ 藍

p0 .8 方 \ 透 cx,cy 心 .4 方

\ 建議: p q 測試區間 -0.5 到 0.5

\ 建議: x y 測試區間 0.0 到 1.0 )

( D. xyrapq距角 層格摺格

p0 距 sin p0 角 t sin - 5 摺 +

\ y

x 3 摺 y 3 摺 + 2 /

\ x y 9 摺格

\ x 9 層 y 9 層 + 2 /

\ x y 9 層格

\ x y + 2/

\ p0 距 p0 角 9 摺格

\ p0 距 9 摺 p0 角 9 摺 \*

\ p0 距 p0 角 9 層格

\ p0 距 9 層 p0 角 9 層 \* \ )

( E. 風扇

\ p0 角 t 移 3 摺 \ 3葉扇正轉

\ p0 角 t 負 移 3 摺 \ 3葉扇反轉

: 風扇

p0 角 t 5 / - 4 摺 \ 4紅葉正轉

dup \ 綠 \ 與紅重疊變黃

0 \ 無 藍

p0 距 8 層 反 .45 中圓 \* \ 透視

; 風扇 \ )

( F. x 函數 等於 y 隨 t 移 的線

: t t 5 縮 ; \ t 區縮小 5 倍

: x x t 移 ; \ x 原點 隨 t 移

: x x 2pi 放 ; \ x 區放大

: y y .5 移 ; \ y 原點 移到中間

: y y 5 放 ; \ y 區放大 5 倍

: f x sin ; \ f 為 x 的 函數

f y .01 線 \ f 等於 y 的線

f y 暈 \ f 等於 y 的暈

\ 建議: 改變縮放倍數測試效果 )

( G. 時鐘

: 秒 t floor ; \ 捨小數 取整數

: 分 t 60 / ;

: 時 t 3600 / ;

: r \ 中心到 x,y 的距離, 1 到邊

x .5 - dup \* y .5 - dup \*

+ sqrt ;

: a \ 中心到 x,y 的角度, 0 到 1

y .5 - x .5 - atan2

pi + pi / 2 / ;

\ 中心發 角 t 線

: 格 \ t n -- 線

/ .25 - \ 0 向上

2pi \* \ 值域 -pi 到 pi

>r \ 角度儲存備用

r@ sin x .5 - \*

r@ cos y .5 - \*

+ abs 1.005 - 150 \*\* \ 角a 心線

r> 2pi / a + .5 - 2pi \* cos \*

; \ 去 角a+pi 線

: 秒針

秒 60 格 \ 每秒走 1/60 圈

r .05 .37 間 \* \ 秒針起訖端點

r .03 .05 間 + \ 中心紅圈

; 秒針 \ 顯示 紅色秒針

: 秒標 60 2pi \* \ 60 週期

a \* cos \ 餘旋波

.93 > \ 振幅大於.93 設定 時標 長

r .41 .43 間 \* \ 設定 秒標 寬

; 秒標 + \ 紅色秒標

: 分針

分 60 格 \ 每分走 1/60 圈

r .07 .32 間 \* \ 分針起訖端點

r .05 .07 間 + \ 中心綠圈

; 分針 \ 顯示 綠色分針

: 時標 12 2pi \* \ 12 週期

a \* cos \ 餘旋波

.97 > \ 振幅大於.97 設定 時標 長

r .41 .425 間 \* \ 設定 時標 寬

; 時標 + \ 綠色時標

: 時針

時 12 格 \ 每時走 1/12 圈

r .09 .3 間 \* \ 時針起訖端點

r .07 .09 間 + \ 中心藍圈

; 時針 \ 顯示 藍色時針

: 框 \ v -- 框

x y \* .001 > \* \ 右下黑

x 反 y \* .001 > \* \ 左下黑

x y 反 \* .001 > \* \ 右上黑

x 反 y 反 \* .001 > \* \ 左上黑

;

.5 框 \ 亮度 .5

\ 藍色盤面 \\\\\\\\\\\\\\\\\\\

.3 \ 亮度 .3

x y \* .009 > \* \ 右下紅

x 反 y \* .009 > \* \ 左下紅

x y 反 \* .009 > \* \ 右上紅

x 反 y 反 \* .009 > \* \ 左上紅

+ \ 增中間亮度為 .8

.2 \ 綠色亮度 .2

x y \* .022 > \* \ 右下紅

x 反 y \* .022 > \* \ 左下紅

x y 反 \* .022 > \* \ 右上紅

x 反 y 反 \* .022 > \* \ 左上紅

+ \ 增中間紅色亮度為 1

r .39 > \*

+ \ 半徑 .39 洞

1 框 \ )

( H 從點 x,y 向角 a 發出的線

: x1 .1 ; : y1 .4 ; : p1 x1 y1 ;

: x2 .6 ; : y2 .8 ; : p1 x2 y2 ;

: a1 x2 x1 - y2 y1 - atan2

2pi / ;

\ 紅色參考格線

x 10 摺 .05 <

y 10 摺 .05 < +

\ 紅色點角線

\ .5 .5 a1 點角線 +

\ 綠色兩點線

\ x1 y1 x2 y2 兩點線

\ 藍色兩點區間

\ x1 y1 a1 .5 + 點角向

\ x2 y2 a1 點角向 \* \* \ )

\ I 國旗飄揚

\ ( I1 旗桿左右移動 週期 20 秒

: x x t 20 / sin 2 + 8 / - ; \ )

: 桿 x 0 > x .02 < \*

x .01 - 2 \*\* y .98 - 2 \*\* +

sqrt .02 < + ;

\ ( I2 改 x y 值域 0 到 2

: x x 2 \* ; : y y 2 \* ; \ )

\ ( I3 國旗上下升降 週期 8 秒

: y y t 8 / sin 1 + 2 / - ; \ )

\ ( I4 國旗迎風飄動

: y x 3 / t 6 / pi 8 /

mod - pi \* 10 \*

cos 40 / \ 水平波動 dy

y + 1.1 \* ; \ )

\ ( I5 改值域 x 0 到 4, y -3 到 1

: x x 2 \* ; : y y 2 \* 1 - ; \ )

: r \ 日心 到 x,y 距離

x .5 - 2 \*\*

y .5 - 2 \*\* + sqrt ;

: θ \ 日心 到 x,y 角 徑度

x .5 - y .5 - atan2 ;

: n 12 ;

: α \ n角星 內頂角 徑度 的 一半

pi 9 / ; \ 改 9 為 2 即 n邊形

: a 2 pi \* n / ; : h a 2 / ;

: β \ n 道 光芒

θ a mod h - abs ;

: n角星 α sin .3 \*

α cos β sin \* β cos α sin \* +

/ r > ;

: 洞 r .17 > ; : 圓 r .1 < ;

: 日

n角星

洞 \*

圓 + ;

: 天 y 0 > y .9 < \*

x .1 > \* x 1 < \* ;

: 地 1 天 - y abs .9 < \*

x .1 > \* x 2 < \* ;

: 幽暗大地 0 0 0 ; \ RGB 亮度歸零

: 藍天晨曦 \ 加 右上角 藍天晨曦

x y + .1 \* + ;

: 綠野山嵐 \ 加 左下角 綠野山嵐

swap

.1 x y + 2 / .1 \* - +

swap ;

: 國旗飄揚 \ 青天白日滿地紅

rot 日 + 地 +

rot 日 +

rot 天 + ;

: 升上桿頭 \ 升上 白色旗桿

rot 桿 +

rot 桿 +

rot 桿 + ;

\ ( I6 範例展示

幽暗大地

藍天晨曦

綠野山嵐

國旗飄揚

升上桿頭 \ )

\ )