Sub DeleteFromArray(ByRef InputArray As Variant, ByVal DeleteValue As Variant, \_

Optional ByVal StartIndex As Long = 0, Optional ByVal StopIndex As Variant)

'---------------------------------------------------------------------------------------

' Procedure : DeleteFromArray

' Author : Adiv

' Date : 09/26/2018

' Purpose : Remove specified value from specified array between specified start

' : and stop indexes.

' : Return Null if no more elements remain after deletion

' :

' Versions : 1.0 09/26/2018 - Adiv Abramson

' :

'---------------------------------------------------------------------------------------

'Numerics:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim i As Long

Dim lngHighIndex As Long

Dim lngLowIndex As Long

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Arrays:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim arNew As Variant

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

10 On Error GoTo ErrProc

'========================================================

'Validate inputs.

'========================================================

20 If IsEmpty(InputArray) Or IsNull(InputArray) Then Exit Sub

30 If Not IsArray(InputArray) Then Exit Sub

'========================================================

'Get lower and upper bounds of input array and compare

'against specified start and stop indexes to ensure the

'they are within bounds.

'========================================================

40 lngLowIndex = LBound(InputArray)

50 lngHighIndex = UBound(InputArray)

60 If StartIndex < lngLowIndex Or StartIndex > lngHighIndex Then Exit Sub

70 If Not IsMissing(StopIndex) Then

80 If Not IsNumeric(StopIndex) Then Exit Sub

90 If StopIndex < lngLowIndex Or StopIndex > lngHighIndex Or StopIndex < StartIndex Then Exit Sub

100 Else

110 StopIndex = lngHighIndex

120 End If

130 arNew = Null

140 For i = lngLowIndex To lngHighIndex

150 If i >= StartIndex And i <= StopIndex Then

160 If InputArray(i) <> DeleteValue Then

170 AddToArray DataArray:=arNew, InputValue:=InputArray(i), KeepUnique:=False

180 End If

190 Else

200 AddToArray DataArray:=arNew, InputValue:=InputArray(i), KeepUnique:=False

210 End If 'i >= StartIndex And i <= StopIndex

220 Next i

230 InputArray = arNew

240 Exit Sub

ErrProc:

250 MsgBox "Error " & Err.Number & " (" \_

& Err.Description & ") in procedure DeleteFromArray of " & MODULE\_NAME

End Sub