Provide a min viable http://bazel.build integration.

This allows other projects that use bazel to utilize re2c as a tool.

Limitations:

. Input files (docs, lexer, parser) are not being re-generated.
. No tests are executed.
. Only the main binary is being build as nothing else is needed.

A user will load the package using bazel's 'http_archive' in their
WORKSPACE file.

In their BUILD files they can then use:

```
load("@re2c//bazel:re2c.bzl", "re2c_gen")

re2c_gen(
    name = "file_re2c",
    srcs = ["file.re2c"],
    outs = [
        "file.cc",
        "file.h",
    ]
)

cc_library(
    name = "file_cc",
    srcs = ["file.cc"],
    hdrs = ["file.h"],
)
```

The approach here is to automate as much as possible. In that way, all
source and header files will be found automatically (using glob). Also,
the provided bazel integration is kept to an absolute minimum.

An alternative is to use a `rules_foreign_cc` based approach. But that
would require much more bazel work and knowledge. Plus the result would
end up being a non-hermetic build, thereby bypassing bazel's advantages.
Further, using a rules_foreign_cc approach is much slower (for me ~x10).

Author: helly25

.gitignore

@@ -11,6 +11,7 @@
 /m4
 /test_*
 /.build*
+/bazel-*
 
 # Ignore user defined CMake presets
 CMakeUserPresets.json

BUILD.bazel

@@ -0,0 +1,45 @@
+package(default_visibility = ["//visibility:private"])
+
+genrule(
+    name = "re2c_config",
+    srcs = [
+        "CMakeLists.txt",
+        "//bazel:re2c_config.h",
+    ],
+    outs = ["config.h"],
+    cmd = """
+        cat $(location //:CMakeLists.txt) |\\
+            sed -rne 's/project\\(re2c VERSION ([^ ]+).*/#define PACKAGE_VERSION "\\1-bootstrap"/p' >> "$@"
+        cat $(location //bazel:re2c_config.h) >> "$@"
+    """,
+)
+
+cc_library(
+    name = "re2c_config_cc",
+    hdrs = ["config.h"],
+    defines = ["""RE2C_STDLIB_DIR='"$(BINDIR)/re2c.runfiles/re2c/include"'"""],
+    data = ["include/unicode_categories.re"],
+)
+
+cc_library(
+    name = "re2c_bootstrap_cc",
+    includes = ["bootstrap"],
+    hdrs = glob([
+        "bootstrap/src/**/*.h",
+        "src/**/*.h",
+    ]),
+    srcs = glob([
+        "bootstrap/src/**/*.cc",
+        "src/**/*.cc",
+    ]),
+    deps = [
+        "re2c_config_cc",  # Needed for 're2c_config_cc' data files
+    ],
+)
+
+cc_binary(
+    name = "re2c",
+    srcs = ["src/main.cc"],
+    deps = [":re2c_bootstrap_cc"],
+    visibility = ["//visibility:public"],
+)

WORKSPACE

@@ -0,0 +1,14 @@
+workspace(name = "re2c")
+
+load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
+
+http_archive(
+    name = "bazel_skylib",
+    urls = [
+        "https://mirror.bazel.build/github.com/bazelbuild/bazel-skylib/releases/download/1.3.0/bazel-skylib-1.3.0.tar.gz",
+        "https://github.com/bazelbuild/bazel-skylib/releases/download/1.3.0/bazel-skylib-1.3.0.tar.gz",
+    ],
+    sha256 = "74d544d96f4a5bb630d465ca8bbcfe231e3594e5aae57e1edbf17a6eb3ca2506",
+)
+load("@bazel_skylib//:workspace.bzl", "bazel_skylib_workspace")
+bazel_skylib_workspace()

bazel/BUILD.bazel

@@ -0,0 +1,13 @@
+package(default_visibility = ["//visibility:private"])
+
+load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
+
+exports_files([
+    "re2c_config.h",
+])
+
+bzl_library(
+    name = "re2c_bzl",
+    srcs = ["re2c.bzl"],
+    visibility = ["//visibility:public"],
+)

bazel/re2c.bzl

@@ -0,0 +1,70 @@
+# re2c generator rules - assuming that re2c is available as '@re2c//:re2c'.
+
+load("@bazel_skylib//lib:paths.bzl", "paths")
+
+visibility("public")
+
+# Define supported extensions as defined by:
+# . https://bazel.build/reference/be/c-cpp#cc_library_args
+# . https://github.com/bazelbuild/bazel/blob/master/src/main/java/com/google/devtools/build/lib/rules/cpp/CppFileTypes.java
+_C_SRC_EXT = [".c", ".cc", ".cpp", ".cxx", ".c++", ".C", ".cu", ".cl"]
+_C_HDR_EXT = [".h", ".hh", ".hpp", ".ipp", ".hxx", ".h++", ".inc", ".inl", ".tlh", ".tli", ".H", ".tcc"]
+_RE2C_EXT = [".re", ".re2c"]
+
+def _re2c_impl(ctx):
+    srcs = ctx.files.srcs
+    if len(srcs) != 1:
+        fail("Attribute `srcs` must contain exactly 1 re2c source file ({exts}).".format(exts=", ".join(_RE2C_EXT)))
+    outs = ctx.outputs.outs
+    if not outs or [o for o in outs if paths.split_extension(o.path)[1] not in _C_SRC_EXT + _C_HDR_EXT]:
+        fail("Attribute `outs` must contain at least 1 C/C++ shource or header file ({exts}).".format(exts=", ".join(_C_SRC_EXT + _C_HDR_EXT)))
+    ctx.actions.run_shell(
+        outputs = outs + [err_file],
+        tools = [ctx.executable._re2c_tool],
+        inputs = ctx.files.srcs + ctx.files.data,
+        command = """
+            "{re2c}" "{src}" -o "{out}" {re2c_args} {includes}
+        """.format(
+            re2c = ctx.executable._re2c_tool.path,
+            src = srcs[0].path,
+            out = outs[0].path,
+            includes = " ".join(list(dict([("-I" + f.dirname, 1) for f in ctx.files.data]))),
+            re2c_args = " ".join(ctx.attr.re2c_args),
+        ),
+        mnemonic = "RE2C",
+        progress_message = "Generating re2c %{label}",
+    )
+
+_re2c_attr = {
+    "srcs": attr.label_list(
+        doc = "The re2c source.",
+        allow_files = _RE2C_EXT,
+        mandatory = True,
+    ),
+    "data": attr.label_list(
+        doc = "Other input data files (e.g. include files).",
+        allow_files = _C_SRC_EXT + _C_HDR_EXT,
+        mandatory = False,
+    ),
+    "outs": attr.output_list(
+        doc = "The generated output source.",
+        mandatory = True,
+    ),
+    "re2c_args": attr.string_list(
+        doc = "Arguments to re2c invocation.",
+    ),
+    "_re2c_tool": attr.label(
+        doc = "The target of the 're2c' executable.",
+        default = Label("//:re2c"),
+        allow_single_file = True,
+        executable = True,
+        cfg = "exec",
+    ),
+}
+
+re2c_gen = rule(
+    attrs = _re2c_attr,
+    doc = """Use re2c tool to create an output file (e.g. '.cc') from a '.re' input.""",
+    output_to_genfiles = True,
+    implementation = _re2c_impl,
+)

bazel/re2c_config.h

@@ -0,0 +1,4 @@
+#define HAVE_SYS_TYPES_H 1
+#define HAVE_SYS_STAT_H 1
+#define HAVE_FCNTL_H 1
+#define HAVE_UNISTD_H 1