Makefile.am, CMake: simplify bootstrap process.

Re2c is a self-hosting lexer generator, therefore it needs re2c in order
to rebuild itself. It bootstraps using precompiled files in the bootstrap
subdirectory. Precompiled files can be used as long as the .re files are
not changed, otherwise lexers must be regenerated. Previosuly the build
system tried to autodetect whether to regenerate or to copy bootstrap
files by checking if the re2c executable exists in the build directory.

However, for the build system it means that dependency graph is changed
on every build, because bootstrap commands and regenerate commands have
different dependencies: bootstrap commands depend on the bootstrap
files, and regenerate commands depend on the .re files. It is not
possible to choose the commands statically, because the check for re2c
executable should run on every build rather than once at configure time.
CMake used a workaround and set both bootstrap and .re files as
dependencies for both commands, which caused weird rebuilds on Travis CI
(when the same lexer was regenerated multiple times during one build).
Automake used a different workaround (a pattern rule that didn't have
the dependency on bootstrap files at all).

This commit disables the checking mechanism and requires passing an
explicit configure parameter and a path to the re2c executable in order
to regenerate lexers. Otherwise, by default lexers are copied from
bootstrap files.

CMake:       cmake ...  -DRE2C_REBUILD_LEXERS=on -DRE2C_FOR_BUILD=<path>
Makefile.am: configure ... --enable-lexers RE2C_FOR_BUILD=<path>

Author: skvadrik

CMakeLists.txt

@@ -10,11 +10,16 @@ include(Re2cTryCXXFlag)
 
 ac_subst(PACKAGE_VERSION "${PROJECT_VERSION}")
 
+option(RE2C_REBUILD_LEXERS "Regenerate lexers" OFF)
+if(RE2C_REBUILD_LEXERS AND NOT RE2C_FOR_BUILD)
+    message(FATAL_ERROR "need RE2C_FOR_BUILD for RE2C_REBUILD_LEXERS")
+endif()
+
 option(RE2C_REBUILD_DOCS "Regenerate manpage" OFF)
-if (RE2C_REBUILD_DOCS)
+if(RE2C_REBUILD_DOCS)
     find_program(RST2MAN NAMES rst2man rst2man.py)
-    if (NOT RST2MAN)
-        message(FATAL_ERROR "need rst2man or rst2man.py for RE2C_REBUILD_DOCS=YES")
+    if(NOT RST2MAN)
+        message(FATAL_ERROR "need rst2man or rst2man.py for RE2C_REBUILD_DOCS")
     endif()
 endif()
 

Makefile.am

@@ -9,12 +9,11 @@ if DEBUG
 AM_CXXFLAGS += -DRE2C_DEBUG
 endif
 
-RE2CFLAGS = -br -W
+RE2CFLAGS = -br -W -Wno-match-empty-string
 
 # binary
 bin_PROGRAMS = re2c
 noinst_PROGRAMS =
-RE2C = re2c$(EXEEXT)
 
 # sources
 re2c_HDR = \
@@ -310,26 +309,35 @@ CLEANFILES = \
 	$(re2c_GEN) \
 	$(DOCS)
 
+if REBUILD_LEXERS
+# generate lexer and update bootstrap files
 .re.cc:
 	$(AM_V_at)$(MKDIR_P) $(@D)
-	$(AM_V_GEN) if test -x $(RE2C); \
+	$(AM_V_GEN)if test -x $(RE2C_FOR_BUILD); \
 	then \
-		$(top_builddir)/$(RE2C) $(RE2CFLAGS) -o $@ $< && \
+		$(RE2C_FOR_BUILD) $(RE2CFLAGS) -o $@ $< && \
 		cp $(@:cc=[ch]*) $(top_srcdir)/bootstrap/$(@D); \
 	else \
-		cp $(top_srcdir)/bootstrap/$(@:cc=*) $(@D); \
+		echo "RE2C is not an executable file" && exit 1 ; \
 	fi
