Skip to content

HTTPS clone URL

Subversion checkout URL

You can clone with HTTPS or Subversion.

Download ZIP
Browse files

added new files for setup

  • Loading branch information...
commit 40e88aa47b21ad007c59f22bf5b96de2e04a2243 1 parent 3554d45
sergio authored
Showing with 569 additions and 0 deletions.
  1. +230 −0 autoload/pathogen.vim
  2. +241 −0 plugin/hashrocket.vim
  3. +98 −0 vimrc
230 autoload/pathogen.vim
View
@@ -0,0 +1,230 @@
+" pathogen.vim - path option manipulation
+" Maintainer: Tim Pope <http://tpo.pe/>
+" Version: 2.0
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `call pathogen#infect()` to your .vimrc
+" prior to `fileype plugin indent on` is the only other setup necessary.
+"
+" The API is documented inline below. For maximum ease of reading,
+" :set foldmethod=marker
+
+if exists("g:loaded_pathogen") || &cp
+ finish
+endif
+let g:loaded_pathogen = 1
+
+" Point of entry for basic default usage. Give a directory name to invoke
+" pathogen#runtime_append_all_bundles() (defaults to "bundle"), or a full path
+" to invoke pathogen#runtime_prepend_subdirectories(). Afterwards,
+" pathogen#cycle_filetype() is invoked.
+function! pathogen#infect(...) abort " {{{1
+ let source_path = a:0 ? a:1 : 'bundle'
+ if source_path =~# '[\\/]'
+ call pathogen#runtime_prepend_subdirectories(source_path)
+ else
+ call pathogen#runtime_append_all_bundles(source_path)
+ endif
+ call pathogen#cycle_filetype()
+endfunction " }}}1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+ if type(a:path) == type([]) | return a:path | endif
+ let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+ return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+ if type(a:1) == type(1) && a:1
+ let i = 1
+ let space = ' '
+ else
+ let i = 0
+ let space = ''
+ endif
+ let path = ""
+ while i < a:0
+ if type(a:000[i]) == type([])
+ let list = a:000[i]
+ let j = 0
+ while j < len(list)
+ let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+ let path .= ',' . escaped
+ let j += 1
+ endwhile
+ else
+ let path .= "," . a:000[i]
+ endif
+ let i += 1
+ endwhile
+ return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+ return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+ let i = 0
+ let seen = {}
+ while i < len(a:list)
+ if has_key(seen,a:list[i])
+ call remove(a:list,i)
+ else
+ let seen[a:list[i]] = 1
+ let i += 1
+ endif
+ endwhile
+ return a:list
+endfunction " }}}1
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#separator() abort " {{{1
+ return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+ let files = split(glob(a:pattern),"\n")
+ return map(files,'substitute(v:val,"[".pathogen#separator()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+ return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() " {{{1
+ if exists('g:did_load_filetypes')
+ filetype off
+ filetype on
+ endif
+endfunction " }}}1
+
+" Checks if a bundle is 'disabled'. A bundle is considered 'disabled' if
+" its 'basename()' is included in g:pathogen_disabled[]' or ends in a tilde.
+function! pathogen#is_disabled(path) " {{{1
+ if a:path =~# '\~$'
+ return 1
+ elseif !exists("g:pathogen_disabled")
+ return 0
+ endif
+ let sep = pathogen#separator()
+ return index(g:pathogen_disabled, strpart(a:path, strridx(a:path, sep)+1)) != -1
+endfunction "}}}1
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+ let sep = pathogen#separator()
+ let before = filter(pathogen#glob_directories(a:path.sep."*"), '!pathogen#is_disabled(v:val)')
+ let after = filter(pathogen#glob_directories(a:path.sep."*".sep."after"), '!pathogen#is_disabled(v:val[0:-7])')
+ let rtp = pathogen#split(&rtp)
+ let path = expand(a:path)
+ call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+ let &rtp = pathogen#join(pathogen#uniq(before + rtp + after))
+ return &rtp
+endfunction " }}}1
+
+" For each directory in rtp, check for a subdirectory named dir. If it
+" exists, add all subdirectories of that subdirectory to the rtp, immediately
+" after the original directory. If no argument is given, 'bundle' is used.
+" Repeated calls with the same arguments are ignored.
+function! pathogen#runtime_append_all_bundles(...) " {{{1
+ let sep = pathogen#separator()
+ let name = a:0 ? a:1 : 'bundle'
+ if "\n".s:done_bundles =~# "\\M\n".name."\n"
+ return ""
+ endif
+ let s:done_bundles .= name . "\n"
+ let list = []
+ for dir in pathogen#split(&rtp)
+ if dir =~# '\<after$'
+ let list += filter(pathogen#glob_directories(substitute(dir,'after$',name,'').sep.'*[^~]'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
+ else
+ let list += [dir] + filter(pathogen#glob_directories(dir.sep.name.sep.'*[^~]'), '!pathogen#is_disabled(v:val)')
+ endif
+ endfor
+ let &rtp = pathogen#join(pathogen#uniq(list))
+ return 1
+endfunction
+
+let s:done_bundles = ''
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() " {{{1
+ let sep = pathogen#separator()
+ for dir in pathogen#split(&rtp)
+ if (dir.sep)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir.'/doc') == 2 && !empty(glob(dir.'/doc/*')) && (!filereadable(dir.'/doc/tags') || filewritable(dir.'/doc/tags'))
+ helptags `=dir.'/doc'`
+ endif
+ endfor
+endfunction " }}}1
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#rtpfindfile(file,count) "{{{1
+ let rtp = pathogen#join(1,pathogen#split(&rtp))
+ return fnamemodify(findfile(a:file,rtp,a:count),':p')
+endfunction " }}}1
+
+function! s:find(count,cmd,file,...) " {{{1
+ let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+ let file = pathogen#rtpfindfile(a:file,a:count)
+ if file ==# ''
+ return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+ elseif a:0
+ let path = file[0:-strlen(a:file)-2]
+ execute a:1.' `=path`'
+ return a:cmd.' '.fnameescape(a:file)
+ else
+ return a:cmd.' '.fnameescape(file)
+ endif
+endfunction " }}}1
+
+function! s:Findcomplete(A,L,P) " {{{1
+ let sep = pathogen#separator()
+ let cheats = {
+ \'a': 'autoload',
+ \'d': 'doc',
+ \'f': 'ftplugin',
+ \'i': 'indent',
+ \'p': 'plugin',
+ \'s': 'syntax'}
+ if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+ let request = cheats[a:A[0]].a:A[1:-1]
+ else
+ let request = a:A
+ endif
+ let pattern = substitute(request,'\'.sep,'*'.sep,'g').'*'
+ let found = {}
+ for path in pathogen#split(&runtimepath)
+ let matches = split(glob(path.sep.pattern),"\n")
+ call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+ call map(matches,'v:val[strlen(path)+1:-1]')
+ for match in matches
+ let found[match] = 1
+ endfor
+ endfor
+ return sort(keys(found))
+endfunction " }}}1
+
+command! -bar -bang -count=1 -nargs=1 -complete=customlist,s:Findcomplete Ve :execute s:find(<count>,'edit<bang>',<q-args>)
+command! -bar -bang -count=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit :execute s:find(<count>,'edit<bang>',<q-args>)
+command! -bar -bang -count=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit :execute s:find(<count>,'split<bang>',<q-args>)
+command! -bar -bang -count=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit :execute s:find(<count>,'vsplit<bang>',<q-args>)
+command! -bar -bang -count=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit<bang>',<q-args>)
+command! -bar -bang -count=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit :execute s:find(<count>,'pedit<bang>',<q-args>)
+command! -bar -bang -count=1 -nargs=1 -complete=customlist,s:Findcomplete Vread :execute s:find(<count>,'read<bang>',<q-args>)
+command! -bar -bang -count=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen :execute s:find(<count>,'edit<bang>',<q-args>,'lcd')
+
+" vim:set ft=vim ts=8 sw=2 sts=2:
241 plugin/hashrocket.vim
View
@@ -0,0 +1,241 @@
+" hashrocket.vim
+" vim:set ft=vim et tw=78 sw=2:
+
+if $HASHROCKET_DIR == '' && expand('<sfile>') =~# '/dotmatrix/\.vim/plugin/hashrocket\.vim$'
+ let $HASHROCKET_DIR = expand('<sfile>')[0 : -38]
+endif
+if $HASHROCKET_DIR == '' && filereadable(expand('~/.bashrc'))
+ let $HASHROCKET_DIR = expand(matchstr("\n".join(readfile(expand('~/.bashrc')),"\n")."\n",'\n\%(export\)\=\s*HASHROCKET_DIR="\=\zs.\{-\}\ze"\=\n'))
+endif
+if $HASHROCKET_DIR == ''
+ let $HASHROCKET_DIR = substitute(system("bash -i -c 'echo \"$HASHROCKET_DIR\"'"),'\n$','','')
+endif
+if $HASHROCKET_DIR == ''
+ let $HASHROCKET_DIR = expand('~/hashrocket')
+endif
+
+function! s:HComplete(A,L,P)
+ let match = split(glob($HASHROCKET_DIR.'/'.a:A.'*'),"\n")
+ return map(match,'v:val[strlen($HASHROCKET_DIR)+1 : -1]')
+endfunction
+command! -bar -nargs=1 Hcommand :command! -bar -bang -nargs=1 -complete=customlist,s:HComplete H<args> :<args><lt>bang> $HASHROCKET_DIR/<lt>args>
+
+Hcommand cd
+Hcommand lcd
+Hcommand read
+Hcommand edit
+Hcommand split
+Hcommand saveas
+Hcommand tabedit
+
+command! -bar -nargs=* -complete=dir Terrarails :execute 'Rails --template='.system("ruby -rubygems -e 'print Gem.bin_path(%(terraformation))'") . ' ' . <q-args>
+
+command! -bar -range=% Trim :<line1>,<line2>s/\s\+$//e
+command! -bar -range=% NotRocket :<line1>,<line2>s/:\(\w\+\)\s*=>/\1:/ge
+
+command! -bar -nargs=* -bang -complete=file Rename :
+ \ let v:errmsg = ""|
+ \ saveas<bang> <args>|
+ \ if v:errmsg == ""|
+ \ call delete(expand("#"))|
+ \ endif
+
+command! -bar -nargs=0 -bang -complete=file Remove :
+ \ let v:errmsg = ''|
+ \ let s:removable = expand('%:p')|
+ \ bdelete<bang>|
+ \ if v:errmsg == ''|
+ \ call delete(s:removable)|
+ \ endif|
+ \ unlet s:removable
+
+function! HTry(function, ...)
+ if exists('*'.a:function)
+ return call(a:function, a:000)
+ else
+ return ''
+ endif
+endfunction
+
+set nocompatible
+set autoindent
+set autoread
+set backspace=indent,eol,start
+set complete-=i " Searching includes can be slow
+set display=lastline " When lines are cropped at the screen bottom, show as much as possible
+if &grepprg ==# 'grep -n $* /dev/null'
+ set grepprg=grep\ -rnH\ --exclude='.*.swp'\ --exclude='*~'\ --exclude='*.log'\ --exclude=tags\ $*\ /dev/null
+endif
+set incsearch
+set laststatus=2 " Always show status line
+if &listchars ==# 'eol:$'
+ set listchars=tab:>\ ,trail:-,extends:>,precedes:<,nbsp:+
+endif
+set list " show trailing whiteshace and tabs
+set modelines=5
+set scrolloff=1
+set sidescrolloff=5
+set showcmd
+set showmatch
+set smarttab
+if &statusline == ''
+ set statusline=[%n]\ %<%.99f\ %h%w%m%r%{HTry('CapsLockStatusline')}%y%{HTry('rails#statusline')}%{HTry('fugitive#statusline')}%#ErrorMsg#%{HTry('SyntasticStatuslineFlag')}%*%=%-14.(%l,%c%V%)\ %P
+endif
+set ttimeoutlen=50 " Make Esc work faster
+set wildmenu
+
+if $TERM == '^\%(screen\|xterm-color\)$' && t_Co == 8
+ set t_Co=16
+endif
+
+let g:is_bash = 1 " Highlight all .sh files as if they were bash
+let g:ruby_minlines = 500
+let g:rubycomplete_buffer_loading = 1
+let g:rubycomplete_rails = 1
+
+let g:NERDCreateDefaultMappings = 0
+let g:NERDSpaceDelims = 1
+let g:NERDShutUp = 1
+let g:VCSCommandDisableMappings = 1
+
+let g:surround_{char2nr('s')} = " \r"
+let g:surround_{char2nr(':')} = ":\r"
+let g:surround_indent = 1
+
+
+if !exists('g:w_sleep')
+ let g:w_sleep = 0
+endif
+
+function! s:Wall() abort
+ let sleep = g:w_sleep ? 'sleep '.g:w_sleep.'m' : ''
+ let tab = tabpagenr()
+ let win = winnr()
+ let seen = {}
+ if !&readonly && expand('%') !=# ''
+ let seen[bufnr('')] = 1
+ write
+ endif
+ tabdo windo if !&readonly && expand('%') !=# '' && !has_key(seen, bufnr('')) | exe sleep | silent write | let seen[bufnr('')] = 1 | endif
+ execute 'tabnext '.tab
+ execute win.'wincmd w'
+endfunction
+
+command! -bar W :call s:Wall()
+
+command! -bar -nargs=0 SudoW :setl nomod|silent exe 'write !sudo tee % >/dev/null'|let &mod = v:shell_error
+
+runtime! plugin/matchit.vim
+runtime! macros/matchit.vim
+
+map Y y$
+nnoremap <silent> <C-L> :nohls<CR><C-L>
+inoremap <C-C> <Esc>`^
+
+cnoremap <C-O> <Up>
+inoremap ø <C-O>o
+inoremap <M-o> <C-O>o
+" Emacs style mappings
+inoremap <C-A> <C-O>^
+inoremap <C-X><C-@> <C-A>
+cnoremap <C-A> <Home>
+cnoremap <C-X><C-A> <C-A>
+" If at end of a line of spaces, delete back to the previous line.
+" Otherwise, <Left>
+inoremap <silent> <C-B> <C-R>=getline('.')=~'^\s*$'&&col('.')>strlen(getline('.'))?"0\<Lt>C-D>\<Lt>Esc>kJs":"\<Lt>Left>"<CR>
+cnoremap <C-B> <Left>
+" If at end of line, decrease indent, else <Del>
+inoremap <silent> <C-D> <C-R>=col('.')>strlen(getline('.'))?"\<Lt>C-D>":"\<Lt>Del>"<CR>
+cnoremap <C-D> <Del>
+" If at end of line, fix indent, else <Right>
+inoremap <silent> <C-F> <C-R>=col('.')>strlen(getline('.'))?"\<Lt>C-F>":"\<Lt>Right>"<CR>
+inoremap <C-E> <End>
+cnoremap <C-F> <Right>
+
+noremap <F1> <Esc>
+noremap! <F1> <Esc>
+
+" Enable TAB indent and SHIFT-TAB unindent
+vnoremap <silent> <TAB> >gv
+vnoremap <silent> <S-TAB> <gv
+
+iabbrev Lidsa Lorem ipsum dolor sit amet, consectetur adipisicing elit, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. Ut enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut aliquip ex ea commodo consequat. Duis aute irure dolor in reprehenderit in voluptate velit esse cillum dolore eu fugiat nulla pariatur. Excepteur sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt mollit anim id est laborum
+iabbrev rdebug require 'ruby-debug'; Debugger.start; Debugger.settings[:autoeval] = 1; Debugger.settings[:autolist] = 1; debugger
+
+inoremap <silent> <Bar> <Bar><Esc>:call <SID>align()<CR>a
+
+function! s:align()
+ let p = '^\s*|\s.*\s|\s*$'
+ if exists(':Tabularize') && getline('.') =~# '^\s*|' && (getline(line('.')-1) =~# p || getline(line('.')+1) =~# p)
+ let column = strlen(substitute(getline('.')[0:col('.')],'[^|]','','g'))
+ let position = strlen(matchstr(getline('.')[0:col('.')],'.*|\s*\zs.*'))
+ Tabularize/\\\@<!|/l1
+ normal! 0
+ call search(repeat('[^|]*|',column).'\s\{-\}'.repeat('.',position),'ce',line('.'))
+ endif
+endfunction
+
+if !exists('g:syntax_on')
+ syntax on
+endif
+filetype plugin indent on
+
+" Bundle Open command, from Bernerd Schaefer
+" Call with :BO <gemname>
+function! s:BundleOpen(Gem) abort
+ if exists(':Btabedit')
+ execute 'Btabedit '.a:Gem
+ redraw
+ let v:warningmsg = 'Use :Btabedit instead. It has tab complete!'
+ echomsg v:warningmsg
+ return
+ endif
+ let path = system('bundle show '.a:Gem)
+ if v:shell_error != 0
+ echo 'failed to run command'
+ else
+ exe 'tabedit '.substitute(path, '\v\C\n$', '', '') | :lcd %
+ endif
+endfunction
+
+" :BO capybara
+:command! -nargs=1 BundleOpen :call s:BundleOpen(<q-args>)
+
+augroup hashrocket
+ autocmd!
+
+ autocmd CursorHold,BufWritePost,BufReadPost,BufLeave *
+ \ if isdirectory(expand("<amatch>:h")) | let &swapfile = &modified | endif
+
+ autocmd BufNewFile,BufRead *.haml set ft=haml
+ autocmd BufNewFile,BufRead *.feature,*.story set ft=cucumber
+ autocmd BufRead * if ! did_filetype() && getline(1)." ".getline(2).
+ \ " ".getline(3) =~? '<\%(!DOCTYPE \)\=html\>' | setf html | endif
+
+ autocmd FileType javascript,coffee setlocal et sw=2 sts=2 isk+=$
+ autocmd FileType html,xhtml,css,scss setlocal et sw=2 sts=2
+ autocmd FileType eruby,yaml,ruby setlocal et sw=2 sts=2
+ autocmd FileType cucumber setlocal et sw=2 sts=2
+ autocmd FileType gitcommit setlocal spell
+ autocmd FileType gitconfig setlocal noet sw=8
+ autocmd FileType ruby setlocal comments=:#\ tw=79
+ autocmd FileType sh,csh,zsh setlocal et sw=2 sts=2
+ autocmd FileType vim setlocal et sw=2 sts=2 keywordprg=:help
+
+ autocmd Syntax css syn sync minlines=50
+
+ autocmd FileType ruby nmap <buffer> <leader>bt <Plug>BlockToggle
+
+ autocmd User Rails nnoremap <buffer> <D-r> :<C-U>Rake<CR>
+ autocmd User Rails nnoremap <buffer> <D-R> :<C-U>.Rake<CR>
+ autocmd User Rails Rnavcommand decorator app/decorators -suffix=_decorator.rb -default=model()
+ autocmd User Rails Rnavcommand uploader app/uploaders -suffix=_uploader.rb -default=model()
+ autocmd User Rails Rnavcommand steps features/step_definitions -suffix=_steps.rb -default=web
+ autocmd User Rails Rnavcommand blueprint spec/blueprints -suffix=_blueprint.rb -default=model()
+ autocmd User Rails Rnavcommand factory spec/factories -suffix=_factory.rb -default=model()
+ autocmd User Rails Rnavcommand fabricator spec/fabricators -suffix=_fabricator.rb -default=model()
+ autocmd User Rails Rnavcommand feature features -suffix=.feature -default=cucumber
+ autocmd User Rails Rnavcommand support spec/support features/support -default=env
+ autocmd User Rails Rnavcommand worker app/workers -suffix=_worker.rb -default=model()
+ autocmd User Fugitive command! -bang -bar -buffer -nargs=* Gpr :Git<bang> pull --rebase <args>
+augroup END
98 vimrc
View
@@ -0,0 +1,98 @@
+runtime! autoload/pathogen.vim
+if exists('g:loaded_pathogen')
+ call pathogen#runtime_prepend_subdirectories(expand('~/.vimbundles'))
+endif
+
+syntax on
+filetype plugin indent on
+"
+" ---------------------------------------------------------------------------
+" " General
+" "
+" ---------------------------------------------------------------------------
+"
+let mapleader = ","
+let g:mapleader = ","
+
+set cursorline
+
+" quickly switch between buffers
+nnoremap <leader><leader> <c-^>
+
+" remap escape
+imap jj <ESC>
+
+" Auto format
+map === mmgg=G`m^zz
+
+"close buffer
+nmap <leader>d :bd<CR>
+
+" close all buffers
+nmap <leader>D :bufdo bd<CR>
+
+"saving and exit
+nmap <leader>q :wqa!<CR>
+nmap <leader>w :w!<CR>
+nmap <leader><Esc> :q!<CR>
+
+" Nerd Tree Settings
+let NERDTreeShowBookmarks = 0
+let NERDChristmasTree = 1
+let NERDTreeWinPos = "left"
+let NERDTreeHijackNetrw = 1
+let NERDTreeQuitOnOpen = 1
+let NERDTreeWinSize = 50
+" open file browser
+map <leader>p :NERDTreeToggle<cr>
+
+"tags
+set tags=./tags;
+set tags+=gems.tags
+map <leader>l :TlistToggle <cr>
+let Tlist_Use_Right_Window = 1
+let Tlist_WinWidth = 60
+"autocomplete
+set complete=.,w,b,u,t,i
+
+"find buffer
+nmap <silent> <leader>b :FufBuffer<CR>
+
+" Settings for Ruby/Rails
+map <leader>gv :CommandTFlush<cr>\|:CommandT app/views<cr>
+map <leader>gc :CommandTFlush<cr>\|:CommandT app/controllers<cr>
+map <leader>gm :CommandTFlush<cr>\|:CommandT app/models<cr>
+map <leader>gh :CommandTFlush<cr>\|:CommandT app/helpers<cr>
+map <leader>gl :CommandTFlush<cr>\|:CommandT lib<cr>
+map <leader>gp :CommandTFlush<cr>\|:CommandT public<cr>
+map <leader>gs :CommandTFlush<cr>\|:CommandT public/stylesheets<cr>
+map <leader>ga :CommandTFlush<cr>\|:CommandT app/assets<cr>
+
+" View routes or Gemfile in large split
+map <leader>gr :topleft :split config/routes.rb<cr>
+map <leader>gg :topleft 100 :split Gemfile<cr>
+"
+" " Skip to Model, View or Controller
+map <Leader>m :Rmodel
+map <Leader>v :Rview
+map <Leader>c :Rcontroller
+au BufRead,BufNewFile Gemfile,Rakefile,Thorfile,config.ru,Vagrantfile,Guardfile,Capfile set ft=ruby
+
+
+set visualbell
+set guifont=Monaco:h16
+set guioptions-=T guioptions-=e guioptions-=L guioptions-=r
+set shell=bash
+set number
+set relativenumber
+set ignorecase
+set nowrap
+
+augroup vimrc
+ autocmd!
+ autocmd GuiEnter * set columns=120 lines=70 number
+augroup END
+
+if filereadable(expand('~/.vimrc.local'))
+ source ~/.vimrc.local
+endif
Please sign in to comment.
Something went wrong with that request. Please try again.