Public Function GetArraySlice(ByVal InputArray As Variant, \_

ByVal StartIndex As Long, \_

ByVal StopIndex As Long, \_

Optional ByVal DELIMITER As Variant) As Variant

'---------------------------------------------------------------------------------------

' Procedure : GetArraySlice

' Author : Adiv Abramson

' Date : 03/15/2019

' Purpose : Mimics Python's sequence slicing method.

' : Returns the elements of the specified array from StartIndex up to and

' : including StopIndex. Optionally delimit the elements of the returned array

' : (1.1) Now able to detect empty dynamic array.

' :

' Versions : 1.0 - 03/15/2019 - Adiv Abramson

' : 1.1 - 09/24/2024 - Adiv Abramson

' :

'---------------------------------------------------------------------------------------

'Numerics:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim i As Long

Dim lngUbound As Long

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Variants:

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim arOutput As Variant

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

10 On Error GoTo ErrProc

20 GetArraySlice = Null

'========================================================

'Validate input array

'========================================================

30 If IsNull(InputArray) Then

40 Exit Function

50 ElseIf Not IsArray(InputArray) Then

60 Exit Function

70 End If

'========================================================

'NEW CODE: 09/24/2024 If input array is an empty dynamic

'array, exit early.

'========================================================

80 On Error Resume Next

90 lngUbound = UBound(InputArray)

100 If Err <> 0 Then

110 Err.Clear

120 Exit Function

130 End If

140 On Error GoTo ErrProc

'========================================================

'Validate start and stop indexes

'========================================================

150 If StartIndex < 0 Then

160 Exit Function

170 ElseIf StopIndex < 0 Then

180 Exit Function

190 ElseIf StopIndex < StartIndex Then

200 Exit Function

210 ElseIf StartIndex < LBound(InputArray) Then

220 Exit Function

230 ElseIf StartIndex > UBound(InputArray) Then

240 Exit Function

250 ElseIf StopIndex > UBound(InputArray) Then

260 StopIndex = UBound(InputArray)

270 ElseIf Not IsMissing(DELIMITER) Then

280 If Trim(DELIMITER) = "" Then

290 Exit Function

300 End If

310 End If 'IsNull(InputArray)

320 For i = StartIndex To StopIndex

330 If IsMissing(DELIMITER) Then

340 AddToArray arOutput, InputArray(i), False

350 Else

360 AddToArray arOutput, DELIMITER & CStr(InputArray(i)) & DELIMITER, False

370 End If 'IsMissing(Delimiter)

380 Next i

390 GetArraySlice = arOutput

400 Exit Function

ErrProc:

410 GetArraySlice = Null

420 MsgBox "Error " & Err.Number & " (" & Err.Description & ") in line " \_

& Erl & " of procedure GetArraySlice of Module mdlUtil"

End Function