build.gradle

plugins {
  id 'base'

  id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'

  id "com.github.ben-manes.versions" version "0.54.0"
  id "com.gorylenko.gradle-git-properties" version "4.0.1" apply false
}

def isNonStable = { String version ->
  def stableKeyword = ['RELEASE', 'FINAL', 'GA'].any { it -> version.toUpperCase().contains(it) }
  def regex = /^[0-9,.v-]+(-r)?$/
  return !stableKeyword && !(version ==~ regex)
}
tasks.named("dependencyUpdates").configure {
  rejectVersionIf {
    isNonStable(it.candidate.version)
  }
}
// ./gradlew dependencyUpdates

allprojects {
  group = 'org.sitemesh'
  repositories { mavenCentral() }
}

subprojects {
  // Aggregator projects (e.g. :examples) exist only to group child projects
  // by directory convention and get no build conventions of their own.
  if (!buildFile.exists()) {
    return
  }

  // Examples are runnable demos, not published artifacts — especially now
  // that their project names (:examples:struts etc.) are too generic to be
  // Maven coordinates under org.sitemesh.
  boolean isExample = path.startsWith(':examples:')

  apply plugin: 'java-library'
  if (!isExample) {
    apply plugin: 'maven-publish'
    apply plugin: 'signing'
  }
  apply plugin: 'com.gorylenko.gradle-git-properties'

  java {
    toolchain { languageVersion = JavaLanguageVersion.of(17) }
    withSourcesJar()
    withJavadocJar()
  }

  // Stamp the version into the jar manifest so Package.getImplementationVersion()
  // resolves at runtime (used by the "SiteMesh <version> initialized" startup log).
  tasks.named('jar') {
    manifest {
      attributes(
        'Implementation-Title': project.name,
        'Implementation-Version': project.version,
        'Specification-Title': project.name,
        'Specification-Version': project.version
      )
    }
  }

  // gradle-git-properties 4.x emits git.properties into a generated resources
  // source dir that sourcesJar also reads. Declare the dependency Gradle 9
  // requires, and keep the generated file out of the published -sources.jar
  // (it still ships in the runtime jar via processResources, as before).
  tasks.named('sourcesJar') {
    dependsOn 'generateGitProperties'
    exclude 'git.properties'
  }

  if (isExample) {
    return
  }

  publishing {
    publications {
      mavenJava(MavenPublication) {
        from components.java
        pom {
          name = project.name
          description = 'SiteMesh 3 – HTML decoration and layout framework'
          url = 'https://github.com/sitemesh/sitemesh3'
          licenses {
            license {
              name = 'Apache License, Version 2.0'
              url = 'https://www.apache.org/licenses/LICENSE-2.0'
              distribution = 'repo'
            }
          }
          scm {
            url = 'https://github.com/sitemesh/sitemesh3'
            connection = 'scm:git:https://github.com/sitemesh/sitemesh3.git'
            developerConnection = 'scm:git:ssh://git@github.com/sitemesh/sitemesh3.git'
          }
          developers {
            developer {
              id = 'sitemesh'
              name = 'SiteMesh Contributors'
              url = 'https://github.com/sitemesh'
            }
          }
        }
      }
    }
  }

  signing {
    def key = findProperty('signing.key') as String
    def pass = findProperty('signing.password') as String
    if (key && pass) {
      useInMemoryPgpKeys(key, pass)
      sign publishing.publications
    }
  }
}

// The maven-publish/signing/nexus-publish stack is not configuration-cache
// compatible; declaring the incompatibility makes publish builds skip the
// cache instead of failing.
allprojects {
  tasks.configureEach { task ->
    if (task instanceof org.gradle.api.publish.maven.tasks.AbstractPublishToMaven
        || task instanceof org.gradle.api.publish.maven.tasks.GenerateMavenPom
        || task instanceof org.gradle.plugins.signing.Sign
        || task.class.name.startsWith('io.github.gradlenexus')) {
      task.notCompatibleWithConfigurationCache('publishing plugins do not support the configuration cache')
    }
  }
}

nexusPublishing {
  packageGroup.set('org.sitemesh')
  repositories {
    sonatype {
      nexusUrl.set(uri('https://ossrh-staging-api.central.sonatype.com/service/local/'))
      snapshotRepositoryUrl.set(uri('https://central.sonatype.com/repository/maven-snapshots/'))
      username.set(providers.gradleProperty('sonatypeUsername'))
      password.set(providers.gradleProperty('sonatypePassword'))
    }
  }
}