+else
+# copy bootstrap files
+.re.cc:
+	$(AM_V_at)$(MKDIR_P) $(@D)
+	$(AM_V_GEN)cp $(top_srcdir)/bootstrap/$(@:cc=*) $(@D)
+	$(AM_V_at)echo "Reconfigure with --enable-lexers to regenerate $@"
+endif
 
 # cannot update bootstrap with distcheck (it makes srcdir readonly),
 # so we update bootstrap only on incremental build (if re2c binary exists)
 .ypp.cc:
 	$(AM_V_at)$(MKDIR_P) $(@D)
-	$(AM_V_GEN) if test $(BISON) = "no"; \
+	$(AM_V_GEN)if test $(BISON) = "no"; \
 	then \
 		cp $(top_srcdir)/bootstrap/$(@:cc=*) $(@D); \
 	else \
 		$(BISON) --output=$@ --defines=$(@:cc=h) $< && \
-		if test -x $(RE2C); then \
+		if test -x $(top_builddir)/re2c$(EXEEXT); then \
 			cp $@ $(@:cc=h) $(top_srcdir)/bootstrap/$(@D); \
 		fi; \
 	fi
@@ -371,7 +379,7 @@ $(re2c_GEN_HELP): $(re2c_CUSTOM_HELP) $(GENHELP)
 		&& rm $@.1
 else
 docs: $(DOCS) $(re2c_GEN_HELP)
-	$(AM_V_at)echo "Reconfigure to rebuild docs: ./configure --enable-docs"
+	$(AM_V_at)echo "Reconfigure with --enable-docs to rebuild docs"
 # copy bootstrap manpage for C
 $(DOC_C): $(re2c_BOOT_DOC_C)
 	$(AM_V_at)$(MKDIR_P) $(@D)

cmake/Re2cBootstrapLexer.cmake

@@ -1,55 +1,58 @@
-if (CMAKE_CURRENT_LIST_FILE STREQUAL CMAKE_SCRIPT_MODE_FILE)
-    get_filename_component(parent_dir "${cc_file}" DIRECTORY)
-    file(RELATIVE_PATH relative_re_file "${CMAKE_CURRENT_BINARY_DIR}" "${source_dir}/${re_file}")
+function(re2c_bootstrap_lexer input output)
+    # optional header file, 3rd argument
+    set(header "${ARGN}")
 
-    file(MAKE_DIRECTORY "${parent_dir}")
-    if (EXISTS "${re2c}")
-        execute_process(
-            COMMAND "${re2c}" -br -W "${relative_re_file}" -o "${cc_file}"
-            RESULT_VARIABLE ret
-        )
-        if (NOT ret EQUAL 0)
-             message(FATAL_ERROR "Failure running re2c: got exit status ${ret}")
-        endif()
-        file(COPY "${cc_file}" DESTINATION "${source_dir}/bootstrap/${parent_dir}")
-        if (NOT "${h_file}" STREQUAL "")
-            file(COPY "${h_file}" DESTINATION "${source_dir}/bootstrap/${parent_dir}")
-        endif()
-    else()
-        file(COPY "${source_dir}/bootstrap/${cc_file}" DESTINATION "${parent_dir}")
-        if (NOT "${h_file}" STREQUAL "")
-            file(COPY "${source_dir}/bootstrap/${h_file}" DESTINATION "${parent_dir}")
-        endif()
-    endif()
+    # source files (use relative path to avoid hardcoding in line directives)
+    set(source "${CMAKE_CURRENT_SOURCE_DIR}/${input}")
+    file(RELATIVE_PATH relative_source "${CMAKE_CURRENT_BINARY_DIR}" "${source}")
 
-    return()
-endif()
+    # bootstrap files
+    set(boot_output "${CMAKE_CURRENT_SOURCE_DIR}/bootstrap/${output}")
+    set(boot_header "${CMAKE_CURRENT_SOURCE_DIR}/bootstrap/${header}")
 
-set(__re2c_bootstrap_lexer_cmake "${CMAKE_CURRENT_LIST_FILE}")
+    set(re2c_flags "-br" "-W" "-Wno-match-empty-string")
 
