Міністерство освіти і науки України

Національний технічний університет України

«Київський політехнічний інститут»

Факультет прикладної математики

Кафедра системного програмування та спеціалізованих комп’ютерних систем

Комплекс лабораторних робіт

з дисципліни

«Комп’ютерні системи автоматичної ідентифікації»

Виконав студент групи КВ-83мн

Савицький Т. П.

Перевірив \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

Київ 2019

Interleaved 2 of 5 (ITF) є двовимірними числовими кодами, які можуть кодувати інформацію будь-якої довжини, доки в коді є парне число цифр. Інформація кодується на основі ширини смуг і пробілів, і рівно 2 з кожних 5 барів є широкими. Штрих-коди ITF зазвичай використовуються для ідентифікації розподілу та складу. Наприклад, коробки або ящики, які самі містять предмети зі своїми штрих-кодами UPC. Крім того, вони часто використовуються для позначення типу плівки «135».

Технічні характеристики: Штрих-код Interleaved 2 of 5 починається з характерним початковим символом. Далі йдуть закодовані дані, за якими йдуть додаткові контрольні цифри, і стоп-символ. Штрих-код ITF може кодувати парну кількість цифр, оскільки кожен символ складається з двох перемежовуваних цифр. Якщо код має непарну кількість цифр, до фронту штрих-коду додається нуль.

Переваги: ​​Штрих-код Interleaved 2 з 5 може кодувати більше інформації, ніж звичайний код 2 з 5, оскільки він використовує проміжки, а також самі бари. Крім того, він самоконтролюється і не вимагає контрольної цифри.

Недоліки: не може кодувати букви, тільки цифри.

Алгоритм:

1. Перша цифра пари кодується 5 чорними смугами, а друга цифра - 5 білими;
2. Смуги можуть бути тонкими або товстими;
3. Серед 5 барів завжди є 2 товсті бари;
4. 2 спеціальні символи використовуються як розділювач початку і кінця;
5. Контрольна сума може бути додана; Ось метод розрахунку:

* Цифри нумеруються справа наліво, потім обчислюється X суми парних цифр і Y сума непарних цифр.
* Розрахуємо Z = X + 3 \* Y
* Нехай M число, ділене на 10, безпосередньо перевищує Z
* Контрольна сума: M - Z

1. У наступній таблиці вузькі смуги символізуються символом "N", а товсті - "W".


Приклад контрольної суми для: 65732

|  |  |
| --- | --- |
| Значення | Кодування |
| 0 | NNWWN |
| 1 | WNNNW |
| 2 | NWNNW |
| 3 | WWNNN |
| 4 | NNWNW |
| 5 | WNWNN |
| 6 | NWWNN |
| 7 | NNNWW |
| 8 | WNNWN |
| 9 | NWNWN |

(2 + 7 + 6) x 3 + 3 + 5 = 53 ---> M = 60

60 - 53 = 7

Новий код з контрольною сумою: 657327 (Зауважте, що кількість цифр, включаючи контрольну суму, рівна.)



Public Function Code25I$(chaine$, Optional key As Boolean)

  'V 2.0.0

  'Parametres : \* une chaine

  '             \* un drapeau vrai si une cle doit etre ajoutee

  'Parameters : \* a string

  '             \* a flag true if a key must be added

  'Retour : \* une chaine qui, affichee avec la police CODE25I.TTF, donne le code barre

  '         \* une chaine vide si parametre fourni incorrect

  'Return : \* a string which give the bar code when it is dispayed with CODE25I.TTF font

  '         \* an empty string if the supplied parameter is no good

  Dim i%, checksum&, dummy%

  Code25I$ = ""

  If Len(chaine$) > 0 Then

    'Verifier si caracteres valides

    'Check for valid characters

    For i% = 1 To Len(chaine$)

      If Asc(Mid$(chaine$, i%, 1)) < 48 Or Asc(Mid$(chaine$, i%, 1)) > 57 Then Exit Function

    Next

    'Ajouter si necessaire la cle

    'Add if necessary the checksum

    If key Then

      For i% = Len(chaine$) To 1 Step -2

        checksum& = checksum& + Val(Mid$(chaine$, i%, 1))

      Next

      checksum& = checksum& \* 3

      For i% = Len(chaine$) - 1 To 1 Step -2

        checksum& = checksum& + Val(Mid$(chaine$, i%, 1))

      Next

      chaine$ = chaine$ & (10 - checksum& Mod 10) Mod 10

    End If

    'Verifier si la longueur est paire

    'Check if the length is odd

    If Len(chaine$) \ 2 <> Len(chaine$) / 2 Then Exit Function

    'Calculer la chaine de code

    'Calculation of the code string

    For i% = 1 To Len(chaine$) Step 2

      dummy% = Val(Mid$(chaine$, i%, 2))

      dummy% = IIf(dummy% < 94, dummy% + 33, dummy% + 101)

      Code25I$ = Code25I$ & Chr$(dummy%)

    Next

    'Ajoute START et STOP / Add START and STOP

    Code25I$ = Chr$(201) & Code25I$ & Chr$(202)

  End If

End Function