Skip to content
This repository
tree: 6cd530395f
Fetching contributors…

Cannot retrieve contributors at this time

file 493 lines (441 sloc) 13.052 kb
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493
.assembly extern mscorlib { }
.assembly 'LoopMicro'
{
  .permissionset reqmin = (
  3C 00 50 00 65 00 72 00 6D 00 69 00 73 00 73 00 // <.P.e.r.m.i.s.s.
  69 00 6F 00 6E 00 53 00 65 00 74 00 20 00 63 00 // i.o.n.S.e.t. .c.
  6C 00 61 00 73 00 73 00 3D 00 22 00 53 00 79 00 // l.a.s.s.=.".S.y.
  73 00 74 00 65 00 6D 00 2E 00 53 00 65 00 63 00 // s.t.e.m...S.e.c.
  75 00 72 00 69 00 74 00 79 00 2E 00 50 00 65 00 // u.r.i.t.y...P.e.
  72 00 6D 00 69 00 73 00 73 00 69 00 6F 00 6E 00 // r.m.i.s.s.i.o.n.
  53 00 65 00 74 00 22 00 0A 00 76 00 65 00 72 00 // S.e.t."...v.e.r.
  73 00 69 00 6F 00 6E 00 3D 00 22 00 31 00 22 00 // s.i.o.n.=.".1.".
  3E 00 0A 00 3C 00 49 00 50 00 65 00 72 00 6D 00 // >...<.I.P.e.r.m.
  69 00 73 00 73 00 69 00 6F 00 6E 00 20 00 63 00 // i.s.s.i.o.n. .c.
  6C 00 61 00 73 00 73 00 3D 00 22 00 53 00 79 00 // l.a.s.s.=.".S.y.
  73 00 74 00 65 00 6D 00 2E 00 53 00 65 00 63 00 // s.t.e.m...S.e.c.
  75 00 72 00 69 00 74 00 79 00 2E 00 50 00 65 00 // u.r.i.t.y...P.e.
  72 00 6D 00 69 00 73 00 73 00 69 00 6F 00 6E 00 // r.m.i.s.s.i.o.n.
  73 00 2E 00 53 00 65 00 63 00 75 00 72 00 69 00 // s...S.e.c.u.r.i.
  74 00 79 00 50 00 65 00 72 00 6D 00 69 00 73 00 // t.y.P.e.r.m.i.s.
  73 00 69 00 6F 00 6E 00 2C 00 20 00 6D 00 73 00 // s.i.o.n.,. .m.s.
  63 00 6F 00 72 00 6C 00 69 00 62 00 2C 00 20 00 // c.o.r.l.i.b.,. .
  56 00 65 00 72 00 73 00 69 00 6F 00 6E 00 3D 00 // V.e.r.s.i.o.n.=.
  32 00 2E 00 30 00 2E 00 30 00 2E 00 30 00 2C 00 // 2...0...0...0.,.
  20 00 43 00 75 00 6C 00 74 00 75 00 72 00 65 00 // .C.u.l.t.u.r.e.
  3D 00 6E 00 65 00 75 00 74 00 72 00 61 00 6C 00 // =.n.e.u.t.r.a.l.
  2C 00 20 00 50 00 75 00 62 00 6C 00 69 00 63 00 // ,. .P.u.b.l.i.c.
  4B 00 65 00 79 00 54 00 6F 00 6B 00 65 00 6E 00 // K.e.y.T.o.k.e.n.
  3D 00 62 00 37 00 37 00 61 00 35 00 63 00 35 00 // =.b.7.7.a.5.c.5.
  36 00 31 00 39 00 33 00 34 00 65 00 30 00 38 00 // 6.1.9.3.4.e.0.8.
  39 00 22 00 0A 00 76 00 65 00 72 00 73 00 69 00 // 9."...v.e.r.s.i.
  6F 00 6E 00 3D 00 22 00 31 00 22 00 0A 00 46 00 // o.n.=.".1."...F.
  6C 00 61 00 67 00 73 00 3D 00 22 00 53 00 6B 00 // l.a.g.s.=.".S.k.
  69 00 70 00 56 00 65 00 72 00 69 00 66 00 69 00 // i.p.V.e.r.i.f.i.
  63 00 61 00 74 00 69 00 6F 00 6E 00 22 00 2F 00 // c.a.t.i.o.n."./.
  3E 00 0A 00 3C 00 2F 00 50 00 65 00 72 00 6D 00 // >...<./.P.e.r.m.
  69 00 73 00 73 00 69 00 6F 00 6E 00 53 00 65 00 // i.s.s.i.o.n.S.e.
  74 00 3E 00 0A 00 ) // t.>...
}

