Public Function GetArrayInfo(ByVal DataArray As Variant) As Dictionary

'---------------------------------------------------------------------------------------

' Procedure : GetArrayInfo

' Author : Adiv Abramson

' Date : 06/10/2022

' Purpose : Generates dictionary with the following keys:

' :

' : CountAll, CountOfStrings, CountOfNumbers, CountOfVariants, CountOfBooleans

' : For string elements: Shortest, Longest

' : For numeric elements: Smallest, Largest

' : Strings - array of string elements, if any

' : Numbers - array of numeric elements, if any

' : Booleans - array of Boolean elements, if any

' : Variants - array of all other elements, if any

' :

' Versions : 1.0 - 06/10/2022 - Adiv Abramson

' :

'---------------------------------------------------------------------------------------

'Strings:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim strDataType As String

Dim strKey As String

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Numerics:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim lngMaxLength As Long

Dim lngMinLength As Long

Dim dblMinValue As Double

Dim dblMaxValue As Double

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Arrays:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim arStrings As Variant

Dim arNumbers As Variant

Dim arBooleans As Variant

Dim arVariants As Variant

Dim arLengths As Variant

Dim arArrays As Variant

Dim arData As Variant

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Objects:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim dictArrayInfo As Dictionary

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Variants:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim vntElement As Variant

Dim vntValue As Variant

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

10 On Error GoTo ErrProc

20 Set GetArrayInfo = Nothing

'========================================================

'Validate DataArray

'========================================================

30 If IsNull(DataArray) Then Exit Function

40 If IsEmpty(DataArray) Then Exit Function

50 If Not IsArray(DataArray) Then Exit Function

60 If LBound(DataArray) = -1 Then Exit Function

'========================================================

'Populate array for each data type, if any elements for

'it exist.

'========================================================

70 arStrings = Null

80 arNumbers = Null

90 arBooleans = Null

100 arVariants = Null

110 arArrays = Null

120 arLengths = Null

130 For Each vntElement In DataArray

140 strDataType = TypeName(vntElement)

150 Select Case strDataType

Case "String"

160 AddToArray DataArray:=arStrings, InputValue:=vntElement, KeepUnique:=False

170 Case "Double", "Long", "Integer"

180 AddToArray DataArray:=arNumbers, InputValue:=vntElement, KeepUnique:=False

190 Case "Boolean"

200 AddToArray DataArray:=arBooleans, InputValue:=vntElement, KeepUnique:=False

210 Case Else

220 AddToArray DataArray:=arVariants, InputValue:=vntElement, KeepUnique:=False

230 End Select

240 Next vntElement

250 Set dictArrayInfo = New Dictionary

'========================================================

'Compute stats

'========================================================

260 If Not IsNull(arStrings) Then

270 For Each vntElement In arStrings

280 vntValue = Len(vntElement)

290 AddToArray DataArray:=arLengths, InputValue:=vntValue, KeepUnique:=True

300 Next vntElement

310 lngMinLength = Application.WorksheetFunction.Min(arLengths)

320 lngMaxLength = Application.WorksheetFunction.Max(arLengths)

330 dictArrayInfo.Item("Shortest") = lngMinLength

340 dictArrayInfo.Item("Longest") = lngMaxLength

350 End If 'Not IsNull(arStrings)

360 If Not IsNull(arNumbers) Then

370 dblMinValue = Application.WorksheetFunction.Min(arNumbers)

380 dblMaxValue = Application.WorksheetFunction.Max(arNumbers)

390 dictArrayInfo.Item("Smallest") = dblMinValue

400 dictArrayInfo.Item("Largest") = dblMaxValue

410 End If 'Not IsNull(arNumbers)

'========================================================

'Add overall stats to dictionary

'========================================================

420 arArrays = Array(Array("Strings", arStrings), \_

Array("Numbers", arNumbers), \_

Array("Booleans", arBooleans), \_

Array("Variants", arVariants))

430 With dictArrayInfo

440 For Each vntElement In arArrays

450 strDataType = vntElement(0)

460 strKey = "CountOf" & strDataType

470 arData = vntElement(1)

480 If Not IsNull(arData) Then

490 .Item(strKey) = UBound(arData) + 1

500 .Item(strDataType) = arData

510 Else

520 .Item(strKey) = 0

530 .Item(strDataType) = Null

540 End If 'Not IsNull(arData)

550 Next vntElement

560 End With

570 With dictArrayInfo

580 .Item("CountAll") = UBound(DataArray) + 1

590 End With

600 Set GetArrayInfo = dictArrayInfo

610 Exit Function

ErrProc:

620 Set GetArrayInfo = Nothing

630 MsgBox "Error " & Err.Number & " (" & Err.Description & ") at line " \_

& Erl & " in procedure GetArrayInfo of Module " & MODULE\_NAME

End Function