Skip to content
Fetching contributors…
Cannot retrieve contributors at this time
222 lines (196 sloc) 7.13 KB
# -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.
AC_PREREQ(2.59)
AC_INIT(sleuthkit, 4.0.0b1)
m4_include([m4/ax_pthread.m4])
# include the version from 1.12.1. This will work for
m4_include([m4/cppunit.m4])
m4_include([m4/ax_jni_include_dir.m4])
m4_include([m4/ac_prog_javac_works.m4])
m4_include([m4/ac_prog_javac.m4])
AC_CONFIG_SRCDIR([tsk3/base/tsk_base.h])
AM_CONFIG_HEADER([tsk3/tsk_config.h])
AC_CONFIG_AUX_DIR(config)
AM_INIT_AUTOMAKE([foreign])
AM_PATH_CPPUNIT(1.12.1)
AM_CONDITIONAL([CPPUNIT],[test "x$no_cppunit" = x])
AM_PROG_LIBTOOL
AM_MAINTAINER_MODE
AC_CONFIG_MACRO_DIR([m4])
# Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PATH_PROG(PERL, perl)
# Checks for header files.
AC_HEADER_STDC
#AC_HEADER_MAJOR
#AC_HEADER_SYS_WAIT
#AC_CHECK_HEADERS([fcntl.h inttypes.h limits.h locale.h memory.h netinet/in.h stdint.h stdlib.h string.h sys/ioctl.h sys/param.h sys/time.h unistd.h utime.h wchar.h wctype.h])
AC_CHECK_HEADERS([inttypes.h unistd.h sys/param.h])
# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_CONST
AC_TYPE_UID_T
AC_TYPE_MODE_T
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
#AC_CHECK_MEMBERS([struct stat.st_rdev])
#AC_HEADER_TIME
#AC_STRUCT_TM
# check for large file support
AC_SYS_LARGEFILE
# Checks for library functions.
AC_FUNC_ALLOCA
AC_FUNC_ERROR_AT_LINE
#AC_FUNC_FORK
AC_FUNC_FSEEKO
AC_PROG_GCC_TRADITIONAL
AC_FUNC_LSTAT
AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
#AC_FUNC_MALLOC
#AC_FUNC_MBRTOWC
#AC_FUNC_MEMCMP
#AC_FUNC_MKTIME
#AC_FUNC_MMAP
#AC_FUNC_REALLOC
AC_FUNC_SELECT_ARGTYPES
#AC_FUNC_STAT
AC_FUNC_UTIME_NULL
AC_FUNC_VPRINTF
#AC_CHECK_FUNCS([dup2 gethostname isascii iswprint memset munmap regcomp select setlocale strcasecmp strchr strdup strerror strndup strrchr strtol strtoul strtoull utime wcwidth])
AX_PTHREAD( [
AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
CLIBS="$PTHREAD_LIBS $LIBS"
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
LDFLAGS="$LDFLAGS $PTHREAD_CFLAGS"
CC="$PTHREAD_CC"],[])
# Not all compilers include /usr/local in the include and link path
if test -d /usr/local/include; then
CFLAGS="$CFLAGS -I/usr/local/include"
LDFLAGS="$LDFLAGS -L/usr/local/lib"
fi
# Checks for libraries.
# Check if we should link afflib.
AC_ARG_WITH([afflib],
[AS_HELP_STRING([--without-afflib],[Do not use AFFLIB even if it is installed])]
[AS_HELP_STRING([--with-afflib=dir],[Specify that AFFLIB is installed in directory 'dir'])],
# If --with-afflib or --without-afflib is given
[],
# if nothing was specified, default to a test
[with_afflib=yes])
# check for the lib if they did not specify no
AS_IF([test "x$with_afflib" != "xno"],
# Test the dir if they specified something beyond yes/no
[AS_IF([test "x$with_afflib" != "xyes"],
[AS_IF([test -d ${with_afflib}/include],
[CFLAGS="$CFLAGS -I${with_afflib}/include"
LDFLAGS="$LDFLAGS -L${with_afflib}/lib"],
# Dir given was not correct
[AC_MSG_FAILURE([AFFLIB directory not found at ${with_afflib}])])
]
)]
# Check for the header file first to make sure they have the dev install
[AC_CHECK_HEADERS([afflib/afflib.h],
[AC_CHECK_LIB([afflib], [af_open])]
)]
)
#needed for sqllite
AC_CHECK_LIB(dl, dlopen)
# Check if we should link libewf.
AC_ARG_WITH([libewf],
[AS_HELP_STRING([--without-libewf],[Do not use libewf even if it is installed])]
[AS_HELP_STRING([--with-libewf=dir],[Specify that libewf is installed in directory 'dir'])],
# If --with-libewf or --without-libewf is given
[],
# if nothing was specified, default to a test
[with_libewf=yes])
# check for the lib if they did not specify no
AS_IF([test "x$with_libewf" != "xno"],
# Test the dir if they specified something beyond yes/no
[AS_IF([test "x$with_libewf" != "xyes"],
[AS_IF([test -d ${with_libewf}/include],
[CFLAGS="$CFLAGS -I${with_libewf}/include"
LDFLAGS="$LDFLAGS -L${with_libewf}/lib"],
# Dir given was not correct
[AC_MSG_FAILURE([libewf directory not found at ${with_libewf}])])
]
)]
# Check for the header file first to make sure they have the dev install
[AC_CHECK_HEADERS([libewf.h],
[AC_CHECK_LIB([ewf], [libewf_open])]
)]
)
# sqlite requires pthread libraries - this was copied from its configure.ac
# AC_SEARCH_LIBS(pthread_create, pthread)
AC_SEARCH_LIBS(dlopen, dl)
# Test for java/jni so that we can compile the java bindings
AC_PROG_JAVAC
if test "x$JAVAC" != x; then
AX_JNI_INCLUDE_DIR
for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
do
JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
done
# Export the paths so that the makefile gets them
AC_SUBST(JNI_CPPFLAGS, $JNI_CPPFLAGS)
fi
AM_CONDITIONAL([X_JNI],[test "x$JNI_CPPFLAGS" != x])
AC_CONFIG_COMMANDS([tsk3/tsk_incs.h],
[
echo "#ifndef _TSK_INCS_H" > tsk3/tsk_incs.h
echo "#define _TSK_INCS_H" >> tsk3/tsk_incs.h
echo "// automatically by ./configure" >> tsk3/tsk_incs.h
echo "// Contains the config.h data needed by programs that use libtsk" >> tsk3/tsk_incs.h
echo "" >> tsk3/tsk_incs.h
if test x$ac_cv_header_unistd_h = xyes; then
echo "#include <unistd.h>" >> tsk3/tsk_incs.h
fi
if test x$ac_cv_header_inttypes_h = xyes; then
echo "#ifndef __STDC_FORMAT_MACROS" >> tsk3/tsk_incs.h
echo "#define __STDC_FORMAT_MACROS" >> tsk3/tsk_incs.h
echo "#endif" >> tsk3/tsk_incs.h
echo "#include <inttypes.h>" >> tsk3/tsk_incs.h
fi
if test x$ac_cv_header_sys_param_h = xyes; then
echo "#include <sys/param.h>" >> tsk3/tsk_incs.h
fi
if test x$ax_pthread_ok = xyes; then
echo "#define TSK_MULTITHREAD_LIB" >> tsk3/tsk_incs.h
fi
echo "" >> tsk3/tsk_incs.h
echo "#endif" >> tsk3/tsk_incs.h
],
[
ac_cv_header_unistd_h=$ac_cv_header_unistd_h
ac_cv_header_inttypes_h=$ac_cv_header_inttypes_h
ac_cv_header_sys_param_h=$ac_cv_header_sys_param_h
ax_pthread_ok=$ax_pthread_ok
])
AC_CONFIG_FILES([Makefile
tsk3/Makefile
tsk3/base/Makefile
tsk3/img/Makefile
tsk3/vs/Makefile
tsk3/fs/Makefile
tsk3/hashdb/Makefile
tsk3/auto/Makefile
tools/Makefile
tools/imgtools/Makefile
tools/vstools/Makefile
tools/fstools/Makefile
tools/hashtools/Makefile
tools/srchtools/Makefile
tools/autotools/Makefile
tools/sorter/Makefile
tools/timeline/Makefile
tests/Makefile
samples/Makefile
man/Makefile
bindings/java/jni/Makefile
unit_tests/Makefile
unit_tests/base/Makefile])
AC_OUTPUT
Something went wrong with that request. Please try again.