.class public auto ansi sealed LoopDel
    extends [mscorlib]System.MulticastDelegate
{
    .method public hidebysig specialname rtspecialname instance default
        void '.ctor' (object A_1, native int A_2) runtime managed {}
    .method public virtual hidebysig newslot instance default
        class FrameD Invoke (class FrameD f) runtime managed {}
    .method public virtual hidebysig newslot instance default
        class [mscorlib]System.IAsyncResult BeginInvoke
        (class FrameD f, class [mscorlib]System.AsyncCallback callback,
        object 'object') runtime managed {}
    .method public virtual hidebysig newslot instance default
        class FrameD EndInvoke (class [mscorlib]System.IAsyncResult result)
        runtime managed {}
}

.class public auto ansi sealed beforefieldinit FrameD
    extends [mscorlib]System.Object
{
    .field public class LoopDel dgt
    .field public int32 lex

    .method public hidebysig specialname rtspecialname
           instance default void '.ctor' () cil managed
    {
        .maxstack 8
        ldarg.0
        call instance void object::'.ctor'()
        ret
    }
}

.class public auto ansi sealed beforefieldinit FrameI
    extends [mscorlib]System.Object
{
    .field public method class FrameI *(class FrameI) dgt
    .field public int32 lex

    .method public hidebysig specialname rtspecialname
           instance default void '.ctor' () cil managed
    {
        .maxstack 8
        ldarg.0
        call instance void object::'.ctor'()
        ret
    }
}

.class public auto ansi abstract beforefieldinit LoopCls
    extends [mscorlib]System.Object
{
    .method family hidebysig specialname rtspecialname
        instance default void '.ctor' () cil managed
    {
        .maxstack 8
        ldarg.0
        call instance void object::'.ctor'()
        ret
    }

    .method public virtual hidebysig newslot abstract
        instance default class FrameC Invoke (class FrameC f) cil managed { }
}

.class public auto ansi sealed beforefieldinit FrameC
      extends [mscorlib]System.Object
{
    .field public class LoopCls dgt
    .field public int32 lex

  .method public hidebysig specialname rtspecialname
         instance default void '.ctor' () cil managed
  {
      .maxstack 8
      ldarg.0
      call instance void object::'.ctor'()
      ret
  }
}

.class auto ansi beforefieldinit Dgt1 extends LoopCls
{

  .method public hidebysig specialname rtspecialname
         instance default void '.ctor' () cil managed
  {
      .maxstack 8
      ldarg.0
      call instance void class LoopCls::'.ctor'()
      ret
  }

  .method public virtual hidebysig
         instance default class FrameC Invoke (class FrameC f) cil managed
  {
      .maxstack 5
      ldarg.1
      ldfld int32 FrameC::lex
      brtrue noexit

      ldc.i4.0
      call void class [mscorlib]System.Environment::Exit(int32)
noexit:
      ldarg.1
      dup
      ldfld int32 FrameC::lex
      ldc.i4.1
      sub
      stfld int32 FrameC::lex
      ldarg.1
      ret
  }
}

