;; 1. Based on: EPA\_Model1

;; 2. Description: CITN-05 study (Model by Shi et al.)

;; x1. Author: user

;; 3. Label:

$PROBLEM PKPD model for epacadostat

$INPUT C ID STUDYDAY TIME AMT DV CMT FLG EVID MDV BLQ TRP AGE RACE WTKG BMI STAGE SITE

$DATA CITN-05\_NM\_dataset\_wdemo\_pkpd.csv IGNORE=C

$SUBROUTINES ADVAN13 TOL=9

$MODEL

COMP = (SCDEP)

COMP = (CENTRAL)

COMP = (PERI,NODOSE)

COMP = (EFFECT,NODOSE)

$PK

;--- PK PARAMETERS ---

KA = THETA(1) \* EXP(ETA(1))

TLAG = 0.1 ; h-1

CL = THETA(2) \* EXP(ETA(2)) \* (WTKG/87.4)\*\*0.75

VC = THETA(3) \* EXP(ETA(3)) \* (WTKG/87.4)\*\*1

VP = THETA(4)

CLD = THETA(5) \* EXP(ETA(4))

;--- PD PARAMETERS ---

K1 = THETA(6) \* EXP(ETA(5))

K2 = THETA(7)

KDEG = THETA(8) \* EXP(ETA(6))

ISD15 = 0

IF (STUDYDAY.GE.15) THEN

ISD15=1

ENDIF

IC50 = (1 - ISD15) \* THETA(9) + ISD15 \* THETA(10)

IC50\_1=THETA(9)

IC50\_15=THETA(10)

KYN = TRP \* (K1 + K2)/KDEG

; ------INITIAL CONDITIONS FOR COMPARTMENTS------

A\_0(1) = 0 ; SC DEPOT

A\_0(2) = 0 ; PLASMA

A\_0(3) = 0 ; PERIPHERAL

A\_0(4) = KYN ; KYN

$DES

KEL = CL/VC

K12 = CLD/VC

K21 = CLD/VP

IF (TIME.LT.TLAG) THEN

DADT(1) = 0

DADT(2) = 0

DADT(3) = 0

ELSE

DADT(1) = -KA \* A(1)

DADT(2) = KA \* A(1) - KEL \* A(2) - K12\* A(2) + K21 \* A(3)

DADT(3) = K12\* A(2) - K21 \* A(3)

ENDIF

CP = A(2)/VC

; conversion from mg/L to nM

CPnm = CP/438.232\*(10\*\*6)

IMAX = 1

HILL = 1

INH = IMAX \* (CPnm\*\*HILL) / (IC50\*\*HILL + CPnm\*\*HILL)

DADT(4) = TRP \* (K1 - INH \* K1 + K2) - A(4) \* KDEG

$ERROR

IF (FLG.EQ.0) THEN

IPRED=((A(2)/VC)/438.232)\*(10\*\*6)

Y = IPRED\*EXP(EPS(1))

IRES = DV-IPRED

ENDIF

IF (FLG.EQ.1) THEN

IPRED=A(4)

Y = IPRED\*(1+EPS(2))

IRES = DV-IPRED

ENDIF

W=1

IF (IPRED.GT.0) THEN

W=IPRED

ENDIF

IWRES=IRES/W

$THETA

;-- PK thetas --

(0.582) ; THETA1 KA, h-1

(49.3) ; THETA2 CL/F, L/h

(152) ; THETA3 Vc/F, L

(888) ; THETA4 Vp/F, L

(27.7) ; THETA5 CLD, L/h

;-- PD thetas ---

(0.00447) ; THETA6 K1, h-1

(0.00330) ; THETA7 K2, h-1

(0.238) ; THETA8 KDEG, h-1

(167) ; THETA9 IC50 Day 1, uM

(70.4) ; THETA10 IC50 Day 15, uM

$OMEGA

0.0424 ; ETA1 IIV\_KA

0.16 ; ETA2 IIV\_CL/F

0.0708 ; ETA3 IIV\_VC

0.526 ; ETA4 IIV\_CLD

0.503 ; ETA5 IIV\_K1

0.194 ; ETA6 IIV\_KDEG

$SIGMA

0.185 ; EPS1 (PK)

0.0185 ; EPS2 (PD)

$EST METHOD=1 INTER MAXEVAL=0 POSTHOC

$TABLE ID TIME DV MDV EVID FLG IPRED IRES CWRES ONEHEADER NOPRINT FILE=sdtabcitn-focei

$TABLE ID KA CL VC VP CLD K1 K2 KDEG IC50 IC50\_1 IC50\_15 ONEHEADER NOPRINT FILE=patabcitn-focei

$TABLE ID ETA1 ETA2 ETA3 ETA4 ETA5 ETA6 ONEHEADER NOPRINT FILE=etatabcitn-focei