-function(re2c_bootstrap_lexer re_file cc_file)
-    set(h_file "${ARGN}")
-    set(outputs)
-    list(APPEND outputs "${cc_file}")
-    if(h_file)
-        list(APPEND outputs "${h_file}")
-    endif()
-    if(NOT TARGET re2c)
-        message(FATAL_ERROR "'re2c' is not a valid target")
+    if (RE2C_REBUILD_LEXERS)
+        # recompile the lexer and update bootstrap file(s)
+        if("${header}" STREQUAL "")
+            # without header
+            add_custom_command(
+                OUTPUT "${output}"
+                COMMAND "${RE2C_FOR_BUILD}" ${re2c_flags} "${relative_source}" -o "${output}"
+                COMMAND "${CMAKE_COMMAND}" -E copy_if_different "${output}" "${boot_output}"
+                DEPENDS "${source}"
+                COMMENT "Generating ${output}"
+            )
+        else()
+            # with header
+            add_custom_command(
+                OUTPUT "${output}" "${header}"
+                COMMAND "${RE2C_FOR_BUILD}" ${re2c_flags} "${relative_source}" -o "${output}"
+                COMMAND "${CMAKE_COMMAND}" -E copy_if_different "${output}" "${boot_output}"
+                COMMAND "${CMAKE_COMMAND}" -E copy_if_different "${header}" "${boot_header}"
+                DEPENDS "${source}"
+                COMMENT "Generating ${output} and ${header}"
+            )
+        endif()
+    else()
+        # copy precompiled bootstrap file(s)
+        if("${header}" STREQUAL "")
+            # without header
+            add_custom_command(
+                OUTPUT "${output}"
+                COMMAND "${CMAKE_COMMAND}" -E copy "${boot_output}" "${output}"
+                DEPENDS "${source}" "${boot_output}"
+                COMMENT "Copying bootstrap ${output}, reconfigure with RE2C_REBUILD_LEXERS to regenerate"
+            )
+        else()
+            # with header
+            add_custom_command(
+                OUTPUT "${output}" "${header}"
+                COMMAND "${CMAKE_COMMAND}" -E copy "${boot_output}" "${output}"
+                COMMAND "${CMAKE_COMMAND}" -E copy "${boot_header}" "${header}"
+                DEPENDS "${source}" "${boot_output}" "${boot_header}"
+                COMMENT "Copying bootstrap ${output} and ${header}, reconfigure with RE2C_REBUILD_LEXERS to regenerate"
+            )
+        endif()
     endif()
-    add_custom_command(
-        OUTPUT ${outputs}
-        COMMAND
-            "${CMAKE_COMMAND}"
-            -Dsource_dir="${CMAKE_CURRENT_SOURCE_DIR}"
-            -Dre_file="${re_file}" -Dcc_file="${cc_file}" -Dh_file="${h_file}"
-            # Avoid $<TARGET_FILE:re2c>, because that adds a dependency on re2c,
-            # which causes CMake to error if we put this into an object library,
-            # which we need to have libre2c built from bootstrap too
-            -Dre2c="${CMAKE_CURRENT_BINARY_DIR}/re2c${CMAKE_EXECUTABLE_SUFFIX}"
-            -P "${__re2c_bootstrap_lexer_cmake}"
-        WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
-        MAIN_DEPENDENCY "${CMAKE_CURRENT_SOURCE_DIR}/${re_file}"
-        DEPENDS "${__re2c_bootstrap_lexer_cmake}"
-    )
 endfunction()

configure.ac

@@ -35,6 +35,17 @@ AM_COND_IF([REBUILD_DOCS], [
 ])
 
 
+# --enable-lexers
+AC_ARG_ENABLE([lexers], [AS_HELP_STRING([--enable-lexers], [regenerate lexers])])
+AM_CONDITIONAL([REBUILD_LEXERS], [test "x$enable_lexers" = "xyes"])
+AM_COND_IF([REBUILD_LEXERS], [
+    AC_ARG_VAR(RE2C_FOR_BUILD, re2c executable used to regenerate lexers)
+    AS_IF([test ! -x "$RE2C_FOR_BUILD"], [
+        AC_MSG_ERROR([RE2C_FOR_BUILD must be set to an executable file with --enable-lexers])
+    ])
+])
+
+
 # --enable-libs
 AC_ARG_ENABLE([libs], [AS_HELP_STRING([--enable-libs], [build libraries])])
 AM_CONDITIONAL([WITH_LIBS], [test "x$enable_libs" = "xyes"])