.class auto ansi beforefieldinit Dgt4 extends LoopCls
{

  .method public hidebysig specialname rtspecialname
         instance default void '.ctor' () cil managed
  {
      .maxstack 8
      ldarg.0
      call instance void class LoopCls::'.ctor'()
      ret
  }

  .method public virtual hidebysig
         instance default class FrameC Invoke (class FrameC f) cil managed
  {
      .maxstack 5
      ldarg.1
      ldfld int32 FrameC::lex
      brtrue noexit

      ldc.i4.0
      call void class [mscorlib]System.Environment::Exit(int32)
noexit:
      ldarg.1
      dup
      ldfld int32 FrameC::lex
      ldc.i4.1
      sub
      stfld int32 FrameC::lex

      ldarg.1
      ldfld class LoopCls FrameC::dgt
      ldarg.1
      tail.
      callvirt instance class FrameC class LoopCls::Invoke(class FrameC)
      ret
  }
}

.class public auto ansi beforefieldinit LoopMicro
      extends [mscorlib]System.Object
{
  .method public hidebysig specialname rtspecialname
         instance default void '.ctor' () cil managed
  {
      .maxstack 8
      ldarg.0
      call instance void object::'.ctor'()
      ret
  }

  .method private static hidebysig
         default class FrameD Dgt0 (class FrameD f) cil managed
  {
      .maxstack 5
      ldarg.0
      ldfld int32 FrameD::lex
      brtrue noexit

      ldc.i4.0
      call void class [mscorlib]System.Environment::Exit(int32)
noexit:
      ldarg.0
      dup
      ldfld int32 FrameD::lex
      ldc.i4.1
      sub
      stfld int32 FrameD::lex
      ldarg.0
      ret
  }

  .method public static hidebysig
         default void RunLoop0 (int32 itr) cil managed
  {
      .maxstack 5
      .locals init (
              class FrameD th)
      newobj instance void class FrameD::'.ctor'()
      stloc.0
      ldloc.0
      ldarg.0
      stfld int32 FrameD::lex
      ldloc.0
      ldnull
      ldftn class FrameD class LoopMicro::Dgt0(class FrameD)
      newobj instance void class LoopDel::'.ctor'(object, native int)
      stfld class LoopDel FrameD::dgt

again:
      ldloc.0
      ldfld class LoopDel FrameD::dgt
      ldloc.0
      callvirt instance class FrameD class LoopDel::Invoke(class FrameD)
      stloc.0
      br again
  }

  .method public static hidebysig
         default void RunLoop1 (int32 itr) cil managed
  {
      .maxstack 3
      .locals init (
              class FrameC V_0)
      newobj instance void class FrameC::'.ctor'()
      stloc.0
      ldloc.0
      ldarg.0
      stfld int32 FrameC::lex
      ldloc.0
      newobj instance void class Dgt1::'.ctor'()
      stfld class LoopCls FrameC::dgt

again:
      ldloc.0
      ldfld class LoopCls FrameC::dgt
      ldloc.0
      callvirt instance class FrameC class LoopCls::Invoke(class FrameC)
      stloc.0
      br again

  }

  .method private static hidebysig
         default class FrameI Dgt2 (class FrameI f) cil managed
  {
      .maxstack 5
      ldarg.0
      ldfld int32 FrameI::lex
      brtrue noexit

      ldc.i4.0
      call void class [mscorlib]System.Environment::Exit(int32)
noexit:
      ldarg.0
      dup
      ldfld int32 FrameI::lex
      ldc.i4.1
      sub
      stfld int32 FrameI::lex
      ldarg.0
      ret
  }

  .method public static hidebysig
         default void RunLoop2 (int32 itr) cil managed
  {
      .maxstack 5
      .locals init (
              class FrameI th)
      newobj instance void class FrameI::'.ctor'()
      stloc.0
      ldloc.0
      ldarg.0
      stfld int32 FrameI::lex
      ldloc.0
      ldftn class FrameI class LoopMicro::Dgt2(class FrameI)
      stfld method class FrameI *(class FrameI) FrameI::dgt

again:
      ldloc.0
      ldloc.0
      ldfld method class FrameI *(class FrameI) FrameI::dgt
      calli class FrameI(class FrameI)
      stloc.0
      br again
  }

  .method private static hidebysig
         default class FrameD Dgt3 (class FrameD f) cil managed
  {
      .maxstack 5
      ldarg.0
      ldfld int32 FrameD::lex
      brtrue noexit

      ldc.i4.0
      call void class [mscorlib]System.Environment::Exit(int32)
noexit:
      ldarg.0
      dup
      ldfld int32 FrameD::lex
      ldc.i4.1
      sub
      stfld int32 FrameD::lex

      ldarg.0
      ldfld class LoopDel FrameD::dgt
      ldarg.0
      tail.
      callvirt instance class FrameD class LoopDel::Invoke(class FrameD)
      ret
  }

  .method public static hidebysig
         default void RunLoop3 (int32 itr) cil managed
  {
      .maxstack 5
      .locals init (
              class FrameD th)
      newobj instance void class FrameD::'.ctor'()
      stloc.0
      ldloc.0
      ldarg.0
      stfld int32 FrameD::lex
      ldloc.0
      ldnull
      ldftn class FrameD class LoopMicro::Dgt3(class FrameD)
      newobj instance void class LoopDel::'.ctor'(object, native int)
      stfld class LoopDel FrameD::dgt

again:
      ldloc.0
      ldfld class LoopDel FrameD::dgt
      ldloc.0
      callvirt instance class FrameD class LoopDel::Invoke(class FrameD)
      stloc.0
      br again
  }

  .method public static hidebysig
         default void RunLoop4 (int32 itr) cil managed
  {
      .maxstack 3
      .locals init (
              class FrameC V_0)
      newobj instance void class FrameC::'.ctor'()
      stloc.0
      ldloc.0
      ldarg.0
      stfld int32 FrameC::lex
      ldloc.0
      newobj instance void class Dgt4::'.ctor'()
      stfld class LoopCls FrameC::dgt

again:
      ldloc.0
      ldfld class LoopCls FrameC::dgt
      ldloc.0
      callvirt instance class FrameC class LoopCls::Invoke(class FrameC)
      stloc.0
      br again

  }

  .method private static hidebysig
         default class FrameI Dgt5 (class FrameI f) cil managed
  {
      .maxstack 5
      ldarg.0
      ldfld int32 FrameI::lex
      brtrue noexit

      ldc.i4.0
      call void class [mscorlib]System.Environment::Exit(int32)
noexit:
      ldarg.0
      dup
      ldfld int32 FrameI::lex
      ldc.i4.1
      sub
      stfld int32 FrameI::lex

      ldarg.0
      ldarg.0
      ldfld method class FrameI *(class FrameI) FrameI::dgt
      tail.
      calli class FrameI(class FrameI)
      ret
  }

  .method public static hidebysig
         default void RunLoop5 (int32 itr) cil managed
  {
      .maxstack 5
      .locals init (
              class FrameI th)
      newobj instance void class FrameI::'.ctor'()
      stloc.0
      ldloc.0
      ldarg.0
      stfld int32 FrameI::lex
      ldloc.0
      ldftn class FrameI class LoopMicro::Dgt5(class FrameI)
      stfld method class FrameI *(class FrameI) FrameI::dgt

again:
      ldloc.0
      ldloc.0
      ldfld method class FrameI *(class FrameI) FrameI::dgt
      calli class FrameI(class FrameI)
      stloc.0
      br again
  }

  .method private static hidebysig
         default void Main (string[] args) cil managed
  {
      .entrypoint
      .maxstack 5
      ldarg.0
      ldc.i4.1
      ldelem.ref
      call int32 int32::Parse(string)
      ldarg.0
      ldc.i4.0
      ldelem.ref
      call int32 int32::Parse(string)
      switch (l0, l1, l2, l3, l4, l5)
      pop
      ret

l0:
      call void class LoopMicro::RunLoop0(int32)
      ret

l1:
      call void class LoopMicro::RunLoop1(int32)
      ret

l2:
      call void class LoopMicro::RunLoop2(int32)
      ret

l3:
      call void class LoopMicro::RunLoop3(int32)
      ret

l4:
      call void class LoopMicro::RunLoop4(int32)
      ret

l5:
      call void class LoopMicro::RunLoop5(int32)
      ret
  } // end of method LoopMicro::Main


}
Something went wrong with that request. Please try again.