Possibili titoli:

1. Amiga Game Programming in Assembly
2. Assembly Language Game Programming for Amiga
3. Amiga Assembly Game Programming
4. Retrogame programming for Amiga in Assembly
5. Old school game programming for Amiga
6. Bare metal game programming for Amiga
7. Amiga Bare Metal Game Programming
8. Programming a shoot’em up game for Amiga
9. Programming games in assembly for Amiga
10. Black art of assembly game programming for Amiga

Blank page

**Table of contents**

[1. Tools & Documentation 12](#_Toc185947120)

[Visual Studio Code 12](#_Toc185947121)

[Amiga Assembly Extension for VS Code 13](#_Toc185947122)

[First Project 14](#_Toc185947123)

[WinUAE Amiga Emulator 15](#_Toc185947124)

[WinUAE Configuration 17](#_Toc185947125)

[Taking Screenshots 22](#_Toc185947126)

[Screen recording 23](#_Toc185947127)

[Window size and video mode 24](#_Toc185947128)

[Joystick configuration 24](#_Toc185947129)

[Source code versioning with Git 24](#_Toc185947130)

[Online resources on Amiga programming 29](#_Toc185947131)

[2. Amiga hardware overview 30](#_Toc185947132)

[Amiga hardware architecture 30](#_Toc185947133)

[CPU 30](#_Toc185947134)

[RAM memory 31](#_Toc185947135)

[Custom Chips 32](#_Toc185947136)

[OCS features 32](#_Toc185947137)

[ECS Features 33](#_Toc185947138)

[AGA Features 33](#_Toc185947139)

[3. Motorola 68K Assembly Short Course 34](#_Toc185947140)

[Assembler directives 34](#_Toc185947141)

[Labels 35](#_Toc185947142)

[Comments 35](#_Toc185947143)

[Move instruction 36](#_Toc185947144)

[Debugging 37](#_Toc185947145)

[Data structures 40](#_Toc185947146)

[Arithmetic instructions 41](#_Toc185947147)

[Shift instructions 42](#_Toc185947148)

[Logical instructions 43](#_Toc185947149)

[Conditional statement 43](#_Toc185947150)

[Loops 44](#_Toc185947151)

[Subroutines 45](#_Toc185947152)

[4. Take control of Amiga hardware 47](#_Toc185947153)

[DMA 47](#_Toc185947154)

[Amiga Operating System and libraries 48](#_Toc185947155)

[Modular structure of the source code 48](#_Toc185947156)

[Take System 49](#_Toc185947157)

[Release System 51](#_Toc185947158)

[Main program 52](#_Toc185947159)

[Main loop 52](#_Toc185947160)

[Run the program 52](#_Toc185947161)

[5. Game concept 54](#_Toc185947162)

[Video game genres 54](#_Toc185947163)

[Let's create a shoot'em up 54](#_Toc185947164)

[Game Design 54](#_Toc185947165)

[Technical game design 58](#_Toc185947166)

[6. The Copper and copperlist 59](#_Toc185947167)

[Move Instruction 59](#_Toc185947168)

[Wait Instruction 59](#_Toc185947169)

[The Copperlist 60](#_Toc185947170)

[Save and restore the system copperlist 61](#_Toc185947171)

[7. How to display images on screen 64](#_Toc185947172)

[RAW format 64](#_Toc185947173)

[RAW Converter 65](#_Toc185947174)

[Palette 66](#_Toc185947175)

[Bitplanes 67](#_Toc185947176)

[Display window size 71](#_Toc185947177)

[How to enlarge the display window 74](#_Toc185947178)

[Hires Mode 76](#_Toc185947179)

[Interlaced mode 77](#_Toc185947180)

[8. Blitter 80](#_Toc185947181)

[Introduction 80](#_Toc185947182)

[DMA Channels 80](#_Toc185947183)

[Logic functions 81](#_Toc185947184)

[Blitter busy 81](#_Toc185947185)

[BLTSIZE and how to start Blitter 82](#_Toc185947186)

[Modulus 82](#_Toc185947187)

[Shift 83](#_Toc185947188)

[Masking 83](#_Toc185947189)

[Example of copying an image to the screen 83](#_Toc185947190)

[9. Tiles and tilemaps 89](#_Toc185947191)

[Tiles 89](#_Toc185947192)

[Tilemap 89](#_Toc185947193)

[Why are tiles used? 90](#_Toc185947194)

[Creating the tileset 90](#_Toc185947195)

[Creating the tilemap 97](#_Toc185947196)

[Alternative way to create a tileset/tilemap 103](#_Toc185947197)

[Export tilesets, palettes and map 104](#_Toc185947198)

[Import tilesets and tilemaps into our program 106](#_Toc185947199)

[Drawing a tile 107](#_Toc185947200)

[Drawing a column of tiles 110](#_Toc185947201)

[Let's fill the screen with tiles 111](#_Toc185947202)

[10. Scrolling background 114](#_Toc185947203)

[Blitter-based scrolling 114](#_Toc185947204)

[Background initialization 117](#_Toc185947205)

[Background Drawing Using Blitter 121](#_Toc185947206)

[Vertical Blank 122](#_Toc185947207)

[Background scrolling 123](#_Toc185947208)

[Hide the first 16 pixels to remove noise 125](#_Toc185947209)

[Double buffering 125](#_Toc185947210)

[Hardware scrolling 127](#_Toc185947211)

[Implementing hardware scrolling 129](#_Toc185947212)

[Vertical scrolling 133](#_Toc185947213)

[Implementing Vertical Scrolling 137](#_Toc185947214)

[Multi directional scrolling 146](#_Toc185947215)

[Implementing multi directional scrolling 149](#_Toc185947216)

[11. Hardware sprites and joystick input 156](#_Toc185947217)

[What are hardware sprites? 156](#_Toc185947218)

[Example 1: Joystick movement of an attached sprite 156](#_Toc185947219)

[Sprite DMA Channels 156](#_Toc185947220)

[Sprite size 157](#_Toc185947221)

[Sprite coordinates 157](#_Toc185947222)

[Sprites data structure 158](#_Toc185947223)

[Creating Sprite Data Structure 159](#_Toc185947224)

[Inspecting the Sprite Data Structure with Hex Editor 160](#_Toc185947225)

[Sprite pointers 163](#_Toc185947226)

[Sprite colors 165](#_Toc185947227)

[Sprites “attached” 165](#_Toc185947228)

[Priority between sprites and playfields 166](#_Toc185947229)

[Placing a Sprite 167](#_Toc185947230)

[Joystick input 168](#_Toc185947231)

[Moving the Sprite with the Joystick 171](#_Toc185947232)

[Collisions 172](#_Toc185947233)

[AGA Sprites 175](#_Toc185947234)

[32/64 pixel sprite data structure 176](#_Toc185947235)

[Creation of sprites 64 pixels wide 178](#_Toc185947236)

[Changes to sprite pointer initialization 181](#_Toc185947237)

[Sprite placement changes 182](#_Toc185947238)

[Collision detection changes 185](#_Toc185947239)

[12. Blitter objects (Bobs) 187](#_Toc185947240)

[Need to use Blitter Objects (Bobs) 187](#_Toc185947241)

[Mask 187](#_Toc185947242)

[Configuring Blitter Channels and Logic Function 188](#_Toc185947243)

[Shifting and masking the last word 188](#_Toc185947244)

[Creating Images 190](#_Toc185947245)

[Bob data structure 196](#_Toc185947246)

[Spritesheet 197](#_Toc185947247)

[Bob drawing 198](#_Toc185947248)

[Saving bob’s background 202](#_Toc185947249)

[Background restore 206](#_Toc185947250)

[13. Player’s ship 209](#_Toc185947251)

[Introduction 209](#_Toc185947252)

[Dual Playfield mode 209](#_Toc185947253)

[Bobs drawing optimization 213](#_Toc185947254)

[Preparing the graphics 216](#_Toc185947255)

[Import graphics 221](#_Toc185947256)

[Data structures 221](#_Toc185947257)

[Initializing the Data Structure 222](#_Toc185947258)

[Draw ship 223](#_Toc185947259)

[State update 224](#_Toc185947260)

[Main loop 227](#_Toc185947261)

[14. Enemies 229](#_Toc185947262)

[Introduction 229](#_Toc185947263)

[Data structure 229](#_Toc185947264)

[When to spawn an enemy 229](#_Toc185947265)

[How to make an enemy move 230](#_Toc185947266)

[Let's add two hidden parts to the left and right of the playfield for clipping 231](#_Toc185947267)

[Preparing the graphics 232](#_Toc185947268)

[Creating Enemy Arrays 232](#_Toc185947269)

[Drawing enemies 234](#_Toc185947270)

[Enemy activation 235](#_Toc185947271)

[Executing enemy commands 235](#_Toc185947272)

[Enemy state update 238](#_Toc185947273)

[Main loop 239](#_Toc185947274)

[15. Firing shots 241](#_Toc185947275)

[Player’s ship Shots 241](#_Toc185947276)

[Shot Data Structure 244](#_Toc185947277)

[Preparing graphics 245](#_Toc185947278)

[Graphics import 246](#_Toc185947279)

[Shots Array 246](#_Toc185947280)

[Instantiating a Shot 247](#_Toc185947281)

[Drawing shots 248](#_Toc185947282)

[Movement and animation of the shots 248](#_Toc185947283)

[Enemy shots 252](#_Toc185947284)

[Preparation and import graphics of enemy shots 254](#_Toc185947285)

[Drawing enemy shots 255](#_Toc185947286)

[Enemy shots update 255](#_Toc185947287)

[16. Collisions and explosions 259](#_Toc185947288)

[Collisions player’s ship shots – enemies 259](#_Toc185947289)

[Bounding box collisions 259](#_Toc185947290)

[Intersecting rectangles 259](#_Toc185947291)

[Changes to shot and enemy data structures 261](#_Toc185947292)

[Collision detection between player's ship shots and enemies 263](#_Toc185947293)

[Collision response 264](#_Toc185947294)

[Enemy explosion 265](#_Toc185947295)

[Collisions shots – player’s ship 268](#_Toc185947296)

[Changes to the player's ship data structure 268](#_Toc185947297)

[Collision Routine 269](#_Toc185947298)

[Collision response 270](#_Toc185947299)

[Hit and explosion states of player’s ship 271](#_Toc185947300)

[Player’s ship explosion 273](#_Toc185947301)

[Collisions player’s ship – enemies 275](#_Toc185947302)

[Collision Routines 275](#_Toc185947303)

[Collision response 276](#_Toc185947304)

[Collisions player’s ship – map 277](#_Toc185947305)

[Pixel-perfect collisions 277](#_Toc185947306)

[Creating a mask for tileset 278](#_Toc185947307)

[Collision plane 278](#_Toc185947308)

[Drawing a tile mask 279](#_Toc185947309)

[Collision detection between player's ship and map 281](#_Toc185947310)

[Collision response 283](#_Toc185947311)

[17. Text rendering 286](#_Toc185947312)

[Bitmap font 286](#_Toc185947313)

[Drawing a character 287](#_Toc185947314)

[Drawing a string 288](#_Toc185947315)

[Converting a number to a string 289](#_Toc185947316)

[Example of drawing a string 290](#_Toc185947317)

[Example of debugging using draw\_string 291](#_Toc185947318)

[18. HUD 294](#_Toc185947319)

[HUD Graphics 294](#_Toc185947320)

[Copperlist dedicated to HUD 295](#_Toc185947321)

[HUD initialization 296](#_Toc185947322)

[Game Score 297](#_Toc185947323)

[Energy bar 299](#_Toc185947324)

[Final result 304](#_Toc185947325)

[19. Game states 305](#_Toc185947326)

[Defining Game States 305](#_Toc185947327)

[State transitions 306](#_Toc185947328)

[Updating the current state 310](#_Toc185947329)

[Playing state 310](#_Toc185947330)

[Changes to the main 312](#_Toc185947331)

[20. Game over 314](#_Toc185947332)

[Graphics 314](#_Toc185947333)

[Initialization 315](#_Toc185947334)

[Game over text drawing 316](#_Toc185947335)

[Game over text animation 316](#_Toc185947336)

[Game over state update 317](#_Toc185947337)

[Switching to the game over state 318](#_Toc185947338)

[Final result 318](#_Toc185947339)

[21. Title screen 320](#_Toc185947340)

[Graphics 320](#_Toc185947341)

[Initialization 321](#_Toc185947342)

[Title screen state update 323](#_Toc185947343)

[Switching to title screen state 325](#_Toc185947344)

[Final result 325](#_Toc185947345)

[22. Sound 327](#_Toc185947346)

[Amiga audio hardware 327](#_Toc185947347)

[Audio registers 327](#_Toc185947348)

[Loading sound effects into memory 328](#_Toc185947349)

[Data structures for sound effects 328](#_Toc185947350)

[Sound Effects Table 329](#_Toc185947351)

[Playing a sound effect 330](#_Toc185947352)

[Interrupts 331](#_Toc185947353)

[INTENA Register 331](#_Toc185947354)

[INTREQ Register 334](#_Toc185947355)

[Interrupt Routine 334](#_Toc185947356)

[Stop a sound effect from playing 336](#_Toc185947357)

[Add calls to play sound effects 337](#_Toc185947358)

[Play ProTracker Modules 340](#_Toc185947359)

[23. Keyboard and mouse input 344](#_Toc185947360)

[Keyboard input 344](#_Toc185947361)

[CIAA Registers 345](#_Toc185947362)

[Initializing the keyboard 345](#_Toc185947363)

[Keyboard Interrupt Routine 346](#_Toc185947364)

[Changes to main module 348](#_Toc185947365)

[Mouse input 348](#_Toc185947366)

[24. Power-ups 352](#_Toc185947367)

[Data structure 352](#_Toc185947368)

[Creating a powerup object 354](#_Toc185947369)

[Powerup graphics 356](#_Toc185947370)

[Powerup drawing 357](#_Toc185947371)

[Powerup state update 357](#_Toc185947372)

[Collisions between player's ship and powerups 358](#_Toc185947373)

[Activating a powerup 359](#_Toc185947374)

[Adding a new type of fire to the player's ship 359](#_Toc185947375)

[25. End level boss 362](#_Toc185947376)

[Graphics 362](#_Toc185947377)

[Boss data structure 363](#_Toc185947378)

[26. Loading assets from disk 366](#_Toc185947379)

[File Module 366](#_Toc185947380)

[File loading 368](#_Toc185947381)

[Asset management 369](#_Toc185947382)

[27. Fixed Point Math 372](#_Toc185947383)

# 1. Tools & Documentation

At the Amiga times (late 80s – early 90s), video game programmers used the same Amiga, perhaps in the more professional versions Amiga 2000, 3000, 4000, to write code and debug it. It wasn't a very convenient method, because if the computer crashed during execution, you risked losing the unsaved code. To solve this problem, they began using another computer to write the code, often an IBM PC clone, and transfer the code to the Amiga via the serial port.

## Visual Studio Code

Today we are lucky because there are much more advanced development tools, which allow you to write code, format it, debug it and even test it. For writing the code we will use Microsoft's "Visual Studio Code", which can be downloaded free of charge from the following URL:

<https://code.visualstudio.com/download>

This tool is available for Windows, Mac Os and Linux.

After installation, when you launch Visual Studio Code, you will see the window shown in the following figure.



Visual Studio Code allows you to install extensions. To program in Assembly for Amiga, we'll install a fantastic extension that will make the task easier for us.

## Amiga Assembly Extension for VS Code

Press the “Extensions” button on the left menu (circled in green in the following figure). Visual Studio code will display a panel called "Extensions Marketplace", containing a list of available extensions. You type "amiga assembly" in the search box. An extension called "Amiga Assembly" will appear at the top of the list (highlighted in yellow in the next figure). Click on the "Install" button to install it.

Immagine che contiene testo, schermata, software, Icona del computer

Descrizione generata automaticamente

The extension we installed provides the following features:

* Compiling the assembly source code for the Motorola 68000 CPU using the VASM assembler.
* Syntax highlighting and formatting for Motorola 68000 Assembly
* Calculator
* Color Editor
* Hexadecimal to Decimal Conversion
* Online Documentation
* Debugger
* sin/cos table generator

To learn more about using the extension, visit the following page:

<https://github.com/prb28/vscode-amiga-assembly/wiki/Getting-started>

## First Project

Now let's see how to create an example project. First, let's create a folder for our project, calling it "chapter1". Press the key combination CONTROL + SHIFT + P. The Command Palette will appear, shown in the following figure. Let's select the first item, "Amiga Assembly: Create example workspace". In the next dialog box that will appear, select the "chapter1" folder you created earlier. You will be asked for the name of the executable program, call it "chapter1".

Immagine che contiene testo, elettronica, schermata, schermo

Descrizione generata automaticamente

Visual Studio Code will show the image in the next figure. On the left we find the Explorer, which allows you to explore the folder. Let's see the contents of the subfolders:

* “.vscode” contains the files to configure builds and debug
* “build” contains compiled object code (\*.o files)
* “include” contains some files with the definitions of constants and macros, to be included in the assembly source
* “uae” contains a virtual hard disk that is mounted in the Amiga emulator and that contains the executable of our program.
* “chapter1.s” contains the source code for the sample. Assembly files have \*.s or \*.asm extension.

If you click on the chapter1.s file, it will be displayed in the main pane, with the colored syntax.

Immagine che contiene testo, schermata, software, numero

Descrizione generata automaticamente

## WinUAE Amiga Emulator

To run the sample program in assembly, we use an Amiga emulator, called WinUAE and integrated into the Amiga Assembly extension for VS Code.

From the VS Code Explorer, open the "launch.json" file (see picture below). Let's change the value of the "stopOnEntry" attribute, putting it to "false". In this way we will prevent the program from stopping on the first statement when we execute it.



Now let's see how to run the program. By pressing the yellow circled button in the following figure, the "Run and Debug" panel is displayed. From the drop-down menu at the top, we can choose the debug configuration between WinUAE and FS-UAE (another emulator). We choose WinUAE and press the triangle-shaped key to activate debugging.



The emulator window will open, which will run the sample program, as in the following figure. The sample program shows a horizontal line moving up and down. If you press left mouse button, the program terminates and exits to Amiga OS.



## WinUAE Configuration

Let's see how to configure WinUAE to emulate an Amiga 500, an Amiga 1200 and an Amiga 4000.

Pressing F12 when WinUAE is open will take you to the properties screen, shown in the following figure.



First of all, we should create a “winuae” folder in our downloads folder and create the following subfolders inside it (see following figure):

* roms
* screenshots
* videos



Now we can configure the file paths in WinUAE. We press the "Paths" item in the tree menu on the left of the WinUAE properties window. The screen shown in the following figure will appear.



Let's change the paths of System ROMs, Screenshots and Videos so that they point to the 3 folders created earlier.

By default, the emulator uses a compatible AROS ROM. If you want as much fidelity as possible, you need to get the original ROMs.

The only legal way to get the Amiga ROMs is to purchase the “Amiga Forever Plus Edition” package, available at the following url:

<https://www.amigaforever.com/plus/>


By Googling, you can find alternative ways to get ROMs.

The following figure shows a table with the Amiga models and compatible ROMs.



You need Kickstart 1.3 for A500 emulation and Kickstart 3.1 for A1200 and A4000 emulation. For the videogame created in this book, you need only Kickstart 3.1, because the game will be designed for AGA chipset available only on A1200 and A4000. Once you have the files, you need to copy them to the “winuae/roms” folder.

Now let's create the configuration for the Amiga 1200. By pressing the "Quickstart" button from the tree menu, the screen in the following figure appears. We need to select A1200 as the model.




In addition (see next figure), you must uncheck the "Start in Quickstart mode" checkbox and press the "Set Configuration" button. A warning message will appear because the ROMs were not found. Press OK.



Now select the item "Hardware\ROM" from the tree menu. The screen in the following figure will appear. As the main ROM file you select the Kickstart 3.1 file that you got earlier.



Now select the item "Hardware\Chipset" and the window in the following figure will appear. You need to select the "Cycle-exact" checkbox to get the most faithful simulation of the Amiga chipset.




To save the configuration and make it the default, you need to select the "Configurations" item from the tree menu. In the window that appears (see following figure), you must press the "Save" button.



Now the default configuration of WinUAE will be the emulation of the Amiga 1200. Press OK to close the properties window.

If you close the emulator now and try to run it again, you will see that it will be launched in A1200 mode. Press the left mouse button to exit the program. You will see the window in the following figure, proving that WinUAE is emulating an Amiga 1200. Now you can close the window, pressing the stop button of VS Code debugger.



If you want to configure an Amiga 500 or 4000, repeat the same steps, selecting the desired model. With the first you must specify Kickstart 1.3 as ROM.

## Taking Screenshots

WinUAE allows you to take screenshots or record videos. Simply select the "Output" item from the tree menu. On the screen that appears (see following figure), press the "Save screenshot" button. The current screen of the emulator will be saved, in png format, in the screenshots folder that we created earlier.



## Screen recording

To record a video with WinUAE output, again from the Output screen, configure the video format by pressing the "Video" button. In the dialog box that appears "Choose Video Codec" (see following figure), select "Microsoft Video 1" as the codec and set the data rate to 2000 KB/sec. Press OK.



To start video recording, press the "AVI Output enabled" button (see following figure). To stop recording, press this button again. When you stop recording, you will find a .avi file in the videos folder that we created earlier.



## Window size and video mode

By selecting the "Display" item from the WinUAE Settings tree menu, the screen in the following figure appears. You can change the size of the window, which by default is 720 x 568 pixels. It is possible to activate the fullscreen mode.



## Joystick configuration

By selecting the "Game ports" item in the Settings menu, the window in the following figure appears. In this window you can select the configuration of joysticks and mouse connected to the two ports available on the Amiga.



## Source code versioning with Git

During the development of our video game, it is useful to keep track of the changes we make to the source code. To do this we will use a software called Github Desktop, which can be downloaded for free from the following url:

<https://desktop.github.com/download/>

Let's see how to create a new source code repository for our video game. After launching Github Desktop, we press the button highlighted in yellow in the following figure:



The window in the following figure will appear, in which we must select the item "Create new repository" from the "Add" menu.



The window in the next figure will appear, in which we can set the name of the repository, a description, the folder that contains the files, if we want to add a .gitignore file that specifies the files to be ignored in version control. By pressing the "Create repository" button, the repository will be created locally to your computer.



After the new repository is created, you will see the screen in the following figure:



By pressing the "Publish repository" button, the screen in the following figure will appear to publish the repository to Github.



By pressing the "Publish repository" button, it will be published to the Github servers. You must have a Github account and you will be asked to log in. If you don't have the account, you need to create it first.

If you now try to edit the "chapter1.s" file, you will get the situation shown in the following figure. The left pane shows the files that have changed (in this case, chapter1.s). The middle pane shows the differences between the two versions of the files. In the box at the bottom left you can enter a description of the changes (in this case the text "Update chapter1.s" is suggested, but you can change it). Pressing the "Commit to main" button will record the changes in the repository. After a commit, you can publish your changes to the remote repository by pressing the "Publish repository" button.



By pressing the "History" button, the screen in the following figure is displayed, showing the history of all commits and also the differences, if you select a file.



Figure 1

Let's say another developer has made changes and posted them to the remote repository. To update your local repository, simply select the "Fetch origin" item from the main screen (see next figure).



## Online resources on Amiga programming

A good reference for the Motorola 68000 Processor Assembly is given by the following document:

<https://www.nxp.com/docs/en/reference-manual/M68000PRM.pdf>

The official Amiga hardware manual is available online at the following url:

<http://amigadev.elowar.com/read/ADCD_2.1/Hardware_Manual_guide/node0000.html>

An online copy of Amiga Developer Documentation is available at the following url:

<http://amigadev.elowar.com/>

# 2. Amiga hardware overview

## Amiga hardware architecture

Since we want to program directly the Amiga hardware, we need to understand its architecture, which is shown in the following figure.



## CPU

The CPU is based on Motorola 680x0 family. The Amiga 500, 1000 and 2000 were equipped with a 68000 running at about 7 Mhz. The Amiga 1200 was equipped with a 68EC020 at 14 Mhz. The Amiga 4000 was equipped with a 68030 or 68040 at 25 Mhz. The 68000 CPU has 32 bit registers, while the data bus and the ALU (Arithmetic Logic Unit) are 16 bits wide. The 68020,030 and 040 are full 32 bits CPUs with 32 bit data bus and ALU.

All the 680x0 CPUs have 8 data registers, 32 bit wide, called D0 - D7. These registers can also be used as 16 or 8 bit registers. 680x0 CPU also have 8 address registers, 32 bit wide, called A0 - A7. A7 is used as stack pointer and should not be changed directly. The following picture shows the registers:



There also is a status register SR, 16 bits wide. The bottom 8 bits are known as Condition Code Register (CCR), whose bottom 5 bits are flags that are set/cleared depending on the outcome of an instruction. The following table shows the meaning of the CCR flags:

|  |  |  |  |
| --- | --- | --- | --- |
| Bit pos. | Flag | Name | Function |
| 0 | C | Carry | This flag is set when the result of an instruction creates a carry from the most significant bit |
| 1 | V | Overflow | This flag indicates that there was an arithmetic overflow, which means that the result was either too large or too small for the destination |
| 2 | Z | Zero | This flag will be set when the result of the operation is zero |
| 3 | N | Negative | This flag will be set when the result of the operation is negative |
| 4 | X | Extend | Holds the carry for calculations with numbers larger than 32 bits |

## RAM memory

Amiga was equipped with two types of RAM memory:

* FAST Ram: could be accessed only by the CPU
* CHIP Ram: could be accessed by the custom chips or the CPU

For our purposes, the Chip RAM is very important, because into it we will store all the graphics and sound assets used by our game. We could store the program into Fast RAM, but only a few models had this type of memory.

The following table shows the amount of RAM memory for various Amiga models:

|  |  |  |
| --- | --- | --- |
| Model | Chip RAM | Fast RAM |
| A1000 | 256KB |  |
| A500 | 512KB |  |
| A2000 | 512KB | 512KB |
| A600 | 1 MB |  |
| A3000 | 1 MB | 1 MB |
| A1200 | 2 MB |  |
| A4000 | 2 MB | 2-4 MB |

## Custom Chips

The strength of Amiga architecture were the custom chips, designed by the legendary Jay Miner. The word "custom" means that the chips were designed specifically for Amiga and were not commercial off-the-shelf parts. There are 3 versions of this custom chipset:

* OCS : is the Original ChipSet available on A1000, A500, A2000. It was composed by 3 chips, named Agnus, Denise and Paula.
* ECS : Enhanced ChipSet available on A600, A3000. It was composed by 3 chips, with the same names of OCS.
* AGA: Advanced Graphics Architecture available on A1200, A4000, CD32. It was composed by 3 chips, named Alice, Lisa, Paula.

## OCS features

The chip Agnus contained the DMA controller, a coprocessor called "Copper" used to manage the screen configurations and special graphic effects, a coprocessor called "Blitter" used to transfer memory blocks.

Denise provided the interface with the monitor. It had a palette of 4096 colors. Various video modes:

* low-resolution 320x256 (200 for NTSC), with a maximum of 32 colors
* high resolution 640x256 (200 for NTSC), with a maximum of 16 colors
* interlaced video modes 320x512 (400 for NTSC) or 640x512 (400 for NTSC)
* HAM mode capable of displaying all the 4096 colors
* hardware horizontal and vertical scrolling
* 8 hardware sprites

The chip Paula provided four digital audio channels, each of them could play 8 bit samples with a maximum frequency of about 28Khz. Two CIA chips provided the input/output interfaces like joystick, serial, parallel ports.

## ECS Features

This chipset added the new following features:

* video mode VGA compatible (640x480)
* super-hires mode 1280x256

## AGA Features

This chipset added the following new features:

* palette with 16.8 million colors
* increased the number of colors of lowres and hires video modes to 256
* increased width of hardware sprites to 64 px

# 3. Motorola 68K Assembly Short Course

In this chapter we will try to explain the Assembly language programming of the Motorola 68000 Amiga processor. We'll explain the most frequently used instructions in video game programming, not the entire instruction set exhaustively. We will try to show a practical example for each instruction.

A microprocessor is only capable of executing a limited set of instructions. Different microprocessors have different instruction sets. Instructions are nothing more than a sequence of bytes, often called "machine code". You will understand that it is inconvenient for a human being to write a program using machine code directly, because the sequence of bytes would be difficult to understand. For these reasons, the Assembly language was invented, which replaces machine code with alphanumeric symbols, maintaining a 1:1 correspondence between machine instructions and assembly instructions. So, for example, instead of byte $7a we will have the assembly statement "ADD".

It is important to distinguish between the term "assembly" which is the name of the language and the term "assembler" which is the software that compiles an assembly program into machine code.

## Assembler directives

In addition to instructions for the microprocessor, there are instructions for the assembler to tell the it how to create the assembly program. These instructions are called **DIRECTIVES.**

An assembly program must begin with the **SECTION directive**, which has the following syntax:

**SECTION** <name>,<type>

<name> name useful for identifying the segment of code

<type> type of memory, can take the following values:

CODE code segment in FAST RAM memory or CHIP in case of absence of FAST

CODE\_C code segment in CHIP RAM memory

DATA data segment in FAST RAM memory

DATA\_C data segment in memory CHIP RAM

BSS zeroed data segment in FAST RAM

BSS\_C zeroed data segment in CHIP RAM

This directive instructs the assembler to allocate all instructions that will follow to a portion of memory of the type specified by the <type> parameter.

An assembly program must end with the **END** directive.

## Labels

A generic line of an Assembly program has the following format:

<label> <instruction>.<size> <operands> <comment>

The label can be made up of letters, numbers and the symbol ".". To allow the use of the dot in labels, you need to add the "-ldots" option to the args in the tasks.json file, as shown in the following figure.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

<size> indicates the size of the operands and can be as follows:

* b – byte, 8 bits
* w – word, 16 bits
* l – long, 32 bits

## Comments

To create a comment in Assembly, just use the ";" character. Everything that follows this character is a comment. It is a good idea to start the source code with a header comment, with the title and description of the program, information about the author and the target platform etc... An example is as follows:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Amiga Assembly Game Programming Book

;

; Chapter 3 - Motorola 68K Assembly Short Course

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Now let's start to see the instructions of the Assembly language of the Motorola 68000 processor.

## Move instruction

Making an analogy with a high-level language, such as the C language, one of the simplest instructions is assignment, which is when we assign a constant value to a variable:

score = 255

The corresponding Assembly statement is MOVE, which is followed by two operands, called source and destination. This statement copies the value of the source operand to the destination.

Assuming that the score variable is stored in the d0 register, the assignment seen above results in:

move.b  #255,d0        ; copies byte 255 into least significant byte (lsb) of

; register d0

In this case, the value 255 is 1 byte in size. This form of MOVE uses what is called **immediate addressing** in jargon.

It is also possible to express numerical values in hexadecimal notation, by prefixing the $ symbol to the number:

move.w  #$1234,d0 ; copies word $1234 into least significant word (lsw) of d0

In this case, the variable in d0 will be assigned the hexadecimal value $1234, which is the size of a word.

Similarly, we can assign a value of long size (32 bits) by writing:

move.l  #$12345678,d0 ; copies a long word into d0

Now let's see how to declare a variable in Assembly. A variable is nothing more than a space in memory, capable of containing a value of a given size. This memory space is referenced by a symbolic name. In Assembly, we use the **dc** directivethat reserves a space in memory and initializes it with the constant value that follows.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

value1  dc.w    0  ; declares a variable, with a length of one word

It is possible to declare variables one byte long with dc.b or 32 bits with dc.l

Now let's see how to assign a value to a variable, using the MOVE statement and absolute addressing:

move.w  #$3456,value1 ; assigns value $3456 to the value1 variable

Another way of addressing is indirect. We use the Load Entire Address (LEA) statement to load the address of the variable into the address register a0. To assign a value to the variable, we use the notation (a0) which indicates the variable whose address is contained in a0.

; indirect addressing

  lea       value1,a0      ; loads address of value1 into a0

  move.w    #$1234,(a0)    ; assigns value $1234 to the word at the address

; contained into a0 (value1)

For those who know the C language, a0 is a pointer to the variable value1, which is a variable that contains the address of another variable.

## Debugging

To better understand how indirect addressing works, let's try using the VS Code debugger. To stop the execution of the program you must insert a breakpoint in the line where we want it to stop:



You must click in the empty space to the left of the line number. A red dot will appear, indicating the breakpoint.

To start debugging, press the F5 key. VS Code will start the emulator and stop running at the line where you inserted the breakpoint. This line will be highlighted in yellow.

Immagine che contiene testo, schermata, numero, Carattere

Descrizione generata automaticamente

In the left pane you find useful information for debugging. In fact, at the top you find the list of CPU registers, with their values in hexadecimal.

In the box in the center, called "Watch", you can add variables whose value you want to see. To add a variable, you have to press the "+" button next to the word Watch and then enter the name of the variable. Try adding the variable "value1".

In the bottom box, called "Disassembled Memory", you can see the memory location where the instruction is located, the assembly instruction and the translation into machine code, in hexadecimal notation.

For example, referring to the following figure, you can see that at memory location $1ba68 the instruction lea value1,a0 is stored, which in machine code corresponds to the sequence of bytes: 41 fa 00 78.

Immagine che contiene testo, Carattere, schermata, bianco

Descrizione generata automaticamente

At the top of the VS Code window, you will notice a buttons bar (see the following figure) that is used to command the execution of the program in debug.

Immagine che contiene testo, Carattere, logo, schermata

Descrizione generata automaticamente

To execute the program one instruction at a time, you must press the second button, called "Step Over" or the F10 key. If you are on a call to subroutines and want to enter the subroutine, you must press the third button, called "Step Into" or the F11 key. The fourth key is used to exit a subroutine. The fifth "Restart" button is used to restart the execution of the program from the beginning. The sixth key is used to end the execution of the program. The first "Continue" button will continue running the program normally.

After pressing F10 once, you see that the highlighted line moves to the next statement and that the value of register a0 has changed and now contains the address of the variable value1.

Immagine che contiene testo, schermata, software, numero

Descrizione generata automaticamente

If you press F10 again, you will take a step further to verify that the value1 variable takes the value $1234, using the watch box. At this point you can finish the execution of the program, by pressing the stop key or SHIFT + F5.

Immagine che contiene testo, software, Icona del computer, numero

Descrizione generata automaticamente

## Data structures

Now let's look at another type of addressing: **indirect with displacement**. To explain this addressing, let's introduce the concept of **data structure**.

If you know the C language, you know that you can declare a data structure with the **struct** keyword:

struct ship

{

  short int x;

  short int y;

}

The data structure is a container that aggregates a set of variables in an orderly manner, logically related. In the example seen it aggregates the x, y coordinates of the position of our spaceship.

In Assembly, a data structure is declared using the following syntax:

; declares a data structure

             rsreset

ship.x       rs.w       1

ship.y       rs.w       1

ship.length  rs.b       0

The RSRESET directive must always be placed at the beginning of the declaration and resets the counter inside the data offset in the structure. The label indicates the name of the field. The **rs.w** directive reserves the amount of word specified by the following numeric value. In this case 1 word. The last field represents the length of the structure itself, and no memory space is allocated for it, in fact the value is 0. We can also reserve space for a long using rs.l.

After declaring a structure, you need to create an instance of it in memory. This is done using the usual way you declare variables, with the dc directive. In fact, the fields are treated as if they were variable.

; instance of ship structure

ship  dc.w    0    ; ship.x

      dc.w    0    ; ship.y

To initialize the structure instance fields, you must assign the ship instance address to the a0 registry. Use the MOVE statement with indirect addressing with displacement to assign the value 100 to the ship.x field.

Indirect addressing with displacement adds the indicated displacement (ship.x and ship.y in this case) to the address contained in a0. Of course, it is possible to specify the displacement with an integer. Ship.y will be equal to 2 for example.

; indirect addressing with displacement

  lea       ship,a0            ; base address of ship structure instance in a0

  move.w    #100,ship.x(a0)    ; assigns value 100 to ship.x field

  move.w    #192,ship.y(a0)    ; assigns value 192 to ship.y field

There is also indirect addressing with post increment, which differs from the previous one in that after assigning the value $1234 to the address contained in a0, the latter is incremented by 2 to point to the next word.

; indirect addressing with post increment

  lea       value1,a0       ; loads address of value1 into a0

  move.w    #$1234,(a0)+    ; assigns value $1234 to the word at the address

; contained into a0 and then increments a0 of one

; word (2 bytes)

If we want to reset the bits of a register or a variable, we can use the CLR instruction.

  clr.b    d0    ; sets lsb of d0 to zero

  clr.w    d0    ; clears lsw of d0

  clr.l    d0    ; clears all 32 bits of d0

## Arithmetic instructions

Now let's look at the arithmetic statements, starting with the ADD, which sums the values of the source and destination operands. The result is stored in the destination operand. Let's see an example below:

  move.w    #10,value1    ; value1 = 10

  move.w    #13,value2    ; value1 = 13

  move.w    value2,d0     ; d0 = value2

  add.w     value1,d0     ; d0 = value1 + value2

  move.w    d0,result     ; result = d0

The SUB instruction subtracts the source operand from the target, putting the result in the target. Below is an example:

  move.w    #100,value1    ; value1 = 100

  move.w    value1,d0      ; d0 = value1

  sub.w     #50,d0         ; d0 = d0 - 50 = value1 - 50

  move.w    d0,result      ; result = d0

The MULU instruction multiplies the 16 bit wide operands and puts the result in the destination, using 32 bits. MULU operates on unsigned numbers. To multiply two signed numbers, you need to use MULS. Below is an example:

  move.w    #30,d0       ; d0 = 30

  mulu      #3,d0        ; d0 = d0 \* 3 = 30 \* 3

  move.w    d0,result    ; result = d0

The DIVU instruction performs a division. The destination operand is divided by the source operand. The destination operand is the size of a long word (32 bits), while the source operand is the size of a word (16 bits). The quotient is inserted in the low word of d0, while the rest is inserted in the high word. Below is an example:

  move.w    #100,d0

  ext.l     d0           ; extends d0 value to a long word, because divu

; destination must be a long

  divu      #30,d0       ; d0 = d0 / 30  lower word = quotient, higher word =

; remainder

  move.w    d0,value1    ; value1 = quotient of 100/30 = 3

  swap      d0           ; swaps the lower and upper words of d0

  move.w    d0,value2    ; value2 = remainder of 100/30 = 10

The DIVU instruction operates on unsigned operands, while the DIVS operates on signed operands.

## Shift instructions

The ASL instruction shifts the target operand to the left, by a number of bits equal to the source operand. From an arithmetic point of view, the shift to the left is equivalent to the multiplication by powers of 2. There is the LSL instruction that operates on unsigned numbers. Below is an example:

  move.w    #20,d0    ; d0 = 20

  asl.w     #2,d0     ; shifts d0 2 bits to the left => d0 = d0 \* 2^2 = d0 \* 4 = 80

The ASR instruction shifts the destination operand to the right. The number of bits to be shifted is equal to the source operand. Arithmetically, the shift to the right is equivalent to the division by powers of 2. There is also the LSR instruction that operates on unsigned numbers, while ASR operates on signed numbers. Below is an example:

  move.w    #20,d0    ; d0 = 20

  asr.w     #1,d0     ; shifts d0 1 bit to the right => d0 = d0 / 2 = 10

## Logical instructions

Now let's see the logical instructions. Let's start with the AND that performs the logical operation “and” on the two operands, storing the result in the destination operand. The most frequent use is the masking operation. Suppose, for example, that you want to extract only the lower 4 bits of a byte. We can use a mask made in the following way: %00001111. By making the and between the byte of which we want to extract the lower 4 bits and the mask, we will get only the low 4 bits, as in the following example:

  move.w    #%10011100,d0    ; d0 = 156

  and.w     #%00001111,d0    ; d0 = 1100 = $c

The OR statement performs an or operation between the two operands, storing the result in the destination operand. An example is as follows:

  move.w    #%11110000,d0    ; d0 = 240 = $f0

  or.w      #%00001111,d0    ; d0 = %11111111 = $ff

The EOR instruction performs the exclusive OR between the two operands, storing the result in the destination operand. We will see later that it will be useful for reading the joystick.

  move.w    #%00001010,d0    ; d0 = %00001010 = $a

  eor.w     #%00001111,d0    ; d0 = %00000101 = $5

Finally, the NOT statement complements one of the only operand. It can be useful to reverse the bits of a word, as in the following example:

  move.w    #%00001111,d0    ; d0 = $000f

  not.w     d0               ; d0 = %1111111111110000 = $fff0

## Conditional statement

Now let's see how to implement the conditional **if** construct, present in high-level languages. Suppose you want to translate the following segment of C code into an assembly:

d0 = 123;

if (d0 >= 100)

    d0 = d1;

else

    d0 = d3;

d0 = 1;

To compare the value of a register or variable to a constant, you use the CMP statement. The comparison is made by subtracting the source operand from the destination operand. The result of this operation is to set the flags of the SR status register. These flags are used as input from the Bxx conditional jump instructions. To translate the segment of code seen earlier into an assembly, we need to use the BGE conditional jump statement, which jumps to the specified address if the result of the previous operation is greater than or equal to zero. Below is the complete example:

  move.w    #123,d0

  cmp.w     #100,d0              ; d0 >= 100?

  bge       .greater\_or\_equal    ; if d0 >= 100 jumps to .greater\_or\_equal

.else:

  move.w    d0,d3                ; else executes this instruction

  bra       .continue

.greater\_or\_equal:

  move.w    d0,d1

.continue:

  move.w    #1,d0

The other conditional jump instructions are as follows:

signed numbers

|  |  |
| --- | --- |
| BGE | branch on greater than or equal |
| BGT | branch on greater than |
| BLE | branch on lower than or equal |
| BLT | branch on less than |

unsigned numbers

|  |  |
| --- | --- |
| BHS | branch on higher than or same |
| BHI | branch on higher than |
| BLS | branch on lower than or same |
| BLO | branch on less than |

## Loops

Now let's see how to translate a loop with a fixed number of iterations, such as the **for** loop of high-level languages, into assembly. The following code snippet shows that loop.

The number of iterations minus one is stored in a data register, d7 in the example. Then you write the instructions to be repeated in a loop. In the example we make a byte-by-byte copy. To repeat the loop, you use the DBRA statement, which requires the register containing the number of iterations and the label that marks the beginning of the loop. This instruction repeats the loop until the register is non-zero.

; cycle with a fixed number of iterations

       moveq     #10-1,d7       ; number of iterations - 1 in d7

.loop  move.b    (a0)+,(a1)+    ; copies a byte from the address contained into

; a0 to the address contained in a1

       dbra      d7,.loop       ; repeats the loop until d7 <> 0

Another typical loop of high-level languages is the **while** loop:

while d0 <= 5

{

    d0 += 1;

}

This results in assemblies as shown in the following code snippet. The BRA instruction makes an **unconditional jump**, that is, the jump always happens, without any conditions. A comparison with the CMP statement and the BGT conditional jump is used to exit the loop.

.while\_loop:

       cmp.w    #5,d0

       bgt      .exit          ; if d0 > 5 exits the loop

       add.w    #1,d0          ; d0 = d0 + 1

       bra      .while\_loop    ; jumps to .while\_loop, repeating the loop

.exit  nop

## Subroutines

When you start writing long programs, it is essential to subdivide the code into **functions**, according to the dictates of structured programming. The C language function, or method, is called a "**subroutine**" in Assembly. Below you will find a subroutine declaration template.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Subroutine description.

;

; parameters:

; <register>.<size> - description

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  movem    d0-a6,-(sp)    ; saves registers from d0 to a6 value into stack

  nop                     ; instructions here

  movem    (sp)+,d0-a6    ; restores registers value from stack

  rts                     ; returns to the instruction after the call

It is important to precede the code of the subroutine itself, with a header comment describing what the subroutine does and the input parameters. For each parameter we must list the register that contains it, its size (b,w,l) and the meaning of the parameter itself. Notice that the subroutine starts with a label that must match its name.

The first statement, MOVEM, saves the current values of the registers on the stack. Then you find the instruction body of the subroutine. At the end of the subroutine, you need to restore the values of the registers previously saved in the stack, again with a MOVEM statement. Finally, you have to return the execution of the program to the instruction following the call, through the RTS instruction.

The call to subroutines is normally made through the BSR statement followed by the label of the subroutine. This statement uses a displacement between the memory address of the subroutine and that of the call. This displacement is automatically calculated by the assembler. You can see it using the "Disassembled memory" box:

0x0001bb7e: bsr.b $6 61 04

0x0001bb80: bsr.b $6 61 02

0x0001bb82: rts 4e 75

0x0001bb84: movem.w d0-a6,-(a7) 48 a7 ff fe

The bytes of the instruction in machine code are 61 indicating the instruction and 04 indicating the operand. So the displacement is 04, in fact the subroutine starts 4 bytes after the instruction following the BSR, at the address 0x0001bb84.

There is also another way to call subroutines, which is with the JSR statement. The difference with BSR lies in the addressing, which in JSR is absolute, i.e. the memory address is indicated. We will see that the JSR will be used for calls to the operating system.

You can find the complete source code at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter3>

# 4. Take control of Amiga hardware

Amiga has a sophisticated operating system (O.S.) that provides the programmer with all the tools to use the graphics and sound capabilities. However, historically, very few games have made use of the O.S. Virtually all commercial games that were developed for the Amiga bypassed the operating system and took direct control of the hardware and were written in assembly language. The reason is simple: in this way it is possible to get the maximum performance from the hardware. Since we want to create a video game in Assembly, programming the Amiga hardware directly, we must take control of the Amiga hardware, stopping the O.S. in a controlled manner. Before starting to write code, we will introduce some theoretical concepts necessary for a full understanding of the code we will write.

## DMA

DMA is an acronym for "Direct Memory Access". We know that both the custom chips and the CPU can access the Amiga chip memory. To increase the level of parallelism of the Amiga, the designers have created channels that allow the custom chips to access the memory directly, without the help of the CPU, leaving it free to do other things. This is one of the strengths of the Amiga architecture. Access to the DMA channels is regulated by a "DMA Controller" present in the Agnus chip. DMA channels can be enabled or disabled via the write-only DMACON register ($dff096). There is a DMACONR read-only register ($dff002) to read the status of these channels. The following table shows the meaning of the bits of these registers:

|  |  |  |
| --- | --- | --- |
| Bit # | Name | Description |
| 15 | SET/CLR | If it is 1 then the bits at 1 indicate enabling, if it is 0 then they indicate disabling |
| 14 | BlitBusy | read-only, 1 indicates that the Blitter is busy |
| 13 | BlitZero |  |
| 12 | X | not used |
| 11 | X | not used |
| 10 | BlitPri | Blitter Priority |
| 9 | Master | General switch for enabling all DMA channels |
| 8 | BPLEN | DMA channel for bitplanes |
| 7 | COPEN | Copper DMA channel |
| 6 | BLTEN | Blitter DMA channel |
| 5 | SPREN | Sprites DMA channel |
| 4 | DSKEN | Disk DMA channel |
| 3 | AUD3EN | DMA channel for voice 3 of the audio |
| 2 | AUD2EN | DMA channel for voice 2 of the audio |
| 1 | AUD1EN | DMA channel for voice 1 of the audio |
| 0 | AUD0EN | DMA channel for voice 0 of the audio |

## Amiga Operating System and libraries

The O.S. of Amiga, called AmigaOS and contained in a ROM memory called Kickstart, is composed of various libraries, which are not all present in memory at the same time, but are loaded dynamically. Its main component is called **Exec** and performs the functions of task scheduler, memory management, interrupt management, inter-process communication through messages, loading of dynamic libraries. At memory location $4, called **ExecBase**, there is the base address of the library. In order to use a dynamic library, it must first be opened using the Exec's OpenLibrary function. This function returns a pointer to the base address of the library, which must be used to call all functions of the library itself. When you stop using a library, you need to close it using the CloseLibrary function.

## Modular structure of the source code

Before we start writing the source code for our video game, let's think about how to structure it so that it's highly readable, maintainable, and reusable across multiple projects.

The simplest solution would be to put all the code in a single file. This solution is not optimal because:

1. As the number of routines increases, the listing would be huge and it would be difficult to search for something and even quickly position yourself on a section.
2. The possibilities of reuse would be practically null.

The optimal solution is one that subdivides the source code into modules based on functionality. For example, in this chapter the only functionality is to take control of the hardware and then we create a module called “takeover”.

In addition, there will be a main module, which will contain the starting point of the program, which calls the routines of all the other modules.

With this solution, we can include the takeover module in other projects, reusing the code. In addition, the takeover module will contain a limited number of routines and therefore will be easily readable.

Each module can consist of two files:

1. Include (.i) file that contains the definition of constants, data structures
2. A .s file that contains the definition of variables and routines.

To avoid multiple inclusions, you place the following code snippet at the beginning of the include file. It is also a good idea to start the file with a header comment, which shows the description of the module and the author.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Takes and releases control of Amiga hardware.

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

IFND        TAKEOVER\_I

TAKEOVER\_I  SET           1

            ENDC

In the “takeover.i” file, define the following constant to enable the DMA channels we need.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; DMACON register settings

                 ;5432109876543210

DMASET       equ %1000001000000000

Now create a file called "takeover.s", with the following structure:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Takes and releases control of Amiga hardware.

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; INCLUDES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  incdir     "include"

  include    "hw.i"

  include    "funcdef.i"

  include    "exec/exec\_lib.i"

  include    "graphics/graphics\_lib.i"

  include    "takeover.i"

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GLOBAL SYMBOLS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; ROUTINES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

The "Includes" section includes the inclusion of ".i" files defining constants. The Amiga Software Development Kit provides an include folder with ".i" files containing the constants necessary for accessing the hardware and functions of the OS. Visual Studio Code automatically creates this includes folder when you create an Amiga Assembly project.

## Take System

Now let's start writing a routine that takes full control of the Amiga hardware, disabling the O.S. in a controlled manner. We will put this routine in the takeover.s file.

At first, we open the graphics.library and save its base address. This will be useful to us later.

So, let's disable O.S. multitasking first, to avoid giving up the use of the CPU to other tasks.

Then we disable the interrupts of the O.S. to prevent our video game from being interrupted.

Load the base address of the CUSTOM chips, $dff000, into register A5. This register **should not be modified** throughout our code. We will use this base address to access the registers of custom chips, through the indirect base + displacement addressing.

We save the state of the DMA channels and then set them according to our needs, so that we only enable the ones we use.

The last instructions disable AGA features. Below is the complete code of the routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Takes full control of Amiga hardware,

; disabling the O.S. in a controlled way.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

take\_system:

  move.l    ExecBase,a6            ; base address of Exec

  lea       gfx\_name,a1            ; OpenLibrary takes 1

; parameter: library name in

; a1

  jsr       OpenLibrary(a6)        ; opens graphics.library

  move.l    d0,gfx\_base            ; saves base address of

; graphics.library in a

; variable

  jsr       Forbid(a6)             ; disables O.S. multitasking

  jsr       Disable(a6)            ; disables O.S. interrupts

  lea       CUSTOM,a5              ; a5 will always contain

; CUSTOM chips base address

; $dff000

  move.w    DMACONR(a5),old\_dma    ; saves state of DMA channels

; in a variable

  move.w    #$7fff,DMACON(a5)      ; disables all DMA channels

  move.w    #DMASET,DMACON(a5)     ; sets only dma channels that

; we will use

  ; disables AGA features. only needed on A1200,A4000

  move.w    #0,$1fc(a5)            ; sets 16 bit FMODE

  move.w    #$c00,$106(a5)         ; disables 24 bit palette

  move.w    #$11,$10c(a5)          ; enables normal palette

  rts

The variables used by this routine are as follows and must be defined in the variables section of the “takeover.s” file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; string containing the name of graphics.library

gfx\_name  dc.b    "graphics.library",0,0

; base address of graphics.library

gfx\_base  dc.l    0

; saved state of DMACON

old\_dma   dc.w    0

To make the take\_system routine visible from the other modules and therefore from the main itself, you must make it global, using the **xdef** directive. Insert the following code snippet in the "GLOBAL SYMBOLS" section of the "takeover.s" file:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GLOBAL SYMBOLS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          xdef       take\_system

## Release System

Now we must see how to release control of the hardware to the O.S., so that, at the end of our program, we can return to the Amiga O.S. without problems.

First, we need to restore the state of the DMA channels saved in the old\_dma variable. Before copying the value to the DMACON register, we need to set bit 15 to 1. To set one bit to 1, leaving the others unchanged, just make the OR with a mask having all the bits at zero and only the bit to be set to one. In this case, the value of the mask is %1000000000000000000 or $8000.

Now we need to re-enable O.S. multitasking and interrupts, using the Permit and Enable routines of the Exec.

Finally, we close the graphics.library, using the CloseLibrary routine of the Exec.

At this point the program can terminate, giving control back to the Amiga O.S. Below is the code of the routine. Put it into the “takeover.s” file.

Also, add the release\_system routine to the global symbols in the “Global Symbols” section.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Releases the hardware control to the O.S.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef      release\_system

release\_system:

  or.w      #$8000,old\_dma           ; sets bit 15

  move.w    old\_dma,DMACON(a5)       ; restores saved DMA state

  move.l    ExecBase,a6              ; base address of Exec

  jsr       \_LVOPermit(a6)           ; enables O.S. multitasking

  jsr       \_LVOEnable(a6)           ; enables O.S. interrupts

  move.l    gfx\_base,a1              ; base address of graphics.library in a1

  jsr       \_LVOCloseLibrary(a6)     ; closes graphics.library

  rts

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GLOBAL SYMBOLS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          xdef       take\_system

          xdef       release\_system

## Main program

Now create a file named main.s. To reference two subroutines defined in another module, you need to use the **xref** directive, followed by the name of the external subroutine. Enter these directives in the "External References" section.

The two routines created, take\_system and release\_system, must be called at the beginning and end of the main program.

Below is the main code:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Amiga Assembly Game Programming Book

;

; Chapter 4 - Take control of Amiga hardware

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; INCLUDES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          incdir     "include"

          include    "hw.i"

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; EXTERNAL REFERENCES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          xref       take\_system

          xref       release\_system

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; MAIN PROGRAM

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          SECTION    code\_section,CODE

main:

          nop

          nop

          jsr        take\_system          ; takes the control of Amiga's

; hardware

mainloop  btst       #6,CIAAPRA           ; left mouse button pressed?

          bne.s      mainloop             ; if not, repeats the loop

          jsr        release\_system       ; releases the hw control to the O.S.

          rts

          END

The two NOP instructions at the beginning, are used to make the debug program stop on the "jsr take\_system" line. NOP is a null instruction, which does nothing.

## Main loop

Our video game will run in a loop, which we have called "mainloop". For now, this loop does not contain any instructions. We will add them later. To exit the loop, we control pressing the left mouse button. When you press this key, bit 6 of the CIAAPRA register becomes 0 and then you exit the loop.

## Run the program

Open the startup-sequence file, located into uae/s directory. Comment the last line using the ; character, like in the following code snippet.

"SYS:chapter4"

; Quits the emulator at the end of the program

;UAEquit

This change to the startup-sequence file eliminates the automatic exit from the emulator when the program ends.

If you try to compile and run the program, pressing the F5 key will bring up a completely black emulator screen. Since we haven't drawn anything on the screen, it is colored with the background color being black by default.

Immagine che contiene schermata, schermo, Rettangolo, portafotografie

Descrizione generata automaticamente

Pressing the left mouse button will terminate the program and will return to the AmigaDOS window. It's not a very exciting result, but the fact that the program closes without blocking the Amiga is already a good result, because it means that we can return to the O.S. in a correct way.



The source code created in this chapter will constitute the skeleton on which we will build our video game step by step, enriching it chapter after chapter. In the next chapters you will start to receive more interesting visual feedback than a black screen.

You can find the complete source code at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter4>

# 5. Game concept

In this chapter we will focus on the design of our video game.

## Video game genres

The first thing to do to start designing a video game is to choose the genre to which it belongs. During the course of video game history, many genres have been invented. Some of the most popular genres are:

* **Shoot'em up**: the aim is to shoot enemies, to earn points and advance in level. The first was Space Invaders, back in 1978.
* **Platform**: the aim is to go through levels made of platforms, jumping from one to another, avoiding enemies and collecting items. The most famous is Nintendo's Super Mario Bros.
* **Racing Games**: the aim is to drive cars or motorcycles, in challenges against the clock or against opponents.
* **Sports Games**: simulate various sports such as football, tennis, basketball.
* **Fighting Games (Beat'em up)**: the aim is to challenge opponents in various types of fights: karate, judo, boxing etc...
* **Role Play Games** (**RPG**): you play a role, trying to evolve your character. They usually have fantasy settings.

## Let's create a shoot'em up

For the main purpose of this book, which is to teach the programming of an Amiga video game in Assembly language, I chose shoot'em up as the genre. This is because it is a type of video game that does not require complex logic or even realistic physics. For example, a platformer requires physics for controlling jumps, logics for releasing and using objects and so on ... A sports video game, for example a football game, requires the implementation of all the logics that govern a football match. A shoot'em up only requires logic for the movement of enemies and for the management of any upgrades.


## Game Design

How do we describe what our video game should do?

First, we need to define what the purpose of the game is. In our case, the ultimate goal is to defend the Earth from the attacks of the evil alien invaders.

Who or what impersonates the human player? We drive a spaceship, called SX-9.

Where is the game set? It is set in the base that aliens have built on the dark side of the Moon, digging tunnels under the lunar surface. The shot is sideways and the spaceship will fly to the right, flying over the base. For the didactic book game, we will have only 1 level.



How do I complete a level? You have to defeat a spaceship that is at the end of the level, guarding that sector of the alien base. It will take many shots to destroy it.

How is the score assigned? Each destroyed enemy assigns a different score.

When does a game end? The player initially has an energy level, indicated by a bar. When the energy becomes zero, the game ends, game over!

How do I lose energy? When my spaceship touches the base structures or an enemy or is hit by an enemy shot, the energy level is decreased.

Can I upgrade my spaceship? Yes, by collecting particular objects, called "power-ups", I can enhance my fire capacity.

How do I get power-ups? By killing a particular type of enemy, which carries weapons.

Why should I choose this game over others in the same genre? Because it allows the upgrade of my spaceship's weapons.

The following table shows the enemies, with the relative score that is obtained by destroying them and the level of energy they initially possess.

|  |  |  |  |
| --- | --- | --- | --- |
| **Enemy** | **Score** | **Initial energy level** | **Notes** |
|  | 100 | 5 |  |
|  | 200 | 10 |  |
|  | 500 | 20 |  |
|  | 300 | 10 | Can fire shots |
|  | 1000 | 30 |  |
|  | 2000 | 40 |  |
|  | 5000 | 20 | End level boss |

At the bottom of the game screen, we want to have a HUD that displays the information the player needs:

* Score
* Energy level of his spaceship



After the game runs, we want a title screen to be displayed. Pressing the fire button on the joystick will start a new game.



For the sound, we want background music and sound effects.

The following table summarizes the sound effects.

|  |  |
| --- | --- |
| Sound effect description | Played when… |
| Start sound | A new game begins |
| Fire sound | A new shot is fired |
| Explosion | When an enemy or player ship explodes |
| Hit | When an enemy or player ship is hit |
| Powerup | When a powerup is taken |
| Game over | When the game is over |

## Technical game design

Now let's approach the game from a technical point of view.

For which platform do we want to develop our video game? In this case we chose the Commodore Amiga. The minimum model will be the A1200, as we want to use the advanced graphics allowed by the AGA chipset. It will also be compatible with the A4000.

What video mode will we use? We will use the lowres mode 320 x 256 pixels. In particular, we will use the dual playfield mode. On a playfield we will draw the map horizontally. On the second playfield we will draw the sprites. Each playfield will use 16 colors, for a total of 32.

How do we store the background of the level? Since we want a levelmap that is several screens wide (up to 20), we can't store it as a single image because it would take up too much memory. For example, a 320x256 screen with 16 colors occupies about 40,960 bytes. If we multiply this value by 20, we get 819,200 bytes or about 0.8 MB. Considering that the A1200 has a total of 2MB of RAM memory, you understand how the occupation of the background is excessive.

The solution is to use a tilemap, in which the map is built from a set of tiles or blocks of fixed size, as if it were a puzzle. In this way you only have to store the image containing the tiles and then the matrix that contains the tile index.

Can we use hardware sprites? Since the Amiga's hardware sprites are 8 per row of screen, and also for them to be 16 colors, we have to overlap two sprites, it is difficult to think of being able to manage enemies with only 4 sprites per row.

For the player's spaceship, enemies, bullets and other objects we will use Blitter Objects.

How do we scroll the screen? Using the Amiga hardware scrolling.

How do we control the game? Since it is a shoot'em up, the ideal control method is the joystick. There is no point in operating the spaceship with a mouse or keyboard. How many joystick buttons do we use? 1 button will be enough.

What kind of audio do we use? We will use sampled sound effects.

We will also use music, in ProTracker format, for the title screen.

Do we need to display text? Yes, for scoring and can be useful for viewing debugging information.

# 6. The Copper and copperlist

The **Copper** is a coprocessor that is used to control the Amiga's graphics subsystem. It can modify the graphics processor registers even at each scan line of the screen. In this way it is possible to mix multiple video modes on the same screen and display more colors than the video mode allows.

Copper fetches instructions from RAM via DMA channels and can therefore operate independently from the CPU. Below we will look at the two most used Copper instructions. All Copper instructions consist of two consecutive words.

## Move Instruction

This instruction moves a constant numeric value into a custom chip register.

The Move instruction has the following format:

|  |  |  |  |
| --- | --- | --- | --- |
| First word | | Second word | |
| Bit.pos. | **Description** | **Bit.pos.** | **Description** |
| 0 | Always set to 0 | 0-15 | Value to be inserted into the register |
| 1-8 | address of the destination register |  |  |
| 9-15 | Unused, always set to 0 |  |  |

An example of a MOVE instruction is the following, which moves the value $fff to register $180, COLOR0:

dc.w $0180,$0fff

Basically, it sets the first color of the palette to white.

## Wait Instruction

This instruction causes Copper to wait until the electron beam reaches a given position.

The wait instruction has the following format:

|  |  |  |  |
| --- | --- | --- | --- |
| First word | | Second word | |
| Bit.pos. | **Description** | **Bit.pos.** | **Description** |
| 0 | always set to 1 | 0 | always set to 0 |
| 1-7 | horizontal position | 1-7 | mask used for enabling horizontal comparison |
| 8-15 | vertical position | 8-14 | mask used for enabling vertical comparison |
|  |  | 15 | generally set to 1 |

An example is the following, which waits the line $40:

dc.w $4001,$fffe

The following statement is used to terminate a Copper program:

dc.w $ffff,$fffe

It tells Copper to wait for a position that doesn't exist, so Copper waits until the next frame. In fact, the horizontal position $FF is not reachable from the electron beam.

## The Copperlist

A set of instructions for Copper is commonly called a "**Copperlist**". After writing a copperlist, you need to tell Copper its address. The COP1LC ($dff080) register tells Copper the address of the copperlist. There is also a second COP2LC ($dff084) register that allows you to use a second copperlist, but we will not use it.

After loading the address of the copperlist into the COP1LC register, it is necessary to tell Copper to place its program counter at the beginning of the copperlist. This is done by writing any value into the COPJMP1 register ($dff088). In fact, this is a strobe register. In this way, at each frame, Copper will execute the copperlist.

Now let's try to write a very simple copperlist example, which colors the background half blue and half black.

We start with a MOVE statement that loads blue into the COLOR0 register, which is used for the background. Then we need to use a WAIT statement to wait for line 192. At this point we use another MOVE to change the COLOR0 color of the background to black. We end the program with the WAIT statement to terminate.

The complete copperlist is as follows:

; segment loaded in CHIP RAM

  SECTION    graphics\_data,DATA\_C

  xdef       copperlist

copperlist:

  ; BPLCON0 lowres video mode

  dc.w       $100,$0200

  ; puts blue value into COLOR0 register

  dc.w       $0180,$000f

  ; WAIT line 192 ($c0)

  dc.w       $c001,$fffe

  ; puts black value into COLOR0 register

  dc.w       $0180,$0000

  ; end of copperlist

  dc.w       $ffff,$fffe

Note that the first instruction enables the low resolution 320x256 video mode. This will be explained later.

The copperlist must be stored in the Amiga's CHIP memory, the only one Copper can access. To do this, you need to use the SECTION directive.

In this case we will use the following syntax to allocate a chip memory segment for the copperlist:

SECTION    graphics\_data,DATA\_C

This directive should be placed before the copperlist.

The xdef directive makes the copperlist public, i.e. visible to other modules.

To continue using a modular organization of the source code, place the copperlist in a separate file, called "copperlist.s".

Now let's see the code needed to tell Copper where the copperlist is located and to position it at its beginning:

  ; sets our copperlist address into Copper

  move.l     #copperlist,COP1LC(a5)

  ; reset Copper PC to the beginning of our copperlist

  move.w     d0,COPJMP1(a5)

This code snipped must be placed at the end of take\_system routine.

## Save and restore the system copperlist

Before modifying the COP1LC register, we need to save the address of the system copperlist, so that it can be restored when our program exits.

To get the address of the system copperlist, you just need to know the base address of graphics.library. The address of the system copperlist is at offset $26. This address should be saved in a variable, for example sys\_coplist. Here is an example code, that must be included in the routine take\_system.

  ; gfx base

  move.l     d0,a0

  ; saves system copperlist address

  move.l     $26(a0),sys\_coplist

In the variables section, we must add the following variable:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

...

; address of system copperlist

sys\_coplist:

  dc.l       0

At the end of our program, we will have to restore the system copperlist, by loading the contents of the sys\_coplist variable into the COP1LC register and resetting the Copper PC, by writing to COP1JMP. The following code must be inserted at the beginning of the release\_system routine:

release\_system:

  ; restores the system copperlist

  move.l     sys\_coplist,COP1LC(a5)

  ; starts the system copperlist

  move.w     d0,COPJMP1(a5)

...

We must also remember to enable the DMA channel of the Copper, acting on the DMASET constant and setting bit 7:

; DMACON register settings

; enables only copper DMA (bit 7)

                 ;5432109876543210

DMASET       equ %1000001010000000

The complete code for this chapter can be downloaded from the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter6>

If you try to run the program we have written, pressing F5, you will get an image similar to the following figure. You'll see that the background is blue up to line 192, then it turns black.

Immagine che contiene schermata, schermo, Rettangolo

Descrizione generata automaticamente

# 7. How to display images on screen

In this chapter we will see how to display images on the Amiga screen. Finally, by running the sample program, you will have the satisfaction of seeing something on the screen!

What are the most popular formats of graphic images? Nowadays, the most popular formats for bitmap images are JPEG and PNG. The first format is used for digital images, while the second is more used to store graphics for video games, as it also supports palette mode.

Game artists also use the PSD format, native of Photoshop, which also contains layers information, or the XCF format, native of GIMP.

Back in the days of the Amiga, the most popular format was IFF, native of the famous drawing software Deluxe Paint.

## RAW format

The most convenient format to use when programming in Assembly is the **RAW** format, which is a sequence of bytes that directly represents the graphic data, without any metadata or header.

The VASM assembler provides a directive to include a RAW file in the source code.

The directive has the following syntax:

incbin <raw\_filename>

Please note that the graphic data must be loaded into the chip ram memory, so you must create a specific section in the listing.

SECTION graphics\_segment,DATA\_C

incbin "image.raw"

## RAW Converter

But how can we convert PNG images in RAW format?

On Windows there is a command line tool, called **Amiga Image Converter** or **amigeconv**, which can be downloaded for free at the following url:

<https://github.com/tditlu/amigeconv>

Let's start to see how to use this tool.

Suppose we have a PNG image, with 256 colors. To convert it to raw format we must type the following command, in a Windows command prompt window:

amigeconv -f bitplane -d 8 ./space.png space.raw

The meaning of the parameters is as follows:

* -f format, bitplane in this case
* -d number of bitplanes, 8 in this case

In addition to the image graphics data, we need to export the palette. Just type:

amigeconv -f palette -p pal8 -c 256 -x ./space.png space.pal

The meaning of the parameters in this case is as follows:

* -f format, palette in this case
* -p palette type, pal8 indicates 8 bits per color
* -c number of colors, 256 in this case
* -x indicates that the palette should be exported as copperlist statements, so that it can be included directly in the copperlist

This tool also allows the generation of masks for BOBs (which we will see later), export in the format required by hardware sprites, in the interleaved format.

After converting the image to raw format, we can load it into memory, in the ram chip segment, with the following instructions:

; segment loaded in CHIP RAM

            SECTION    graphics\_data,DATA\_C

img\_space6  incbin     "gfx/space.raw"         ; image 320 x 256 pixel , 8

; bitplanes

## Palette

Now we need to understand how Amiga handles colors and then load the palette into memory. Amigas with OCS/ECS chipsets have a palette of up to 32 colors. To set the colors of the palette, the registers called COLOR0 - COLOR31 are used, which correspond to the addresses $dff180 - $dff1be. The value to be written in the register has the following format:

|  |  |  |  |
| --- | --- | --- | --- |
| Bit 15-12 | Bit 11-8 | Bit 7-4 | Bit 3-0 |
| Not used | **Red** | **Green** | **Blue** |

In total we will have 12 bits to define the color, so Amiga can display 2^12 = 4096 different colors. As we saw in chapter 6 on Copper, to set the value of the custom chip registers we use the Copper MOVE instruction, creating a copperlist.

Amigas with AGA chipsets have 2 differences:

1. The values for the red, green, and blue components of the color use 8 bits. So, it uses 24 bits to represent a color. The color combinations that can be represented are 2^24 = 16M of colors!
2. The palette can have a maximum of 256 colors.

How do we enter an 8-bit value for the color components, since the color register has only 16 bits?

Let's represent the components of a color using uppercase letters for the upper nibble and lowercase letters for the low nibble:

RrGgBb

In the color register we will first insert the high nibbles:

dc.w $180,$RGB

Then we will set bit 9 of the BPLCON3 register ($dff106), which enables low nibbles.

dc.w $106,$200

Then we will insert the low nibbles:

dc.w $180,$rgb

How do we set the colors ranging from 32 to 256, given that there are only 32 color registers?

The 256 colors are divided into 8 banks of 32 each, numbered from 0 to 7. The active bank is selected using bits 13-15 of the BPLCON3 register. The following table shows the values needed for selecting each bank.

|  |  |  |
| --- | --- | --- |
| Value of bit 13-15 | Bank | BPLCON3 value |
| 000 | 0: colors 0-31 | $0 |
| 001 | 1: colors 32-63 | $2000 |
| 010 | 2: colors 64-95 | $4000 |
| 011 | 3: colors 96-127 | $6000 |
| 100 | 4: colors 128-159 | $8000 |
| 101 | 5: colors 160-191 | $A000 |
| 110 | 6: colors 192-223 | $B000 |
| 111 | 7: colors 224-255 | $E000 |

The amigeconv tool, using the -x option, exports the palette directly to the format suitable for inclusion in the copperlist.

In this way you will simply have to import the palette into the copperlist, as in the following code snippet.

copperlist:

         ...

palette  incbin    "gfx/space.pal"

## Bitplanes

Now let's see how Amiga displays images.

The Amiga video processor reads the image data from memory and drives the electron beam to draw the image on the monitor screen. An image on the screen is formed by moving the electron beam from left to right, one line at a time, starting from top to bottom. This process is repeated 50 times per second in the European PAL system or 60 times on NTSC systems.

Immagine che contiene linea, cassettiera, cassetto

Descrizione generata automaticamente

But how are images encoded in memory? The concept of **Bitplane** is used. A bitplane is nothing more than a matrix of bits, having the same dimensions as the screen resolution. For example, if we have a low-resolution screen of 320x256 pixels, it will be represented by a bitplane made up of 256 lines of 320 bits each, or 40 bytes. With a single bitplane we can display images with only two colors, in fact the zero bits will represent pixels colored with the first color of the palette (COLOR0 register), while the 1 bits will represent pixels colored with the second color of the palette (COLOR1).

At this point the question might be: how do we represent images with more than 2 colors? The answer is: using more bitplanes. In fact, if we have 2 bitplanes, we have 2^2=4 combinations, corresponding to the first 4 colors of the palette. To know the color of a pixel, we must:

1. calculate the index N of the color in the palette
2. Read the element N of the palette

To calculate the index N of a pixel, simply read the value of the pixel in the various bitplanes and write them down, starting from the bitplane with the highest index, which will correspond to the most significant digit of the index.

Immagine che contiene testo, diagramma, linea, Parallelo

Descrizione generata automaticamente

Immagine che contiene testo, schermata, Carattere, linea

Descrizione generata automaticamente

So, with 3 bitplanes, we can display 2^3=8 different colors, while with 4 bitplanes the colors will be 2^4=16 and so with 5 bitplanes we will have 2^5=32 different colors. The OCS/ECS chipsets support a maximum of 5 bitplanes. The AGA chipset supports up to 8 bitplanes. The bitplanes are normally stored one after the other. So, in the case of our 320x256 pixel resolution image with 16 colors, a bitplane is made up of 256 rows of 320 bits (40 bytes) each, with a total size of 10240 bytes. Having 16 colors, we will have to use 4 bitplanes. So, we will first have 10240 bytes representing bitplane0, then 10240 bytes of bitplane1, 10240 bytes of bitplane2 and 10240 bytes of bitplane3. In total the image takes up 10240\*4 = 40960 bytes.

There is another way to store bitplanes: the INTERLEAVED one, that is, the first line of bitplane0 is stored, the first line of bitplane1, ..., the first line of bitplane3, the second line of bitplane0, the second line of bitplane1, etc... This format is always managed by the amigeconv tool that we used, however we will not use it in this book.

At this point we have understood how an image is organized in memory and how it is drawn on the screen. But we still do not know how to tell the video processor where to read the image data from in memory. There are registers called BPLxPT, or simply bitplane pointers, that contain the memory address of the various bitplanes.

|  |  |  |
| --- | --- | --- |
| Register | Address | Bitplane |
| BPL0PT | **$dff0e0** | **bitplane0** |
| BPL1PT | **$dff0e4** | **bitplane1** |
| BPL2PT | **$dff0e8** | **bitplane2** |
| BPL3PT | **$dff0ec** | **bitplane3** |
| BPL4PT | **$dff0f0** | **bitplane4** |
| BPL5PT | **$dff0f4** | **bitplane5** |
| BPL6PT | **$dff0f8** | **bitplane6** |
| BPL7PT | **$dff0fc** | **bitplane7** |

In the copperlist we will have a section where we will set the bitplane pointers.

Each pointer is composed of a high and a low word. We initialize the values to zero. Then we'll use a routine to initialize them.

bplpointers:

             dc.w       $e0,0,$e2,0                    ; plane 0

             dc.w       $e4,0,$e6,0                    ; plane 1

             dc.w       $e8,0,$ea,0                    ; plane 2

             dc.w       $ec,0,$ee,0                    ; plane 3

             dc.w       $f0,0,$f2,0                    ; plane 4

             dc.w       $f4,0,$f6,0                    ; plane 5

             dc.w       $f8,0,$fa,0                    ; plane 6

             dc.w       $fc,0,$fe,0                    ; plane 7

How do you specify the number of bitplanes to use? There is the BPLCON0 ($dff100) register, whose bits 12-14 indicate least significant bits of the number of active bitplanes while bit 4 indicates the most significant bit. So, to set 8 bitplanes, you must clear bits 12-14 and set bit 4.

It is good practice to always set bit 9 of this register.

In the copperlist we must add the following code:

; BPLCON0 ($100)

; bit 0: set to enable BLTCON3 register

; bit 4: most significant bit of bitplane number

; bit 9: set to enable composite video output

; bit 12-14: least significant bits of bitplane number

;                  5432109876543210

  dc.w    BPLCON0,%0000001000010001

## Display window size

The visible portion of the screen, called the display window, is smaller than the entire monitor screen.

Immagine che contiene diagramma, linea, Rettangolo, Disegno tecnico

Descrizione generata automaticamente

Therefore, there are registers to set the start and end of the video window, called DIWSTRT and DIWSTOP respectively.

|  |  |  |
| --- | --- | --- |
| register | address | value |
| DIWSTRT | **$dff08e** | **bit 8-15 vertical position** |
|  |  | **bit 0-7 horizontal position** |
| DIWSTOP | **$dff090** | **bit 8-15 vertical position (add $1 as MSB)** |
|  |  | **bit 0-7 horizontal position (add $1 as MSB)** |

Typically, a 320x256 lowres display in PAL format has the following values:

DIWSTRT $2c81 ($81,$2c) = (129,44)

DIWSTOP $2cc1 ($1c1,$12c) = (449,300)

Note that the DIWSTOP values ​​must be preceded by a $1 as the most significant bit.

There are also two registers to set the start and end position of reading data from memory, called DDFSTRT and DDFSTOP.

|  |  |  |  |
| --- | --- | --- | --- |
| register | address | format | default PAL lowres value |
| DDFSTRT | **$dff092** | **bit 0-1: always 0** | **$38** |
|  |  | **bit 2-7: horizontal position in pixel** |  |
|  |  | **bit 8-15: always 0** |  |
| DDFSTOP | **$dff094** | **bit 0-1: always 0** | **$D0** |
|  |  | **bit 2-7: horizontal position in pixel** |  |
|  |  | **bit 8-15: always 0** |  |

The value of DDFSTRT is calculated with the following formula:

DDFSTRT = DIWSTRT.x/2 - 8

In fact, DIWSTRT.x = 129/2 - 8 = 64 - 8 = 56 ($38)

The value of DDFSTOP is calculated with the following formula:

DDFSTOP = DDFSTART + 8 \* (display\_window\_in\_word -1)

In fact, we have DDFSTOP = $38 + 8\*(20 -1) = $38 + $98 = $D0

Let's see how to set the size of the display window in the copperlist:

  dc.w    DIWSTRT,$2c81    ; display window start at ($81,$2c)

  dc.w    DIWSTOP,$2cc1    ; display window stop at ($1c1,$12c)

  dc.w    DDFSTRT,$38      ; display data fetch start at $38

  dc.w    DDFSTOP,$d0      ; display data fetch stop at $d0

  dc.w    BPLCON1,0

  dc.w    BPLCON2,0

  dc.w    BPL1MOD,0

  dc.w    BPL2MOD,0

We will see the meaning of the BPLCON1 registers, etc. afterwards.

Now let's write a routine to initialize bitplane pointers.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes bitplane pointers

;

; parameters:

; d0.l - address of bitplanes

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_bplpointers:

  movem     d0-a6,-(sp)

  lea       bplpointers,a1          ; bitplane pointers in a1

  move.l    #(N\_PLANES-1),d1        ; number of loop iterations in d1

.loop:

  move.w    d0,6(a1)                ; copy low word of image address into

; BPLxPTL (low word of BPLxPT)

  swap      d0                      ; swap high and low word of image address

  move.w    d0,2(a1)                ; copy high word of image address into

; BPLxPTH (high word of BPLxPT)

  swap      d0                      ; resets d0 to the initial condition

  add.l     #DISPLAY\_PLANE\_SZ,d0    ; point to the next bitplane

  add.l     #8,a1                   ; point to next bplpointer

  dbra      d1,.loop                ; repeats the loop for all planes

  movem     (sp)+,d0-a6

  rts

This routine must be called in the main, before entering the mainloop, as shown below.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; MAIN PROGRAM

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

main:

  nop

  nop

  bsr       take\_system         ; takes the control of Amiga's hardware

  move.l    #img\_space6,d0      ; address of image in d0

  bsr       init\_bplpointers    ; initializes bitplane pointers to our image

mainloop:

  btst      #6,CIAAPRA          ; left mouse button pressed?

  bne.s     mainloop            ; if not, repeats the loop

  bsr       release\_system      ; releases the hw control to the O.S.

  rts

Running the code we have created, we will get the display of a beautiful 256-color space image, in 320 \* 256 resolution.



The complete source code can be downloaded from the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter7>

## How to enlarge the display window

Many commercial video games use non-standard display window sizes.

The dimensions are always adjusted by acting on the DIWSTRT, DIWSTOP, DDFSTRT, DDFSTOP registers.

Let's say you want a display window that's 352 pixels wide instead of the classic 320.

Let's start the display window 16 pixels first, then at position x = 113 ($71)

DIWSTRT = $2c71

If we want a width of 352 pixels, the display window should end at 113+352 = 465 ($1d1)

DIWSTOP = $2cd1

The DDFSTRT value should be calculated using the following formula:

DDFSTRT = DIWSTRT.x/2 – 8 = 113/2 – 8 = 48 = $30

The DDFSTOP value should be calculated using the following formula:

DDFSTOP = DDFSTRT + 8 \* (display\_window\_in\_word -1) = 48 + 8 \* (22-1) = 48 + 8\*21 = 48 + 168 = 216 = $D8

To prove that these values work, in the example above, replace the included image with a 352-pixel-wide, 4-bitplane image.

img\_space  incbin    "gfx/image352.raw"    ; image 352 x 256 pixel , 4

; bitplanes

Edit the constants in the playfield.i file, like this:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

BPP           equ 4

WINDOW\_WIDTH  equ 352

WINDOW\_HEIGHT equ 256

PF\_PLANE\_SZ   equ WINDOW\_HEIGHT\*(WINDOW\_WIDTH/8)

Finally, in the copperlist, change the values of the DIWSTRT, DIWSTOP, DDFSTRT, DDFSTOP registers. Also edit BPLCON0 to use 4 bitplanes and include the new image palette.

copperlist:

         dc.w      DIWSTRT,$2c71         ; display window start at ($71,$2c)

         dc.w      DIWSTOP,$2cd1         ; display window stop at ($1d1,$12c)

         dc.w      DDFSTRT,$30           ; display data fetch start at $30

         dc.w      DDFSTOP,$d8           ; display data fetch stop at $d8

         ...

  ; BPLCON0 ($100)

  ; bit 0: set to 1 to enable BLTCON3 register

  ; bit 4: most significant bit of bitplane number

  ; bit 9: set to 1 to enable composite video output

  ; bit 12-14: least significant bits of bitplane number

  ;                         5432109876543210

         dc.w      BPLCON0,%0100001000000000

         ...

palette  incbin    "gfx/image352.pal"           ; palette

If you run the program, you will get the following image, 352 pixels wide and 256 pixels high.

Immagine che contiene schermata, testo, schermo, software

Descrizione generata automaticamente

The complete source code of the example can be found at the following url:

## Hires Mode

The OCS chipset also features hires video mode, 640 x 256 pixels. In this mode, the maximum number of colors is 16 (4 bitplanes).

To set this mode it is necessary to set bit 15 of the BPLCON0 register.

Also use the following values for DDFSTRT = $3c and DDFSTOP = $d4

Change the BPLCON0, DDFSTRT and DDFSTOP registers and change the image with one 640 x 256 pixels, 4 bitplanes.

If you run the program, will get the following image.

Immagine che contiene schermata, testo, software, Software multimediale

Descrizione generata automaticamente

The complete source code of the example can be found at the following url:

## Interlaced mode

This mode allows you to double the number of vertical rows, going from 256 to 512 in the case of PAL or from 200 to 400 in the case of NTSC.

Since the monitors of the time could not show more than 256 lines, a trick was used: the odd lines are shown first, then in the next frame the even line and so on. In fact, 256 lines are obtained, but with a refresh frequency halved, from 50 to 25 Hz. This caused the image to flicker. For this reason, it was a little-used video mode.

To set the interlaced mode, you need to set bit 2 of BPLCON0.

In addition, the module must be set with the values necessary to skip a line, so 40 in lowres or 80 in hires.

Change the copperlist as follows:

copperlist:

  dc.w    DIWSTRT,$2c81

  dc.w    DIWSTOP,$2cc1

  dc.w    DDFSTRT,$3c

  dc.w    DDFSTOP,$d4

  dc.w    BPLCON1,0

  dc.w    BPLCON2,0

  dc.w    BPL1MOD,80

  dc.w    BPL2MOD,80

  ; BPLCON0 ($100)

  ; bit 0: set to 1 to enable BLTCON3 register

  ; bit 2: interlaced mode

  ; bit 4: most significant bit of bitplane number

  ; bit 9: set to 1 to enable composite video output

  ; bit 12-14: least significant bits of bitplane number

  ; bit 15: hires mode

  ;                5432109876543210

  dc.w    BPLCON0,%1100001000000100

In addition, we must read at each frame the value of bit 15 of VPOSR, which indicates whether we are in a long frame (LF). If the bit is set, we need to show the odd lines, then set the bitplane pointers to the first odd line. If the bit is zeroed, we need to show the even lines and then set the bitplane pointers to the first even line.

The following code snippet shows the mainloop modified to alternate between odd and even lines.

main:

  jsr       take\_system         ; takes the control of Amiga's hardware

mainloop:

  lea       bplpointers,a1      ; address of bitplane pointers in copperlist

  move.l    #img,d0             ; address of image in d0

  move.l    #PF\_PLANE\_SZ,d1     ; plane size

  move.l    #BPP,d7             ; number of bitplanes

  move.w    VPOSR(a5),d2

  btst.l    #15,d2

  beq       .oddlines

  add.l     #80,d0

.oddlines:

  jsr       init\_bplpointers    ; initializes bitplane pointers to our image

  btst      #6,CIAAPRA          ; left mouse button pressed?

  bne.s     mainloop            ; if not, repeats the loop

  jsr       release\_system      ; releases the hw control to the O.S.

  rts

If you run the program, you will get the following image with 640 x 512 interlaced resolution.

Immagine che contiene schermata, software, Software multimediale, testo

Descrizione generata automaticamente

The complete source code of the example can be found at the following url:

# 8. Blitter

## Introduction

What is the **Blitter**? It is a coprocessor specialized in copying blocks of memory and drawing lines. It is physically located in the Agnus chip. Its name comes from the acronym of "BLock Image Transfer" or transfer of image blocks. In jargon, the operations of copying image blocks are called "blit" operations or "blittings". Much of the graphics capabilities of the Amiga are due to this coprocessor, which can operate in parallel with the CPU, accessing the chip memory via DMA. We need to learn how to use it if we want to do graphics with the Amiga.

## DMA Channels

The Blitter accesses the chip ram memory via DMA, without the need for the CPU. In this way the CPU is free to do other things during image copying operations, which generally require long times. This parallelism between the CPU and the coprocessors is the secret of the Amiga's efficiency. The characteristic of the DMA channels used by the Blitter is that they have a width of 16 bits, so they can transfer one word at a time. For this reason, the DMA channels can only access memory addresses that are multiples of 16 bits, i.e. even ones. The Blitter can use 3 DMA channels for input, called "A, B, C". For output it has only one channel, called "D".

How do you enable DMA channels? There is a BLTCON0 (**Blitter Control Register 0**) register, which has the following format:

|  |  |  |  |
| --- | --- | --- | --- |
| Register | Address | Bit position | Usage |
| BLTCON0 | $dff040 | 12-15 | Shift value for channel A |
|  |  | 11 | Enable channel A |
|  |  | 10 | Enable channel B |
|  |  | 9 | Enable channel C |
|  |  | 8 | Enable channel D |
|  |  | 0-7 | Minterms selection |

How do you specify the memory location to read from (channels A, B, C) or write to (channel D)? You use the **BPLxPT** registers, which are pointers to each DMA channel of the Blitter.

|  |  |  |
| --- | --- | --- |
| Register | Address | Usage |
| BPLAPT | $dff050 | Pointer for Blitter Channel A |
| BPLBPT | $dff04c | Pointer for Blitter Channel B |
| BPLCPT | $dff048 | Pointer for Blitter Channel C |
| BPLDPT | $dff054 | Pointer for Blitter Channel D |

## Logic functions

We have seen that the Blitter can use up to three DMA channels as input that read from memory and a single D channel as output. But what operations can it perform on the read data?

These operations are called **logic functions** or **minterms** and are specified by bits 0-7 of the BLTCON0 register. The table below shows the values ​​for the most used logic functions.

|  |  |
| --- | --- |
| value of bit 0-7 of BLTCON0 | Logic function |
| $F0 | D = A |
| $CA | D = AB + (NOT A)C |
| $0F | D = NOT A |

The logic function in the second line is used to draw sprites, as we will see later. For now, we will use the first logic function.

## Blitter busy

Before modifying any Blitter registers, you need to check that the Blitter is not already operating. Bit 14 of the DMACONR register ($dff002) is called BBUSY and is set if the Blitter is performing an operation. We can write a simple routine that waits until the Blitter is free, that is, until the BBUSY bit is zero.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Wait for the blitter to finish

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef       wait\_blitter

wait\_blitter:

.loop:

  btst.b     #6,DMACONR(a5)       ; if bit 6 is 1, the blitter is busy

  bne        .loop                ; and then wait until it's zero

  rts

Put this routine in a file called “bob.s”. This module will manage the Blitter Objects, called in jargon “bob”.

## BLTSIZE and how to start Blitter

How do you tell the Blitter how much data to process? There is a register called BLTSIZE ($dff058). The Blitter specifies the size of the area to process as a rectangle. The height is measured in number of rows, while the width is measured in number of WORDS. Bits 0-5 of BLTSIZE indicate the width, while bits 6-15 indicate the height. How do you start the Blitter? The Blitter starts as soon as the BLTSIZE register is written. For this reason, it must be the last register to be set.

## Modulus

Suppose we want to copy a 32-pixel wide image onto a 320 pixel wide screen. When the Blitter has copied the first line of the image onto the screen, it must move on to transferring the second line. We must tell the Blitter how many bytes it must skip before writing the second line of the image. This quantity is called **Modulus** and is calculated with the following formula:

Modulus = (H-L)/8

where H = destination image width in pixel

L = source image width in pixel

If H=320 and L=32, the modulus of the D channel will be (320-32)/8 = 36. If the source image is exactly 32 pixels wide, then its modulus will be zero. The following image helps to understand the concept of modulus.



To set the moduli for each Blitter channel, the following registers are used:

|  |  |  |
| --- | --- | --- |
| Register | Address | Channel |
| BLTAMOD | $dff064 | A |
| BLTBMOD | $dff062 | B |
| BLTCMOD | $dff060 | C |
| BLTDMOD | $dff066 | D |

## Shift

We have seen that DMA channels operate on words and that their pointer addresses must be aligned to word, i.e. integer multiples of 16. How do we draw an object via the Blitter with an x ​​coordinate that is not a multiple of 16? We must use the ability to shift the source data of channels A, B up to a maximum of 16 pixels.

|  |  |  |  |
| --- | --- | --- | --- |
| Register | Address | Shift value | Channel |
| BLTCON0 | $dff040 | bit 12-15 | A |
| BLTCON1 | $dff042 | bit 12-15 | B |

We will see in detail how to use the shift in a next chapter on drawing Bobs.

## Masking

The blitter can mask the first and last word of each line that passes through the A channel. Masking means that the Blitter performs a logical AND operation between the read word and a mask. The mask is specified in two registers called BLTAFWM ($dff044) and BLTALWM ($dff046), and they serve respectively to indicate the mask of the first and last word of each line read through the A channel. This functionality will be used for drawing the Bobs and will be explained in detail later.

## Example of copying an image to the screen

For the example of this chapter, we will start from the example of last chapter. Instead of pointing the bitplane pointers to a raw image, we point them to a completely cleared memory area. This will make the displayed screen completely blank. To create a cleared memory area in chip ram, without taking up space in the file, there is the BSS\_C segment. So, we will have to declare it as follows:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

        SECTION    bss\_data,BSS\_C

        xdef       screen

screen  ds.b       (PF\_PLANE\_SZ\*BPP)    ; visible screen

Put the BSS segment in the playfield.s file.

To learn how to use the Blitter, we will copy a 64x64 pixel 8-color image from memory to the screen.

To convert the PNG image to indexed format, we need to type the following command, in a Windows Command Prompt window:

amigeconv -f bitplane -d 3 tile.png tile.raw

To extract the palette from the PNG image, with the colors in 8 bit format per component, in a format suitable for inclusion in the copperlist, we must type the following command:

amigeconv -f palette -p pal8 -c 8 -x -n tile.png tile.pal

Let's start by creating a new file “tilemap.s” and including the image in memory, in the chip ram segment:

; segment loaded in CHIP RAM

          SECTION    graphics\_data,DATA\_C

img\_tile  incbin     "gfx/tile.raw"   ; image 64 x 64 pixel , 3 bitplanes

We include the palette directly in the copperlist, right after the bitplane pointers. Make sure that the palette has been exported in Copper format.

Compared to the previous chapter, here we will use 3 bitplanes, so in binary %0011. Of the binary number, the most significant bit must be inserted in bit 4 of BPLCON0. The three least significant bits are inserted into bits 12-14.

copperlist:

         ...

  ; BPLCON0 ($100)

  ; bit 0: set to 1 to enable BLTCON3 register

  ; bit 4: most significant bit of bitplane number

  ; bit 9: set to 1 to enable composite video output

  ; bit 12-14: least significant bits of bitplane number

  ; bitplane number: 3 => %0011

  ;                         5432109876543210

         dc.w      BPLCON0,%0011001000000000

         dc.w      FMODE,0                      ; 16 bit fetch mode

bplpointers:

         dc.w      $e0,0,$e2,0                  ; plane 1

         dc.w      $e4,0,$e6,0                  ; plane 2

         dc.w      $e8,0,$ea,0                  ; plane 3

palette  incbin    "gfx/tile.pal"               ; palette

         dc.w      $ffff,$fffe                  ; end of copperlist

Let's create a routine that copies this image to the visible screen. Put this routine in tilemap.s file. This module will manage the tilemaps, as we will see later.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draw a 64x64 pixel tile using blitter

;

; parameters:

; a0 - address of tile

; a1 - address where draw the tile

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          xdef       draw\_tile

draw\_tile:

          movem.l    d0-a6,-(sp)             ; saves registers into the stack

          moveq      #BPP-1,d1

          bsr        wait\_blitter

          move.w     #$ffff,BLTAFWM(a5)      ; don't use mask

          move.w     #$ffff,BLTALWM(a5)

          move.w     #$09f0,BLTCON0(a5)      ; enable channels A,D

                                             ; logical function = $f0, D = A

          move.w     #0,BLTCON1(a5)

          move.w     #0,BLTAMOD(a5)

          move.w     #(WINDOW\_WIDTH-TILE\_WIDTH)/8,BLTDMOD(a5) ; D channel

; modulus

.loop:

          bsr        wait\_blitter

          move.l     a0,BLTAPT(a5)           ; source address

          move.l     a1,BLTDPT(a5)           ; destination address

          move.w     #64\*64+4,BLTSIZE(a5)    ; blit size: 64 rows for 4 words

          add.l      #TILE\_PLANE\_SZ,a0       ; advances to the next plane

          add.l      #PF\_PLANE\_SZ,a1

          dbra       d1,.loop

          bsr        wait\_blitter

          movem.l    (sp)+,d0-a6             ; restores registers values from

; the stack

          rts

Notice that 3 blit operations are performed, one for each bitplane, using a loop. After each blit operation, the source and destination addresses are incremented to point to the next plane.

The draw\_tile routine must be called after the call to init\_bplpointers. We need to initialize the a0 register with the tile address and the a1 register with the address where we want to draw the tile. Suppose we want to display it at the center of the screen. The x and y coordinates must be loaded into the d0, d1 registers. We need to calculate the y\_offset and x\_offset to add to the base address of the screen. The vertical offset is simply the y position multiplied by the size in bytes of a display row, PF\_ROW\_SIZE. The horizontal offset is the x position divided by 8. Note that instead of division, we use a right shift, since the division instruction takes more clock cycles than the shift.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; MAIN PROGRAM

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

main:

          nop

          nop

          jsr       take\_system         ; takes the control of Amiga's hardware

          lea       bplpointers,a1      ; address of bitplane pointers in

; copperlist

          move.l    #screen,d0          ; address of screen in d0

          move.l    #PF\_PLANE\_SZ,d1     ; plane size

          move.l    #BPP,d7             ; number of bitplanes

          jsr       init\_bplpointers    ; initializes bitplane pointers to our

; image

          lea       img\_tile,a0

          move.w    #(WINDOW\_WIDTH-TILE\_WIDTH)/2,d0   ; x position

          move.w    #(WINDOW\_HEIGHT-TILE\_HEIGHT)/2,d1 ; y position

          mulu      #PF\_ROW\_SIZE,d1     ; y\_offset = y \* PF\_ROW\_SIZE

          asr.w     #3,d0               ; x\_offset = x/8

          add.w     d1,d0               ; sum the offsets

          ext.l     d0

          lea       screen,a1

          add.l     d0,a1               ; sum the offset to a1

          bsr       draw\_tile

mainloop  btst      #6,CIAAPRA          ; left mouse button pressed?

          bne.s     mainloop            ; if not, repeats the loop

          jsr       release\_system      ; releases the hw control to the O.S.

          rts

In the take\_system routine we added a call to the \_LVOOwnBlitter routine of graphics.library, which grants exclusive use of the Blitter to the application.

take\_system:

  ...

  move.l    d0,gfx\_base            ; saves base address of graphics.library in a variable

  move.l    d0,a6

  move.l    $26(a6),sys\_coplist    ; saves system copperlist address

  jsr       \_LVOOwnBlitter(a6)     ; takes the Blitter exclusive

  ...

In the release\_system routine we added a call to the \_LVODisownBlitter routine of graphics.library, to release the use of Blitter to other processes.

release\_system:

  ...

  or.w      #$8000,old\_dma           ; sets bit 15

  move.w    old\_dma,DMACON(a5)       ; restores saved DMA state

  move.l    gfx\_base,a6

  jsr       \_LVODisownBlitter(a6)    ; release Blitter ownership

  ...

The complete listing can be downloaded from the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter8>

By compiling the program and running it, you will get the image below, which shows a tile with which we will build the level of shoot’em up videogame.

Immagine che contiene schermata, testo, Rettangolo

Descrizione generata automaticamente

# 9. Tiles and tilemaps

## Tiles

A tile is nothing more than a square image, such as 64 x 64 pixels, that is used to compose the image of the game level. Making an analogy with a puzzle, the game level is the puzzle itself, made up of tiles.

The set of tiles used to make up a layer is called a **tileset**. Each tile is assigned a unique id, called a **tile index**.

Immagine che contiene schermata, testo, Rettangolo

Descrizione generata automaticamente

## Tilemap

How can the game level, made up of tiles, be represented? You can represent it with a matrix, whose elements represent the tile index. This matrix is called **Tilemap**.

To recap, to represent a game level, you need a tileset and a tilemap.



## Why are tiles used?

This question arises, in fact one might think that the easiest thing is to use a single large image of the level. The problem is in the size of that image. If we want a map 20 screens long, the image will have dimensions 20\*320=6400 horizontal pixels and 256 pixels vertical. A single bitplane of this image occupies (6400/8) \*256 = 204,800 bytes. If we use 8 bitplanes, the image will take up 1,638,400 bytes or 1.56 MBytes. You'll understand that we can't use all that memory for the background of the level alone, otherwise there wouldn't be enough memory for the rest of the graphics and sound. In addition, the video game could only run on Amiga AGA with more than 2 MB of chip memory.

Let's see how much a level takes up using tiles. Assuming tiles of 64 x 64 pixels, the tilemap will be a matrix of 6400/64 = 100 columns and 256/64 = 4 rows. Assuming you use a word for tile indexes, the tilemap will consist of 100 \* 4 = 400 words or 400 \* 2 = 800 bytes. To this must be added the image of the tileset, which we assume is 640 x 640 pixels. A bitplane occupies (640/8) \*640 = 51,200 bytes. Assuming you use 8 bitplanes, the tileset will take up 51,200 \* 8 = 409,600 bytes, which is 400KB or 0.39MB. So, with about 0.4 MB we can store the entire layer against 1.56 MB for the single image. We manage to reduce memory occupancy by a factor of almost 4. In this way we can use the remaining memory for other graphics or sound and the video game can also run on the base A1200. If we used fewer bitplanes, it could run on the A500 as well.

## Creating the tileset

As a tool for all graphics operations we will use Pro Motion NG, available at the following url:

<https://www.cosmigo.com/pixel_animation_software/downloads>

Both free and full paid versions of this tool are available. For our purposes, the free one is sufficient.

Now we should draw the tiles. Since I'm not an artist, I thought I'd buy a ready-made set of graphics for space shoot'em ups, costing about $10, from the following website:

<https://craftpix.net/>

Let's see how to prepare a tileset. Let's open a single tile with Pro Motion NG, using the "Load image" item from “File” menu. If the file is in RGB mode, the following dialog box will appear, to reduce the number of colors to 256, creating an optimized palette. In fact, Pro Motion NG works exclusively with palettes. Press OK to accept the default options.

Immagine che contiene testo, schermata, numero, Carattere

Descrizione generata automaticamente

The tile will be loaded and an image similar to the following will appear:

Immagine che contiene testo, schermata, software, Software multimediale

Descrizione generata automaticamente

To add the other tiles, we first need to enlarge the size of the image. From the “Frame” menu, select the "Resize Canvas" item. The following dialog box will appear. Set Width = 640 and Height = 640 and press OK.

Immagine che contiene testo, schermata, schermo, numero

Descrizione generata automaticamente

You will see that the image has been enlarged. To show a grid, you right-click on the grid-shaped button, highlighted in the figure below. In the "Tool & Paint Settings" box, set the grid size to 64 x 64 pixels and press the "Show Grid" checkbox. The grid will be displayed.



To add a second tile, from the "Brush" menu, select the "Load Brush..." item. Then select the tile file using the dialog box that will appear and press OK. The dialog box for optimizing the palette will appear. Press OK again. Now the tile will be loaded and you can place it on the grid with the mouse. You will observe anomalous colors. In fact, we must import the colors of the brush palette into the palette of our image. To do this, from the "Colors" menu, select the item "Import Colors from Brush...". The following dialog box will appear.

Immagine che contiene testo, schermata, schermo, software

Descrizione generata automaticamente

This window shows the number of colors required by the brush, those already present in the palette and those left to be imported. Press on the "Auto" button and we will see that the colors will be added to the palette. At this point we press the "Import" button. We will see that now the tile will take on the correct colors. Let's place it next to the first tile:

Immagine che contiene modello, arte, Rettangolo, piastrella

Descrizione generata automaticamente

Let's look at the box at the bottom right, called "Color Palette". This box shows the palette of the current image. The selected color is shown with a white triangle. At the bottom you can see the values of the selected color and you can change it using the sliders.

Immagine che contiene testo, schermata, schermo, software

Descrizione generata automaticamente

We continue to add the various tiles, repeating the same procedure. With each tile added, the palette will increase in size. To find out the number of colors used, from the "Colors" menu, select the item "Count Colors used":

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

The following dialog box will appear:

Immagine che contiene testo, schermata, Carattere

Descrizione generata automaticamente

Pro Motion NG also allows you to reduce the number of colors in an image.

From the "Colors" menu, select "Reduce Colors...":

Immagine che contiene testo, schermata, software, numero

Descrizione generata automaticamente

The following window will appear:

Immagine che contiene testo, schermata, schermo, numero

Descrizione generata automaticamente

The only value to change is the number of colors. By pressing "OK" we will be able to see the result. Obviously, by greatly reducing the number of colors, image quality is lost as it is not possible to reproduce the shades.

At the end we will have a tileset, in indexed PNG format, with 16 colors, like the one in the figure.

Immagine che contiene modello, Rettangolo, arte

Descrizione generata automaticamente

Be careful to always leave the first tile empty so as not to have problems later. You can find the tileset file I used at this url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/blob/main/chapter9/gfx/shooter_tiles.png>

## Creating the tilemap

To create a tilemap with Pro Motion NG, from the "File" menu, select the "New Project" item and then "Create...".



The following window will appear:



Enter the project name, tile size (64 x 64), tile width and height (100 x 3), and leave the rest of the options as is. Press OK. The following image will appear:



In the upper part you will have the tileset, while in the central part you will have the tilemap. Now they are both empty.

Now let's import the tileset we created earlier. From the "Tile Mapping" menu, select the "Import Tiles..." option.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

Select the PNG image containing the tileset and press OK. The following window will appear. Select "Append new Tiles" and press OK.

Immagine che contiene testo, schermata, schermo, numero

Descrizione generata automaticamente

The following window will appear to import the colors. Press "Auto" and then "Import".

Immagine che contiene testo, schermata, software, schermo

Descrizione generata automaticamente

If you now enlarge the "Tile Set" window, you will be able to see all the tiles, with the currently selected one highlighted in purple.

Immagine che contiene testo, schermata, modello, arte

Descrizione generata automaticamente

To create the map, select a tile in the tileset window and then draw it on the main map window, as shown in the following figure.

Immagine che contiene schermata, design

Descrizione generata automaticamente

Use a little imagination and creativity and complete the map. If you want to use a background color instead of a transparent one, select the "Background" box in the top left corner. You can choose the color or palette index for the background.

Immagine che contiene testo, schermata, software, schermo

Descrizione generata automaticamente

At the end, you will get something like the figure below.

Immagine che contiene schermata, linea

Descrizione generata automaticamente

You can find the complete project of the layer used in the book at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/blob/main/chapter9/gfx/map_final.pmp>

## Alternative way to create a tileset/tilemap

There is an alternative way to create a tileset. Suppose you draw the level map directly and save it to a “map.png” image.

Load the map image into Pro Motion NG and then select the "Turn Project into Tile Maps" item from the "Tile Mapping" menu:



The following window will appear:

Immagine che contiene testo, schermata, schermo, numero

Descrizione generata automaticamente

Enter 32 for the width and height of a Tile and press OK.

Pro Motion NG will automatically create a tileset, with tiles measuring 32x32 pixels this time:

Immagine che contiene schermata, testo, modello, Rettangolo

Descrizione generata automaticamente

It will also automatically create a tilemap corresponding to the layer image we initially provided:

Immagine che contiene schermata, linea

Descrizione generata automaticamente

## Export tilesets, palettes and map

To export the tileset and the tilemap, from the "Tile Mapping" menu, select the "Export All..." item.



The following window will appear:

Immagine che contiene testo, schermata, schermo, numero

Descrizione generata automaticamente

You can enter the number of columns in the tileset. For "Tile Map File Type" select "TXM – Text Tile Map", which is basically a csv file. Select the destination directory and press "Export". In that directory you will find both the PNG file of the tileset and the TXM file with the tilemap.

You can find these files at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter9/gfx>

## Import tilesets and tilemaps into our program

Let's convert the PNG image of the tileset to raw format and extract the palette using the amigeconv tool. Remember that the PNG image is 16 colors, so we need to use 4 bitplanes. To extract the palette, we use the pal4 format, with 4 bits per color, 16 total colors, and the -x option to export to Copperlist format.

amigeconv.exe -f bitplane -d 4 .\shooter\_tiles.png shooter\_tiles.raw

amigeconv.exe -f palette -p pal4 -c 16 -x .\shooter\_tiles.png shooter\_tiles.pal

Let's include the tileset in a chip memory segment, in tilemap.s file:

; segment loaded in CHIP RAM

         SECTION    graphics\_data,DATA\_C

tileset  incbin     "gfx/shooter\_tiles.raw" ; image 640 x 512 pixel , 4

; bitplanes

The palette file must be included directly in the copperlist:

copperlist:

         ...

palette  incbin    "gfx/shooter\_tiles.pal"    ; palette

         dc.w      $ffff,$fffe                ; end of copperlist

To create the tilemap file, we rename the \*.txm file to “map.s”. Then we open this file with Visual Studio Code. We add the dc.w directive at the beginning of each line, so that we can then include this file in the Assembly source.

dc.w 0,0,0,0,0,0,0,0,0, ...

dc.w 0,0,0,0,0,0,0,0,0, ...

 dc.w 0,0,0,0,2,3,3,69, ...

Before the dc.w directives, enter the "map" label and headers, as shown below.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Tilemap

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef    map

map:

  dc.w    0,0,0,0,0,0,0,0,...

## Drawing a tile

The routine that draws a tile using Bliiter is an evolution of the one created in the previous chapter. First we calculate the memory address where to copy the tile. At the base address of the screen we must add the x and y offsets. The offset\_y is obtained by multiplying the y by the size in bytes of the screen (PF\_ROW\_SIZE). The offset\_x is obtained by dividing the x by 8 (for efficiency reasons we use a right shift of 3).

We need to calculate the row and column of the tile in the tileset. By dividing the tile index by the number of columns in the tileset (TILESET\_COLS), we get the row in the quotient and the remainder is the column of the tile.

To get the x,y coordinates of the tile in the tileset, just multiply the row and column by 64 (tile width and height).

We then need to calculate the source address of the tile to be copied to the screen. We need to add the x and y offsets to the base address of the tileset.

At this point we set the Blitter registers and perform a loop to copy all 4 planes of the image. The complete routine code is the following:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a 64x64 pixel tile using Blitter.

;

; parameters:

; d0.w - tile index

; d2.w - x position of the screen where the tile will be drawn (multiple of 16)

; d3.w - y position of the screen where the tile will be drawn

; a1   - address where draw the tile

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef       draw\_tile

draw\_tile:

  movem.l    d0-a6,-(sp)             ; saves registers into the stack

    ; calculates the screen address where to draw the tile

  mulu       #PF\_ROW\_SIZE,d3         ; y\_offset = y \* PF\_ROW\_SIZE

  lsr.w      #3,d2                   ; x\_offset = x / 8

  ext.l      d2

  add.l      d3,a1                   ; sums offsets to a1

  add.l      d2,a1

    ; calculates row and column of tile in tileset starting from index

  ext.l      d0                      ; extends d0 to a long because the destination operand if divu must be long

  divu       #TILESET\_COLS,d0        ; tile\_index / TILESET\_COLS

  swap       d0

  move.w     d0,d1                   ; the remainder indicates the tile column

  swap       d0                      ; the quotient indicates the tile row

    ; calculates the x,y coordinates of the tile in the tileset

  lsl.w      #6,d0                   ; y = row \* 64

  lsl.w      #6,d1                   ; x = column \* 64

    ; calculates the offset to add to a0 to get the address of the source image

  mulu       #TILESET\_ROW\_SIZE,d0    ; offset\_y = y \* TILESET\_ROW\_SIZE

  lsr.w      #3,d1                   ; offset\_x = x / 8

  ext.l      d1

  lea        tileset,a0              ; source image address

  add.l      d0,a0                   ; add y\_offset

  add.l      d1,a0                   ; add x\_offset

  moveq      #BPP-1,d7

  bsr        wait\_blitter

  move.w     #$ffff,BLTAFWM(a5)      ; don't use mask

  move.w     #$ffff,BLTALWM(a5)

  move.w     #$09f0,BLTCON0(a5)      ; enable channels A,D

                                     ; logical function = $f0, D = A

  move.w     #0,BLTCON1(a5)

  move.w     #(TILESET\_WIDTH-TILE\_WIDTH)/8,BLTAMOD(a5)    ; A channel modulus

  move.w     #(WINDOW\_WIDTH-TILE\_WIDTH)/8,BLTDMOD(a5)     ; D channel modulus

.loop:

  bsr        wait\_blitter

  move.l     a0,BLTAPT(a5)           ; source address

  move.l     a1,BLTDPT(a5)           ; destination address

  move.w     #64\*64+4,BLTSIZE(a5)    ; blit size: 64 rows for 4 word

  add.l      #TILESET\_PLANE\_SZ,a0    ; advances to the next plane

  add.l      #PF\_PLANE\_SZ,a1

  dbra       d7,.loop

  bsr        wait\_blitter

  movem.l    (sp)+,d0-a6             ; restore registers from the stack

  rts

This routine must be called in the main, right after init\_bplpointers. We draw the tiles of index 2,3 side by side.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; MAIN PROGRAM

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

main:

  nop

  nop

  bsr       take\_system         ; takes the control of Amiga's hardware

  move.l    #screen,d0          ; address of screen in d0

  bsr       init\_bplpointers    ; initializes bitplane pointers to our image

  lea       screen,a1           ; address where draw the tile

  move.w    #0,d2               ; x position

  move.w    #256-64,d3          ; y position

  move.w    #2,d0               ; tile index

  bsr       draw\_tile

  move.w    #64,d2              ; x position

  move.w    #256-64,d3          ; y position

  move.w    #3,d0               ; tile index

  bsr       draw\_tile

On the screen we will have the following output:

Immagine che contiene testo, schermata, design

Descrizione generata automaticamente

## Drawing a column of tiles

Now we need to write a routine that draws a column of tiles, starting from the top.

The routine calls draw\_tile in a loop. At each iteration the y position is incremented and the next line of the tilemap is read. The complete code is the following:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a column of 3 tiles.

;

; parameters:

; d0.w - map column

; d2.w - x position (multiple of 16)

; a1   - address where draw the tile

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef       draw\_tile\_column

draw\_tile\_column:

  movem.l    d0-a6,-(sp)

    ; calculates the tilemap address from which to read the tile index

  lea        map,a0

  lsl.w      #1,d0                   ; offset\_x = map\_column \* 2

  ext.l      d0

  add.l      d0,a0

  moveq      #3-1,d7                 ; number or tilemap rows - 1

  move.w     #0,d3                   ; y position

.loop:

  move.w     (a0),d0                 ; tile index

  bsr        draw\_tile

  add.w      #TILE\_HEIGHT,d3         ; increment y position

  add.l      #TILEMAP\_ROW\_SIZE,a0    ; move to the next row of the tilemap

  dbra       d7,.loop

  movem.l    (sp)+,d0-a6

  rts

To test this routine, add the following code in main, after init\_bplpointers:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; MAIN PROGRAM

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

main:

  nop

  nop

  bsr       take\_system         ; takes the control of Amiga's hardware

  move.l    #screen,d0          ; address of screen in d0

  bsr       init\_bplpointers    ; initializes bitplane pointers to our image

  lea       screen,a1           ; address where draw the tile

  move.w    #11,d0              ; map column to draw

  move.w    #0,d2               ; x position (multiple of 16)

  bsr       draw\_tile\_column

The result is shown in the following figure:

Immagine che contiene testo, schermata

Descrizione generata automaticamente

## Let's fill the screen with tiles

Now let's try reusing the draw\_tile\_column routine to fill the entire screen. We write a routine called fill\_screen\_with\_tiles that takes as input the column of the map from which to start drawing the tiles. The routine calls in a loop the draw\_tile\_column. After each iteration the column of the map to draw and the x position are incremented. The code is the following:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Fills the screen with tiles.

;

; parameters:

; d0.w - map column from which to start drawing tiles

; a1   - address where draw the tile

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

fill\_screen\_with\_tiles:

       movem.l    d0-a6,-(sp)

       moveq      #5-1,d7             ; number of tile columns - 1 to draw

       move.w     #0,d2               ; position x

.loop  bsr        draw\_tile\_column

       add.w      #1,d0               ; increments map column

       add.w      #64,d2              ; increases position x

       dbra       d7,.loop

       movem.l    (sp)+,d0-a6

       rts

To test this routine, add the following statements to main:

main:

  nop

  nop

  bsr       take\_system               ; takes the control of Amiga's hardware

  move.l    #screen,d0                ; address of screen in d0

  bsr       init\_bplpointers          ; initializes bitplane pointers to our

; image

  lea       screen,a1                 ; address where draw the tile

  move.w    #11,d0                    ; map column to start drawing from

  bsr       fill\_screen\_with\_tiles

The result of running this routine is a screen that reproduces a piece of the game map, shown in the following figure. As you can see, we are starting to visualize something interesting and that looks more and more like a video game!

Immagine che contiene testo, schermata, Rettangolo, design

Descrizione generata automaticamente

You can find the complete source code at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter9>

# 10. Scrolling background

In this chapter, we'll look at how to implement a scrolling background. First, we will see a horizontal scrolling solution based on the Blitter, then one based on the hardware scrolling of the Amiga playfield. Therefore, we will see how to implement vertical scrolling, for purely educational purposes, since our game uses horizontal scrolling. Finally, we will see how to implement multi-directional scrolling.

## Blitter-based scrolling

The main motivation for using this scrolling technique is that it is easy to combine scrolling with sprite drawing.

In fact, since we completely redraw the background at each frame, we can simply draw the sprites over the background without worrying about restoring the background. Also, managing hardware scrolling together with double buffering is more complex.

Now let's see how Blitter-based scrolling works. Referring to the following figure, we have an image of the entire game level, several screens long. The rectangle highlighted in blue represents the camera, which has the same size as the screen, and shows a part of the level. By moving the camera to the right, we get the level to scroll. To display the part shown by the camera on the screen, we need to blit the shown portion of the level on the screen.

Immagine che contiene diagramma, linea, Rettangolo, schermata

Descrizione generata automaticamente

We saw in the last chapter that we don't have enough memory to store the entire level as a single image. To overcome this problem, we used a tilemap to represent the level.

So how do we achieve scrolling using tilemap?

Imagine we have an area the size of two screens, over which the camera can scroll. Refer to the figure below.

Immagine che contiene diagramma, linea, Parallelo, Piano

Descrizione generata automaticamente

We scroll the camera one pixel at a time to the right, as in the following figure.

Immagine che contiene diagramma, linea, Parallelo, Piano

Descrizione generata automaticamente

When the camera reaches an x-position that is a multiple of 16, we draw two columns of tiles at the left and right ends of the camera, taking the tiles from the tilemap (see the following figure).

Immagine che contiene diagramma, linea, Parallelo, Piano

Descrizione generata automaticamente

We continue scrolling and repeat the same steps (see following figure).

Immagine che contiene diagramma, linea, Parallelo, Piano

Descrizione generata automaticamente

When the camera reaches the edge of the background (see following figure), we notice that the left and right parts of the background have the same content.

Immagine che contiene diagramma, linea, Parallelo, Piano

Descrizione generata automaticamente

We can then reposition the camera to the initial position (see the following figure) without changing the image shown.

Immagine che contiene diagramma, linea, Parallelo, Piano

Descrizione generata automaticamente

At this point we can start over again.

Immagine che contiene diagramma, linea, Parallelo, Piano

Descrizione generata automaticamente

In this way we can scroll a tilemap of arbitrary length, using only a surface equal to twice the screen.

Obviously, to display the portion of the background shown by the camera we use the Blitter.

### Background initialization

Now it's time to put into practice the theoretical notions seen previously. For the example program we reuse part of the source code from the last chapter.

Let's create a new file called "scroll\_bgnd.i", in which we will insert the following constants:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Scrolling background

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

               IFND       SCROLL\_BGND\_I

SCROLL\_BGND\_I  SET        1

               include    "playfield.i"

               include    "tilemap.i"

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

BGND\_WIDTH      equ 2\*WINDOW\_WIDTH+2\*TILE\_WIDTH

BGND\_HEIGHT     equ 192

BGND\_PLANE\_SIZE equ BGND\_HEIGHT\*(BGND\_WIDTH/8)

BGND\_ROW\_SIZE   equ (BGND\_WIDTH/8)

VIEWPORT\_HEIGHT equ 192

VIEWPORT\_WIDTH  equ 320

SCROLL\_SPEED    equ 1

               ENDC

Now let's create another file called "scroll\_bgnd.s", which will contain the variables and subroutines of the background scrolling module.

We need to allocate memory for the background surface, 2 times the width of the display + 2\*64 pixels for the two columns of tiles at the edges. In the previously created file, we create a BSS\_C segment that can only contain zero-value data, allocated in chip memory. We also define the map\_ptr variable that contains the index of the next column of the tilemap to be drawn and the bgnd\_x variable, which is the current x coordinate of the camera into background surface.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

              SECTION    bss\_data,BSS\_C

bgnd\_surface  ds.b       (BGND\_PLANE\_SIZE\*BPP)    ; invisible surface used for

; scrolling background

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

              SECTION    code\_section,CODE

              xdef       map\_ptr

map\_ptr       dc.w       0                        ; current map column

              xdef       bgnd\_x

bgnd\_x        dc.w       0                        ; current x coordinate of

; camera into background

; surface

The background surface must be initialized with the first portion of the tilemap. To do this, we create the init\_background routine that reuses the draw\_tile\_column routine seen in last chapter, with some slight modifications to adapt it to draw on the background surface.

We draw the part that will be visible in the camera, composed of 5 columns 64 pixels wide each, for a total of 320 pixels.

Below is the code:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the background, copying the initial part of the level map.

;

; parameters:

; d0.w - map column from which to start drawing tiles

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

       xdef       init\_background

init\_background:

       movem.l    d0-a6,-(sp)

; initializes the part that will be visible in the display window

       moveq      #5-1,d7             ; number of tile columns - 1 to draw

       lea        bgnd\_surface,a1     ; address where draw the tile

       move.w     #TILE\_WIDTH,d2      ; position x

.loop  bsr        draw\_tile\_column

       add.w      #1,d0               ; increment map column

       add.w      #1,map\_ptr

       add.w      #TILE\_WIDTH,d2      ; increase position x

       dbra       d7,.loop

       sub.w      #1,map\_ptr

       movem.l    (sp)+,d0-a6

       rts

The init\_background routine uses the draw\_tile\_column routine to draw a column of tiles. The latter uses the draw\_tile routine to draw a tile. Compared to the version seen in the last chapter, now draw\_tile must draw not directly on the visible screen, but on a surface in memory, called bgnd\_surface and having a width greater than that of the visible screen. It is necessary to make some changes to adapt it to draw on this surface:

* in the calculation of the source address, we must use BGND\_ROW\_SIZE, or the size in bytes of a background row to calculate the y offset.
* the module of the D channel becomes the following: (BGND\_WIDTH-TILE\_WIDTH)/8
* to advance to the next plane, we must add BGND\_PLANE\_SIZE to a1

The updated code is the following, with the changes highlighted in green.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a 64x64 pixel tile using Blitter.

;

; parameters:

; d0.w - tile index

; d2.w - x position of the screen where the tile will be drawn (multiple of 16)

; d3.w - y position of the screen where the tile will be drawn

; a1   - address where draw the tile

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_tile:

  movem.l    d0-a6,-(sp)             ; saves registers into the stack

; calculates the screen address where to draw the tile

  mulu       #BGND\_ROW\_SIZE,d3       ; y\_offset = y \* BGND\_ROW\_SIZE

  lsr.w      #3,d2                   ; x\_offset = x / 8

  ext.l      d2

  add.l      d3,a1                   ; sums offsets to a1

  add.l      d2,a1

; calculates row and column of tile in tileset starting from index

  ext.l      d0                      ; extends d0 to a long because the

; destination operand if divu must be long

  divu       #TILESET\_COLS,d0        ; tile\_index / TILESET\_COLS

  swap       d0

  move.w     d0,d1                   ; the remainder indicates the tile column

  swap       d0                      ; the quotient indicates the tile row

; calculates the x,y coordinates of the tile in the tileset

  lsl.w      #6,d0                   ; y = row \* 64

  lsl.w      #6,d1                   ; x = column \* 64

; calculates the offset to add to a0 to get the address of the source image

  mulu       #TILESET\_ROW\_SIZE,d0    ; offset\_y = y \* TILESET\_ROW\_SIZE

  lsr.w      #3,d1                   ; offset\_x = x / 8

  ext.l      d1

  lea        tileset,a0              ; source image address

  add.l      d0,a0                   ; add y\_offset

  add.l      d1,a0                   ; add x\_offset

  moveq      #BPP-1,d7

  bsr        wait\_blitter

  move.w     #$ffff,BLTAFWM(a5)      ; don't use mask

  move.w     #$ffff,BLTALWM(a5)

  move.w     #$09f0,BLTCON0(a5)      ; enable channels A,D

                                     ; logical function = $f0, D = A

  move.w     #0,BLTCON1(a5)

  move.w     #(TILESET\_WIDTH-TILE\_WIDTH)/8,BLTAMOD(a5)    ; A channel modulus

  move.w     #(BGND\_WIDTH-TILE\_WIDTH)/8,BLTDMOD(a5)       ; D channel modulus

.loop:

  bsr        wait\_blitter

  move.l     a0,BLTAPT(a5)           ; source address

  move.l     a1,BLTDPT(a5)           ; destination address

  move.w     #64\*64+4,BLTSIZE(a5)    ; blit size: 64 rows for 4 word

  add.l      #TILESET\_PLANE\_SZ,a0    ; advances to the next plane

  add.l      #BGND\_PLANE\_SIZE,a1

  dbra       d7,.loop

  bsr        wait\_blitter

  movem.l    (sp)+,d0-a6             ; restore registers from the stack

  rts

### Background Drawing Using Blitter

Now we need to create a routine that allows us to implement the camera seen in the previous figure, that is, one that can display a portion of the background surface, where we have drawn a part of the tilemap that represents the game level. We call this routine draw\_background and it takes as parameters:

* x coordinate of the camera in the background surface
* address of the buffer in which to draw

The routine uses the Blitter to copy a rectangular window of dimensions (VIEWPORT\_WIDTH+16) \* VIEWPORT\_HEIGHT from the background surface to the screen.

Since the x coordinate can be any and not necessarily a multiple of 16, we need to use the shift of the Blitter channel A.

We calculate the source address to which the channel A should point by adding a horizontal offset to the base address of bgnd\_surface. The vertical offset is zero because we always start from y=0. The horizontal offset is obtained by dividing x by 8 and rounding to an even address.

To calculate the shift value, we select the first 4 bits of x using a mask, which represent the shift value S. Since we want to make a shift to the left, we must first initialize the shift value to the maximum and then decrement it. To do this, we calculate the shift value as 15-S. This value must be placed in the 4 most significant bits of the BLTCON0 register. To position it correctly we need to perform 2 shifts of 8 and 4 positions to the left, for a total of 12.

For the rest the routine makes a copy from channel A to channel D via Blitter. Pay attention to the values ​​of the modules, otherwise you will see a corrupted image.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the background, copying it from background\_surface via Blitter.

;

; parameters:

;

; d0.w - x position of the part of background to draw

; a1   - buffer where to draw

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_background:

  movem.l    d0-a6,-(sp)

  moveq      #BPP-1,d7

  lea        bgnd\_surface,a0

; calculates the source image address

  move.w     d0,d2                  ; copy of x

  asr.w      #3,d0                  ; offset\_x = x/8

  and.w      #$fffe,d0              ; rounds to even addresses

  ext.l      d0

; calculates the shift value

  add.l      d0,a0                  ; address of image to copy

  and.w      #$000f,d2              ; selects the first 4 bits, which

; correspond to the shift

  move.w     #$f,d3                 ; since we want a left scroll,

  sub.w      d2,d3                  ; we need to decrement the value of scroll,

; i.e. $f-scroll

  lsl.w      #8,d3                  ; moves the 4 shift bits to the position

; they occupy in BLTCON0

  lsl.w      #4,d3

  or.w       #$09f0,d3              ; inserts the 4 bits into the value to be

; assigned to BLTCON0

.planeloop:

  jsr        wait\_blitter

  move.l     a0,BLTAPT(a5)          ; channel A points to background surface

  move.l     a1,BLTDPT(a5)          ; channel D points to draw buffer

  move.w     #$ffff,BLTAFWM(a5)     ; no first word mask

  move.w     #$0000,BLTALWM(a5)     ; masks last word

  move.w     d3,BLTCON0(a5)

  move.w     #0,BLTCON1(a5)

  move.w     #(BGND\_WIDTH-VIEWPORT\_WIDTH-16)/8,BLTAMOD(a5)

  move.w     #(WINDOW\_WIDTH-VIEWPORT\_WIDTH-16)/8,BLTDMOD(a5)

  move.w     #VIEWPORT\_HEIGHT<<6+(VIEWPORT\_WIDTH/16)+1,BLTSIZE(a5)

  move.l     a0,d0

  add.l      #BGND\_PLANE\_SIZE,d0    ; points a0 to the next plane

  move.l     d0,a0

  move.l     a1,d0

  add.l      #PF\_PLANE\_SZ,d0        ; points a1 to the next plane

  move.l     d0,a1

  dbra       d7,.planeloop

  movem.l    (sp)+,d0-a6

  rts

### Vertical Blank

In a previous chapter we saw that the electron beam forms the video image in lines, starting from the top. A complete scan takes 1/50 of a second in the European PAL format. When the electron beam reaches the end of the screen, the electron beam is turned off and repositions itself at the top. This instant is called vertical blanking, since the electron beam is turned off (blank). We can use this signal to time our video game, in fact the vertical blank occurs every 1/50 of a second. Let's start writing a routine that waits for the electron brush to reach a given line. The position of the electron beam is reported in bits 8-16 of the VPOSR register. We use the and with the mask $1ff00 to select only bits 8-16. The value of the line to wait for is shifted to the left by 8 to align it with bits 8-16 of VPOSR. Then a comparison is made, and the loop is repeated until the comparison is zero.

The wait\_vblank routine, which waits for the vertical blank, uses the wait\_vline. Put these routines in the playfield.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Waits for the electron beam to reach a given line.

;

; parameters:

; d2.l - line

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

wait\_vline:

  movem.l    d0-a6,-(sp)     ; saves registers into the stack

  lsl.l      #8,d2

  move.l     #$1ff00,d1

wait:

  move.l     VPOSR(a5),d0

  and.l      d1,d0

  cmp.l      d2,d0

  bne.s      wait

  movem.l    (sp)+,d0-a6     ; restores registers from the stack

  rts

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Waits for the vertical blank

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

wait\_vblank:

  movem.l    d0-a6,-(sp)     ; saves registers into the stack

  move.l     #304,d2         ; line to wait: 304 236

  bsr        wait\_vline

  movem.l    (sp)+,d0-a6     ; restores registers from the stack

  rts

The wait\_vblank should be called in the main loop, so that each iteration of the loop occurs every 1/50 of a second.

### Background scrolling

To scroll the camera to the right, we create the routine scroll\_background. This first draws the background framed by the camera, using the routine draw\_background seen previously.

Every 16 pixels it draws two columns of new tiles, on the non-visible sides of the camera. The camera position is incremented by 16 and the tilemap pointer is incremented. If the end of the tilemap has been reached, the routine immediately returns to stop the scroll.

If the camera has reached the end of the background, it repositions itself to the beginning. Otherwise, the x position of the camera is incremented.

The constant SCROLL\_SPEED  defines the speed of the camera movement in pixels / 50th of a second.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Scrolls the background to the left.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

         xdef       scroll\_background

scroll\_background:

         movem.l    d0-a6,-(sp)

         move.w     bgnd\_x,d0                 ; x position of the part of

; background to draw

         move.l     draw\_buffer,a1            ; buffer where to

; draw

         bsr        draw\_background

         ext.l      d0                        ; every TILE\_WIDTH (64) pixels

; draws a new column

         divu       #TILE\_WIDTH,d0

         swap       d0

         tst.w      d0                        ; remainder of bgnd\_x/TILE\_WIDTH

; is zero?

         beq        .draw\_new\_column

         bra        .check\_bgnd\_end

.draw\_new\_column:

         add.w      #1,map\_ptr

         cmp.w      #TILEMAP\_WIDTH,map\_ptr    ; end of map?

         bge        .return

         move.w     map\_ptr,d0                ; map column

         move.w     bgnd\_x,d2                 ; x position = bgnd\_x –

; TILE\_WIDTH

         sub.w      #TILE\_WIDTH,d2

         lea        bgnd\_surface,a1

         bsr        draw\_tile\_column          ; draws the column to the left of

; the viewport

         move.w     bgnd\_x,d2                 ; x position = bgnd\_x +

; VIEWPORT\_WIDTH

         add.w      #VIEWPORT\_WIDTH,d2

         lea        bgnd\_surface,a1

         bsr        draw\_tile\_column          ; draws the column to the right

; of the viewport

.check\_bgnd\_end:

         cmp.w      #TILE\_WIDTH+VIEWPORT\_WIDTH,bgnd\_x ; end of background

; surface?

         ble        .incr\_x

         move.w     #SCROLL\_SPEED,bgnd\_x      ; resets x position of the part

; of background to draw

         bra        .return

.incr\_x  add.w      #SCROLL\_SPEED,bgnd\_x      ; increases x position of the

; part of background to draw

.return  movem.l    (sp)+,d0-a6

         rts

The scroll\_background  routine must be called in the main loop, just after the wait\_vblank. This way we are sure that it will be executed every 1/50 of a second.

mainloop:

  bsr      wait\_vblank          ; waits for vertical blank

  bsr      swap\_buffers

  bsr      scroll\_background

  btst     #6,CIAAPRA           ; left mouse button pressed?

  bne.s    mainloop             ; if not, repeats the loop

### Hide the first 16 pixels to remove noise

If you try to run the program now, you will notice that at the far left of the screen there are black pixels that go back and forth. They are due to the shift we make for scrolling. To avoid seeing this part, we can move the beginning of the display window 16 pixels forward, acting on the DIWSTRT register, as shown below:

dc.w       DIWSTRT,$2c91            ; display window start at ($91,$2c)

### Double buffering

If we make changes to the screen while the electron beam is drawing it, we see some noise in the image. To avoid this, the double buffering technique was invented.

To implement it, we create 2 video buffers, in the zeroed data segment, in CHIP RAM. We define two pointers to the video buffers, called view\_buffer and draw\_buffer. For all drawing operations we use the draw\_buffer, which is not visible. The view\_buffer instead is visible, in fact the bitplane pointers will point to it. At each vertical blank we will call the routine swap\_buffers, which will exchange the two pointers draw\_buffer and view\_buffer, causing the draw\_buffer to be displayed. The bitplane pointers are made to point to view\_buffer.

Put the following sections in the bob.s file. In fact bobs will require double buffering too.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

             SECTION    bss\_data,BSS\_C

             xdef       dbuffer1

dbuffer1     ds.b       (PF\_PLANE\_SZ\*BPP)    ; display buffers used for double

; buffering

dbuffer2     ds.b       (PF\_PLANE\_SZ\*BPP)

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

             SECTION    code\_section,CODE

view\_buffer  dc.l       dbuffer1             ; buffer displayed on screen

             xdef       draw\_buffer

draw\_buffer  dc.l       dbuffer2             ; drawing buffer (not visible)

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Swaps video buffers, causing draw\_buffer to be displayed.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef       swap\_buffers

swap\_buffers:

  movem.l    d0-a6,-(sp)                ; saves registers into the stack

  move.l     draw\_buffer,d0             ; swaps the values ​​of draw\_buffer and

; view\_buffer

  move.l     view\_buffer,draw\_buffer

  move.l     d0,view\_buffer

  lea        bplpointers,a1             ; sets the bitplane pointers to the

; view\_buffer

  moveq      #BPP-1,d1

.loop:

  move.w     d0,6(a1)                   ; copies low word

  swap       d0                         ; swaps low and high word of d0

  move.w     d0,2(a1)                   ; copies high word

  swap       d0                         ; resets d0 to the initial condition

  add.l      #PF\_PLANE\_SZ,d0            ; points to the next bitplane

  add.l      #8,a1                      ; points to next bplpointer

  dbra       d1,.loop                   ; repeats the loop for all planes

  movem.l    (sp)+,d0-a6                ; restores registers from the stack

  rts

You can find the full source code at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter10>

Running the program we created will scroll the entire level. You can adjust the scrolling speed by adjusting the constant SCROLL\_SPEED.

Immagine che contiene arte, Motivo, modello, design

Descrizione generata automaticamente

## Hardware scrolling

Now we want to implement the left scrolling of the background in a more optimized way, using the hardware scrolling feature provided by the Amiga.

The Amiga hardware provides the ability to scroll the playfield, i.e. the visible screen, up to a maximum of 15 pixels. The amount of the scrolling must be entered in register BPLCON1 ($dff102). More precisely, bits 0-3 contain the scroll for odd bitplanes, while bits 4-7 contain the scroll for even bitplanes.

How do you scroll the screen for more than 15 pixels? Once you reach 15 pixels, you must increase the bitplane pointers by 2 and reset the scroll value, so that you can scroll another 15 pixels and so on.

To scroll a tilemap, you can use a technique like the one seen earlier with the Blitter. You must create a playfield with a width of 2\*viewport\_width + 2\*tile\_width. You place the viewport tile\_width (64) pixels from the beginning of the playfield. Let's initialize the viewport with the first 5 columns of the tilemap. Then you draw the sixth column of the tilemap at either end of the viewport, as shown in the following picture. The bitplane pointer must be initialized at the beginning of the viewport, i.e. tile\_width pixels from the beginning of the playfield. Scroll values in BPLCON1 must be initialized to the maximum, i.e. $f. This is because to make a scroll to the left, we have to decrement this value to 0.

Immagine che contiene testo, linea, schermata, diagramma

Descrizione generata automaticamente

At this point we can act on the BPLCON1 register to decrement the scroll value until it brings it to 0. This causes the viewport to shift to the left by 1 pixel at a time. When the value of the scroll reaches 0, we need to move the bitplane pointer by 16 pixels, or 2 bytes. We also need to reset the scroll value to $f.

Immagine che contiene linea, testo, diagramma, schermata

Descrizione generata automaticamente

Every TILE\_WIDTH, or 64 pixels of displacement, we need to copy a new tilemap column at the ends of the viewport, as in the following figure:

Immagine che contiene testo, linea, diagramma, schermata

Descrizione generata automaticamente

Repeat the scrolling process until the viewport reaches the right end of the playfield minus the distance of one tile\_width. In this situation, we observe that the two halves of the playfield have identical content.

Immagine che contiene testo, linea, numero, Carattere

Descrizione generata automaticamente

You can then return the viewport to the beginning of the playfield, without changing the image on the screen for the player. From this point on, you can repeat the whole process, until you reach the end of the tilemap.

Immagine che contiene linea, diagramma, Diagramma, testo

Descrizione generata automaticamente

### Implementing hardware scrolling

Let's start by allocating memory for the playfield , larger than display window, in the chip ram zeroed data segment. Put this declaration in a file named “scroll\_bgnd.s”.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

              SECTION    bss\_data,BSS\_C

bgnd\_surface  ds.b       (BGND\_PLANE\_SIZE\*N\_PLANES)    ; surface used for

; scrolling background

Since we have a playfield larger than the display window, we need to set the odd and even bitplane modules. We also label with "scrollx" the value of BPLCON1, which contains the amount of scrolling. We initialize it at $00FF since to scroll to the left we must start from the maximum value and decrement it by 1. Apply these changes to the copperlist.s file, like in the following code snippet.

copperlist:

...

         dc.w    BPLCON1

scrollx  dc.w    $00ff           ; bits 0-3 and 4-7 scroll value

         dc.w    BPLCON2,0

         dc.w    BPL1MOD,(BGND\_WIDTH-VIEWPORT\_WIDTH)/8

         dc.w    BPL2MOD,(BGND\_WIDTH-VIEWPORT\_WIDTH)/8

We also need to initialize the bitplane pointers to 64 pixels (8 bytes) from the beginning of the bgnd\_surface. To do this, we use the init\_bplpointers routine, in main. We also initialize the background, draw the first 5 columns of the tilemap in the viewport and draw the sixth column on the sides of the viewport itself. These operations are carried out by the init\_background routine.

main:

  nop

  nop

  jsr       take\_system             ; takes the control of Amiga's hardware

  lea       bplpointers,a1          ; address of bitplane pointers in

; copperlist

  move.l    #bgnd\_surface+8-2,d0    ; address of visible screen buffer

  move.l    #BGND\_PLANE\_SIZE,d1     ; plane size

  move.l    #BPP,d7                 ; number of bitplanes

  jsr       init\_bplpointers        ; initializes bitplane pointers to

; bgnd\_surface

  move.w    map\_ptr,d0

  bsr       init\_background

  move.w    #TILE\_WIDTH,bgnd\_x      ; x position of the part of background to

; draw

Running the program now, you will see the beginning of the tilemap displayed.

To make the tilemap scroll, we need to write a new routine scroll\_background, placed in “scroll\_bgnd.s” file. If the viewport's move value is a multiple of 64, draw a new column of tiles at the left and right ends of the viewport.

Then set the amount of the scroll in the BPLCON1 register of the copperlist. If the amount of the scroll is zero, then refresh the bitplane pointers and reset the value of the scroll to $00ff.

If the viewport shift has reached the maximum value of TILE\_WIDTH+VIEWPORT\_WIDTH, then it returns the bitplane pointers to the initial position and resets the scroll value again to $00ff.

Finally, increments the value of the viewport shift by 1, bgnd\_x.

Below is the complete code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Scrolls the background to the left.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

         xdef       scroll\_background

scroll\_background:

         movem.l    d0-a6,-(sp)

         move.w     bgnd\_x,d0             ; x position of the part of

; background to draw

         tst.w      d0

         beq        .set\_scroll

         ext.l      d0                    ; every 64 pixels draws a new column

         divu       #TILE\_WIDTH,d0

         swap       d0

         tst.w      d0                    ; remainder of bgnd\_x/TILE\_WIDTH is

; zero?

         beq        .draw\_new\_column      ; if yes, draws new tile columns at

; the sides of viewport

         bra        .set\_scroll

.draw\_new\_column:

         add.w      #1,map\_ptr

         cmp.w      #TILEMAP\_WIDTH,map\_ptr    ; end of map?

         bge        .return

         move.w     map\_ptr,d0            ; map column

         move.w     bgnd\_x,d2             ; x position = bgnd\_x - TILE\_WIDTH

         sub.w      #TILE\_WIDTH,d2

         lea        bgnd\_surface,a1

         bsr        draw\_tile\_column      ; draws the column to the left of the

; viewport

         move.w     bgnd\_x,d2             ; x position = bgnd\_x +

; VIEWPORT\_WIDTH

         add.w      #VIEWPORT\_WIDTH,d2

         lea        bgnd\_surface,a1

         bsr        draw\_tile\_column      ; draws the column to the right of

; the viewport

.set\_scroll:

         move.w     bgnd\_x,d0

         and.w      #$000f,d0             ; selects the first 4 bits, which

; correspond to the shift

         move.w     #$f,d1                ; since we want a left scroll,

         sub.w      d0,d1                 ; we need to decrement the value of

; scroll, i.e. $f-scroll

         move.w     d1,d2                 ; copy

         move.w     d1,d0                 ; copy

         lsl.w      #4,d0

         or.w       d0,d1                 ; value of bits 0-3 and 4-7 of

; BPLCON1

         move.w     d1,scrollx            ; sets the BPLCON1 value for

; scrolling

         tst.w      d2                    ; scroll = 0?

         beq        .update\_bplptr        ; yes, update bitplane pointers

         bra        .check\_bgnd\_end

.update\_bplptr:

         move.w     bgnd\_x,d1

         asr.w      #3,d1                 ; offset\_x = bgnd\_x/8

         and.w      #$fffe,d1             ; rounds to even addresses

         ext.l      d1                    ; extends to long

         move.l     #bgnd\_surface,d0

         add.l      d1,d0                 ; adds offset\_x

         move.l     #BGND\_PLANE\_SIZE,d1

         bsr        init\_bplpointers

         move.w     #$00ff,scrollx        ; resets scroll value

.check\_bgnd\_end:

         cmp.w      #TILE\_WIDTH+VIEWPORT\_WIDTH,bgnd\_x    ; end of background

; surface?

         ble        .incr\_x

         move.w     #0,bgnd\_x             ; resets x position of the part of

; background to draw

         move.l     #bgnd\_surface-2,d0

         move.l     #BGND\_PLANE\_SIZE,d1

         bsr        init\_bplpointers

         move.w     #$00ff,scrollx        ; resets scroll value

         bra        .return

.incr\_x:

         add.w      #1,bgnd\_x             ; increases x position of the part of

; background to draw

.return  movem.l    (sp)+,d0-a6

         rts

The scroll\_background routine must be invoked in the main loop. It must also be synchronized with the vertical blank signal, so that it is recalled 50 times per second.

mainloop:

  jsr      wait\_vblank          ; waits for vertical blank

  jsr      scroll\_background

  btst     #6,CIAAPRA           ; left mouse button pressed?

  bne.s    mainloop             ; if not, repeats the loop

When you run the program, you will see image noise on the left side of the screen. To remove it, simply change the DDFSTRT register value, making the data fetch start 32 pixels before the display window starts. This will no longer make the disturbing part visible. However, we must reduce the modules by 4 bytes (32 pixels).

copperlist:

...

  dc.w    DDFSTRT,$28                                ; display data fetch start at $28 to hide scrolling artifacts

...

  dc.w    BPL1MOD,(BGND\_WIDTH-VIEWPORT\_WIDTH)/8-4    ; -4 because we fetch 32 more pixels

  dc.w    BPL2MOD,(BGND\_WIDTH-VIEWPORT\_WIDTH)/8-4

You can find the complete code at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter10B>

## Vertical scrolling

Now let's see how to implement vertical scrolling of a tilemap. By learning this technique, you can create vertically scrolling shoot'em ups like the famous Xenon!

To achieve vertical scrolling on the Amiga, you must first have a playfield with a height greater than the viewport. To scroll the viewport, simply change the bitplane pointers. Incrementing them by a number of bytes equal to the size of a line will move the display window one line down, while decrementing them by the same amount will move the display window one line up. The following picture illustrates the concept.



To achieve vertical scrolling down of a tilemap, we use a procedure similar to that seen for horizontal scrolling. Let's start with the situation shown in the following figure. We have a playfield with a width of 320 pixels while the height is:

2 \* (viewport height + tile\_height) = 2 \* (256 + 64) = 640 pixels

We place the viewport at a distance of (256 + 64) = 320 pixels from the bottom of the playfield, acting on the bitplanes pointers. Let's initialize the viewport by drawing the first 4 lines of the tilemap, numbered from 1 to 4 in the figure. Now let's draw row 5 of the tilemap at the top and bottom of the viewport.



Now let's move the viewport upwards, one line at a time, decrementing the bitplanes pointers, as shown in the following figure.



Whenever the viewport move is a multiple of tile\_height, i.e. 64, we need to draw a new row of the tilemap at the top and bottom of the viewport, as shown in the following figure.



When the viewport moves relative to the bottom of the playfield will be:

2 \* viewport\_height + tile\_height = 2 \* 256 + 64 = 576 pixel

We will have the situation shown in the following figure. We notice that the two halves of the playfield have identical content. So, we can move the viewport down without changing the content and therefore without the player noticing.



Then we move the viewport down so that we can start the whole process again, as shown in the figure below.



### Implementing Vertical Scrolling

Let's start creating a tilemap suitable for vertical scrolling. Let's use the same process used in chapter 9 for the horizontal tilemap.

The dimensions of the tilemap are:

* Width: 320 pixels
* Height: 2560 pixels, or 10 screens

Let's reuse the tileset from chapter 9, shown in the following image:



Have fun creating the map, an example can be seen in the following figure.



You can find the complete tilemap project, in Pro Motion NG format, at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/blob/main/chapter10C/gfx/vertical%20shooter%20map.pmp>

Export the tilemap and tileset as seen in chapter 9. You will get two files:

1. PNG image containing the tileset, rename as “vshooter\_tiles.png”
2. text file containing the tilemap, rename as “map.s”

At this point we need to convert the png image to raw format and extract the palette to copperlist format, using the amigeconv command line tool.

Type the following commands in a Windows terminal window.

amigeconv -f bitplane -d 4 .\vshooter\_tiles.png vshooter\_tiles.raw

amigeconv.exe -f palette -p pal4 -c 16 -x -n .\vshooter\_tiles.png vshooter.pal

Include the palette in the copperlist, while include vshooter\_tiles.raw in the chip memory segment, in the tilemap.s file.

copperlist:

...

bplpointers:

...

palette       incbin     "gfx/vshooter.pal"         ; palette

              dc.w       $ffff,$fffe               ; end of copperlist

Open the file map.s and add “dc.w” before every row. To do this quickly, you can use the replace function of Visual Studio Code. Press CTRL+H. In the upper right corner of the screen will appear a window similar to the following.



Select the “.\*” button, which enables the use of regular expressions.

Digit “^” in the Find text field. This regular expression means “at the beginning of a line”.

Digit “ dc.w “ in the Replace text field.

Press the replace all button.

At the beginning of each row, will be inserted the string “ dc.w “.

Press CTRL+ALT+F to autoformat the document.

Now add the “map:” label and the xdef directive at the beginning.

The file will appear like the following.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Tilemap

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef    map

map:

  dc.w    0,0,0,0,0

  dc.w    5,6,0,0,0

  dc.w    14,15,0,0,0

In the tilemap.i file, define the following constants. Notice that the tilemap is now 5 x 40 in size.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Tilemap and tileset

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

           IFND    TILEMAP\_I

TILEMAP\_I  SET     1

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

TILE\_WIDTH       equ 64

TILE\_HEIGHT      equ 64

TILE\_PLANE\_SZ    equ TILE\_HEIGHT\*(TILE\_WIDTH/8)

TILESET\_WIDTH    equ 640

TILESET\_HEIGHT   equ 192

TILESET\_ROW\_SIZE equ (TILESET\_WIDTH/8)

TILESET\_PLANE\_SZ equ (TILESET\_HEIGHT\*TILESET\_ROW\_SIZE)

TILESET\_COLS     equ 10

TILEMAP\_WIDTH    equ 5

TILEMAP\_HEIGHT   equ 40

TILEMAP\_ROW\_SIZE equ TILEMAP\_WIDTH\*2

           ENDC

In the file scroll\_bgnd.i, define the following constants.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Scrolling background

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

               IFND       SCROLL\_BGND\_I

SCROLL\_BGND\_I  SET        1

               include    "playfield.i"

               include    "tilemap.i"

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

BGND\_WIDTH      equ 320

BGND\_HEIGHT     equ 2\*VIEWPORT\_HEIGHT+2\*TILE\_HEIGHT

BGND\_PLANE\_SIZE equ BGND\_HEIGHT\*(BGND\_WIDTH/8)

BGND\_ROW\_SIZE   equ (BGND\_WIDTH/8)

VIEWPORT\_HEIGHT equ 256

VIEWPORT\_WIDTH  equ 320

SCROLL\_SPEED    equ 1

               ENDC

Modify the copperlist, in file copperlist.s, as below. Notice that the DDFSTRT register value has returned to the default of $38. In addition, the scroll is zero, as well as the modules.

copperlist:

  dc.w    DIWSTRT,$2c81    ; display window start at ($81,$2c)

  dc.w    DIWSTOP,$2cc1    ; display window stop at ($1c1,$12c)

  dc.w    DDFSTRT,$38      ; display data fetch start at $38

  dc.w    DDFSTOP,$d0      ; display data fetch stop at $d0

  dc.w    BPLCON1,0

  dc.w    BPLCON2,0

  dc.w    BPL1MOD,0

  dc.w    BPL2MOD,0

In the main you need to initialize the bitplanes pointers so that the viewport is at a distance of (256 + 64) pixels from the start of the playfield. This situation corresponds to the first figure in the previous paragraph.

main:

  nop

  nop

  jsr       take\_system            ; takes the control of Amiga's hardware

  lea       bplpointers,a1         ; address of bitplane pointers in copperlist

  move.l    #bgnd\_surface+(256+64)\*BGND\_ROW\_SIZE,d0    ; address of visible

; screen buffer

  move.l    #BGND\_PLANE\_SIZE,d1    ; plane size

  move.l    #BPP,d7                ; number of bitplanes

  jsr       init\_bplpointers       ; initializes bitplane pointers to our image

In this case, the tilemap will be drawn in horizontal rows, instead of columns as in the previous case of horizontal scrolling.

We then need to create a routine that draws a row of tiles. The code is similar to that of the draw\_tile\_column routine. Add this routine at the tilemap.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a row of 5 tiles.

;

; parameters:

; d0.w - map row

; d3.w - y position

; a1   - address where draw the tile

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef       draw\_tile\_row

draw\_tile\_row:

  movem.l    d0-a6,-(sp)

; calculates the tilemap address from which to read the tile index

  lea        map,a0

  mulu       #TILEMAP\_ROW\_SIZE,d0    ; offset\_y = map\_row \* TILEMAP\_ROW\_SIZE

  ext.l      d0

  add.l      d0,a0

  moveq      #TILEMAP\_WIDTH-1,d7     ; number or tilemap column - 1

  move.w     #0,d2                   ; x position

.loop:

  move.w     (a0),d0                 ; tile index

  bsr        draw\_tile

  add.w      #TILE\_WIDTH,d2          ; increment x position

  add.l      #2,a0                   ; move to the next column of the tilemap

  dbra       d7,.loop

  movem.l    (sp)+,d0-a6

  rts

Now you need to initialize the viewport, drawing the first 4 lines of the tilemap on it. Initialize the pointer to the tilemap line, map\_ptr, 4 lines before the end. This is because you will start showing the final part of the tilemap, moving the viewport upwards. To initialize the viewport, modify the init\_background routine, used for horizontal scrolling. Below is the code.

map\_ptr  dc.w       TILEMAP\_HEIGHT-4    ; current map row

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the background, copying the initial part of the level map.

;

; parameters:

; d0.w - map row from which to start drawing tiles

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

         xdef       init\_background

init\_background:

         movem.l    d0-a6,-(sp)

; initializes the part that will be visible in the viewport

         moveq      #4-1,d7             ; number of tile rows - 1 to draw

         lea        bgnd\_surface,a1     ; address where draw the tile

         move.w     #(256+64),d3        ; position y

.loop    bsr        draw\_tile\_row

         add.w      #1,d0               ; increment map row

         add.w      #1,map\_ptr

         add.w      #TILE\_HEIGHT,d3     ; increase position y

         dbra       d7,.loop

         move.w     #TILEMAP\_HEIGHT-4,map\_ptr

         movem.l    (sp)+,d0-a6

         rts

To scroll down the tilemap, you need to create a new routine, which you call scroll\_background. The following figure shows a flowchart of the routine.



The assembly code corresponding to the flowchart is as follows:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Scrolls the background downwards.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

         xdef       scroll\_background

scroll\_background:

         movem.l    d0-a6,-(sp)

         tst.w      map\_ptr                ; end of map?

         beq        .return                ; if yes, returns

; every 64 pixels draws a new map row at at the upper and lower edges of the viewport

         move.w     viewport\_y,d0

         ext.l      d0

         divu       #64,d0                 ; viewport\_y / 64

         swap       d0

         tst.w      d0                     ; remainder = 0?

         beq        .draw\_new\_row          ; yes, draws new row

         bra        .scroll\_viewport

.draw\_new\_row:

         sub.w      #1,map\_ptr

         move.w     map\_ptr,d0             ; map row

         move.w     viewport\_y,d3          ; y = viewport\_y - TILE\_HEIGHT

         sub.w      #TILE\_HEIGHT,d3

         lea        bgnd\_surface,a1

         bsr        draw\_tile\_row          ; draws the row at the top of the

; viewport

         move.w     viewport\_y,d3          ; y = viewport\_y + VIEWPORT\_HEIGHT

         add.w      #VIEWPORT\_HEIGHT,d3

         bsr        draw\_tile\_row          ; draws the row at the bottom of the

; viewport

.scroll\_viewport:

         sub.w      #1,viewport\_y          ; decreases viewport y, to move it

; upwards

         tst.w      viewport\_y             ; viewport\_y = 0?

         beq        .reset\_viewporty       ; if yes, resets the viewport y

; position

         bra        .update\_bplpointers

.reset\_viewporty:

         move.w     #VIEWPORT\_HEIGHT+TILE\_HEIGHT,viewport\_y

.update\_bplpointers:

         move.w     viewport\_y,d1

         mulu       #BGND\_ROW\_SIZE,d1      ; offset\_y = viewport\_y \*

; BGND\_ROW\_SIZE

         ext.l      d1

         move.l     #bgnd\_surface,d0

         add.l      d1,d0                  ; adds offset\_y

         move.l     #BGND\_PLANE\_SIZE,d1

         bsr        init\_bplpointers       ; updates bitplane pointers

.return  movem.l    (sp)+,d0-a6

         rts

To achieve vertical scrolling, you need to invoke the scroll\_background routine in the main loop:

mainloop:

  jsr      wait\_vblank          ; waits for vertical blank

  jsr      scroll\_background

  btst     #6,CIAAPRA           ; left mouse button pressed?

  bne.s    mainloop             ; if not, repeats the loop

By running the program, you will get the vertical scrolling of the tilemap.



The complete source code is available at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter10C>

## Multi directional scrolling

Now let's see how to implement a map with multi-directional scrolling. The following figure shows a map. The portion visible on the screen of this map is represented by the camera, depicted with a blue-bordered rectangle. In fact, bitplane pointers point to the memory address corresponding to the position of the camera.

Offset\_x and offset\_y are the distances (in bytes) between the base address of the map and the camera position.

With each frame, the camera position may change. Then the bitplane pointers must be reset, recalculating the offset values.

Immagine che contiene testo, schermata, diagramma, schermo

Descrizione generata automaticamente

Now let's see how to calculate offsets.

The y offset is obtained by multiplying camera\_y by the size of a map line in bytes. The following figure helps you understand the concept.

Immagine che contiene testo, schermata, Rettangolo, diagramma

Descrizione generata automaticamente

The x offset is obtained with the algorithm shown in the following figure.

Camera\_x is divided by 16. The offset\_x is obtained by multiplying the quotient by two.

Since we want to position the camera in arbitrary x coordinates and not just multiples of 16, we must also calculate the horizontal scroll value, which we will enter in the BPLCON1 register.

To calculate this value, we subtract the rest of the division from the $f value (the maximum allowed scroll value).

Then we shift this value to the left and make a logical or with the result of subtraction. This value represents scroll\_x and must be entered in the BPLCON1 register.

Immagine che contiene testo, schermata, cerchio, design

Descrizione generata automaticamente

### Implementing multi directional scrolling

To create an example program that implements multi-directional scrolling of a map, let's start by including the following modules in the project:

1. main.s
2. copperlist.s
3. takeover.s
4. takeover.i
5. playfield.s

The map image is shown below.

The dimensions are 640 x 576 pixels. It uses 16 colors.

Immagine che contiene schermata

Descrizione generata automaticamente

Convert the PNG image to raw format and extract the palette to copper format.

Below is the code to be inserted into the .bat file that performs the conversions.

@echo off

amigeconv.exe -f bitplane -d 4 .\map.png map.raw

amigeconv.exe -f palette -p pal4 -c 16 -x -n .\map.png map.pal

Create a map.s file, in which to insert a segment of chip memory.

In this segment, load the map.raw image, as shown in the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          SECTION    graphics\_data,DATA\_C

map\_gfx   incbin     "gfx/map.raw"             ; map playfield

Now you need to edit the copperlist, located in the copperlist.s file.

Set the DDFSTRT value to $30, which is 16 pixels less than the standard value, to remove scrolling artifacts.

Set the bitplane modulus two bytes less than the calculated one, to compensate for the 16 extra pixels read due to the DDFSTRT value.

The video mode is lowres, 320x256, with 4 bitplanes.

Include the palette that you generated earlier.

Below is the complete copperlist.

copperlist:

         dc.w      DIWSTRT,$2c81                ; display window start at

; ($81,$2c)

         dc.w      DIWSTOP,$2cc1                ; display window stop at

; ($1c1,$12c)

         dc.w      DDFSTRT,$30                  ; display data fetch start at

; $30 to hide scrolling

; artifacts

         dc.w      DDFSTOP,$d0                  ; display data fetch stop at

; $d0

         dc.w      BPLCON1

scrollx  dc.w      $0000                        ; bits 0-7 scroll value

         dc.w      BPL1MOD,MAP\_MOD-2            ; -2 because we fetch 16 more

; pixels

         dc.w      BPL2MOD,MAP\_MOD-2

  ; BPLCON0 ($100)

  ; bit 9: set to 1 to enable composite video output

  ; bit 12-14: bitplane number: 4 (%100)

  ;                         5432109876543210

         dc.w      BPLCON0,%0100001000000000

         dc.w      FMODE,0                      ; 16 bit fetch mode

bplpointers:

         dc.w      $e0,0,$e2,0                  ; plane 1

         dc.w      $e4,0,$e6,0                  ; plane 2

         dc.w      $e8,0,$ea,0                  ; plane 3

         dc.w      $ec,0,$ee,0                  ; plane 4

palette:

         incbin    "gfx/map.pal"                ; background palette

         dc.w      $ffff,$fffe                  ; end of copperlist

Even in order to statically display a portion of the map, it is necessary to initialize the bitplane pointers by pointing them to the base address of the map, map\_gfx. In addition, it is necessary to make our copperlist active.

These operations are carried out in the init\_map routine, the source code of which you can find below.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the game map.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          xdef       init\_map

init\_map:

          movem.l    d0-a6,-(sp)

; initializes bitplane pointers to map playfield

          lea        bplpointers,a1            ; bitplane pointers in the copperlist

          move.l     #map\_gfx,d0               ; address of playfield

          move.l     #MAP\_PLANE\_SZ,d1          ; playfield plane size

          move.l     #MAP\_BPP,d7               ; bitplanes number

          jsr        init\_bplpointers

; sets our copperlist address into Copper and starts copperlist execution

          move.l     #copperlist,COP1LC(a5)

          move.w     d0,COPJMP1(a5)

          movem.l    (sp)+,d0-a6

          rts

The init\_map routine must be called in main, at initialization time, as shown in the following code snippet.

main:

  jsr    take\_system    ; takes the control of Amiga's hardware

  jsr    init\_map

To track the position of the camera relative to the map, define two variables, as shown in the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          SECTION    code\_section,CODE

camera\_x  dc.w       0                         ; camera coordinates

camera\_y  dc.w       0

To move the camera and see the map move accordingly, you need to calculate the memory address corresponding to the camera's position on the map and then point the bitplane pointers to this address. In addition, it is necessary to calculate the amount of scrolls, to be set in the BPLCON1 register, since we want a movement on the x-axis not restricted to multiples of 8. These operations are carried out by the update\_map routine. The source code can be found below.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates map position, based on the camera position.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef       update\_map

update\_map:

  movem.l    d0-a6,-(sp)

  move.l     #map\_gfx,d0         ; address of playfield

; calculates offset\_x

  move.w     camera\_x,d1

  and.l      #$0000ffff,d1       ; clears high word of d1

  divu       #16,d1              ; offset\_x = camera\_x / 16 (in words)

  move.l     d1,d2               ; makes a copy

  and.l      #$0000ffff,d1       ; clears the remainder (upper word)

  lsl        #1,d1               ; offset\_x in bytes

  add.l      d1,d0               ; adds offset\_x to playfield address

; calculates offset\_y

  move.w     camera\_y,d1

  mulu       #MAP\_ROW\_SIZE,d1    ; offset\_y = camera\_y \* MAP\_ROW\_SIZE

  add.l      d1,d0               ; adds offset\_y to playfield address

; initializes bitplane pointers to map playfield calculated address

  lea        bplpointers,a1      ; bitplane pointers in the copperlist

  move.l     #MAP\_PLANE\_SZ,d1    ; playfield plane size

  move.l     #MAP\_BPP,d7         ; bitplanes number

  jsr        init\_bplpointers

; calculates the scroll value

  swap       d2                  ; remainder of camera\_x / 16

  and.w      #$000f,d2           ; gets only the least significant 4 bits

  move.w     #$f,d4

  sub.w      d2,d4               ; $f - remainder

  move.w     d4,d3               ; makes a copy

  lsl.w      #4,d3

  or.w       d4,d3               ; combines the scroll values for odd and even bitplanes

  move.w     d3,scrollx

  movem.l    (sp)+,d0-a6

  rts

For the example program, we want to be able to move the camera position with the joystick, so that we can navigate the map.

The routine move\_map\_with\_joy reads the joystick and updates the camera position. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Moves map with joystick.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  xdef       move\_map\_with\_joy

move\_map\_with\_joy:

  movem.l    d0-a6,-(sp)

  move.w     JOY1DAT(a5),d0            ; reads joystick port 1

  btst.l     #1,d0                     ; joy right?

  bne        .joy\_right

  btst.l     #9,d0                     ; joy left?

  bne        .joy\_left

  bra        .check\_vertical

.joy\_right:

  add.w      #CAMERA\_SPEED,camera\_x

  bra        .check\_vertical

.joy\_left:

  sub.w      #CAMERA\_SPEED,camera\_x

.check\_vertical:

  move.w     d0,d1                     ; makes a copy of d0

  lsr.w      #1,d1

  eor.w      d1,d0

  btst.l     #8,d0                     ; joy up?

  bne        .joy\_up

  btst.l     #0,d0                     ; joy down?

  bne        .joy\_down

  bra        .return

.joy\_up:

  sub.w      #CAMERA\_SPEED,camera\_y

  bra        .return

.joy\_down:

  add.w      #CAMERA\_SPEED,camera\_y

.return:

  bsr        limits\_map\_movement

  movem.l    (sp)+,d0-a6

  rts

To prevent the camera from going off the map, we write the limits\_map\_movement routine, which limits the location of the camera within the boundaries of the map. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Limits map movement.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

limits\_map\_movement:

  movem.l    d0-a6,-(sp)

  cmp.w      #CAM\_MINY,camera\_y     ; camera\_y < CAM\_MINY?

  blt        .limit\_miny

  cmp.w      #CAM\_MAX\_Y,camera\_y    ; camera\_y > CAM\_MAX\_Y?

  bgt        .limit\_maxy

  bra        .checkx

.limit\_miny:

  move.w     #CAM\_MINY,camera\_y     ; camera\_y = CAM\_MINY

  bra        .checkx

.limit\_maxy:

  move.w     #CAM\_MAX\_Y,camera\_y    ; camera\_y = CAM\_MAX\_Y

  bra        .checkx

.checkx:

  cmp.w      #CAM\_MINX,camera\_x     ; camera\_x < CAM\_MINX ?

  blt        .limit\_minx

  cmp.w      #CAM\_MAXX,camera\_x     ; camera\_x > CAM\_MAXX ?

  bgt        .limit\_maxx

  bra        .return

.limit\_minx:

  move.w     #CAM\_MINX,camera\_x     ; camera\_x = CAM\_MINX

  bra        .return

.limit\_maxx:

  move.w     #CAM\_MAXX,camera\_x     ; camera\_x = CAM\_MAXX

.return:

  movem.l    (sp)+,d0-a6

  rts

The update\_map and move\_map\_with\_joy routines must be called in the mainloop, as shown by the following code snippet.

mainloop:

  jsr     wait\_vblank          ; waits for vertical blank

  jsr     move\_map\_with\_joy

  jsr     update\_map

  btst    #6,CIAAPRA           ; left mouse button pressed?

  bne     mainloop             ; if not, repeats the loop

By running the test program, the camera will be placed in the map origin, at the top left. Using the joystick you can move the camera around the map, in 8 directions.

Immagine che contiene testo, schermata, arte, modello

Descrizione generata automaticamente

You can find the full source code of the example at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter10D>

# 11. Hardware sprites and joystick input

## What are hardware sprites?

A sprite is a graphic object that is independent of the background and other sprites themselves. Amiga provides up to 8 hardware sprites, managed by as many DMA channels.

With OCS/ECS chipsets, the sprites are 16 pixels wide while they can be as tall as the entire screen. A sprite can use 3 different colors. By attaching two sprites, you get a 15-color sprite. The hardware can detect collisions between sprites and between sprites and playfields.

## Example 1: Joystick movement of an attached sprite

To teach you how to use hardware sprites, we'll create an example program that will display a hardware sprite in attached mode, with 15 colors. The user will be able to move the sprite with the joystick. In addition, the program will detect collisions between the sprite and an image displayed on the playfield, coloring the edge of the screen red.

The starting point for this program will be the code created in Chapter 10.

### Sprite DMA Channels

To use hardware sprites, we need to enable the corresponding DMA channel. In practice we must set bit 5 of the DMACON register. In the following code, located in takeover.i file, we set the value of DMACON by means of a constant, which will then be assigned to DMACON in the take\_system routine.

; DMACON register settings

; enables sprites DMA (bit 5)

; enables copper DMA (bit 7)

; enables bitplanes DMA (bit 8)

           ;5432109876543210

DMASET equ %1000001110100000

### Sprite size

A hardware sprite, for Amigas with OCS/ECS chipset, has a width of 16 pixels, while the height can vary from 0 to the entire screen.

Immagine che contiene testo, schermata, Carattere, diagramma

Descrizione generata automaticamente

### Sprite coordinates

The origin of the sprite coordinate system is placed outside the visible screen. With reference to the following figure, the visible screen is 64 pixels horizontally and 44 vertically from the origin of the sprites. Then you need to add these quantities to the coordinates of the sprites on the visible screen.

Immagine che contiene testo, schermata, diagramma, linea

Descrizione generata automaticamente

### Sprites data structure

A hardware sprite has the data structure represented in the following figure.

Immagine che contiene testo, schermata, numero, Carattere

Descrizione generata automaticamente

The structure begins with two control words, named SPRxPOS and SPRxCTL. It ends with two control words that are both 0. After the initial two control words, two words follow that represent line 1, then line 2, line N.

The following figure shows how to calculate:

* VSTART, which is the line number at which the sprite begins
* VSTOP, the line number at which the sprite ends
* HSTART, the horizontal position at which the sprite begins



### Creating Sprite Data Structure

The data structure just seen will not be created manually, but the **amigeconv** tool will take care of it. For our example, we want to display a 15-color sprite. So, we create a 15-color, 16-pixel-wide PNG image and call it alien.png. The figure is shown, magnified by 800%, below.

Immagine che contiene modello, schermata, Policromia, quadrato

Descrizione generata automaticamente

To create the sprite's data structure, open a window with the Windows command prompt and type the following command.

amigeconv -f sprite -a -w 16 -t -d 4 .\alien.png alien.raw

The -a option indicates that the sprite is in attached mode.

The -w 16 option indicates the width 16 pixels.

The -t option indicates that control words should be created.

The -d 4 option indicates that 4 bitplanes are used.

### Inspecting the Sprite Data Structure with Hex Editor

The data structure will be created in the binary file “alien.raw”, which we can open with the Hex Editor of Visual Studio Code. Let's see how to do it.

First, you need to install the "Hex Editor" extension for Visual Studio Code.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

Once the extension is installed, you need to right-click on the file name alien.raw. From the context menu that appears, select the "Open With..." item.

Immagine che contiene testo, Carattere, numero, linea

Descrizione generata automaticamente

The following window will appear. Choose the "Hex Editor" item.

Immagine che contiene testo, schermata, Carattere, linea

Descrizione generata automaticamente

The following window will appear. On each line are shown 16 bytes of the file, in hexadecimal notation. In addition, the ascii representation of the bytes themselves is shown. Note that the first 4 bytes, highlighted in the figure, with a value of 0, represent the 2 control words of the 0 sprite.

Immagine che contiene testo, schermata, numero, Carattere

Descrizione generata automaticamente

The next word, highlighted in the following figure, represents plane 1 of the first line of sprite 0.



The next word, highlighted in the following figure, represents plane 2 of the first row of sprite 0.



Sprite 0 will end with another 4 bytes at 0, highlighted in the following figure.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

Sprite 1 will begin with the next 2 control words, highlighted in the following figure.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

Sprite 1 ends with 2 words to 0, highlighted in the following figure.



The alien.raw file must be included in the chip memory segment, as shown in the following code.

; segment loaded in CHIP RAM

              SECTION    graphics\_data,DATA\_C

...

alien\_sprite  incbin     "gfx/alien.raw"

Put this code into a new file, named “sprite.s”.

### Sprite pointers

Each sprite has a pointer that should point to a data structure like the one seen in the previous paragraph. The following table shows the pointer sprite logs.

|  |  |  |
| --- | --- | --- |
| Register | Address | Description |
| SPR0PT | $dff120 | Sprite 0 pointer |
| SPR1PT | $dff124 | Sprite 1 pointer |
| SPR2PT | $dff128 | Sprite 2 pointer |
| SPR3PT | $dff12c | Sprite 3 pointer |
| SPR4PT | $dff130 | Sprite 4 pointer |
| SPR5PT | $dff134 | Sprite 5 pointer |
| SPR6PT | $dff138 | Sprite 6 pointer |
| SPR7PT | $dff13c | Sprite 7 pointer |

Normally, sprite pointers are set in the copperlist, as in the following code snippet.

copperlist:

  ; BPLCON0 ($100)

  ; bit 9: set to 1 to enable composite video output

  ; bit 12-14: least significant bits of bitplane number

  ;                           5432109876543210

             dc.w    BPLCON0,%0100001000000000

bplpointers  :

             dc.w    $e0,0,$e2,0                  ; plane 1

             dc.w    $e4,0,$e6,0                  ; plane 2

             dc.w    $e8,0,$ea,0                  ; plane 3

             dc.w    $ec,0,$ee,0                  ; plane 4

sprite\_pointers:

             dc.w    SPR0PTH,0,SPR0PTL,0

             dc.w    SPR1PTH,0,SPR1PTL,0

             dc.w    SPR2PTH,0,SPR2PTL,0

             dc.w    SPR3PTH,0,SPR3PTL,0

             dc.w    SPR4PTH,0,SPR4PTL,0

             dc.w    SPR5PTH,0,SPR5PTL,0

             dc.w    SPR6PTH,0,SPR6PTL,0

             dc.w    SPR7PTH,0,SPR7PTL,0

Notice that in the copperlist we set the BPLCON0 register to display a 4-bitplane playfield and we also declared bitplane pointers.

To initialize the sprite pointers we create the following routine, init\_sprite\_pointers.

Put this routine into sprite.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes sprite pointers

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_sprite\_pointers:

  movem.l    d0-a6,-(sp)

  lea        sprite\_pointers,a1

  move.l     #alien\_sprite,d0

  move.w     d0,6(a1)                ; low word

  swap       d0

  move.w     d0,2(a1)                ; high word

  add.l      #8,a1                   ; next sprite pointer

  move.l     #alien\_sprite+76,d0     ; next sprite

  move.w     d0,6(a1)                ; low word

  swap       d0

  move.w     d0,2(a1)                ; high word

  bset       #7,alien\_sprite+76+3    ; sets sprite1 attached bit

  movem.l    (sp)+,d0-a6

  rts

The init\_sprite\_pointers routine must be invoked during the initialization phase, on the main, as shown in the following code snippet.

main:

  nop

  nop

  jsr       take\_system             ; takes the control of Amiga's hardware

; initializes bitplane pointers to background image

  lea       bplpointers,a1          ; address of bitplane pointers in

; copperlist

  move.l    #bgnd,d0                ; address of background image

  move.l    #PF\_PLANE\_SZ,d1         ; plane size

  move.l    #BPP,d7                 ; number of bitplanes

  jsr       init\_bplpointers

; initializes sprite pointers

  jsr       init\_sprite\_pointers

### Sprite colors

Sprites can use 3 colors, since the fourth is given by the transparent background. The following table shows the color registers associated with each pair of sprites.

|  |  |  |
| --- | --- | --- |
| Sprite no. | Color register | Address |
| Sprite 0,1 | Color17 | $dff1a2 |
| Color18 | $dff1a4 |
| Color19 | $dff1a6 |
| Sprite 2,3 | Color21 | $dff1aa |
| Color22 | $dff1ac |
| Color23 | $dff1ae |
| Sprite 4,5 | Color25 | $dff1b2 |
| Color26 | $dff1b4 |
| Color27 | $dff1b6 |
| Sprite 6,7 | Color29 | $dff1ba |
| Color30 | $dff1bc |
| Color31 | $dff1be |

### Sprites “attached”

To overcome the limitation of only 3 colors per sprite, you can use two "attached" sprites. In this mode, 15 colors can be used. Of course, the total number of sprites is reduced to 4. Sprites can only be stacked in pairs:

Pair 1: Sprite0 + Sprite 1

Pair 2: Sprite2 + Sprite 3

Pair 3: Sprite4 + Sprite 5

Pair 4: Sprite6 + Sprite 7

The colors are those ranging from:

Color 17 - $dff1a2 to Color 31 - $dff1be

We saw that we needed the -a flag to export the file with the data structure of our sprite in attached mode. Now we need to generate the palette and load it into memory.

To generate the palette, we use the amigeconv tool. Let's type the following command in a window with the Windows Command Prompt.

amigeconv.exe -f palette -p pal4 -c 16 -x .\alien.png alien.pal

We will get the alien.pal file, in binary copperlist format that will contain the palette of our sprite.

Since attached sprites use color registers 17 to 31, we need to edit the palette manually, using Hex Editor. After opening the file with Hex Editor, we notice that the palette uses color registers ranging from 0 to 15. Instead of the word $0180, which indicates the COLOR0 register, we must enter the value $01A0 corresponding to the COLOR16 register. Instead of $0182 (COLOR1) we replace $01A2 (COLOR17) and so on until COLOR31.

Immagine che contiene testo, Carattere, schermata

Descrizione generata automaticamente

After editing the alien.pal file, we include it in the copperlist, as in the following code snippet.

copperlist:

...

sprite\_pointers:

...

         dc.w      SPR7PTH,0,SPR7PTL,0

palette  incbin    "gfx/alien.pal"

### Priority between sprites and playfields

The priority between the sprites and playfield 1 is handled by bits 0-2 of register BPLCON2, while the priority between playfield 2 is handled by bits 3-5.

The following table shows the values to be entered in the BPLCON2 register.

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| Code | 000 | 001 | 010 | 011 | 100 |
| Max priority | Playfield | Pair 1 | Pair 1 | Pair 1 | Pair 1 |
|  | Pair 1 | Playfield | Pair 2 | Pair 2 | Pair 2 |
|  | Pair 2 | Pair 2 | Playfield | Pair 3 | Pair 3 |
|  | Pair 3 | Pair 3 | Pair 3 | Playfield | Pair 4 |
| Min Priority | Pair 4 | Pair 4 | Pair 4 | Pair 4 | Playfield |

On a practical level, you need to set the priority of all sprites on playfields, as in the following code snippet.

copperlist:

  ...

  dc.w    BPLCON2,%100100    ; sets sprites priority over playfield

### Placing a Sprite

We have seen on a theoretical level the meaning of the VSTART, VSTOP, HSTART fields of the sprite control words. Now let's create a routine that allows the positioning of a sprite, using the visible screen as a reference system. Below is the source code. Put this routine in sprites.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Sets the position of a sprite

;

; parameters:

; a1 - sprite address

; d0.w - y position (0-255)

; d1.w - x position (0-319)

; d2.w - sprite height

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

set\_sprite\_position:

  movem.l    d0-a6,-(sp)

  add.w      #$2c,d0                ; adds offset of screen beginning

  move.b     d0,(a1)                ; copies y into sprite VSTART byte

  btst.l     #8,d0                  ; bit 8 of y position is set?

  beq        .dontset\_bit8

  bset.b     #2,3(a1)               ; sets bit 8 of VSTART

  bra        .vstop

.dontset\_bit8:

  bclr.b     #2,3(a1)               ; clears bit 8 of VSTART

.vstop:

  add.w      d2,d0                  ; adds height to y position to get VSTOP

  move.b     d0,2(a1)               ; copies the value into sprite VSTOP byte

  btst.l     #8,d0                  ; bit 8 of VSTOP is set?

  beq        .dontset\_VSTOP\_bit8

  bset.b     #1,3(a1)               ; sets bit 8 of VSTOP

  bra        .set\_hpos

.dontset\_VSTOP\_bit8:

  bclr.b     #1,3(a1)               ; clears bit 8 of VSTOP

.set\_hpos:

  add.w      #128,d1                ; adds horizontal offset to x

  btst.l     #0,d1

  beq        .HSTART\_lsb\_zero

  bset.b     #0,3(a1)               ; sets bit 0 of HSTART

  bra        .set\_HSTART

.HSTART\_lsb\_zero:

  bclr.b     #0,3(a1)               ; clears bit 0 of HSTART

.set\_HSTART:

  lsr.w      #1,d1                  ; shifts 1 position to right to get the 8 most significant bits of x position

  move.b     d1,1(a1)               ; sets HSTART value

  movem.l    (sp)+,d0-a6

  rts

The set\_sprite\_position routine must be invoked at initialization time, immediately after the sprite pointers has been initialized, as shown in the following code snippet.

main:

  ...

; initializes sprite pointers

  jsr       init\_sprite\_pointers

; initializes sprite position

  lea       alien\_sprite,a1

  move.w    sprite\_y,d0             ; y position

  move.w    sprite\_x,d1             ; x position

  move.w    #SPRITE\_HEIGHT,d2       ; sprite height

  jsr       set\_sprite\_position

  lea       alien\_sprite+76,a1      ; attached sprite

  jsr       set\_sprite\_position

## Joystick input

The Amiga has 2 joystick ports, called port0 and port1. Normally the mouse is connected to port0, while the joystick is connected to port1. Of course, it is also possible to connect a joystick to the port0.

To read the movement of the joystick, you need to use the JOY0DAT register for the joystick connected to port0, while JOY1DAT for the one connected to port1.

Immagine che contiene testo, schermata, Carattere, linea

Descrizione generata automaticamente

Let's see how to detect the movement of the joystick lever. If we move the lever to the right, bit 1 of the JOYxDAT register is set. While if we move the lever to the left, bit 9 is set.

Immagine che contiene testo, linea, schermata, numero

Descrizione generata automaticamente

To detect the movement of the lever down, we need to make eor between bits 0 and 1 of JOYxDAT. If the result is 1 then the lever has been moved down. For the upward movement, we need to make the eor between bits 8 and 9.

From a practical point of view, just make a copy of the JOYxDAT register and make a shift to the right by 1 bit. Then the eor is made between the original register and the shifted copy.

The down state will correspond to bit 0 of the result, while the up state will correspond to bit 8.

Immagine che contiene diagramma, linea, testo, Rettangolo

Descrizione generata automaticamente

Normally Amiga joysticks had only 1 button. To detect the joystick button press in port0, just test bit 6 of the $bfe001 register. For the joystick button in port1, test bit 7. If the button is pressed, the bit is 0.

Immagine che contiene testo, linea, diagramma, numero

Descrizione generata automaticamente

The joystick ports of the Amiga provide support for 2 other buttons. The state of these buttons can be read through the bits of the POGGOR register, as shown in the following figure. Be careful, that the pressed state of the button corresponds to the 0 state of the bit.

Immagine che contiene testo, numero, linea, schermata

Descrizione generata automaticamente

Using the WinUAE emulator you can configure a 3-button joystick.

By pressing F12 and selecting the "Game Ports" item, the window shown in the following figure will appear. Select Gamepad from the drop-down menu. Configuration testing is also possible.

Immagine che contiene testo, schermata, software, Icona del computer

Descrizione generata automaticamente

### Moving the Sprite with the Joystick

We want to move the newly created sprite with the joystick. We create a new routine, move\_sprite\_with\_joystick, which reads the state of the joystick and changes the sprite coordinates accordingly. Put this routine in sprite.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Moves the sprite with the joystick

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

move\_sprite\_with\_joystick:

  movem.l    d0-a6,-(sp)

  move.w     JOY1DAT(a5),d0

  btst.l     #1,d0                     ; joy right?

  bne        .set\_right

  btst.l     #9,d0                     ; joy left?

  bne        .set\_left

  bra        .check\_up

.set\_right:

  add.w      #SPRITE\_SPEED,sprite\_x

  bra        .check\_up

.set\_left:

  sub.w      #SPRITE\_SPEED,sprite\_x

.check\_up:

  move.w     d0,d1

  lsr.w      #1,d1

  eor.w      d1,d0

  btst.l     #8,d0                     ; joy up?

  bne        .set\_up

  btst.l     #0,d0                     ; joy down?

  bne        .set\_down

  bra        .move\_sprite

.set\_up:

  sub.w      #SPRITE\_SPEED,sprite\_y

  bra        .move\_sprite

.set\_down:

  add.w      #SPRITE\_SPEED,sprite\_y

.move\_sprite:

  lea        alien\_sprite,a1

  move.w     sprite\_y,d0               ; y position

  move.w     sprite\_x,d1               ; x position

  move.w     #SPRITE\_HEIGHT,d2         ; sprite height

  bsr        set\_sprite\_position

  lea        alien\_sprite+76,a1

  bsr        set\_sprite\_position

  movem.l    (sp)+,d0-a6

  rts

The move\_sprite\_with\_joystick routine must be invoked in the main loop, at every frame.

mainloop:

  bsr      wait\_vblank                  ; waits for vertical blank

  bsr      move\_sprite\_with\_joystick

  bsr      check\_collisions

  btst     #6,CIAAPRA                   ; left mouse button pressed?

  bne.s    mainloop                     ; if not, repeats the loop

## Collisions

The Amiga hardware is capable of detecting collisions both between sprites and between sprites and playfields. Using the CLXCON register ($dff098) you can set the type of collisions to be detected. The following figure shows the register bits and their function. If we want to enable collisions of one of the odd sprites, we just need to set the corresponding bit. Collisions of even sprites are always detected. If we want to detect collisions between sprites and bitplanes, we need to enable planes. In addition, the color index must be loaded in bits 0-5. The collision will only be detected with the playfield bits of that color.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

The CLXDAT register ($dff00e) indicates which collisions have been detected. Bit 1 is set if there is a collision between playfield1 and the sprite pair1, i.e. sprites 0 and 1. The following figure shows the meaning of all the bits in the register.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

In our example program, we want to color the edge of the screen red when a collision between the sprite and the playfield is detected.

In the copperlist we set the CLXCON register to enable planes 1-4, enable sprite 1 and set the color number 8 as color index.

The check\_collisions routine will check if bit 1 of CLXDAT is set, which indicates a collision between playfield1 and pair 1, i.e. sprites 0 and 1. In this case, change the color 0 to red. Put this routine in sprites.s file.

copperlist:

  ...

  ; Controls sprite-bitplane collisions

  ; bit 12: enable sprite 1

  ; bit 6-9: enable bitplanes 1-4

  ; bit 0-5: color index for collisions with playfield

  ;                  5432109876543210

  dc.w       CLXCON,%0001001111001000

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Checks the collisions between sprite and playfield.

; If a collision is detected, change the border color to red.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

check\_collisions:

  movem.l    d0-a6,-(sp)

  move.w     CLXDAT(a5),d0

  btst.l     #1,d0                       ; bit 1 checks collisions between playfield and sprites 0-1

  bne        .collision

  move.w     #$0000,bgnd\_palette+2

  bra        .return

.collision:

  move.w     #$0f00,bgnd\_palette+2

.return:

  movem.l    (sp)+,d0-a6

  rts

The check\_collisions routine must be invoked in the main loop, as in the following code snippet.

mainloop:

  bsr      wait\_vblank                  ; waits for vertical blank

  bsr      move\_sprite\_with\_joystick

  bsr      check\_collisions

  btst     #6,CIAAPRA                   ; left mouse button pressed?

  bne.s    mainloop                     ; if not, repeats the loop

Running the example program, we will see a sprite in the shape of an alien's face that can move in 4 directions with the joystick in port 1. If we move the sprite to the playfield rock, we will see that the edge of the screen turns red, to detect the collision.

Immagine che contiene schermata, testo

Descrizione generata automaticamente

You can download the full code of the example at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter11>

## AGA Sprites

Amigas equipped with AGA chipsets can use sprites with a width of 16, 32 or 64 pixels.

Let's assume we want to use sprites that are 64 pixels wide. First, we need to enable the 64-bit fetch mode, i.e. the 64-bit transfer of data from memory to the video chip. To do this, we need to set the 0-1 bits of the FMODE register ($dff1fc) to the value %11. In addition, the bitplane modulus must be set to -8.

Bits 2-3 of FMODE set the width of the sprites. To set 64 pixels, the value will be %11. If we wanted 32 pixels, the value would be %01, while for 16 %00. In addition, with 64-bit transfer, you need to align the graphics data to 64-bit, using the CNOP 0,8 directive. This alignment must be done before the copperlist, before the sprite data, and before the playfield data.

Going back to the code of the previous example, we report the settings discussed above in the copperlist shown below.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Graphics data

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; segment loaded in CHIP RAM

  SECTION    graphics\_data,DATA\_C

  CNOP       0,8                     ; 64-bit alignment

copperlist:

  ...

  dc.w       BPL1MOD,-8              ; due to 64 bit fetch mode

  dc.w       BPL2MOD,-8

; FMODE

; bit 0-1: 64 bit fetch mode

; bit 2-3: 64 pixel sprite width

  dc.w       FMODE,%1111

The background image we want to use in this example uses a 256-color palette. Let's use the amigeconv tool to convert the image from PNG to raw format, by typing the following command in a Windows prompt window.

amigeconv.exe -f bitplane -d 8 .\bgnd\_256.png bgnd\_256.raw

Let's export the palette, in copperlist format, using the following command.

amigeconv.exe -f palette -p pal8 -c 256 -x .\bgnd\_256.png bgnd\_256.pal

Include the palette in the copperlist:

copperlist:

...

bgnd\_palette  incbin    "gfx/bgnd\_256.pal"

and include the image in the chip memory segment, preceded by the 64-bit alignment directive, as in the following code snippet.

      CNOP      0,8                   ; 64-bit alignment

bgnd  incbin    "gfx/bgnd\_256.raw"    ; background image

### 32/64 pixel sprite data structure

The following figure shows how the data structure of a 64-pixel-wide sprite is organized. In practice, the two initial control words are now 64 bits each. VSTART and HSTART remain in the first two bytes of the first control word, followed by 48 bits to zero. Similarly, VSTOP and control bits remain in the first two bytes of the second control word. The sprite ends with two 64-bit words at zero.

Immagine che contiene testo, ricevuta, numero, Parallelo

Descrizione generata automaticamente

Immagine che contiene testo, ricevuta, numero, Parallelo

Descrizione generata automaticamente

The data structure of a 32-pixel-wide sprite is shown in the following figure. In this case, the two control words are 32 bits long. In addition, VSTART and HSTART are followed by 16 bits to zero. Similarly, VSTOP and control bits are followed by 16 bits to zero.

Immagine che contiene testo, ricevuta, numero, Parallelo

Descrizione generata automaticamente

Immagine che contiene testo, ricevuta, numero, Parallelo

Descrizione generata automaticamente

### Creation of sprites 64 pixels wide

We want to use two attached sprites, 64 pixels wide, to represent the player-controlled spaceship. To do this, let's take an image of a spaceship, 128 pixels wide and reduce it to 16 colors. It is shown below, enlarged by 400%.

Immagine che contiene pixel, schermata, Modellazione 3D, cartone animato

Descrizione generata automaticamente

To generate sprite data, type the following command into a window with the Windows Command Prompt:

amigeconv.exe -f sprite -a -w 64 -t -d 4 .\ship.png ship.raw

To export the sprite 16-color palette, type:

amigeconv.exe -f palette -p pal8 -c 16 -x .\ship.png ship.pal

Include the sprite data in the chip memory segment, aligning it to 64 bits, as in the following code snippet.

             CNOP      0,8               ; 64-bit alignment

ship\_sprite  incbin    "gfx/ship.raw"

You need to select which palette to use for the sprites, using bits 0-7 of the BPLCON4 register. Bits 0-3 select the palette for even sprites, while bits 4-7 select for odd sprites. The values to be entered must be taken from the following table:

|  |  |  |
| --- | --- | --- |
| Value of BPLCON4 bits 0-3 or 4-7 | palette # | Initial color register |
| 0000 | 0 | 0 |
| 0001 | 0 | 16 |
| 0010 | 1 | 32 |
| 0011 | 1 | 48 |
| 0100 | 2 | 64 |
| 0101 | 2 | 80 |
| 0110 | 3 | 96 |
| 0111 | 3 | 112 |
| 1000 | 4 | 128 |
| 1001 | 4 | 144 |
| 1010 | 5 | 160 |
| 1011 | 5 | 176 |
| 1100 | 6 | 192 |
| 1101 | 6 | 208 |
| 1110 | 7 | 224 |
| 1111 | 7 | 240 |

Assuming you want to use palette 7, with colors starting at 224, you need to write the following code.

copperlist:

; BPLCON4

; bit 0-3 palette selection for even sprites

; bit 4-7 palette selection for odd sprites

; we select palette 7 for both so %1110

  dc.w    BPLCON4,%11101110

We want to load the palette in bank 7, the one with colors ranging from 224 to 240. The amigeconv tool exports the palette to copperlist format always using bank 0. So, before including the ship palette file in the copperlist, we need to edit it with the Hex Editor.

The value of bits 13-15 to be inserted in the BPLCON3 register ($106) can be found in the table in chapter 7 and is equal to %111 or $E000. Then open the "ship.pal" file with VS Code's Hex Editor. Press CTRL+F to search for a value. The following dialog box will appear. Click on the button containing the zeros, to enable the search in bytes. In the search box, type the value "0106", which is the address of the registry BPLCON3 in hexadecimal, and press enter. You will see two values highlighted, which you can navigate between using the arrows.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

Right after the first value, you will find the byte sequence "00", "00". Replace the first byte with the value "E0", to select bank 7 of the palette, high nibbles, as shown in the following figure.

Immagine che contiene testo, schermata, Carattere, numero

Descrizione generata automaticamente

Now you need to change the selection for the low nibbles of the palette. Go to the second value "0106" found. You will see that it will be followed by the bytes "02", "00". You must replace the first byte with "E2", since we are using bank 7. Now save the file.

Immagine che contiene testo, Carattere, schermata, linea

Descrizione generata automaticamente

You can now include the palette in the copperlist, right after the background palette, as shown in the following code snippet.

copperlist:

              ...

bgnd\_palette  incbin    "gfx/bgnd\_256.pal"

palette       incbin    "gfx/ship.pal"

### Changes to sprite pointer initialization

In the file sprites.i, change the sprite width and height, and add a constant for sprite size, like in the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

SPRITE\_WIDTH     equ 64

SPRITE\_HEIGHT    equ 70

SPRITE\_SIZE      equ SPRITE\_HEIGHT\*(SPRITE\_WIDTH/8)\*2+2\*4\*4

SPRITE\_SPEED     equ 1

You must change the init\_sprite\_pointers routine, located in sprites.s file, because now there are 4 sprites to initialize. To calculate the address of subsequent sprites, add the constant SPRITE\_SIZE, which represents the size of the sprite in bytes. It also sets the attached bit on sprite 3 as well.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes sprite pointers

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_sprite\_pointers:

  movem.l    d0-a6,-(sp)

  lea        sprite\_pointers,a1

  move.l     #ship\_sprite,d0

  move.w     d0,6(a1)                          ; low word

  swap       d0

  move.w     d0,2(a1)                          ; high word

  add.l      #8,a1                             ; next sprite pointer

  move.l     #ship\_sprite+SPRITE\_SIZE,d0       ; next sprite

  move.w     d0,6(a1)                          ; low word

  swap       d0

  move.w     d0,2(a1)                          ; high word

  bset       #7,ship\_sprite+SPRITE\_SIZE+9      ; sets sprite1 attached bit

  add.l      #8,a1                             ; next sprite pointer

  move.l     #ship\_sprite+SPRITE\_SIZE\*2,d0     ; next sprite

  move.w     d0,6(a1)                          ; low word

  swap       d0

  move.w     d0,2(a1)                          ; high word

  add.l      #8,a1                             ; next sprite pointer

  move.l     #ship\_sprite+SPRITE\_SIZE\*3,d0     ; next sprite

  move.w     d0,6(a1)                          ; low word

  swap       d0

  move.w     d0,2(a1)                          ; high word

  bset       #7,ship\_sprite+SPRITE\_SIZE\*3+9    ; sets sprite3 attached bit

  movem.l    (sp)+,d0-a6

  rts

### Sprite placement changes

You also need to change the set\_sprite\_position routine, as the data structure of a 64-pixel-wide sprite is different from a 16-pixel-wide one, as we've seen. In fact, the byte with control bits now has an offset of 9 and the byte with the lsb of VSTOP now has an offset of 8. Below is the modified version of the routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Sets the position of a sprite

;

; parameters:

; a1 - sprite address

; d0.w - y position (0-255)

; d1.w - x position (0-319)

; d2.w - sprite height

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

set\_sprite\_position:

  movem.l    d0-a6,-(sp)

  add.w      #$2c,d0                ; adds offset of screen beginning

  move.b     d0,(a1)                ; copies y into sprite VSTART byte

  btst.l     #8,d0                  ; bit 8 of y position is set?

  beq        .dontset\_bit8

  bset.b     #2,9(a1)               ; sets bit 8 of VSTART

  bra        .vstop

.dontset\_bit8:

  bclr.b     #2,9(a1)               ; clears bit 8 of VSTART

.vstop:

  add.w      d2,d0                  ; adds height to y position to get VSTOP

  move.b     d0,8(a1)               ; copies the value into sprite VSTOP byte

  btst.l     #8,d0                  ; bit 8 of VSTOP is set?

  beq        .dontset\_VSTOP\_bit8

  bset.b     #1,9(a1)               ; sets bit 8 of VSTOP

  bra        .set\_hpos

.dontset\_VSTOP\_bit8:

  bclr.b     #1,9(a1)               ; clears bit 8 of VSTOP

.set\_hpos:

  add.w      #128,d1                ; adds horizontal offset to x

  btst.l     #0,d1

  beq        .HSTART\_lsb\_zero

  bset.b     #0,9(a1)               ; sets bit 0 of HSTART

  bra        .set\_HSTART

.HSTART\_lsb\_zero:

  bclr.b     #0,9(a1)               ; clears bit 0 of HSTART

.set\_HSTART:

  lsr.w      #1,d1                  ; shifts 1 position to right to get the 8

; most significant bits of x position

  move.b     d1,1(a1)               ; sets HSTART value

  movem.l    (sp)+,d0-a6

  rts

The set\_sprite\_position routine must be called in the main. Now we need to initialize 2 pairs of attached sprites. Referring to the figure below, the second pair will have an x-coordinate shifted 64 pixels to the right of the first.

Immagine che contiene schermata, cartone animato, Modellazione 3D, Software per videogiochi

Descrizione generata automaticamente

Below is the code snippet to initialize the position of the sprites.

main:

  nop

  nop

  bsr       take\_system                     ; takes the control of Amiga's

; hardware

  move.l    #bgnd,d0                        ; address of bgnd image in d0

  bsr       init\_bplpointers                ; initializes bitplane pointers to

; our image

  bsr       init\_sprite\_pointers

  lea       ship\_sprite,a1

  move.w    sprite\_y,d0                     ; y position

  move.w    sprite\_x,d1                     ; x position

  move.w    #SPRITE\_HEIGHT,d2               ; sprite height

  bsr       set\_sprite\_position

  lea       ship\_sprite+SPRITE\_SIZE,a1

  bsr       set\_sprite\_position

  lea       ship\_sprite+SPRITE\_SIZE\*2,a1

  add.w     #SPRITE\_WIDTH,d1

  bsr       set\_sprite\_position

  lea       ship\_sprite+SPRITE\_SIZE\*3,a1

  bsr       set\_sprite\_position

You also need to change the move\_sprite\_with\_joystick routine, in the part where it invokes the set\_sprite\_position routine, as we need to update the position of 2 pairs of sprites now. Below is the code of the routine, with the modified part highlighted in green.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Moves the sprite with the joystick

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

move\_sprite\_with\_joystick:

  movem.l    d0-a6,-(sp)

  move.w     JOY1DAT(a5),d0

  btst.l     #1,d0                           ; joy right?

  bne        .set\_right

  btst.l     #9,d0                           ; joy left?

  bne        .set\_left

  bra        .check\_up

.set\_right:

  add.w      #SPRITE\_SPEED,sprite\_x

  bra        .check\_up

.set\_left:

  sub.w      #SPRITE\_SPEED,sprite\_x

.check\_up:

  move.w     d0,d1

  lsr.w      #1,d1

  eor.w      d1,d0

  btst.l     #8,d0                           ; joy up?

  bne        .set\_up

  btst.l     #0,d0                           ; joy down?

  bne        .set\_down

  bra        .move\_sprite

.set\_up:

  sub.w      #SPRITE\_SPEED,sprite\_y

  bra        .move\_sprite

.set\_down:

  add.w      #SPRITE\_SPEED,sprite\_y

.move\_sprite:

  lea        ship\_sprite,a1

  move.w     sprite\_y,d0                     ; y position

  move.w     sprite\_x,d1                     ; x position

  move.w     #SPRITE\_HEIGHT,d2               ; sprite height

  bsr        set\_sprite\_position

  lea        ship\_sprite+SPRITE\_SIZE,a1

  bsr        set\_sprite\_position

  lea        ship\_sprite+SPRITE\_SIZE\*2,a1

  add.w      #SPRITE\_WIDTH,d1

  bsr        set\_sprite\_position

  lea        ship\_sprite+SPRITE\_SIZE\*3,a1

  bsr        set\_sprite\_position

  movem.l    (sp)+,d0-a6

  rts

### Collision detection changes

Finally, you have to change the value of the CLXCON register that checks for collisions: you also need to enable sprite 3, all 6 bitplanes and as color index enter the value %10001 = 17.

copperlist:

  ...

; Controls sprite-bitplane collisions

; bit 13: set to enable sprite 3

; bit 12: enable sprite 1

; bit 6-11: enable bitplanes 1-6

; bit 0-5: color index for collisions with playfield

;                 5432109876543210

  dc.w    CLXCON,%0011111111010001

You also need to change the check\_collisions routine, as we want to detect collisions with both the 0-1 and 2-3 sprite pairs. In addition, there are several values to be entered in the palette to change the background color in the event of a collision.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Checks the collisions between sprite and playfield.

; If a collision is detected, change the border color to red.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

check\_collisions:

  movem.l    d0-a6,-(sp)

  move.w     CLXDAT(a5),d0

  btst.l     #1,d0                    ; bit 1 checks collisions between

; playfield and sprites 0-1

  bne        .collision

  btst.l     #2,d0                    ; bit 2 checks collisions between

; playfield and sprites 2-3

  bne        .collision

  move.w     #$0444,bgnd\_palette+6

  bra        .return

.collision:

  move.w     #$0f00,bgnd\_palette+6

.return:

  movem.l    (sp)+,d0-a6

  rts

Now, by running the program, you will finally see the result of so much effort: a spaceship 128 pixels wide, with 16 colors, which can be moved with the joystick. When it collides with the rock displayed on the playfield (256 colors), the background turns red.

You can find the full source code at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter11B>

Immagine che contiene testo, schermata

Descrizione generata automaticamente

# 12. Blitter objects (Bobs)

## Need to use Blitter Objects (Bobs)

2D video games make extensive use of animated characters, called in jargon “Sprite”. The Amiga hardware provides the ability to manage up to 8 sprites per scan line. However, these sprites can only have 3 colors and be a maximum of 64 pixels wide. If you want to use 15 colors, you must use two "attached" sprites and therefore the number of sprites per line drops to 4. Given all these limitations, it is not possible to use only hardware sprites to make a video game. Then there is the possibility of drawing sprites using the Blitter. In jargon these sprites are called **"Bobs"** or **B**litter **OB**ject**s**. Below we will see how to draw a bob.

## Mask

A basic requirement of a sprite is that it must have a transparent background. How do we specify the solid and transparent parts of a sprite image?

We use the concept of **mask**. This is a 1-bitplane image, where the transparent parts are set to zero, while the solid parts are set to one. The image below shows a sprite and its mask.



It is possible to automatically generate the mask from the color image of the sprite. Using the amigeconv tool we need to type the following command:

amigeconv -f bitplane -m -d 1 image.png image.mask

The image.mask file will contain the mask, in raw format.

## Configuring Blitter Channels and Logic Function

How do we use the mask with the Blitter?

We need to configure the Blitter DMA channels as follows:

* channel A: mask
* channel B: bob image
* channel C: background
* channel D: background

At this point we need a logic function that implements the following logic:

* read each pixel of the mask
* if the pixel is 1 then copy the pixel of the bob image (channel B) to D
* if the pixel is 0 then copy the corresponding pixel of the background (channel C) to D

The value to insert in bits 0-7 of BLTCON0 is equal to $CA. I will avoid the theoretic demonstration of how to get this value.

## Shifting and masking the last word

In chapter 10 we saw that, to copy an image with the Blitter in an x ​​position that is not a multiple of 16, we need to use the shift register. This explains why we used the A, B channels for the mask and the image, since only these two channels have the shifter.

When we perform a shift to the right, the bits that enter from the left are set to zero for the first word, while those that exit from the previous word enter in the next one. The bits that exit to the right of the last word would instead end up in the first word of the next line. But this behavior is not wanted, because it alters the image. The following figure shows this.

Immagine che contiene schermata, Rettangolo, linea, quadrato

Descrizione generata automaticamente

To avoid altering the sprite image during the shift, we must add 16 zeroed pixels after each line of the image. This empty space will accommodate the bits that exit from the shift of the last word and therefore the image will remain intact. Some graphics export tools can add this strip of 16 zeroed pixels to the image. However, adding the empty strip increases the size of the sprite images.

Immagine che contiene schermata, Rettangolo, linea

Descrizione generata automaticamente

Is there a way to avoid the increase in size?

If we increase the width of the Blitter window by 1 word, we will get those 16 pixels that are needed at the end of the line to accommodate the bits moved by the shift, without increasing the size of the image file. But what do these 16 extra pixels contain? They will contain the first 16 pixels of the next line, instead we want them to be zeroed out. Let's remember that the Blitter allows us to mask the first and last word of the A channel. In this case we must set the mask of the last word to $0000, so that the 16 added pixels are zeroed out. This way these 16 additional pixels can accommodate the bits moved by the shift. The following image exemplifies the previous explanation.

Immagine che contiene schermata, Rettangolo, linea

Descrizione generata automaticamente

## Creating Images

As an example program, we want to draw one or more spaceships moving on a space background. As a background we use the one used in chapter 7, with 256 colors, which is shown below.

Immagine che contiene Oggetto astronomico, spazio, Universo, Spazio esterno

Descrizione generata automaticamente

The spaceship image is shown below.

Immagine che contiene ingranaggio, cartone animato, testo, oggetti in metallo

Descrizione generata automaticamente

The first thing you need to do is create a unique palette for the two images. Let's see how to do it with Pro Motion NG.

Open the image with the space background.

Open the image of the spaceship and select the "Rectangular Brush Grab Tool" shown in the figure below.



With this tool, select the entire image to create a brush. You can move the entire brush with the mouse. Move the brush over the background image. From the Colors menu, select the item "Import Colors from Brush..."

Immagine che contiene testo, schermata, numero, software

Descrizione generata automaticamente

The following window will appear. Press the "Auto" button to automatically import the spaceship's colors and add them to the palette. Then press "Import".

Immagine che contiene schermata, testo, software, Software multimediale

Descrizione generata automaticamente

Now you need to save the two images with the new palette.

Create a new layer for the spaceship by pressing the "+" button.

Immagine che contiene testo, schermata, software, Icona del computer

Descrizione generata automaticamente

Press the left mouse button to draw the spaceship on Layer 2.

Now hide Layer2 by clicking on the eye icon, as shown in the following figure.

Immagine che contiene testo, schermata, Carattere

Descrizione generata automaticamente

Only the background image will be displayed. Save it in indexed PNG format, making sure that the "Visible Layers" option is selected in the dialog box that appears.

Immagine che contiene testo, schermata, schermo, software

Descrizione generata automaticamente

Repeat the same process to save the image of the spaceship.

Now you need to convert the images to raw format, extract the palette to copperlist format and generate the mask for the bob using the "amigeconv" command line tool. Then type the following commands, in a Windows command prompt:

amigeconv.exe -f bitplane -d 8 .\space\_bgnd.png .\space\_bgnd.raw

amigeconv.exe -f palette -p pal8 -c 256 -x .\space\_bgnd.png palette.pal

amigeconv.exe -f bitplane -d 8 .\ship6.png ship6.raw

amigeconv.exe -f bitplane -m -d 1 .\ship6.png ship6.mask

Note that the -m and -d 1 options are used to generate the mask, as the image will have only one bitplane.

Now load the background image in a chip ram segment, into bob.s file. Note that we include the background image twice because we use the double buffering technique to avoid flickering.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Graphics data

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; segment loaded in CHIP RAM

             SECTION    graphics\_data,DATA\_C

dbuffer1     incbin     "gfx/space\_bgnd.raw"       ; display buffers used for double buffering

dbuffer2     incbin     "gfx/space\_bgnd.raw"

Include the ship image and the mask in a chip memory segment, in main.s file.

; segment loaded in CHIP RAM

           SECTION    graphics\_data,DATA\_C

ship       incbin     "gfx/ship6.raw"

ship\_mask  incbin     "gfx/ship6.mask"

To set up 8-bitplanes video mode, with 16-bit fetch mode, you need to define the following copperlist. You also include the palette in it.

copperlist:

         dc.w      DIWSTRT,$2c81                ; display window start at

; ($81,$2c)

         dc.w      DIWSTOP,$2cc1                ; display window stop at

; ($1c1,$12c)

         dc.w      DDFSTRT,$38                  ; display data fetch start at

; $38

         dc.w      DDFSTOP,$d0                  ; display data fetch stop at

; $d0

         dc.w      BPLCON1,0

         dc.w      BPLCON2,0

         dc.w      BPL1MOD,0

         dc.w      BPL2MOD,0

; BPLCON0 ($100)

; bit 0: set to 1 to enable BLTCON3 register

; bit 4: most significant bit of bitplane number

; bit 9: set to 1 to enable composite video output

; bit 12-14: least significant bits of bitplane number

;                           5432109876543210

         dc.w      BPLCON0,%0000001000010001

; FMODE

; bit 0-1: 16 bit fetch mode

; bit 2-3: 16 pixel sprite width

         dc.w      FMODE,0

bplpointers:

         dc.w      $e0,0,$e2,0                  ; plane 1

         dc.w      $e4,0,$e6,0                  ; plane 2

         dc.w      $e8,0,$ea,0                  ; plane 3

         dc.w      $ec,0,$ee,0                  ; plane 4

         dc.w      $f0,0,$f2,0                  ; plane 5

         dc.w      $f4,0,$f6,0                  ; plane 6

         dc.w      $f8,0,$fa,0                  ; plane 7

         dc.w      $fc,0,$fe,0                  ; plane 8

palette  incbin    "gfx/palette.pal"

         dc.w      $ffff,$fffe                  ; end of copperlist

## Bob data structure

Since a bob requires a lot of information for its drawing, it is appropriate to group it into a data structure that we will then pass on to the bob's drawing routine.

Below is the definition of the data structure. Some fields will be explained later.

Place this definition in a new file, named “bob.i”.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; DATA STRUCTURES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; bob

               rsreset

bob.valid1     rs.w       1                        ; 1 valid data for buffer 1,

; 0 invalid

bob.valid2     rs.w       1                        ; 1 valid data for buffer 2,

; 0 invalid

bob.x          rs.w       1

bob.y          rs.w       1

bob.speed      rs.w       1

bob.width      rs.w       1

bob.height     rs.w       1

bob.dst\_addr1  rs.l       1                        ; destination address where

; the background will be

; restored on dbuffer1

bob.dst\_addr2  rs.l       1                        ; destination address where

; the background will be

; restored on dbuffer2

bob.bltsize    rs.w       1                        ; blit size

bob.ssheet\_c   rs.w       1                        ; spritesheet column of the

; bob

bob.ssheet\_r   rs.w       1                        ; spritesheet row of the bob

bob.ssheet\_w   rs.w       1                        ; spritesheet width in

; pixels

bob.ssheet\_h   rs.w       1                        ; spritesheet height in

; pixels

bob.imgdata    rs.l       1                        ; image data address

bob.mask       rs.l       1                        ; mask address

bob.buffer1    rs.b       BOB\_PLANE\_SZ\*N\_PLANES    ; buffer containing the

; background to be restored

; on dbuffer1

bob.buffer2    rs.b       BOB\_PLANE\_SZ\*N\_PLANES    ; buffer containing the

; background to be restored

; on dbuffer2

bob.length     rs.b       0

You need to create three instances of this data structure, to represent 3 spaceships that will move in the background. Below is an example of an instance. Create these instances in the main.s file.

bob\_ship  dc.w     0                          ; bob.valid1

          dc.w     0                          ; bob.valid2

          dc.w     0                          ; x position

          dc.w     81                         ; y position

          dc.w     6                          ; bob.speed

          dc.w     128                        ; width

          dc.w     77                         ; height

          dc.l     0                          ; dst\_addr1

          dc.l     0                          ; dst\_addr2

          dc.w     0                          ; blit size

          dc.w     0                          ; spritesheet column of the bob

          dc.w     0                          ; spritesheet row of the bob

          dc.w     128                        ; spritesheet width in pixels

          dc.w     77                         ; spritesheet height in pixels

          dc.l     ship                       ; image data address

          dc.l     ship\_mask                  ; mask address

          dcb.b    BOB\_PLANE\_SZ\*N\_PLANES,0

          dcb.b    BOB\_PLANE\_SZ\*N\_PLANES,0

## Spritesheet

You may have noticed that the bob's data structure contains the "ssheet\_w" field that indicates the width of the spritesheet. But what is a **spritesheet**? It is simply a table in whose cells we find sprites. A sprite within a spritesheet is identified by the row and column number. In fact, in the data structure we have indicated the "ssheet\_r" and "ssheet\_c" fields that indicate, respectively, the row and column of the sprite in the spritesheet. The spritesheet is useful when you need to animate a sprite. In fact, it is possible to collect all the animation frames in a single image to be loaded into memory. We'll see that the spritesheet will be useful later, when we will use animated sprites.



## Bob drawing

To draw the bob, you must create a new routine, called “draw\_bob”. We try to make it as generic as possible, because we will use it very often. Below is the commented source code of this routine. Put this routine in bob.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a Bob using the blitter.

;

; parameters:

; a3 - bob's data

; a2 - destination video buffer address

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_bob:

  movem.l    d0-a6,-(sp)

; calculates destination address (D channel)

  move.w     bob.y(a3),d1

  mulu.w     #DISPLAY\_ROW\_SIZE,d1    ; offset\_y = y \* DISPLAY\_ROW\_SIZE

  add.l      d1,a2                   ; adds offset\_y to destination address

  move.w     bob.x(a3),d0

  lsr.w      #3,d0                   ; offset\_x = x/8

  and.w      #$fffe,d0               ; makes offset\_x even

  add.w      d0,a2                   ; adds offset\_x to destination address

; calculates source address (channels A,B)

  move.l     bob.imgdata(a3),a0

  move.l     bob.mask(a3),a1

  move.w     bob.width(a3),d1

  lsr.w      #3,d1                   ; bob width in bytes (bob\_width/8)

  move.w     bob.ssheet\_c(a3),d4

  mulu       d1,d4                   ; offset\_x = column \* (bob\_width/8)

  add.w      d4,a0                   ; adds offset\_x to the base address of

; bob's image

  add.w      d4,a1                   ; and bob's mask

  move.w     bob.height(a3),d3

  move.w     bob.ssheet\_r(a3),d5

  mulu       d3,d5                   ; bob\_height \* row

  move.w     bob.ssheet\_w(a3),d1

  asr.w      #3,d1                   ; spritesheet\_row\_size = spritesheet\_width

; / 8

  mulu       d1,d5                   ; offset\_y = row \* bob\_height \*

; spritesheet\_row\_size

  add.w      d5,a0                   ; adds offset\_y to the base address of

; bob's image

  add.w      d5,a1                   ; and bob's mask

; calculates the modulus of channels A,B

  move.w     bob.ssheet\_w(a3),d1     ; copies spritesheet\_width in d1

  move.w     bob.width(a3),d2

  sub.w      d2,d1                   ; spritesheet\_width - bob\_width

  sub.w      #16,d1                  ; spritesheet\_width - bob\_width -16

  asr.w      #3,d1                   ; (spritesheet\_width - bob\_width -16)/8

; calculates the modulus of channels C,D

  move.w     bob.width(a3),d2

  lsr        #3,d2                   ; bob\_width/8

  add.w      #2,d2                   ; adds 2 to the sprite width in bytes, due

; to the shift

  move.w     #DISPLAY\_ROW\_SIZE,d4    ; screen width in bytes

  sub.w      d2,d4                   ; modulus (d4) = screen\_width - bob\_width

; calculates the shift value for channels A,B (d6) and value of BLTCON0 (d5)

  move.w     bob.x(a3),d6

  and.w      #$000f,d6               ; selects the first 4 bits of x

  lsl.w      #8,d6                   ; moves the shift value to the upper

; nibble

  lsl.w      #4,d6                   ; so as to have the value to insert in

; BLTCON1

  move.w     d6,d5                   ; copy to calculate the value to insert in

; BLTCON0

  or.w       #$0fca,d5               ; value to insert in BLTCON0

                                     ; logic function LF = $ca

; calculates the blit size (d3)

  move.w     bob.height(a3),d3

  lsl.w      #6,d3                   ; bob\_height<<6

  lsr.w      #1,d2                   ; bob\_width/2 (in word)

  or         d2,d3                   ; combines the dimensions into the value

; to be inserted into BLTSIZE

; calculates the size of a BOB spritesheet bitplane

  move.w     bob.ssheet\_w(a3),d2     ; copies spritesheet\_width in d2

  lsr.w      #3,d2                   ; spritesheet\_width/8

  and.w      #$fffe,d2               ; makes even

  move.w     bob.ssheet\_h(a3),d0     ; spritesheet\_height

  mulu       d0,d2                   ; multiplies by the height

; initializes the registers that remain constant

  bsr        wait\_blitter

  move.w     #$ffff,BLTAFWM(a5)      ; first word of channel A: no mask

  move.w     #$0000,BLTALWM(a5)      ; last word of channel A: reset all bits

  move.w     d6,BLTCON1(a5)          ; shift value for channel A

  move.w     d5,BLTCON0(a5)          ; activates all 4

; channels,logic\_function=$CA,shift

  move.w     d1,BLTAMOD(a5)          ; modules for channels A,B

  move.w     d1,BLTBMOD(a5)

  move.w     d4,BLTCMOD(a5)          ; modules for channels C,D

  move.w     d4,BLTDMOD(a5)

  moveq      #N\_PLANES-1,d7          ; number of cycle repetitions

; copy cycle for each bitplane

.plane\_loop:

  bsr        wait\_blitter

  move.l     a1,BLTAPT(a5)           ; channel A: Bob's mask

  move.l     a0,BLTBPT(a5)           ; channel B: Bob's image

  move.l     a2,BLTCPT(a5)           ; channel C: draw buffer

  move.l     a2,BLTDPT(a5)           ; channel D: draw buffer

  move.w     d3,BLTSIZE(a5)          ; blit size and starts blit operation

  add.l      d2,a0                   ; points to the next bitplane

  add.l      #DISPLAY\_PLANE\_SZ,a2

  dbra       d7,.plane\_loop          ; repeats the cycle for each bitplane

  movem.l    (sp)+,d0-a6

  rts

To move the spaceship from left to right, you must create a routine called “update\_bob”, of which you can find the code below.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates bob's state.

;

; parameters:

; a1   - address of bob structure instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

update\_bob:

               movem.l    d0-a6,-(sp)

               move.w     bob.speed(a1),d0             ; adds speed to actual

; position

               add.w      d0,bob.x(a1)

               move.w     bob.x(a1),d0                 ; limits x position to

; avoid exiting the

; screen

               cmp.w      #192,d0

               bge        .clampx

               bra        .return

.clampx:

               move.w     #192,bob.x(a1)

.return:

               movem.l    (sp)+,d0-a6

               rts

At this point you need to call the two routines in the main loop, like this:

mainloop:

  bsr       wait\_vblank       ; waits for vertical blank

  bsr       swap\_buffers

  lea       bob\_ship,a1       ; updates bob's position

  bsr       update\_bob

  lea       bob\_ship,a3

  move.l    draw\_buffer,a2

  bsr       draw\_bob          ; draws bob\_ship

  btst      #6,CIAAPRA        ; left mouse button pressed?

  bne       mainloop          ; if not, repeats the loop

By running the program you will see that the spaceship moves leaving behind an annoying trail. This trail is because when drawing the Bob we modify the background image. When we redraw the Bob in a new position, the background modified from the previous drawing remains.

Immagine che contiene testo, schermata, grafica

Descrizione generata automaticamente

## Saving bob’s background

To eliminate the trail we must:

1. restore the background. This returns the background image to its original appearance.

Immagine che contiene testo, schermata, Rettangolo, diagramma

Descrizione generata automaticamente

1. save the background below the bob

Immagine che contiene testo, schermata, Rettangolo, diagramma

Descrizione generata automaticamente

1. Draw the bob

Immagine che contiene Rettangolo, schermata, diagramma, quadrato

Descrizione generata automaticamente

When we use double buffering, as in this case, the process of saving and restoring the background is slightly more complicated. Since there are two buffers containing the background, we must have two buffers in which to save the bob's background. In addition, we also save the address of the background in the buffer and the size of the blit operation. This information is stored in the data structure of the bob. The following diagram illustrates the concept.

Immagine che contiene testo, schermata, diagramma, Rettangolo

Descrizione generata automaticamente

During the restore process, we restore the background using the buffer corresponding to the current drawing buffer, using the previously saved address and blit size. The following diagram illustrates this concept.

Immagine che contiene testo, schermata, diagramma, Rettangolo

Descrizione generata automaticamente

Let's create the save\_bob\_bgnd routine, to save the background of a Bob. Below is the code. Put this code in bob.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Saves Bob's background.

;

; parameters:

; a1 - bob's data

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

save\_bob\_bgnd:

  movem.l    d0-a6,-(sp)

  move.l     draw\_buffer,a0

  move.w     bob.y(a1),d1

  mulu.w     #DISPLAY\_ROW\_SIZE,d1    ; offset\_y = y \* DISPLAY\_ROW\_SIZE

  add.l      d1,a0

  move.w     bob.x(a1),d0

  lsr.w      #3,d0                   ; offset\_x = x/8

  and.w      #$fffe,d0               ; makes offset\_x even

  ext.l      d0

  add.l      d0,a0                   ; calculates address of the background to

; save

  move.l     draw\_buffer,a3

  move.l     a1,a2

  cmp.l      #dbuffer1,a3            ; draw\_buffer = dbuffer1 ?

  beq        .set\_buffer1

  add.l      #bob.buffer2,a2         ; uses bob.buffer2 to save the background

  move.l     a0,bob.dst\_addr2(a1)    ; saves the address where restore the

; background

  move.w     #1,bob.valid2(a1)       ; makes data of buffer 2 valid

  bra        .calc\_modulus

.set\_buffer1:

  add.l      #bob.buffer1,a2         ; uses bob.buffer1 to save the background

  move.l     a0,bob.dst\_addr1(a1)    ; saves the address where restore the

; background

  move.w     #1,bob.valid1(a1)       ; makes data of buffer 1 valid

.calc\_modulus:

; calculates the modulus of channel D

  move.w     bob.width(a1),d2

  lsr        #3,d2                   ; bob\_width/8

  add.w      #2,d2                   ; adds 2 to the sprite width in bytes, due

; to the shift

  move.w     #DISPLAY\_ROW\_SIZE,d4    ; screen width in bytes

  sub.w      d2,d4                   ; modulus (d4) = screen\_width - bob\_width

; calculates the size of a BOB buffer bitplane

  move.w     bob.height(a1),d5

  mulu.w     d2,d5

; calculates the blit size (d3)

  move.w     bob.height(a1),d3

  lsl.w      #6,d3                   ; bob\_height<<6

  lsr.w      #1,d2                   ; bob\_width/2 (in word)

  or         d2,d3                   ; combines the dimensions into the value

; to be inserted into BLTSIZE

  move.w     d3,bob.bltsize(a1)

  bsr        wait\_blitter

  move.w     #$ffff,BLTAFWM(a5)      ; first word of channel A: no mask

  move.w     #$ffff,BLTALWM(a5)      ; last word of channel A: no mask

  move.w     #0,BLTCON1(a5)

  move.w     #$09f0,BLTCON0(a5)      ; copies A to D

  move.w     d4,BLTAMOD(a5)          ; modulus for channel A

  move.w     #0,BLTDMOD(a5)          ; modulus for channel D

  moveq      #N\_PLANES-1,d7          ; number of cycle repetitions

; copy cycle for each bitplane

.plane\_loop:

  bsr        wait\_blitter

  move.l     a0,BLTAPT(a5)           ; channel A: draw buffer

  move.l     a2,BLTDPT(a5)           ; channel D: destination buffer

  move.w     d3,BLTSIZE(a5)          ; blit size and starts blit operation

  add.l      d5,a2                   ; points to the next bitplane

  add.l      #DISPLAY\_PLANE\_SZ,a0

  dbra       d7,.plane\_loop          ; repeats the cycle for each bitplane

  movem.l    (sp)+,d0-a6

  rts

## Background restore

To restore the background, let's create another routine. Initially, the buffers containing the background will be empty. To identify this status, we have introduced the “valid1” and “valid2” fields that indicate that the buffers contain valid data.

Below is the code. Put this code in bob.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Restores Bob's background.

;

; parameters:

; a1   - address of bob structure instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

restore\_bob\_bgnd:

  movem.l    d0-a6,-(sp)

  move.l     draw\_buffer,a0

  cmp.l      #dbuffer1,a0            ; draw\_buffer = dbuffer1?

  beq        .set\_buffer1

  tst.w      bob.valid2(a1)          ; if data aren't valid, returns

  beq        .return

  move.l     a1,a0

  add.l      #bob.buffer2,a0         ; saved background in buffer2

  move.l     bob.dst\_addr2(a1),a2    ; where the background will be restored

  clr.w      bob.valid2(a1)          ; makes data invalid

  bra        .restore

.set\_buffer1:

  tst.w      bob.valid1(a1)          ; if data aren't valid, returns

  beq        .return

  move.l     a1,a0

  add.l      #bob.buffer1,a0         ; saved background in buffer1

  move.l     bob.dst\_addr1(a1),a2    ; where the background will be restored

  clr.w      bob.valid1(a1)          ; makes data invalid

.restore:

  move.w     bob.bltsize(a1),d0

; calculates the modulus of channel D

  move.w     bob.width(a1),d2

  lsr        #3,d2                   ; bob\_width/8

  add.w      #2,d2                   ; adds 2 to the sprite width in bytes, due

; to the shift

  move.w     #DISPLAY\_ROW\_SIZE,d4    ; screen width in bytes

  sub.w      d2,d4                   ; modulus (d4) = screen\_width - bob\_width

  move.w     bob.height(a1),d3

  mulu.w     d2,d3                   ; size of a BOB buffer bitplane

  bsr        wait\_blitter

  move.w     #$ffff,BLTAFWM(a5)      ; first word of channel A: no mask

  move.w     #$ffff,BLTALWM(a5)      ; last word of channel A: no mask

  move.w     #0,BLTCON1(a5)

  move.w     #$09f0,BLTCON0(a5)      ; copies A to D

  move.w     #0,BLTAMOD(a5)          ; modulus for channel A

  move.w     d4,BLTDMOD(a5)          ; modulus for channel D

  moveq      #N\_PLANES-1,d7          ; number of cycle repetitions

; copy cycle for each bitplane

.plane\_loop:

  bsr        wait\_blitter

  move.l     a0,BLTAPT(a5)           ; channel A: bob dest\_addr

  move.l     a2,BLTDPT(a5)           ; channel D: destination buffer

  move.w     d0,BLTSIZE(a5)          ; blit size and starts blit operation

  add.l      d3,a0                   ; points to the next bitplane

  add.l      #DISPLAY\_PLANE\_SZ,a2

  dbra       d7,.plane\_loop          ; repeats the cycle for each bitplane

.return:

  movem.l    (sp)+,d0-a6

  rts

The restore\_bob\_bgnd routine must be called first in the main loop, in fact we must first restore the background state. Then we must call the save\_bob\_bgnd routine to save the background where we are going to draw the bob. Finally, we must call the draw\_bob routine.

The following code snippet implements this.

mainloop:

  bsr       wait\_vblank         ; waits for vertical blank

  bsr       swap\_buffers

  lea       bob\_ship,a1         ; updates bob's position

  bsr       update\_bob

  lea       bob\_ship,a1         ; restores bobs background

  bsr       restore\_bob\_bgnd

  lea       bob\_ship,a1         ; saves bob\_ship background

  bsr       save\_bob\_bgnd

  lea       bob\_ship,a3

  move.l    draw\_buffer,a2

  bsr       draw\_bob            ; draws bob\_ship

  btst      #6,CIAAPRA          ; left mouse button pressed?

  bne       mainloop            ; if not, repeats the loop

Running the program, you'll be able to admire 3 spaceships moving at different speeds against a space background.

Immagine che contiene testo, schermata, grafica, cartone animato

Descrizione generata automaticamente

The complete source code is available at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter12>

# 13. Player’s ship

## Introduction

In this chapter we will continue the design of our video game, starting from the code of chapter 10, in which we had implemented a horizontal scrolling tilemap. In particular, we will start from the case in which we have implemented hardware scrolling. We will add a spaceship controlled by the player via the joystick.

## Dual Playfield mode

To implement the player's ship we intend to use a bob, or a Blitter object, as seen in chapter 12.

Amiga has a video mode called "Dual Playfield", in which two overlapping playfields are displayed on the screen at the same time.

Playfield 1 uses the odd bitplanes, i.e. 1,3,5,7; Playfield 2 uses even bitplanes 2,4,6,8. Playfield 1 is displayed first, and then playfield 2 is displayed above it. Of course, the background of playfield 2 is transparent.

Note that it is possible to use 4 bitplanes for a playfield only with Amigas equipped with AGA chipsets, while for those with OCS/ECS chipsets the maximum number of bitplanes is 3.



For our video game we will use playfield 1 to display the scrolling tilemap, while playfield 2 will be used to draw the bobs.

To enable dual playfield mode, you need to set bit 10 of the BPLCON0 register. Also in this register, you set the number of bitplanes to 8, in binary %1000. The most significant bit is 4, while the least significant are bits 12-14. Insert the following code snippet into the copperlist:

  ; BPLCON0 ($100)

  ; bit 0: set to 1 to enable BLTCON3 register

  ; bit 4: most significant bit of bitplane number

  ; bit 9: set to 1 to enable composite video output

  ; bit 10: set to 1 to enable dual playfield mode

  ; bit 12-14: least significant bits of bitplane number

  ;                5432109876543210

  dc.w    BPLCON0,%0000011000010000

To give display priority to playfield2, you need to set bit 6 of the BPLCON2 register, also in the copperlist:

;                  5432109876543210

  dc.w    BPLCON2,%0000000001000000    ; priority to pf2

In the copperlist, bitplane pointers must be grouped by playfield. We will call the bitplane pointers of playfield 1 "bplpointers1", while those of playfield2 will be called "bplpointers2".

bplpointers1:

         dc.w       $e0,0,$e2,0                      ; plane 1

         dc.w       $e8,0,$ea,0                      ; plane 3

         dc.w       $f0,0,$f2,0                      ; plane 5

         dc.w       $f8,0,$fa,0                      ; plane 7

bplpointers2:

         dc.w       $e4,0,$e6,0                      ; plane 2

         dc.w       $ec,0,$ee,0                      ; plane 4

         dc.w       $f4,0,$f6,0                      ; plane 6

         dc.w       $fc,0,$fe,0                      ; plane 8

Which colors of the palette are used by the two playfields?

Playfield1 uses color registers 0 through 15.

Using bits 10-12 of the BPLCON3 register, the offset between the playfield palette 1 and playfield 2 is set. We want to use color registers 16 to 31 for playfield 2, i.e. an offset of 16. We need to enter the value %100.

;                  5432109876543210

  dc.w    BPLCON3,%0001000000000000    ; offset 16 between the palettes of the

; two playfields

In the following table you will find all the values of bits 10-12 for all possible offsets.

|  |  |
| --- | --- |
| Bits 10-12 | Offset |
| %000 | 0 |
| %001 | 2 |
| %010 | 4 |
| %011 | 8 |
| %100 | 16 |
| %101 | 32 |
| %110 | 64 |
| %111 | 128 |

You can find the complete copperlist at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/blob/main/chapter13/copperlist.s>

In the playfield.i file, we define the constants that represent the various sizes of the two playfields:

BPP             equ 4

WINDOW\_WIDTH    equ 336

WINDOW\_HEIGHT   equ 256

VIEWPORT\_WIDTH  equ 320

VIEWPORT\_HEIGHT equ 192

; playfield 1: scrolling background

PF1\_WIDTH       equ 2\*VIEWPORT\_WIDTH+2\*TILE\_WIDTH

PF1\_HEIGHT      equ 256

PF1\_ROW\_SIZE    equ PF1\_WIDTH/8

PF1\_MOD         equ (PF1\_WIDTH-VIEWPORT\_WIDTH)/8

PF1\_PLANE\_SZ    equ PF1\_ROW\_SIZE\*PF1\_HEIGHT

; playfield2 used for BOBs rendering

PF2\_WIDTH       equ VIEWPORT\_WIDTH+CLIP\_LEFT+CLIP\_RIGHT

PF2\_HEIGHT      equ 256

PF2\_ROW\_SIZE    equ PF2\_WIDTH/8

PF2\_MOD         equ (PF2\_WIDTH-VIEWPORT\_WIDTH)/8

PF2\_PLANE\_SZ    equ PF2\_ROW\_SIZE\*PF2\_HEIGHT

CLIP\_LEFT       equ 64+32

CLIP\_RIGHT      equ 64

The memory for playfield1 is allocated in a BSS memory segment, in the scroll\_bgnd.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

            SECTION    bss\_data,BSS\_C

playfield1  ds.b       (PF1\_PLANE\_SZ\*BPP)    ; used for scrolling background

The memory for playfield 2 is allocated in a BSS segment in the bob.s file. Notice that playfield 2 uses double buffering and therefore memory is allocated for 2 playfields.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

             SECTION    bss\_data,BSS\_C

playfield2a  ds.b       (PF2\_PLANE\_SZ\*BPP)    ; used to draw BOBs using double

; buffering

playfield2b  ds.b       (PF2\_PLANE\_SZ\*BPP)

The bitplane pointers for the two playfields are initialized in main, as shown by the following code snippet:

main:

  jsr       take\_system               ; takes the control of Amiga's hardware

  move.l    #copperlist,COP1LC(a5)    ; sets our copperlist address into Copper

  move.w    d0,COPJMP1(a5)            ; reset Copper PC to the beginning of our

; copperlist

; sets bitplane pointers for dual playfield mode

  move.l    #BPP,d7

  lea       bplpointers1,a1           ; bitplane pointers in a1

  move.l    #playfield1+8-2,d0        ; address of background playfield

  move.l    #PF1\_PLANE\_SZ,d1

  jsr       init\_bplpointers          ; initializes bitplane pointers for

; background playfield

  lea       bplpointers2,a1           ; bitplane pointers in a1

  move.l    #playfield2a,d0           ; address of foreground playfield

  move.l    #PF2\_PLANE\_SZ,d1

  jsr       init\_bplpointers          ; initializes bitplane pointers for

; foreground playfield

## Bobs drawing optimization

The dual playfield mode that we have adopted for our video game allows us to optimize the bobs drawing.

We saw in chapter 12 that to draw a bob it is necessary:

1. restore the portion of the background previously occupied by the bob
2. save the background of the new bob position
3. draw the bob

Since the background on playfield2 is transparent, you don't need to save it. In addition, instead of restoring the portion of the background, we simply have to erase the background at the previous position of the bob. All this saves a Blitter operation.

To keep track of the bob’s background, we create a data structure, in the bob.i file.

; background of a bob, which needs to be cleared for moving the bob

                 rsreset

bob\_bgnd.addr    rs.l       1    ; address in the playfield

bob\_bgnd.width   rs.w       1    ; width in pixel

bob\_bgnd.height  rs.w       1    ; height in pixel

bob\_bgnd.length  rs.b       0

In the bob.s file, we create two lists of bob’s backgrounds structures, due to double buffering. We also create two variables which represents the number of items of the backgrounds lists.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

...

bgnd\_list\_ptr       dc.l    bgnd\_list1    ; points to the list of bob

; backgrounds to delete

bgnd\_list\_ptr2      dc.l    bgnd\_list2    ; two pointers to swap in

; swap\_buffers due to double

; buffering

bgnd\_list\_counter   dc.w    0             ; number of items in the backgrounds

; list

bgnd\_list\_counter2  dc.w    0             ; doubled for double buffering

You must edit the draw\_bob routine to save the background information you want to erase.

It is checked if the wallpaper list is full; in this case he does not draw the bob.

The first free item in the wallpaper list is located.

In this element are saved: memory address of the background, width and height.

The following code snippet shows the change:

draw\_bob:

  movem.l    d0-a6,-(sp)

; calculates destination address (D channel)

  ...

; saves background information to be cleared in a list

  cmp.w      #BGND\_LIST\_MAX\_ITEMS-1,bgnd\_list\_counter    ; if the list is full

  beq        .skip\_save\_bgnd         ; skips saving background

  move.l     bgnd\_list\_ptr,a0        ; locates the first free element in the

; background list

  move.w     bgnd\_list\_counter,d0

  mulu.w     #bob\_bgnd.length,d0

  add.l      d0,a0

  move.l     a2,bob\_bgnd.addr(a0)    ; saves background address in list

  move.w     bob.width(a3),bob\_bgnd.width(a0)      ; saves width

  move.w     bob.height(a3),bob\_bgnd.height(a0)    ; saves height

  add.w      #1,bgnd\_list\_counter

  ...

In the bob.s file, add a routine that erases the background of a bob. This procedure receives as input the address of a bob\_bgnd instance, containing the background information to be erased. Deletion is done via the Blitter. The $00 logical operation is used, which is zeroing out a memory area. Below is the complete code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Erases the background of a bob.

;

; parameters:

; a1 - bob\_bgnd instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

erase\_bob\_bgnd:

  movem.l    d0-a6,-(sp)

; calculates channel D module (d4)

  move.w     bob\_bgnd.width(a1),d2

  lsr.w      #3,d2               ; width/8

  and.w      #$fffe,d2           ; makes it even

  addq.w     #2,d2               ; blit 1 word wider due to shift

  move.w     #PF2\_ROW\_SIZE,d4    ; playfield2 width in bytes

  sub.w      d2,d4               ; modulus = pf2 width - bob width

; calculates blit size (d3)

  move.w     bob\_bgnd.height(a1),d3

  lsl.w      #6,d3               ; height \* 64

  lsr.w      #1,d2               ; width in word

  or.w       d2,d3               ; puts the dimensions together

; initializes the registers that remain constant during the loop

  jsr        wait\_blitter

  move.w     #$0000,BLTCON1(a5)

  move.w     #$0100,BLTCON0(a5)  ; resets the destination

  move.w     d4,BLTDMOD(a5)

  move.l     bob\_bgnd.addr(a1),a0

  moveq      #BPP-1,d7           ; number of loop iterations

.plane\_loop:

  jsr        wait\_blitter

  move.l     a0,BLTDPT(a5)       ; channel D: background address to delete

  move.w     d3,BLTSIZE(a5)      ; sets the size and starts the blitter

  add.l      #PF2\_PLANE\_SZ,a0    ; points to the next plane

  dbra       d7,.plane\_loop      ; repeats the loop for each plane

  movem.l    (sp)+,d0-a6

  rts

Let's create a new routine to delete all the bob’s backgrounds in the list. This routine iterates over the list of backgrounds and invokes the erase\_bob\_bgnd routine. Below is the source code.

This routine must be invoked in the mainloop, immediately before the bobs are drawn.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Clears backgrounds of bobs using a list.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

erase\_bgnds:

  movem.l    d0-a6,-(sp)

  move.w     bgnd\_list\_counter,d7    ; number of loop iterations

  tst.w      d7                      ; if the list is empty, returns immediately

  beq        .return

  sub.w      #1,d7

  move.l     bgnd\_list\_ptr,a1        ; points to the backgrounds list

.loop:

  bsr        erase\_bob\_bgnd

  add.l      #bob\_bgnd.length,a1     ; points to the next item in the list

  dbra       d7,.loop

  clr.w      bgnd\_list\_counter

.return:

  movem.l    (sp)+,d0-a6

  rts

It is also necessary to modify the swap\_buffers routine, in the bob.s file. You need to add code to swap pointers to the lists of bob’s backgrounds to be deleted. In addition, the counters of the number of elements in the list are also exchanged. This means that you always refer in the code to bgnd\_list\_ptr and bgnd\_list\_counter.

swap\_buffers:

  movem.l    d0-a6,-(sp)             ; saves registers into the stack

  ...

  move.l     bgnd\_list\_ptr,d0        ; swaps pointers to the list of bob

; backgrounds to delete

  move.l     bgnd\_list\_ptr2,bgnd\_list\_ptr

  move.l     d0,bgnd\_list\_ptr2

  move.w     bgnd\_list\_counter,d0    ; swaps backgrounds list counters

  move.w     bgnd\_list\_counter2,bgnd\_list\_counter

  move.w     d0,bgnd\_list\_counter2

## Preparing the graphics

Let's start with a png image of the spaceship, shown below, magnified by 400%.



We will also have an animated sprite for the spaceship's engine fire, with 4 frames of animation contained in the following spritesheet.



The first thing to do is to create a single palette for these two images and for the tiles that make up the background.

We will use the same procedure as in the previous chapter.

Let's start by loading the tile image into Pro Motion NG, as shown in the figure below.



From the "Brush" menu, select the "Load Brush..." item.



Then select the ship's png file. It will be loaded as a brush and you can move it with your mouse.

From the “Colors” menu, select the “Import Colors from Brush…” item.



The following window will appear, showing the current palette and the colors to be imported from the ship image.



Press the "Auto" button. You will see that the colors of the ship will be automatically added to the palette, as in the following image.



Now press "Import” button to import the colors into the palette.

From the "Brush" menu, select the item "Save Brush..." to save the ship image with the new palette.

You must repeat the same process for the image of engine fire and also save the image of tiles with the new palette.

You need to convert the images to raw format, with the amigeconv tool.

Since there are so many files to convert, you can create a batch file, called "amigeconv\_commands.bat", which executes all the conversion commands, as in the following code snippet.

This file must be run in a Windows Command Prompt window.

@echo off

amigeconv.exe -f bitplane -d 4 .\shooter\_tiles\_16.png shooter\_tiles\_16.raw

amigeconv.exe -f bitplane -m -d 1 .\shooter\_tiles\_16.png shooter\_tiles\_16.mask

amigeconv.exe -f palette -p pal4 -c 16 -x -n .\shooter\_tiles\_16.png shooter\_tiles\_16.pal

amigeconv.exe -f bitplane -d 4 .\ship.png ship.raw

amigeconv.exe -f bitplane -m -d 1 .\ship.png ship.mask

amigeconv.exe -f palette -p pal4 -c 16 -x -n .\ship.png pf2\_palette.pal

amigeconv.exe -f bitplane -d 4 .\ship\_engine.png ship\_engine.raw


amigeconv.exe -f bitplane -m -d 1 .\ship\_engine.png ship\_engine.mask

We have set the playfield 2 palette to start from color register 16 and above. The amigeconv tool creates the palette by always starting it from the color register 0. Then we need to edit the pf2\_palette.pal file with the Hex Editor and edit the color register values manually, as we did in the previous chapter.


Instead of the value $0180, which corresponds to the color0 register, replace the value $01A0, which corresponds to the color16 register.

Continue substituting $0182 for $01A2 and so on until $019E is replaced with $01BE.

Initial pf2\_palette values:



pf2\_palette values after replacement:



## Import graphics

Now you need to import the palettes of the two playfields at the end of the copperlist, as in the following code snippet.

pf1\_palette:

         incbin     "gfx/shooter\_tiles\_16.pal"       ; background palette

pf2\_palette:

         incbin     "gfx/pf2\_palette.pal"            ; foreground palette

Create a plship.s file. Import the other raw images and masks into the graphics data segment in plship.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                     SECTION    graphics\_data,DATA\_C

player\_ship\_gfx      incbin     "gfx/ship.raw"

player\_ship\_mask     incbin     "gfx/ship.mask"

ship\_engine\_gfx      incbin     "gfx/ship\_engine.raw"

ship\_engine\_mask     incbin     "gfx/ship\_engine.mask"

## Data structures

To represent the properties of the ship's bob, we create a custom data structure, inheriting from the one seen in chapter 12 for the bobs. Place this definition in a new file named “plship.i”.

; player's ship

                    rsreset

ship.bob            rs.b       bob.length

ship.anim\_duration  rs.w       1                 ; duration of animation in

; frames

ship.anim\_timer     rs.w       1                 ; timer for animation

ship.length         rs.b       0

We've added two fields to manage engine fire animations.

In the file plship.s, create a "Variables" section, and into it, create two instances of this data structure to represent the ship and engine fire.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                    SECTION    code\_section,CODE

player\_ship         dc.w       0                    ; bob.x

                    dc.w       0                    ; bob.y

                    dc.w       2                    ; bob.speed

                    dc.w       64                   ; bob.width

                    dc.w       28                   ; bob.height

                    dc.w       0                    ; bob.ssheet\_c

                    dc.w       0                    ; bob.ssheet\_r

                    dc.w       64                   ; bob.ssheet\_w

                    dc.w       28                   ; bob.ssheet\_h

                    dc.l       player\_ship\_gfx      ; bob.imgdata

                    dc.l       player\_ship\_mask     ; bob.mask

                    dc.w       5                    ; ship.anim\_duration

                    dc.w       5                    ; ship.anim\_timer

player\_ship\_engine  dc.w       0                    ; x position

                    dc.w       0                    ; y position

                    dc.w       1                    ; speed

                    dc.w       32                   ; width

                    dc.w       16                   ; height

                    dc.w       0                    ; spritesheet column of the

; bob

                    dc.w       0                    ; spritesheet row of the

; bob

                    dc.w       128                  ; spritesheet width in

; pixels

                    dc.w       16                   ; spritesheet height in

; pixels

                    dc.l       ship\_engine\_gfx      ; image data address

                    dc.l       ship\_engine\_mask

Note that in the case of the engine fire bob, a spritesheet is used, the width and height of which are reported. In addition, an animation duration of 5 frames is set, corresponding to 10 frames per second.

## Initializing the Data Structure

Because you may need to reinitialize the state of the ship, it's a good idea to create a routine that initializes the data structure. All the fields that can vary dynamically during the evolution of the game are initialized, so the position, the column of the spritesheet, the timer for the animation. All these fields are initialized for both the ship bob and the engine fire bob.

It is not necessary to initialize static data such as width, height, image address, mask address, etc. because they never change while playing the game. The code is shown below. Put this routine in plship.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the player's ship state

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

plship\_init:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a0

  move.w     #PLSHIP\_X0,bob.x(a0)

  move.w     #PLSHIP\_Y0,bob.y(a0)

  move.l     #player\_ship\_gfx,bob.imgdata(a0)

  move.l     #player\_ship\_mask,bob.mask(a0)

  move.w     #64,bob.width(a0)

  move.w     #28,bob.height(a0)

  move.w     #0,bob.ssheet\_c(a0)

  move.w     #0,bob.ssheet\_r(a0)

  move.w     #64,bob.ssheet\_w(a0)

  move.w     #28,bob.ssheet\_h(a0)

  move.w     ship.anim\_duration(a0),ship.anim\_timer(a0)

  lea        player\_ship\_engine,a1

  move.w     #PLSHIP\_X0-17,bob.x(a1)

  move.w     #PLSHIP\_Y0+9,bob.y(a1)

  clr.w      bob.ssheet\_c(a1)

.return:

  movem.l    (sp)+,d0-a6

  rts

## Draw ship

To draw the ship we reuse the bob drawing routine seen in chapter 12. All we must do is recall the routine draw\_bob first passing the data structure of the ship and then that of the engine smoke. Put this routine in plship.s.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the player's ship.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

plship\_draw:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a3

  move.l     draw\_buffer,a2

  bsr        draw\_bob                 ; draws ship

  lea        player\_ship\_engine,a3

  move.l     draw\_buffer,a2

  bsr        draw\_bob                 ; draws engine fire

.return:

  movem.l    (sp)+,d0-a6

  rts

## State update

Now we need to create a routine that updates the state of the ship, i.e. it must:

1. Read the joystick and update the position
2. Restrict the movement of the ship to prevent it from exiting the viewport
3. Update the location of the engine fire, to make sure that it remains attached to the ship
4. Animating the engine fire bob

To animate the engine fire, you decrement the animation timer until it reaches zero. Then you increment the sprite column in the spritesheet, so you can move on to the next frame of the animation. Finally, the timer is reset.

Below is the complete code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the player's ship state

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

plship\_update:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a0

  bsr        plship\_move\_with\_joystick

  bsr        plship\_limit\_movement

; sets engine fire bob position

  lea        player\_ship\_engine,a1

  move.w     bob.x(a0),d0

  sub.w      #17,d0

  move.w     d0,bob.x(a1)              ; engine.x = ship.x - 17

  move.w     bob.y(a0),d0

  add.w      #9,d0

  move.w     d0,bob.y(a1)              ; engine.y = ship.y + 9

; animates engine fire

  sub.w      #1,ship.anim\_timer(a0)

  tst.w      ship.anim\_timer(a0)       ; anim\_timer = 0?

  beq        .incr\_frame

  bra        .return

.incr\_frame:

  add.w      #1,bob.ssheet\_c(a1)       ; increases animation frame

  cmp.w      #4,bob.ssheet\_c(a1)       ; ssheet\_c >= 4?

  bge        .reset\_frame

  bra        .reset\_timer

.reset\_frame:

  clr.w      bob.ssheet\_c(a1)          ; resets animation frame

.reset\_timer:

  move.w     ship.anim\_duration(a0),ship.anim\_timer(a0)    ; resets anim\_timer

.return:

  movem.l    (sp)+,d0-a6

  rts

The routine that updates the position of the ship based on the joystick is like the one seen in chapter 11. Below is the code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Moves the player's ship with the joystick

;

; parameters:

; a0 - player's ship

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

plship\_move\_with\_joystick:

  movem.l    d0-a6,-(sp)

  move.w     JOY1DAT(a5),d0

  move.w     bob.speed(a0),d2

  btst.l     #1,d0             ; joy right?

  bne        .set\_right

  btst.l     #9,d0             ; joy left?

  bne        .set\_left

  bra        .check\_up

.set\_right:

  add.w      d2,bob.x(a0)      ; ship.x += ship.speed

  bra        .check\_up

.set\_left:

  sub.w      d2,bob.x(a0)      ; ship.x -= ship.speed

.check\_up:

  move.w     d0,d1

  lsr.w      #1,d1

  eor.w      d1,d0

  btst.l     #8,d0             ; joy up?

  bne        .set\_up

  btst.l     #0,d0             ; joy down?

  bne        .set\_down

  bra        .return

.set\_up:

  sub.w      d2,bob.y(a0)      ; ship.y-= ship.speed

  bra        .return

.set\_down:

  add.w      d2,bob.y(a0)      ; ship.y+= ship.speed

.return:

  movem.l    (sp)+,d0-a6

  rts

The routine that limits the movement of the ship in the viewport compares the current value of the ship's coordinates with constants that represent the minimum and maximum values. If the coordinate exceeds these values, it is set with the values of the constants. Below is the code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Limits player's ship movement, avoiding exiting from the viewport.

;

; parameters:

; a0 - player's ship

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

plship\_limit\_movement:

  movem.l    d0-a6,-(sp)

  move.w     bob.x(a0),d0

  cmp.w      #PLSHIP\_XMIN,d0           ; x < PLSHIP\_XMIN?

  blt        .limit\_xmin

  bra        .check\_xmax

.limit\_xmin:

  move.w     #PLSHIP\_XMIN,bob.x(a0)    ; x = PLSHIP\_XMIN

  bra        .check\_ymin

.check\_xmax:

  cmp.w      #PLSHIP\_XMAX,d0           ; x > PLSHIP\_XMAX?

  bgt        .limit\_xmax

  bra        .check\_ymin

.limit\_xmax:

  move.w     #PLSHIP\_XMAX,bob.x(a0)    ; x = PLSHIP\_XMAX

.check\_ymin:

  move.w     bob.y(a0),d0

  cmp.w      #PLSHIP\_YMIN,d0           ; y < PLSHIP\_YMIN?

  blt        .limit\_ymin

  bra        .check\_ymax

.limit\_ymin:

  move.w     #PLSHIP\_YMIN,bob.y(a0)    ; y = PLSHIP\_YMIN

  bra        .return

.check\_ymax:

  cmp.w      #PLSHIP\_YMAX,d0           ; y > PLSHIP\_YMAX?

  bgt        .limit\_ymax

  bra        .return

.limit\_ymax:

  move.w     #PLSHIP\_YMAX,bob.y(a0)    ; y = PLSHIP\_YMAX

.return:

  movem.l    (sp)+,d0-a6

  rts

## Main loop

The mainloop takes the following form:

mainloop:

  jsr     wait\_vblank          ; waits for vertical blank

  jsr     swap\_buffers         ; swaps draw and view buffers for implementing

; double buffering

  jsr     scroll\_background    ; scrolls tilemap toward left

  jsr     plship\_update        ; updates player's ship state

  jsr     erase\_bgnds          ; erases bobs backgrounds

  jsr     plship\_draw          ; draws player's ship

  btst    #6,CIAAPRA           ; left mouse button pressed?

  bne     mainloop             ; if not, repeats the loop

Running the program, we will see our ship, complete with fire coming out of the engine, flying through a map.



The complete source code is available at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter13>

# 14. Enemies

## Introduction

At this point, our video game shows a spaceship controlled by the player via joystick, which flies through rocky tunnels. Now it's time to introduce enemies to fight against.

## Data structure

The starting point for the enemy's data structure is always the bob's data structure. Otherwise, we could not draw it on the screen using the draw\_bob routine.

We need to extend the data structure of the bob to add new enemy characteristic fields.

We add a "state" field that represents the state. At the moment there are only two states that an enemy can assume: active, non-active.

We add a "score" field that represents the score the player gets for destroying the enemy. It will vary according to the enemy and the difficulty needed to destroy it.

We add an "energy" field that represents the amount of energy available to the enemy. This amount will be decreased with each hit received. When the energy becomes zero, the enemy explodes and is destroyed.

The added fields are shown in the following code snippet. Create a file enemies.i and put this code snippet into it.

; enemy

                     Rsreset

enemy.bob            rs.b       bob.length

enemy.state          rs.w       1

enemy.score          rs.w       1    ; score given when enemy is destroyed by

; the player

enemy.energy         rs.w       1    ; amount of energy. When reaches zero, the

; alien is destroyed.

## When to spawn an enemy

When should a given enemy appear on the screen? Since the background of our video game is based on a map, the most natural response is to make an enemy appear when the player's ship reaches a given location on the map. Since the camera always follows the player's ship, then we can say that we activate an enemy when the camera reaches a given location on the map.

To each enemy we must associate the position of the map in which it will activate. The position of the map is expressed in pixels. Then to the enemy's data structure we must add a "map\_position" field, which contains the column of the map in which it will activate.

...

enemy.map\_position  rs.w    1    ; when the camera reaches this position on the

; map, the enemy will activate

## How to make an enemy move

After an enemy has become active and therefore visible, how do we make it move?

The idea is to give commands to the enemy. The commands can be to reach a given position, take a pause, shoot etc... The enemy must execute them in sequence, one after the other.

The following table represents the commands that can be given to an enemy.

|  |  |  |
| --- | --- | --- |
| Command | Parameters | Description |
| GOTO | x,y | makes enemy reach the indicated position |
| PAUSE | num\_frames | stops the enemy for a given number of frames |
| FIRE |  | fires shots towards the player |
| SETPOS | x,y | sets the enemy position |
| END |  | deactivates the enemy |

How do we encode commands? We use a word to define the command code and one or more words for the parameters. Let's define the following constants, indicating command codes:

ENEMY\_CMD\_END        equ 0

ENEMY\_CMD\_GOTO       equ 1

ENEMY\_CMD\_PAUSE      equ 2

ENEMY\_CMD\_FIRE       equ 3

ENEMY\_CMD\_SETPOS     equ 4

Where do we store the list of commands? We add to the enemy's data structure an area that hosts this list. We set a maximum length of the list of commands, using the constant ENEMY\_CMD\_LIST\_SIZE, equal to 40 bytes. You must also add a field that represents the pointer to the current command.

...

enemy.cmd\_pointer  rs.l    1                      ; pointer to the next command

enemy.cmd\_list     rs.b    ENEMY\_CMD\_LIST\_SIZE    ; commands list

## Let's add two hidden parts to the left and right of the playfield for clipping

Suddenly making enemies appear on the screen is not a good effect for the player. We must therefore initially place an off-screen enemy, in an area not visible to the right of the viewport and then gradually make it enter the screen. Similarly, the enemy will exit the screen from the left side.

To do this, we need to create a playfield that is wider than the viewport. We need to add to the left and right sides of the viewport two areas with enough width to hold an enemy. In the file playfield.i, we define two constants which represents the width of each clip area:

CLIP\_LEFT       equ 64+32

CLIP\_RIGHT      equ 64

We add 32 additional pixels to left clip to account for the extra 32 pixels used to mask the scrolling noise on the left.

As a result, the width of the playfield 2 will be increased by CLIP\_LEFT and CLIP\_RIGHT.

PF2\_WIDTH       equ VIEWPORT\_WIDTH+CLIP\_LEFT+CLIP\_RIGHT

Now the pointers to the bitplanes must no longer point to the beginning of the playfield, but there must be an offset equal to (CLIP\_LEFT-32)/8 bytes.

Bitplane pointers are set in the swap\_buffers routine, which must be modified accordingly, as shown below. In detail, we need to add (CLIP\_LEFT-32)/8 to view\_buffer to account for the large non-visible area to the left of the viewport.

swap\_buffers:

  movem.l    d0-a6,-(sp)

  move.l     draw\_buffer,d0   ; swaps the values ​​of draw\_buffer and view\_buffer

  move.l     view\_buffer,draw\_buffer

  move.l     d0,view\_buffer

  add.l      #(CLIP\_LEFT-32)/8,d0

## Preparing the graphics

The following image shows the spritesheet containing 6 enemies.



To create a single palette for both the enemies and the graphics already created, i.e. the player's tiles and spaceship, we use the procedure described in chapter 12.

After resaving all the images with the new unified palette, you need to export them in raw format, using the amigeconv tool.

Add the following commands to the amigeconv\_commands.bat file:

amigeconv.exe -f bitplane -d 4 .\enemies.png enemies.raw

amigeconv.exe -f bitplane -m -d 1 .\enemies.png enemies.mask

Finally, you need to import the new images into the source code, as in the following code snippet. Put this code into a new file, named “enemies\_model.s”.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                      SECTION    graphics\_data,DATA\_C

enemy\_explosion\_gfx   incbin     "gfx/enemy\_explosion.raw"

enemy\_explosion\_mask  incbin     "gfx/enemy\_explosion.mask"

## Creating Enemy Arrays

For each enemy we want to introduce into the game, we need to specify the values of the fields in its data structure. This is in fact the model with which to build enemy instances.

In the “enemies\_model.s” file, create a "Variables" section and define an array called "enemies\_model" in it. In this array, define all enemy models.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

        SECTION    code\_section,CODE

enemies\_model:

enemy1  dc.w       0                       ; enemy.x

        dc.w       0                       ; enemy.y

        dc.w       2                       ; enemy.speed

        dc.w       64                      ; enemy.width

        dc.w       45                      ; enemy.height

        dc.w       0                       ; enemy.ssheet\_c

        dc.w       0                       ; enemy.ssheet\_r

        dc.w       384                     ; enemy.ssheet\_w

        dc.w       45                      ; enemy.ssheet\_h

        dc.l       enemies\_gfx             ; enemy.imgdata

        dc.l       enemies\_mask            ; enemy.mask

        dc.w       0                       ; enemy.anim\_duration

        dc.w       0                       ; enemy.anim\_timer

        dc.w       0                       ; enemy.num\_frames

        dc.w       ENEMY\_STATE\_INACTIVE    ; enemy.state

        dc.w       100                     ; enemy.score

        dc.w       5                       ; enemy.energy

        dc.w       192                     ; enemy.map\_position

        dc.w       0                       ; enemy.tx

        dc.w       0                       ; enemy.ty

        dc.w       0                       ; enemy.cmd\_pointer

        dc.w       0                       ; enemy.pause\_timer

        dc.w       ENEMY\_CMD\_SETPOS,CLIP\_LEFT+320,53    ; enemy.cmd\_list

        dc.w       ENEMY\_CMD\_GOTO,0,53

        dc.w       ENEMY\_CMD\_END

        dcb.b      ENEMY\_CMD\_LIST\_SIZE-7\*2,0

...

For score and energy you can assign any value for now. In map position put the coordinates of the map at which you want it to activate. To test it, it is advisable to put a small value, so that it activates immediately. Finally, come up with commands to insert into the cmd\_list to move the enemy. As a general rule, it is advisable to place the enemy in an invisible position on the screen, at the right end. In this way, when it activates, we will make it enter the screen by giving a GOTO type command. Then we can make him pause and maybe resume the movement, until he leaves the screen on the left.

Starting from the enemy's model, you need to create an instance, whose fields will be modified during the game. Instead, the fields of the model must be non-editable, read-only.

To contain enemy instances, create an array in a BSS segment of zeroed memory, always in enemies\_model.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

               SECTION    bss\_data,BSS\_C

enemies\_array  ds.b       (enemy.length\*NUM\_ENEMIES)

You can find the complete “enemies\_model.s” file at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/blob/main/chapter14/enemies_model.s>

The enemy array must be initialized, copying data from enemies\_model. This task is performed by the init\_enemies\_array routine, which is defined in a new file named "enemies.s". This routine must be invoked in main, at initialization time. Put this code into enemies.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the enemies array, copying data from enemies\_model

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_enemies\_array:

  movem.l    d0-a6,-(sp)

  move.l     #(enemy.length\*NUM\_ENEMIES),d7

  lea        enemies\_model,a0

  lea        enemies\_array,a1

.copy\_loop:

  move.b     (a0)+,(a1)+

  dbra       d7,.copy\_loop

.return:

  movem.l    (sp)+,d0-a6

  rts

## Drawing enemies

Let's create a routine to draw enemies. Note that enemies are not drawn if they are in the idle state. Below is the source code. Put this code into enemies.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the enemies.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

enemies\_draw:

  movem.l    d0-a6,-(sp)

  lea        enemies\_array,a3

  move.l     #NUM\_ENEMIES-1,d7                   ; iterates over enemies array

.loop:

  cmp.w      #ENEMY\_STATE\_INACTIVE,enemy.state(a3) ; enemy state is inactive?

  beq        .skip\_draw

  move.l     draw\_buffer,a2

  jsr        draw\_bob                      ; draws enemy

.skip\_draw:

  add.l      #enemy.length,a3              ; points to next enemy in the array

  dbra       d7,.loop

.return:

  movem.l    (sp)+,d0-a6

  rts

## Enemy activation

Now you need to create a routine to activate an enemy. If the value of the map\_position field is equal to camera\_x, then the enemy's status is changed to active. Below is the complete code. Put this code into enemies.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Activates enemies based on their map location.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

enemies\_activate:

  movem.l    d0-a6,-(sp)

  lea        enemies\_array,a0

  move.l     #NUM\_ENEMIES-1,d7              ; iterates over enemies array

.loop:

  move.w     enemy.map\_position(a0),d0

  cmp.w      camera\_x,d0                    ; enemy.map\_position = camera\_x?

  beq        .activate

  bra        .next\_element

.activate:

  move.w     #ENEMY\_STATE\_ACTIVE,enemy.state(a0) ; changes state to active

.next\_element:

  add.l      #enemy.length,a0               ; points to next enemy in the array

  dbra       d7,.loop

.return:

  movem.l    (sp)+,d0-a6

  rts

## Executing enemy commands

Now we must create a routine that carries out the commands given to the enemy, which allow him to move. To execute commands, the enemy must not be in the inactive state. First, the current command is taken from the command list, via the cmd\_pointer field. Then based on the command, you jump to the code that executes it.

To execute the GOTO command, you get the target coordinates tx,ty you want to move the enemy to. Then a comparison is made between the target coordinates and the current ones. If the current ones are lower than the targets, then they increase, otherwise they decrease. If both target coordinates are the same as the current ones, it means that the enemy has reached the desired target position and therefore you can move on to the next command, incrementing the pointer to the commands.

To execute the PAUSE command, first check that the enemy is not already in the pause state. If it is not, you get the parameter that indicates the duration of the pause and initialize the pause\_timer with its value. You also change the state to pause. If, on the other hand, the enemy is in a pause state, the pause\_timer is decreased. When this timer reaches zero, the pause is over, so you change the state to active and move on to the next command.

The END command simply puts the enemy in an idle state, so that no draws and commands are not executed.

For now, the FIRE command does nothing, it simply advances the cmd\_pointer. It will be implemented in a later chapter.

The SET\_POS command sets the enemy's x,y coordinates with the values specified as command parameters. Put this routine in enemies.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Executes commands for controlling active enemies.

;

; parameters:

; a0 - enemy instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

enemies\_execute\_command:

  movem.l    d0-a6,-(sp)

  cmp.w      #ENEMY\_STATE\_INACTIVE,enemy.state(a0) ; enemy state is inactive?

  beq        .return

.parse\_command:

  lea        enemy.cmd\_list(a0),a1

  add.w      enemy.cmd\_pointer(a0),a1

  move.w     (a1),d0                       ; fetches current command

  cmp.w      #ENEMY\_CMD\_GOTO,d0            ; interprets the command and

; executes it

  beq        .exec\_goto

  cmp.w      #ENEMY\_CMD\_END,d0

  beq        .exec\_end

  cmp.w      #ENEMY\_CMD\_PAUSE,d0

  beq        .exec\_pause

  cmp.w      #ENEMY\_CMD\_FIRE,d0

  beq        .exec\_fire

  cmp.w      #ENEMY\_CMD\_SETPOS,d0

  beq        .exec\_setpos

  bra        .return

.exec\_goto:

  move.w     #ENEMY\_STATE\_GOTOXY,enemy.state(a0) ; changes state to gotoxy

  move.w     2(a1),enemy.tx(a0)            ; gets target coordinates tx,ty

  move.w     4(a1),enemy.ty(a0)

  move.w     enemy.tx(a0),d0

  cmp.w      bob.x(a0),d0                  ; tx- x

  beq        .check\_ty                     ; if tx = x, checks ty

  bra        .return

.check\_ty:

  move.w     enemy.ty(a0),d0

  cmp.w      bob.y(a0),d0

  beq        .command\_executed             ; if ty = y, then enemy reached

; target, so the command has been

; executed

  bra        .return

.command\_executed:

  move.w     #ENEMY\_STATE\_ACTIVE,enemy.state(a0) ; changes state to active

  add.w      #3\*2,enemy.cmd\_pointer(a0)    ; points to next command

  bra        .return

.exec\_end:

  move.w     #ENEMY\_STATE\_INACTIVE,enemy.state(a0) ; changes state to inactive

  clr.w      enemy.cmd\_pointer(a0)         ; resets cmd\_pointer

  bra        .return

.exec\_pause:

  cmp.w      #ENEMY\_STATE\_PAUSE,enemy.state(a0) ; state = pause?

  beq        .state\_pause

  move.w     2(a1),d0                      ; gets pause duration in frames

  move.w     d0,enemy.pause\_timer(a0)      ; initializes pause timer

  move.w     #ENEMY\_STATE\_PAUSE,enemy.state(a0) ; changes state to pause

  bra        .return

.state\_pause:

  sub.w      #1,enemy.pause\_timer(a0)      ; updates pause timer

  beq        .end\_pause                    ; pause timer = 0?

  bra        .return

.end\_pause:

  move.w     #ENEMY\_STATE\_ACTIVE,enemy.state(a0)      ; change state to active

  add.w      #2\*2,enemy.cmd\_pointer(a0)    ; points to next command

  bra        .return

.exec\_fire:

  add.w      #2,enemy.cmd\_pointer(a0)      ; points to next command

  bra        .return

.exec\_setpos:

  move.w     2(a1),d0                      ; gets x0 coordinate

  move.w     d0,bob.x(a0)                  ; enemy.x = x0

  move.w     4(a1),d0

  move.w     d0,bob.y(a0)                  ; enemy.y = y0

  add.w      #3\*2,enemy.cmd\_pointer(a0)    ; points to next command

  bra        .return

.return:

  movem.l    (sp)+,d0-a6

  rts

## Enemy state update

An enemy's status must be updated with each frame. This task is done by the enemies\_update routine, which iterates over the array of enemies. If the current enemy's status is inactive, move on to the next enemy. If the current enemy's state is gotoxy, then compare x to the tx field. If tx < x then increment x otherwise decrement it. Similarly, compare y with the field ty. Finally, it executes the current command. Below is the complete code of the procedure, to be inserted in the enemies.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the enemies state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

enemies\_update:

  movem.l    d0-a6,-(sp)

  lea        enemies\_array,a0

  move.l     #NUM\_ENEMIES-1,d7

; iterates over the enemies array

.loop:

  cmp.w      #ENEMY\_STATE\_INACTIVE,enemy.state(a0) ; enemy state is inactive?

  beq        .next\_element        ; if yes, doesn't update state and skips to

; next enemy

  cmp.w      #ENEMY\_STATE\_GOTOXY,enemy.state(a0)   ; enemy state is gotoxy?

  beq        .state\_gotoxy

  bra        .exec\_command

.state\_gotoxy:

  move.w     bob.speed(a0),d1

  move.w     enemy.tx(a0),d0

  cmp.w      bob.x(a0),d0

  blt        .decr\_x              ; if tx < x, then decreases x

  bgt        .incr\_x              ; if tx > x, then increases x

  bra        .compare\_y

.decr\_x:

  sub.w      d1,bob.x(a0)

  bra        .compare\_y

.incr\_x:

  add.w      d1,bob.x(a0)

  bra        .compare\_y

.compare\_y:

  move.w     enemy.ty(a0),d0

  cmp.w      bob.y(a0),d0

  blt        .decr\_y              ; if ty < y then decreases y

  bgt        .incr\_y              ; if ty > y then increases y

  bra        .exec\_command

.decr\_y:

  sub.w      d1,bob.y(a0)

  bra        .exec\_command

.incr\_y:

  add.w      d1,bob.y(a0)

  bra        .exec\_command

.exec\_command:

  bsr        enemies\_execute\_command

.next\_element:

  add.l      #enemy.length,a0     ; points to next enemy in the array

  dbra       d7,.loop

.return:

  movem.l    (sp)+,d0-a6

  rts

## Main loop

The new routines we have created must be executed in the main loop, which becomes as below.

mainloop:

  jsr     wait\_vblank          ; waits for vertical blank

  jsr     swap\_buffers         ; swaps draw and view buffers for implementing

; double buffering

  jsr     scroll\_background    ; scrolls tilemap toward left

  jsr     plship\_update        ; updates player's ship state

  jsr     enemies\_activate     ; activates enemies based on their position on

; the map

  jsr     enemies\_update       ; updates enemies state

  jsr     erase\_bgnds          ; erases bobs backgrounds

  jsr     enemies\_draw         ; draws enemies

  jsr     plship\_draw          ; draws player's ship

  btst    #6,CIAAPRA           ; left mouse button pressed?

  bne     mainloop             ; if not, repeats the loop

By running the program, you will be able to command your spaceship along the scrolling level and you will see enemies appear and move.



You can download the full source code from the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter14>

# 15. Firing shots

In the previous chapter we added enemies to our video game. We've also implemented the feature to give commands to enemies to program their behavior. Now we want to give the skill to fire shots at both the player's spaceship and enemies.

## Player’s ship Shots

When to fire a shot from the player's ship? We can choose whether the trigger of the shot should be the press of the fire button on the joystick or the release. Imagining the press of the fire button as a square wave signal, the following figure shows that we can trigger the shot both on the positive front of the wave, when switching from not pressed to pressed, or on the negative front, i.e. when switching from pressed to not pressed. We choose the trigger on the positive front.



To make firing shots more realistic, we want a certain amount of time between two consecutive shots, which we call FIRE\_INTERVAL.



To implement this mechanism, we need to modify the plship.i file, adding the constant FIRE\_INTERVAL and adding the fire\_timer field to the player's ship data structure.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; DATA STRUCTURES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; player's ship

                    rsreset

ship.bob            rs.b       bob.length

ship.anim\_duration  rs.w       1                ; duration of animation in

; frames

ship.anim\_timer     rs.w       1                ; timer for animation

ship.fire\_timer     rs.w       1                ; timer to measure the interval

; between two shots

ship.length         rs.b       0

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

...

FIRE\_INTERVAL equ 7 ; time interval between two shots

Don't forget to also edit the player\_ship instance, in the plship.s file, by adding the fire\_timer field.

player\_ship  ...

             dc.w    0                   ; ship.fire\_timer

To start the shots when the fire button on the joystick is pressed, we need to create a routine, which we call ship\_fire\_shot, in the plship.s module.

The pseudo-code for this routine is as follows:

ship\_fire\_shot

decreases fire\_timer

avoids fire\_timer from becoming negative

if fire button is pressed

if fire button previous frame is not pressed

    if fire\_timer = 0

            fire\_timer = FIRE\_INTERVAL

create shot

    fire\_prev\_fame = 1

else

    fire\_prev\_frame = 0

To remember the state of the joystick's fire button at the previous frame, we introduce a new variable, called fire\_prev\_frame.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                 SECTION    code\_section,CODE

fire\_prev\_frame  dc.w       0  ; state of fire button in the previous frame (1

; pressed)

To detect the press of the fire button on the joystick in port 1, you need to read bit 7 of the CIAAPRA register. If the button is pressed, the bit is reset to zero.

The assembly code of the routine is as follows:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Fires a shot from the ship.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

ship\_fire\_shot:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a0

  sub.w      #1,ship.fire\_timer(a0)                ; decreases fire timer, time

; interval between two shots

  tst.w      ship.fire\_timer(a0)                   ; fire\_timer < 0?

  blt        .avoid\_neg

  bra        .check\_fire\_btn

.avoid\_neg:

  clr.w      ship.fire\_timer(a0)

.check\_fire\_btn:

  btst       #7,CIAAPRA                            ; fire button of joystick #1

; pressed?

  beq        .check\_prev\_state

  bra        .fire\_not\_pressed

.check\_prev\_state:

  cmp.w      #1,fire\_prev\_frame                    ; fire button pressed

; previous frame?

  bne        .check\_timer

  bra        .prev\_frame

.check\_timer:

  tst.w      ship.fire\_timer(a0)                   ; fire\_timer = 0?

  beq        .create\_shot

  bra        .prev\_frame

.create\_shot:

  move.w     #FIRE\_INTERVAL,ship.fire\_timer(a0)    ; fire\_timer = FIRE\_INTERVAL

  jsr        ship\_shot\_create

  bra        .prev\_frame

.fire\_not\_pressed:

  clr.w      fire\_prev\_frame

  bra        .return

.prev\_frame:

  move.w     #1,fire\_prev\_frame

.return:

  movem.l    (sp)+,d0-a6

  rts

This routine must be called in the mainloop, on file main.s, immediately after the plship\_update routine.

mainloop:

  jsr    wait\_vblank          ; waits for vertical blank

  jsr    swap\_buffers

  jsr    scroll\_background

  jsr    plship\_update

  jsr    ship\_fire\_shot       ; fires shots from player's ship

  ...

## Shot Data Structure

The next step is to create a data structure to model a shot.

The shot structure will inherit all the bob fields, adding the fields shown in the following UML diagram.



To define the shot data structure, you create a new “shots.i” file and insert the following code.

; shot fired from ship and enemies

                    rsreset

shot.x              rs.w       1    ; position

shot.y              rs.w       1

shot.speed          rs.w       1

shot.width          rs.w       1    ; width in px

shot.height         rs.w       1    ; height in px

shot.ssheet\_c       rs.w       1    ; spritesheet column of the shot

shot.ssheet\_r       rs.w       1    ; spritesheet row of the shot

shot.ssheet\_w       rs.w       1    ; spritesheet width in pixels

shot.ssheet\_h       rs.w       1    ; spritesheet height in pixels

shot.imgdata        rs.l       1    ; image data address

shot.mask           rs.l       1    ; mask address

shot.state          rs.w       1    ; current state

shot.num\_frames     rs.w       1    ; number of animation frames

shot.anim\_duration  rs.w       1    ; animation duration (in frames)

shot.anim\_timer     rs.w       1    ; animation timer

shot.damage         rs.w       1    ; amount of damage dealt

shot.length         rs.b       0

## Preparing graphics

The next step is preparing the graphics for the shots. The figure below shows the spritesheet for the player's ship shots. You can see that frames 0-5 reproduce the animation of the shot launch. Frame 6 represents the shot that moves. Frames 7-12 play the animation when the shot collides with the target.



Let's convert the spritesheet from png to raw and generate the mask adding the following commands to the “amigeconv\_commands.bat” file.

amigeconv.exe -f bitplane -d 4 .\ship\_shots.png ship\_shots.raw

amigeconv.exe -f bitplane -m -d 1 .\ship\_shots.png ship\_shots.mask

## Graphics import

Create a shots.s file, where you create a section allocated into the chip ram. In this section, import the spritesheet of the shots and its mask.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                 SECTION    graphics\_data,DATA\_C

ship\_shots\_gfx   incbin     "gfx/ship\_shots.raw"

ship\_shots\_mask  incbin     "gfx/ship\_shots.mask"

## Shots Array

Since the player's ship can fire multiple shots at once, we need to create an array to hold instances of these shots. The maximum number of shots is given by the constant PLSHIP\_MAX\_SHOTS, defined in shots.i.

Define the ship\_shots array in a segment of zeroed bss data, in the shots.s file, as shown below.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

             SECTION    bss\_data,BSS\_C

ship\_shots   ds.b       (shot.length\*PLSHIP\_MAX\_SHOTS)    ; ship's shots array

## Instantiating a Shot

In the ship\_fire\_shot routine there was a call to a routine that we haven't created yet, the ship\_shot\_create that creates an instance of a shot and inserts it into the ship\_shots array.

This routine must be created in the shots.s module.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Creates a new ship's shot.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

ship\_shot\_create:

  movem.l    d0-a6,-(sp)

  lea        ship\_shots,a0

; finds the first free element in the array

  move.l     #PLSHIP\_MAX\_SHOTS-1,d7

.loop:

  tst.w      shot.state(a0)                       ; shot.state is idle?

  beq        .insert\_new\_shot

  add.l      #shot.length,a0                      ; goes to next element

  dbra       d7,.loop

  bra        .return

; creates a new shot instance and inserts in the first free element of the array

.insert\_new\_shot:

  lea        player\_ship,a1

  move.w     bob.x(a1),d0

  add.w      #47,d0

  move.w     d0,shot.x(a0)                        ; shot.x = ship.x +

; ship.width

  move.w     bob.y(a1),d0

  sub.w      #9,d0

  move.w     d0,shot.y(a0)                        ; shot.y = ship.y + 10

  move.w     #SHIP\_SHOT\_SPEED,shot.speed(a0)

  move.w     #SHIP\_SHOT\_WIDTH,shot.width(a0)

  move.w     #SHIP\_SHOT\_HEIGHT,shot.height(a0)

  move.w     #0,shot.ssheet\_c(a0)

  move.w     #0,shot.ssheet\_r(a0)

  move.w     #448,shot.ssheet\_w(a0)

  move.w     #128,shot.ssheet\_h(a0)

  move.l     #ship\_shots\_gfx,shot.imgdata(a0)

  move.l     #ship\_shots\_mask,shot.mask(a0)

  move.w     #SHOT\_STATE\_LAUNCH,shot.state(a0)

  move.w     #6,shot.num\_frames(a0)

  move.w     #3,shot.anim\_duration(a0)

  move.w     #3,shot.anim\_timer(a0)

  move.w     #SHIP\_SHOT\_DAMAGE,shot.damage(a0)

.return:

  movem.l    (sp)+,d0-a6

  rts

## Drawing shots

After instantiating the shots, you need to be able to draw them. To do this, you create the ship\_shots\_draw routine, again in the shots.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the ship's shots.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

ship\_shots\_draw:

       movem.l    d0-a6,-(sp)

       lea        ship\_shots,a0

       move.l     #PLSHIP\_MAX\_SHOTS-1,d7

; iterates over the ship\_shots array

.loop:

; doesn't draw shots in idle state

       tst.w      shot.state(a0)

       beq        .next

; draws the current shot

       move.l     a0,a3

       move.l     draw\_buffer,a2

       jsr        draw\_bob

; goes to next element

.next  add.l      #shot.length,a0

       dbra       d7,.loop

       bra        .return

.return:

       movem.l    (sp)+,d0-a6

       rts

## Movement and animation of the shots

The last step necessary to make the player's ship shots work is the movement of the shots and their animation.

Notice that the hit data structure has a "state" field. To define what states it can assume, what the various states do, and when state transitions occur, it is convenient to use a state diagram, such as the one in the following figure.



State transitions will be implemented in the ship\_shots\_update routine, of which we show the pseudo-code.

iterates over the ship\_shots array

    doesn't updates shots in idle state

    if state is launch

        decreases anim\_timer

        if anim\_timer = 0

        increases animation frame

            resets anim\_timer

            if current frame > num frames

                set frame 6 (flight)

                changes state to active

if state is active

    updates position

        if shot reaches the right part of screen

        changes state to idle

   if state is hit

        decreases anim\_timer

        if anim\_timer = 0

        increases animation frame

            resets anim\_timer

            if current frame > num frames

            changes state to idle

The ship\_shots\_update routine must always be created in the shots.s file. Below is the assembly code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates ship's shots position and animates them.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

ship\_shots\_update:

       movem.l    d0-a6,-(sp)

       lea        ship\_shots,a0

       move.l     #PLSHIP\_MAX\_SHOTS-1,d7

.loop:

       tst.w      shot.state(a0)            ; shot.state is idle (0)?

       beq        .next

       cmp.w      #SHOT\_STATE\_LAUNCH,shot.state(a0) ; shot.state is launch?

       beq        .launch

       cmp.w      #SHOT\_STATE\_ACTIVE,shot.state(a0) ; shot.state is active?

       beq        .active

       cmp.w      #SHOT\_STATE\_HIT,shot.state(a0)    ; shot.state is hit?

       beq        .hit

       bra        .next

.launch:

       sub.w      #1,shot.anim\_timer(a0)    ; decreases anim\_timer

       beq        .inc\_frame                ; anim\_timer = 0?

       bra        .next

.inc\_frame:

       add.w      #1,shot.ssheet\_c(a0)      ; increases animation frame

       move.w     shot.anim\_duration(a0),shot.anim\_timer(a0) ; resets

; anim\_timer

       move.w     shot.ssheet\_c(a0),d0

       cmp.w      shot.num\_frames(a0),d0    ; current frame > num frames?

       bgt        .end\_anim

       bra        .next

.end\_anim:

       move.w     #6,shot.ssheet\_c(a0)      ; sets shot flight frame

       move.w     #SHOT\_STATE\_ACTIVE,shot.state(a0) ; changes shot state to

; active

       bra        .next

.active:

       move.w     shot.speed(a0),d0

       add.w      d0,shot.x(a0)             ; shot.x += shot.speed

       cmp.w      #SHOT\_MAX\_X,shot.x(a0)    ; shot.x >= SHOT\_MAX\_X ?

       bge        .deactivate

       bra        .next

.deactivate  move.w     #SHOT\_STATE\_IDLE,shot.state(a0)

       bra        .next

.hit:

       sub.w      #1,shot.anim\_timer(a0)    ; decreases anim\_timer

       beq        .inc\_frame2               ; anim\_timer = 0?

       bra        .next

.inc\_frame2:

       add.w      #1,shot.ssheet\_c(a0)      ; increases animation frame

       move.w     shot.anim\_duration(a0),shot.anim\_timer(a0) ; resets

; anim\_timer

       move.w     shot.ssheet\_c(a0),d0

       cmp.w      shot.num\_frames(a0),d0    ; current frame > num frames?

       bgt        .end\_anim2

       bra        .next

.end\_anim2:

       move.w     #SHOT\_STATE\_IDLE,shot.state(a0) ; changes shot state to idle

       bra        .next

.next  add.l      #shot.length,a0           ; goes to next element

       dbra       d7,.loop

       bra        .return

.return:

       movem.l    (sp)+,d0-a6

       rts

The mainloop, in main.s, must be modified to place calls to ship\_shots\_update and ship\_shots\_draw routines, as shown below.

mainloop:

  jsr      wait\_vblank           ; waits for vertical blank

  jsr      swap\_buffers

  jsr      scroll\_background

  jsr      plship\_update

  jsr      ship\_fire\_shot        ; fires shots from player's ship

  jsr      ship\_shots\_update     ; updates player's ship shots state

  jsr      enemies\_activate

  jsr      enemies\_update

  jsr      erase\_bgnds

  jsr      enemies\_draw

  jsr      plship\_draw

  jsr      ship\_shots\_draw       ; draws player's ship shots

  btst     #6,CIAAPRA            ; left mouse button pressed?

  bne.s    mainloop              ; if not, repeats the loop

Running the program, you can make your ship fire shots by pressing the fire button on the joystick, as shown in the following image.

Immagine che contiene testo, schermata, grafica, design

Descrizione generata automaticamente

## Enemy shots

We now want enemies to be able to fire shots at the player's ship as well.

The event that creates an instance of an enemy shot is the execution of the "fire" command in the list of commands given to the enemy.

Immagine che contiene testo, schermata, Carattere

Descrizione generata automaticamente

Instances of enemy shots will be stored in an array called "enemy\_shots", defined in the bss zeroed data segment, in the shots.s file.

              SECTION   bss\_data,BSS\_C

ship\_shots        ds.b      (shot.length\*PLSHIP\_MAX\_SHOTS) ; ship's shots array

enemy\_shots       ds.b      (shot.length\*ENEMY\_MAX\_SHOTS) ; enemy shots array

To create an instance of an enemy shot, you create the "enemy\_shot\_create" routine, similar to the player's spaceship shot.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Creates a new enemy shot.

;

; parameters:

; a1 - enemy instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

enemy\_shot\_create:

  movem.l    d0-a6,-(sp)

  lea        enemy\_shots,a0

; finds the first free element in the array

  move.l     #ENEMY\_MAX\_SHOTS-1,d7

.loop:

  tst.w      shot.state(a0)            ; shot.state is idle?

  beq        .insert\_new\_shot

  add.l      #shot.length,a0           ; goes to next element

  dbra       d7,.loop

  bra        .return

; creates a new shot instance and inserts in the first free element of the array

.insert\_new\_shot:

  move.w     bob.x(a1),d0

  sub.w      #34,d0

  move.w     d0,shot.x(a0)             ; shot.x = enemy.x -34

  move.w     bob.y(a1),d0

  add.w      #15,d0

  move.w     d0,shot.y(a0)             ; shot.y = enemy.y + 15

  move.w     #ENEMY\_SHOT\_SPEED,shot.speed(a0)

  move.w     #ENEMY\_SHOT\_WIDTH,shot.width(a0)

  move.w     #ENEMY\_SHOT\_HEIGHT,shot.height(a0)

  move.w     #0,shot.ssheet\_c(a0)

  move.w     #0,shot.ssheet\_r(a0)

  move.w     #384,shot.ssheet\_w(a0)

  move.w     #32,shot.ssheet\_h(a0)

  move.l     #enemy\_shots\_gfx,shot.imgdata(a0)

  move.l     #enemy\_shots\_mask,shot.mask(a0)

  move.w     #SHOT\_STATE\_LAUNCH,shot.state(a0)

  move.w     #5,shot.num\_frames(a0)

  move.w     #3,shot.anim\_duration(a0)

  move.w     #3,shot.anim\_timer(a0)

  move.w     #SHIP\_SHOT\_DAMAGE,shot.damage(a0)

.return:

  movem.l    (sp)+,d0-a6

  rts

Add the call to enemy\_shot\_create in the routine enemies\_execute\_command, in the enemies.s file, like in the following code snippet.

enemies\_execute\_command:

  ...

.exec\_fire:

  move.l    a0,a1

  jsr       enemy\_shot\_create    ; creates a new instance of enemy shot

  ...

## Preparation and import graphics of enemy shots

The graphics of the enemies' shots are contained in the following spritesheet.



Note that the first 5 frames represent the animation of the shot launch, while the sixth frame represents the shot moving towards the target.

To convert the spritesheet to raw format and generate the mask, you need to add the following commands to the “amigeconv\_commands.bat” file.

amigeconv.exe -f bitplane -d 4 .\enemy\_shots.png enemy\_shots.raw

amigeconv.exe -f bitplane -m -d 1 .\enemy\_shots.png enemy\_shots.mask

Finally, you need to import the graphics into the code, into the chip memory segment previously defined in the shots.s file.

              SECTION    graphics\_data,DATA\_C

ship\_shots\_gfx    incbin     "gfx/ship\_shots.raw"

ship\_shots\_mask   incbin     "gfx/ship\_shots.mask"

enemy\_shots\_gfx   incbin     "gfx/enemy\_shots.raw"

enemy\_shots\_mask  incbin     "gfx/enemy\_shots.mask"

## Drawing enemy shots

Like the player's ship shots, you also must create a routine that draws them for those of the enemies, which you call "enemy\_shots\_draw". This routine iterates over the enemy\_shots array and , if a shot is not in the idle state, it draws it using the "draw\_bob" routine. This routine must be invoked in the mainloop.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the enemy shots.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

enemy\_shots\_draw:

       movem.l    d0-a6,-(sp)

       lea        enemy\_shots,a0

       move.l     #ENEMY\_MAX\_SHOTS-1,d7

; iterates over the enemy\_shots array

.loop:

       tst.w      shot.state(a0)           ; shot.state is idle?

       beq        .next

       move.l     a0,a3

       move.l     draw\_buffer,a2

       bsr        draw\_bob                 ; draws shot

.next  add.l      #shot.length,a0          ; goes to next element

       dbra       d7,.loop

       bra        .return

.return:

       movem.l    (sp)+,d0-a6

       rts

## Enemy shots update

Like what we saw for the player's ship shots, you need to write a routine that updates the state. Compared to the player's ship shots, the enemy's shots do not have a "Hit" state, as we do not want to animate the collision with the target. Below is the code of the "enemy\_shots\_update" routine, which must be invoked in the mainloop.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the enemy shots state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

enemy\_shots\_update:

             movem.l    d0-a6,-(sp)

             lea        enemy\_shots,a0

             move.l     #ENEMY\_MAX\_SHOTS-1,d7

; iterates over the enemy\_shots array

.loop:

             tst.w      shot.state(a0) ; shot.state is idle?

             beq        .next

             cmp.w      #SHOT\_STATE\_LAUNCH,shot.state(a0) ; shot.state is

; launch?

             beq        .launch

             cmp.w      #SHOT\_STATE\_ACTIVE,shot.state(a0) ; shot.state is active?

             beq        .active

             bra        .next

.launch:

             sub.w      #1,shot.anim\_timer(a0)     ; decreases anim\_timer

             beq        .inc\_frame                 ; anim\_timer = 0?

             bra        .next

.inc\_frame:

             add.w      #1,shot.ssheet\_c(a0)     ; increases animation frame

             move.w     shot.anim\_duration(a0),shot.anim\_timer(a0) ; resets

; anim\_timer

             move.w     shot.ssheet\_c(a0),d0

             cmp.w      shot.num\_frames(a0),d0     ; current frame > numframes?

             bgt        .end\_anim

             bra        .next

.end\_anim:

             move.w     #5,shot.ssheet\_c(a0)       ; sets shot flight frame

             move.w     #SHOT\_STATE\_ACTIVE,shot.state(a0) ; changes shot state

; to active

             bra        .next

.active:

             move.w     shot.speed(a0),d0

             sub.w      d0,shot.x(a0)              ; shot.x -= shot.speed

             cmp.w      #SHOT\_MIN\_X,shot.x(a0)     ; shot.x <= SHOT\_MIN\_X ?

             ble        .deactivate

             bra        .next

.deactivate  move.w     #SHOT\_STATE\_IDLE,shot.state(a0)

.next        add.l      #shot.length,a0            ; goes to next element

             dbra       d7,.loop

             bra        .return

.return:

             movem.l    (sp)+,d0-a6

             rts

Finally, the mainloop must be modified, to recall the last two routines seen.

mainloop:

  jsr      wait\_vblank           ; waits for vertical blank

  jsr      swap\_buffers

  jsr      scroll\_background

  jsr      plship\_update

  jsr      ship\_fire\_shot        ; fires shots from player's ship

  jsr      ship\_shots\_update     ; updates player's ship shots state

  jsr      enemy\_shots\_update    ; updates enemy shots state

  jsr      enemies\_activate

  jsr      enemies\_update

  jsr      erase\_bgnds

  jsr      enemies\_draw

  jsr      plship\_draw

  jsr      ship\_shots\_draw       ; draws player's ship shots

  jsr      enemy\_shots\_draw      ; draws enemy shots

  btst     #6,CIAAPRA            ; left mouse button pressed?

  bne.s    mainloop              ; if not, repeats the loop

As you run the program, you will be able to observe that the third enemy will fire a shot at your spaceship.

Immagine che contiene insetto, testo, schermata, invertebrato

Descrizione generata automaticamente

The complete source code can be found at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter15>

# 16. Collisions and explosions

## Collisions player’s ship shots – enemies

### Bounding box collisions

To detect collisions between the shots fired by the player's ship and the enemies we will use the bounding box technique. Imagine surrounding the sprites of the shot and the enemy with a rectangle, as shown in the following image.

Immagine che contiene schermata, Elementi grafici, grafica, Policromia

Descrizione generata automaticamente

In this way, the collision problem becomes the problem of understanding whether two rectangles intersect.

### Intersecting rectangles

Let's define a data structure for the rectangle, inserting it into a new "collisions.i" file.

; rectangle

              rsreset

rect.x        rs.w       1               ; position of upper left corner

rect.y        rs.w       1

rect.width    rs.w       1               ; width in px

rect.height   rs.w       1               ; height in px

rect.length   rs.b       0

We must now create a routine that given two rectangles r1, r2 returns 1 if they intersect, 0 otherwise.

Looking at the figure below, we notice that the cases in which the two rectangles do not intersect are those shown in the figure. So, in these cases we return 0, in all other cases the two rectangles intersect and therefore we return 1.

Immagine che contiene schermata, quadrato, diagramma, Policromia

Descrizione generata automaticamente

The source code of the procedure, which we call “rect\_intersects” is as follows. This routine must be placed in a new “collisions.s” file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Check if two rectangles r1,r2 intersects.

;

; Input:

; a2 - address of rectangle r1 structure

; a3 - address of rectangle r2 structure

;

; Output:

; d0.w - 1 if the two rectangles intersects, 0 otherwise.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

rect\_intersects:

  movem.l    d1-a6,-(sp)

  clr.w      d0

  move.w     rect.x(a3),d1         ; r2.left

  move.w     rect.x(a2),d2

  add.w      rect.width(a2),d2     ; r1.right

  cmp.w      d2,d1                 ; r2.left - r1.right

  bhi        .return               ; if r2.left > r1.right the rectangles don't

; intersect

  move.w     rect.x(a3),d1

  add.w      rect.width(a3),d1     ; r2.right

  move.w     rect.x(a2),d2         ; r1.left

  cmp.w      d2,d1                 ; r2.right - r1.left

  blo        .return               ; if r2.right < r1.left the rectangles don't

; intersect

  move.w     rect.y(a3),d1         ; r2.top

  move.w     rect.y(a2),d2

  add.w      rect.height(a2),d2    ; r1.bottom

  cmp.w      d2,d1                 ; r2.top - r1.bottom

  bhi        .return               ; if r2.top > r1.bottom the rectangles don't

; intersect

  move.w     rect.y(a2),d1         ; r1.top

  move.w     rect.y(a3),d2

  add.w      rect.height(a3),d2    ; r2.bottom

  cmp.w      d1,d2                 ; r2.bottom - r1.top

  blo        .return               ; if r2.bottom < r1.top the rectangles don't

; intersect

  move.w     #1,d0                 ; else the rectangles intersect

.return:

  movem.l    (sp)+,d1-a6

  rts

### Changes to shot and enemy data structures

You must modify the shot and enemy data structures to add the bounding box and other fields useful for handling collisions.

To the shot's data structure, in the "shots.s" file, add a "damage" field representing the amount of damage inflicted by the shot and the "bbox" field representing the bounding box for collisions.

; shot fired from ship and enemies

                    rsreset

shot.x              rs.w       1              ; position

shot.y              rs.w       1

shot.speed          rs.w       1

shot.width          rs.w       1              ; width in px

shot.height         rs.w       1              ; height in px

shot.ssheet\_c       rs.w       1              ; spritesheet column of the shot

shot.ssheet\_r       rs.w       1              ; spritesheet row of the shot

shot.ssheet\_w       rs.w       1              ; spritesheet width in pixels

shot.ssheet\_h       rs.w       1              ; spritesheet height in pixels

shot.imgdata        rs.l       1              ; image data address

shot.mask           rs.l       1              ; mask address

shot.state          rs.w       1              ; current state

shot.num\_frames     rs.w       1              ; number of animation frames

shot.anim\_duration  rs.w       1              ; animation duration (in frames)

shot.anim\_timer     rs.w       1              ; animation timer

shot.damage         rs.w       1              ; amount of damage dealt

shot.bbox           rs.b       rect.length    ; bounding box

shot.length         rs.b       0

To the enemy's data structure, in the “enemies.i” file, add the "bbox" field, which represents the bounding box for collisions; "flash\_timer" which is a timer for the spaceship flashing; "hit\_timer" to measure the duration of the hit status; “visible” which is 1 when it is visible, 0 invisible; “fire\_offx, fire\_offy” which represent the x,y offset of the fire with the respect of the enemy.

; enemy

                     rsreset

enemy.bob            rs.b       bob.length

enemy.anim\_duration  rs.w       1   ; duration of animation in frames

enemy.anim\_timer     rs.w       1   ; timer for animation

enemy.num\_frames     rs.w       1   ; number of animation frames

enemy.state          rs.w       1

enemy.score          rs.w       1   ; score given when enemy is destroyed by

; the player

enemy.energy         rs.w       1   ; amount of energy. When reaches zero, the

; alien is destroyed.

enemy.map\_position   rs.w       1   ; when the camera reaches this position on

; the map, the enemy will activate

enemy.tx             rs.w       1   ; target x coordinate

enemy.ty             rs.w       1   ; target y coordinate

enemy.cmd\_pointer    rs.w       1   ; pointer to the next command

enemy.pause\_timer    rs.w       1

enemy.bbox           rs.b       rect.length ; bounding box

enemy.flash\_timer    rs.w       1

enemy.hit\_timer      rs.w       1   ; timer used to measure hit state duration

enemy.visible        rs.w       1

enemy.fire\_offx      rs.w       1   ; x offset where to place the fire shot

enemy.fire\_offy      rs.w       1   ; y offset where to place the fire shot

enemy.cmd\_list       rs.b       ENEMY\_CMD\_LIST\_SIZE    ; commands list

enemy.length         rs.b       0

### Collision detection between player's ship shots and enemies

To detect collisions between player's ship shots and enemies, we can use the following algorithm, described in pseudo-code.

iterates over all active player's ship shots

iterates over all active enemies

        checks collision between current shot and current enemy

            setups bounding rectangle for current shot

            setups bounding rectangle for current enemy

            checks if current enemy bounding rectangle intersects with

current shot bounding rectangle

        collision response

The “check\_coll\_shots\_enemies” routine, to be included in the “collisions.s” file, implements this algorithm in assembly language. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Checks for collisions between player's ship shots and enemies.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

check\_coll\_shots\_enemies:

  movem.l    d0-a6,-(sp)

  lea        ship\_shots,a0

  move.l     #PLSHIP\_MAX\_SHOTS-1,d7

; iterates over all active player's ship shots

.shots\_loop:

  cmp.w      #SHOT\_STATE\_ACTIVE,shot.state(a0)        ; is current shot active?

  bne        .next\_shot                               ; if not, move on the

; next shot

  lea        enemies\_array,a1

  move.l     #NUM\_ENEMIES-1,d6

; iterates over all active enemies

.enemies\_loop:

  cmp.w      #ENEMY\_STATE\_INACTIVE,enemy.state(a1)    ; enemy inactive?

  beq        .next\_enemy                              ; if yes, moves on the

; next enemy

; checks collision between current shot and current enemy

  ; setups bounding rectangle for current shot

  lea        rect1,a3

  lea        shot.bbox(a0),a4

  move.w     shot.x(a0),rect.x(a3)

  move.w     rect.x(a4),d0

  add.w      d0,rect.x(a3)

  move.w     shot.y(a0),rect.y(a3)

  move.w     rect.y(a4),d0

  add.w      d0,rect.y(a3)

  move.w     rect.width(a4),rect.width(a3)

  move.w     rect.height(a4),rect.height(a3)

  ; setups bounding rectangle for current enemy

  lea        rect2,a2

  lea        enemy.bbox(a1),a4

  move.w     bob.x(a1),rect.x(a2)

  move.w     rect.x(a4),d0

  add.w      d0,rect.x(a2)

  move.w     bob.y(a1),rect.y(a2)

  move.w     rect.y(a4),d0

  add.w      d0,rect.y(a2)

  move.w     rect.width(a4),rect.width(a2)

  move.w     rect.height(a4),rect.height(a2)

  ; checks if current enemy bounding rectangle intersects with current shot

; bounding rectangle

  bsr        rect\_intersects

  ; response to collision

  bsr        coll\_response\_shots\_enemies

.next\_enemy:

  add.l      #enemy.length,a1

  dbra       d6,.enemies\_loop

.next\_shot:

  add.l      #shot.length,a0

  dbra       d7,.shots\_loop

.return:

  movem.l    (sp)+,d0-a6

  rts

### Collision response

If a collision is detected between the shots and the enemies, the “coll\_response\_shots\_enemies” routine is called. This routine puts the shot in the hit state, so that the shot animation that hits the target is played. It also puts the enemy in the hit state, decreasing the energy by an amount equal to the “shot.damage” field. If the enemy's energy becomes less than or equal to zero, it is blow up, calling the “enemy\_explode” routine. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Responds to collisions between player's ship shots and enemies.

;

; parameters:

; d0.w - collision result: 1 if there is a collision, 0 otherwise

; a0 - pointer to shot instance

; a1 - pointer to enemy instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

coll\_response\_shots\_enemies:

  tst.w     d0                             ; if d0 = 0 there is no collision

  beq       .return                        ; and therefore returns

.collision:

  move.w    shot.anim\_duration(a0),shot.anim\_timer(a0) ; resets anim timer

  move.w    #0,shot.ssheet\_c(a0)           ; sets hit animation frame

  move.w    #1,shot.ssheet\_r(a0)

  move.w    #SHOT\_STATE\_HIT,shot.state(a0) ; changes state to hit

  move.w    #ENEMY\_STATE\_HIT,enemy.state(a1)

  move.w    #ENEMY\_FLASH\_DURATION,enemy.flash\_timer(a1)

  move.w    #ENEMY\_HIT\_DURATION,enemy.hit\_timer(a1)

  move.w    shot.damage(a0),d0

  sub.w     d0,enemy.energy(a1)

  ble       .explode

  bra       .return

.explode:

  bsr       enemy\_explode

.return:

  rts

### Enemy explosion

To blow up an enemy, you need to implement the “enemy\_explode” routine, placed in the “enemies.s” file. This routine changes the enemy's state to explosion and sets the explosion animation data in the enemy's instance. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Blows up the enemy.

;

; parameters:

; a0 - shot instance

; a1 - enemy instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

enemy\_explode:

; changes enemy state to explosion

  move.w    #ENEMY\_STATE\_EXPLOSION,enemy.state(a1)

; setups explosion graphics data and mask

  move.l    #enemy\_explosion\_gfx,bob.imgdata(a1)

  move.l    #enemy\_explosion\_mask,bob.mask(a1)

; adjusts bob position for explosion animation

  sub.w     #3,bob.x(a1)

  sub.w     #12,bob.y(a1)

; setups explosion animation data

  move.w    #64,bob.width(a1)

  move.w    #64,bob.height(a1)

  move.w    #0,bob.ssheet\_c(a1)

  move.w    #0,bob.ssheet\_r(a1)

  move.w    #512,bob.ssheet\_w(a1)

  move.w    #64,bob.ssheet\_h(a1)

  move.w    #3,enemy.anim\_duration(a1)

  move.w    #3,enemy.anim\_timer(a1)

  move.w    #8,enemy.num\_frames(a1)

  rts

For the animation of the enemy's explosion, the following spritesheet is used.

Note that the animation has 8 frames, measuring 64 x 64 pixels.

Immagine che contiene schermata, Ambra, calore

Descrizione generata automaticamente

This spritesheet must be converted to raw format and the mask must be generated, adding the following commands to the “amigeconv\_commands.bat” file.

amigeconv.exe -f bitplane -d 4 .\enemy\_explosion.png enemy\_explosion.raw

amigeconv.exe -f bitplane -m -d 1 .\enemy\_explosion.png enemy\_explosion.mask

The graphics files must be included in the “enemies.s” file, in a chip ram memory segment.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                      SECTION    graphics\_data,DATA\_C

enemy\_explosion\_gfx   incbin     "gfx/enemy\_explosion.raw"

enemy\_explosion\_mask  incbin     "gfx/enemy\_explosion.mask"

Finally, you need to put the call to the “check\_coll\_shots\_enemies” routine in the mainloop, as shown in the code below.

mainloop:

  jsr      wait\_vblank                 ; waits for vertical blank

  jsr      swap\_buffers

  jsr      scroll\_background

  jsr      plship\_update

  jsr      ship\_fire\_shot              ; fires shots from player's ship

  jsr      ship\_shots\_update           ; updates player's ship shots state

  jsr      enemy\_shots\_update          ; updates enemy shots state

  jsr      enemies\_activate

  jsr      enemies\_update

  jsr      check\_coll\_shots\_enemies    ; checks collisions between player's

; shots and enemies

  jsr      erase\_bgnds

  jsr      enemies\_draw

  jsr      plship\_draw

  jsr      ship\_shots\_draw             ; draws player's ship shots

  jsr      enemy\_shots\_draw            ; draws enemy shots

  btst     #6,CIAAPRA                  ; left mouse button pressed?

  bne.s    mainloop                    ; if not, repeats the loop

Running the program now, you can hit the first enemy and see it explode. If, on the other hand, you try to hit the second enemy that appears, you will see it flash, because a single shot is not enough to make it explode. If you hit it with a second shot, it will explode.

Immagine che contiene schermata, grafica, arte, design

Descrizione generata automaticamente

## Collisions shots – player’s ship

To detect collisions between enemy shots and the player's ship, we will use a technique like the one seen in the previous section.

### Changes to the player's ship data structure

You need to add the fields highlighted with a green background to the player’s ship data structure, defined in the "plship.i" file. These are the fields needed to handle collisions, hit status, and explosion of the player's ship.

; player's ship

                    rsreset

ship.bob            rs.b       bob.length

ship.anim\_duration  rs.w       1                 ; duration of animation in

; frames

ship.anim\_timer     rs.w       1                 ; timer for animation

ship.fire\_timer     rs.w       1                 ; timer to measure the

; interval between two shots

ship.fire\_delay     rs.w       1                 ; time interval betweeen two

; shots (in frames)

ship.bbox           rs.b       rect.length       ; bounding box for collisions

ship.visible        rs.w       1                 ; 0 not visible, $ffff visible

ship.flash\_timer    rs.w       1                 ; measures flashing duration

ship.hit\_timer      rs.w       1                 ; timer used to measure hit

; state duration

ship.energy         rs.w       1                 ; amount of energy. When

; reaches zero, the ship is

; destroyed.

ship.state          rs.w       1

ship.length         rs.b       0

### Collision Routine

The detection of collisions between enemy shots and the player's ship is like what we have seen for player's ship shots and enemies.

It iterates on all active enemy hits. The bounding box setup is made for the current shot and for the player's ship. So, it checks if the two bounding boxes intersect. The result of the collision check is passed to the collision response routine. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Checks for collisions between enemy shots and player's ship.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

check\_coll\_shots\_plship:

  movem.l    d0-a6,-(sp)

  lea        enemy\_shots,a0

  move.l     #ENEMY\_MAX\_SHOTS-1,d7

; iterates over enemy shots

.shots\_loop:

  cmp.w      #SHOT\_STATE\_ACTIVE,shot.state(a0)    ; is current shot active?

  bne        .next\_shot                           ; if not, move on the next

; shot

; setups bounding rectangle for current shot

  lea        rect1,a3

  lea        shot.bbox(a0),a4

  move.w     shot.x(a0),rect.x(a3)

  move.w     rect.x(a4),d0

  add.w      d0,rect.x(a3)

  move.w     shot.y(a0),rect.y(a3)

  move.w     rect.y(a4),d0

  add.w      d0,rect.y(a3)

  move.w     rect.width(a4),rect.width(a3)

  move.w     rect.height(a4),rect.height(a3)

; setups bounding rectangle for player's ship

  lea        player\_ship,a1

  lea        rect2,a2

  lea        ship.bbox(a1),a4

  move.w     bob.x(a1),rect.x(a2)

  move.w     rect.x(a4),d0

  add.w      d0,rect.x(a2)

  move.w     bob.y(a1),rect.y(a2)

  move.w     rect.y(a4),d0

  add.w      d0,rect.y(a2)

  move.w     rect.width(a4),rect.width(a2)

  move.w     rect.height(a4),rect.height(a2)

; checks if player's ship bounding rectangle intersects with current shot

; bounding rectangle

  bsr        rect\_intersects

; response to collision

  bsr        coll\_response\_shots\_plship

.next\_shot:

  add.l      #shot.length,a0

  dbra       d7,.shots\_loop

.return:

  movem.l    (sp)+,d0-a6

  rts

### Collision response

The collision response routine between the enemy's shot and the player's ship receives the result of the collision and the pointers to the instances of the shot and the player's ship as input. If there has been a collision, changes the status of the shot to “idle”, causing it to disappear. It also changes the player's ship's status to "hit", causing it to flash. It then subtracts the damage dealt by the shot from the player's ship's energy. If the energy is less than or equal to zero, it causes the player's ship to explode. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Responds to collisions between enemy shots and player's ship.

;

; parameters:

; d0.w - collision result: 1 if there is a collision, 0 otherwise

; a0 - pointer to shot instance

; a1 - pointer to player's ship instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

coll\_response\_shots\_plship:

; if d0 = 0 there is no collision and therefore returns

  tst.w     d0

  beq       .return

.collision:

; changes the shot state to idle

  move.w    #SHOT\_STATE\_IDLE,shot.state(a0)

; changes player's ship state to hit

  move.w    #PLSHIP\_STATE\_HIT,ship.state(a1)

  move.w    #PLSHIP\_FLASH\_DURATION,ship.flash\_timer(a1)

  move.w    #PLSHIP\_HIT\_DURATION,ship.hit\_timer(a1)

; subtracts energy from the player's ship

  move.w    shot.damage(a0),d0

  sub.w     d0,ship.energy(a1)

; if energy <= 0 then makes explode the player's ship

  ble       .explode

  bra       .return

.explode:

  jsr       plship\_explode

.return:

  rts

### Hit and explosion states of player’s ship

In the "plship.s" file, we need to modify the "plship\_update" routine to handle the new "hit" and "explosion" states of the player's ship.

If the player's ship is in the "hit" state, the hit\_timer that adjusts the duration of the hit state and the flash\_timer, which adjusts the duration of the flash, are decremented. If the flash\_timer is equal to zero, the not of the visible field is made, to toggle the visibility of the ship and then make it flash. In addition, the flash\_timer is reset. When hit\_timer is zero, visibility is set to $ffff (always visible) and the state is changed to "normal".

If the player's ship is in the "explosion" state, it is decremented anim\_timer. If this timer reaches zero, the explosion animation advances by one frame and resets anim\_timer. If the current animation frame is greater than or equal to the maximum number of frames (10), it means that we have reached the end of the animation and therefore puts the state back to "normal".

Below is the source code, with the added part highlighted with a green background.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the player's ship state

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

plship\_update:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a0

  bsr        plship\_move\_with\_joystick

  bsr        plship\_limit\_movement

; sets engine fire bob position

  lea        player\_ship\_engine,a1

  move.w     bob.x(a0),d0

  sub.w      #17,d0

  move.w     d0,bob.x(a1)                                   ; engine.x = ship.x

; - 17

  move.w     bob.y(a0),d0

  add.w      #9,d0

  move.w     d0,bob.y(a1)                                   ; engine.y = ship.y

; + 9

; animates engine fire

  sub.w      #1,ship.anim\_timer(a0)

  tst.w      ship.anim\_timer(a0)                            ; anim\_timer = 0?

  beq        .incr\_frame

  bra        .return

.incr\_frame:

  add.w      #1,bob.ssheet\_c(a1)                            ; increases

; animation frame

  cmp.w      #4,bob.ssheet\_c(a1)                            ; ssheet\_c >= 4?

  bge        .reset\_frame

  bra        .reset\_timer

.reset\_frame:

  clr.w      bob.ssheet\_c(a1)                               ; resets animation

; frame

.reset\_timer:

  move.w     ship.anim\_duration(a0),ship.anim\_timer(a0)     ; resets anim\_timer

  cmp.w      #PLSHIP\_STATE\_HIT,ship.state(a0)               ; state = hit?

  beq        .hit\_state

  cmp.w      #PLSHIP\_STATE\_EXPLOSION,ship.state(a0)         ; state =

; explosion?

  beq        .explosion\_state

  bra        .return

.hit\_state:

  sub.w      #1,ship.hit\_timer(a0)

  beq        .hit\_state\_end

  sub.w      #1,ship.flash\_timer(a0)

  beq        .toggle\_visibility

  bra        .return

.hit\_state\_end:

  move.w     #$ffff,ship.visible(a0)                        ; makes ship

; visible

  move.w     #PLSHIP\_STATE\_NORMAL,ship.state(a0)

  bra        .return

.toggle\_visibility:

  not.w      ship.visible(a0)                               ; toggles

; visibility

  move.w     #PLSHIP\_FLASH\_DURATION,ship.flash\_timer(a0)

  bra        .return

.explosion\_state:

  sub.w      #1,ship.anim\_timer(a0)                         ; decreases

; anim\_timer

  beq        .frame\_advance                                 ; if anim\_timer =

; 0, advances

; animation frame

  bra        .return

.frame\_advance:

  add.w      #1,bob.ssheet\_c(a0)                            ; advances to next

; frame

  move.w     ship.anim\_duration(a0),ship.anim\_timer(a0)     ; resets anim timer

  move.w     bob.ssheet\_c(a0),d0

  cmp.w      #10,d0                                         ; ssheet\_c >= 10?

  bge        .end\_animation

  bra        .return

.end\_animation:

  move.w     #PLSHIP\_STATE\_NORMAL,ship.state(a0)

  bra        .return

.return:

  movem.l    (sp)+,d0-a6

  rts

### Player’s ship explosion

The collision response routine, in case the player's ship's energy is less than or equal to zero, invokes the "plship\_explode" routine, which causes the player's ship to explode. You need to create such a routine in the “plship.s” file. This routine changes the state of the player's ship to "explosion" and configures the explosion animation spritesheet. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Blows up the player's ship.

;

; parameters:

; a0 - shot instance

; a1 - player's ship instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

plship\_explode:

  move.w    #PLSHIP\_STATE\_EXPLOSION,ship.state(a1)

  move.l    #ship\_explosion\_gfx,bob.imgdata(a1)

  move.l    #ship\_explosion\_mask,bob.mask(a1)

  move.w    #64,bob.width(a1)

  move.w    #42,bob.height(a1)

  move.w    #0,bob.ssheet\_c(a1)

  move.w    #0,bob.ssheet\_r(a1)

  move.w    #640,bob.ssheet\_w(a1)

  move.w    #42,bob.ssheet\_h(a1)

  move.w    #1,ship.anim\_duration(a1)

  move.w    #1,ship.anim\_timer(a1)

.return:

  rts

The animation of the player's ship explosion uses the following spritesheet, with 10 frames, measuring 64 x 64 pixels.



You must convert the spritesheet to raw format and generate the mask adding the following commands to the “amigeconv\_commands.bat” file.

amigeconv.exe -f bitplane -d 4 .\ship\_explosion.png ship\_explosion.raw

amigeconv.exe -f bitplane -m -d 1 .\ship\_explosion.png ship\_explosion.mask

You must import the graphics files into the “plship.s” file, in a chip memory segment.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                     SECTION    graphics\_data,DATA\_C

player\_ship\_gfx      incbin     "gfx/ship.raw"

player\_ship\_mask     incbin     "gfx/ship.mask"

ship\_engine\_gfx      incbin     "gfx/ship\_engine.raw"

ship\_engine\_mask     incbin     "gfx/ship\_engine.mask"

ship\_explosion\_gfx   incbin     "gfx/ship\_explosion.raw"

ship\_explosion\_mask  incbin     "gfx/ship\_explosion.mask"

Finally, you need to call the “check\_coll\_shots\_plship” routine in the mainloop, as shown below.

mainloop:

  jsr      wait\_vblank                 ; waits for vertical blank

  jsr      swap\_buffers

  jsr      scroll\_background

  jsr      plship\_update

  jsr      ship\_fire\_shot              ; fires shots from player's ship

  jsr      ship\_shots\_update           ; updates player's ship shots state

  jsr      enemy\_shots\_update          ; updates enemy shots state

  jsr      enemies\_activate

  jsr      enemies\_update

  jsr      check\_coll\_shots\_enemies    ; checks collisions between player's

; shots and enemies

  jsr      check\_coll\_shots\_plship     ; checks collisions between enemy shots

; and player's ship

  jsr      erase\_bgnds

  jsr      enemies\_draw

  jsr      plship\_draw

  jsr      ship\_shots\_draw             ; draws player's ship shots

  jsr      enemy\_shots\_draw            ; draws enemy shots

  btst     #6,CIAAPRA                  ; left mouse button pressed?

  bne.s    mainloop                    ; if not, repeats the loop

Running the program, try to take the shot fired by the third enemy and you will see that the player's ship will flash.

## Collisions player’s ship – enemies

Collisions between player's ships and enemies are also handled by detecting the intersection between their respective bounding boxes.

### Collision Routines

You need to add the "check\_coll\_enemy\_plship" routine to the "collisions.s" file.

This routine iterates over all active enemies. Then set the bounding box of the current enemy and the player's ship. See if the two bounding boxes intersect. Sends the test result to the collision response routine. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Checks for collisions between enemy and player's ship.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

check\_coll\_enemy\_plship:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a1                           ; player’s ship instance

  cmp.w      #PLSHIP\_STATE\_NORMAL,ship.state(a1)      ; state is normal?

  bne        .return                                  ; if not, doesn't checks

; for collisions

  lea        enemies\_array,a0

  move.l     #NUM\_ENEMIES-1,d7

.enemies\_loop:

  cmp.w      #ENEMY\_STATE\_INACTIVE,enemy.state(a0)    ; is current enemy

; inactive?

  beq        .next\_enemy                              ; if yes, move on the

; next enemy

  lea        rect1,a3                                 ; bounding rectangle for

; current enemy

  lea        enemy.bbox(a0),a4

  move.w     bob.x(a0),rect.x(a3)

  move.w     rect.x(a4),d0                            ; enemy.bbox.x

  add.w      d0,rect.x(a3)                            ; rect.x = bob.x +

; enemy.bbox.x

  move.w     bob.y(a0),rect.y(a3)

  move.w     rect.y(a4),d0                            ; enemy.bbox.y

  add.w      d0,rect.y(a3)                            ; rect.y = bob.y +

; enemy.bbox.y

  move.w     rect.width(a4),rect.width(a3)            ; rect.width =

; enemy.bbox.width

  move.w     rect.height(a4),rect.height(a3)          ; rect.height =

; enemy.bbox.height

  lea        rect2,a2

  lea        ship.bbox(a1),a4

  move.w     bob.x(a1),rect.x(a2)

  move.w     rect.x(a4),d0

  add.w      d0,rect.x(a2)                            ; rect2.x = ship.x +

; ship.bbox.x

  move.w     bob.y(a1),rect.y(a2)

  move.w     rect.y(a4),d0

  add.w      d0,rect.y(a2)                            ; rect2.y = ship.y +

; ship.bbox.y

  move.w     rect.width(a4),rect.width(a2)            ; rect2.width =

; ship.bbox.width

  move.w     rect.height(a4),rect.height(a2)          ; rect2.height =

; ship.bbox.height

  bsr        rect\_intersects                          ; checks if player's ship

; bbox intersects enemy

; bbox

  bsr        coll\_response\_enemy\_plship               ; collision response

.next\_enemy:

  add.l      #enemy.length,a0

  dbra       d7,.enemies\_loop

.return:

  movem.l    (sp)+,d0-a6

  rts

### Collision response

The collision response routine between enemy and player's ship changes the player's ship's status to "hit" in the event of a collision. It then subtracts 5 from the player's ship's energy. If the energy becomes less than or equal to zero, it causes the player's ship to explode. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Responds to collisions between enemy and player's ship.

;

; parameters:

; d0.w - collision result: 1 if there is a collision, 0 otherwise

; a0 - pointer to enemy instance

; a1 - pointer to player's ship instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

coll\_response\_enemy\_plship:

  tst.w     d0                                             ; d0 = 0?

  beq       .return                                        ; if yes, there is

; no collision and

; therefore returns

.collision:

  move.w    #PLSHIP\_STATE\_HIT,ship.state(a1)               ; changes player's

; ship state to hit

  move.w    #PLSHIP\_FLASH\_DURATION,ship.flash\_timer(a1)    ; resets flash timer

  move.w    #PLSHIP\_HIT\_DURATION,ship.hit\_timer(a1)        ; resets hit timer

  sub.w     #5,ship.energy(a1)                             ; subtracts energy

; from the player's

; ship

  ble       .explode                                       ; if energy <= 0

; then makes explode

; the player's ship

  bra       .return

.explode:

  bsr       plship\_explode

.return:

  rts

## Collisions player’s ship – map

To detect collisions between player's ship and map elements we need to change our approach.

### Pixel-perfect collisions

Pixel perfect collisions are a collision detection technique used in video games to accurately determine when two objects touch. Unlike collisions based on simple geometric shapes such as rectangles, pixel-perfect collisions compare the individual pixels of two images to see if they overlap.

This technique is especially useful for games with detailed graphics and irregular shapes, as it offers very accurate collision detection. However, it can be more complex and require more computational resources than simpler collision methods.

Since the map of our video game has irregular shapes, we use this technique.

To compare pixels, we don't use color images, but their masks, which use only one bitplane.

The Amiga Blitter has a bit called "BZERO" which is set if the result of the blit operation has produced all bits to zero. This is bit 13 of the DMACONR register.

This bit is extremely useful for pixel-perfect collisions.

Let's imagine that we have the map mask and the player's ship mask. Let's perform the logical and operation between these two masks, using Blitter. If they do not intersect, the result will be an image with all bits at zero and therefore the bit 13 of DMACONR will be set. Conversely, if the two masks intersect, the and will produce bits at 1 and therefore BZERO will be set to zero.

Immagine che contiene disegno, cartone animato, clipart, schizzo

Descrizione generata automaticamente

### Creating a mask for tileset

You must also generate the mask for the tileset image, adding the following command to the “amigeconv\_commands.bat” file.

amigeconv.exe -f bitplane -m -d 1 .\shooter\_tiles\_16.png shooter\_tiles\_16.mask

This mask file must be imported into chip memory, in the "tilemap.s" file.

; segment loaded in CHIP RAM

              SECTION    graphics\_data,DATA\_C

tileset       incbin     "gfx/shooter\_tiles\_16.raw"    ; image 640 x 512 pixel

; 8 bitplanes

tileset\_mask  incbin     "gfx/shooter\_tiles.mask"

### Collision plane

You must create a surface where to draw the masks of the tiles that make up the map. We call this surface "ship\_coll\_plane" and you have to define it in a segment of type bss, in the "collisions.s" file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; BSS DATA

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                 SECTION    bss\_data,BSS\_C

ship\_coll\_plane  ds.b       PF1\_PLANE\_SZ      ; plane used for pixel-perfect

; collisions between player's

; ship and map

### Drawing a tile mask

You must create a routine to draw a tile mask on the "ship\_coll\_plane". Call this routine "draw\_tile\_mask."

This routine uses the Blitter to make a copy of the tile mask on the ship\_coll\_plane. The logical operation is D=A, with a value of $f0.

The address of the collision plane where the mask is to be drawn is calculated.

Then you must calculate the address of the tile mask in the tileset\_mask. To do this, you need to start from the tile index, received as an input parameter, and calculate the corresponding row and column in the spritesheet. Starting from the row and column, the x,y coordinates of the tile in the spritesheet can be obtained. Starting from the coordinates, the offsets x and y are obtained to be added to the initial address tileset\_mask.

Then the Blitter registers are set and the copy is started. Because the mask uses only one bitplane, there is no need for a loop on the various planes.

Below is the complete source code of the routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the tile mask on the collision plane.

;

; parameters:

; d0.w - tile index

; d2.w - x position of the screen where the tile will be drawn (multiple of 16)

; d3.w - y position of the screen where the tile will be drawn

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_tile\_mask:

  movem.l    d0-a6,-(sp)                                  ; saves registers

; into the stack

; calculates the address where to draw the tile

  lea        ship\_coll\_plane,a1                           ; destination surface

; is the collision

; plane

  mulu       #PF1\_ROW\_SIZE,d3                             ; y\_offset = y \*

; PF1\_ROW\_SIZE

  lsr.w      #3,d2                                        ; x\_offset = x / 8

  ext.l      d2

  add.l      d3,a1                                        ; sums offsets to a1

  add.l      d2,a1

; calculates row and column of tile in tileset starting from index

  ext.l      d0                                           ; extends d0 to a

; long because the

; destination operand

; if divu must be

; long

  divu       #TILESET\_COLS,d0                             ; tile\_index /

; TILESET\_COLS

  swap       d0

  move.w     d0,d1                                        ; the remainder

; indicates the tile

; column

  swap       d0                                           ; the quotient

; indicates the tile

; row

; calculates the x,y coordinates of the tile in the tileset

  lsl.w      #6,d0                                        ; y = row \* 64

  lsl.w      #6,d1                                        ; x = column \* 64

; calculates the offset to add to a0 to get the address of the source image

  mulu       #TILESET\_ROW\_SIZE,d0                         ; offset\_y = y \*

; TILESET\_ROW\_SIZE

  lsr.w      #3,d1                                        ; offset\_x = x / 8

  ext.l      d1

  lea        tileset\_mask,a0                              ; source is the

; tileset mask

  add.l      d0,a0                                        ; add y\_offset

  add.l      d1,a0                                        ; add x\_offset

  jsr        wait\_blitter

  move.w     #$ffff,BLTAFWM(a5)                           ; don't use mask

  move.w     #$ffff,BLTALWM(a5)

  move.w     #$09f0,BLTCON0(a5)                           ; enable channels A,D

                                            ; logical function = $f0, D = A

  move.w     #0,BLTCON1(a5)

  move.w     #(TILESET\_WIDTH-TILE\_WIDTH)/8,BLTAMOD(a5)    ; A channel modulus

  move.w     #(PF1\_WIDTH-TILE\_WIDTH)/8,BLTDMOD(a5)        ; D channel modulus

  jsr        wait\_blitter

  move.l     a0,BLTAPT(a5)                                ; source address

  move.l     a1,BLTDPT(a5)                                ; destination address

  move.w     #64\*64+4,BLTSIZE(a5)                         ; blit size: 64 rows

; for 4 word

  jsr        wait\_blitter

  movem.l    (sp)+,d0-a6                                  ; restore registers

; from the stack

  rts

The draw\_tile\_mask routine must be called by the draw\_tile\_column routine, immediately after drawing the tile normally, as shown in the following code snippet.

draw\_tile\_column:

...

.loop:

  move.w    (a0),d0                 ; tile index

  bsr       draw\_tile

  bsr       draw\_tile\_mask

  add.w     #TILE\_HEIGHT,d3         ; increment y position

  add.l     #TILEMAP\_ROW\_SIZE,a0    ; move to the next row of the tilemap

  dbra      d7,.loop

...

### Collision detection between player's ship and map

You must write a routine that detects pixel-perfect collisions between player's ship and map.

This routine will perform a logical AND operation between the ship mask and the tilemap mask, using the Blitter.

If the result of the operation produces all bits to zero, the BZERO bit of the Blitter will be set to 1 and there is no collision. On the other hand, if BZERO = 0 there is a collision.

Note that if the player's ship is not in the "normal" state, the collision check is not performed.

The operation performed by the Blitter is a logical and between channels A and C. Channel A points to the player's ship mask, since shift is required. Channel C points to the collision plane containing the tile mask.

The destination address is calculated, i.e. the player's ship on the collision plane. Pay attention to how the x offset is calculated: the x position of the player's ship is added to the position of the viewport, bgnd\_x, and is subtracted CLIP\_LEFT because the collision plane does not have a clipping zone at the left end.

Then the amount of shift of channel A is calculated, starting from the x coordinate of the ship.

The module of channel C is calculated.

The size of the memory area to be copied is calculated.

Then the Blitter registers are set and the Blitter is started.

We wait for the end of the operation and evaluate bit 13, BZERO, of DMACONR.

If that bit is zero, then there has been a collision and the collision response routine is invoked.

Below is the complete source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Checks for collisions between player's ship and map.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

check\_coll\_plship\_map:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a0

  cmp.w      #PLSHIP\_STATE\_NORMAL,ship.state(a0)    ; ship state is normal?

  bne        .return                                ; if not, doesn't check for

; collisions

; performs an AND blitter operation between the ship mask and a collision plane containing the background tiles

  lea        player\_ship\_mask,a1

; calculates ship address on collision plane

  lea        ship\_coll\_plane,a2                     ; destination address

  move.w     bob.y(a0),d1                           ; ship y position

  mulu.w     #PF1\_ROW\_SIZE,d1                       ; offset Y = y \*

; PF1\_ROW\_SIZE

  add.l      d1,a2                                  ; adds offset Y to

; destination address

  move.w     bob.x(a0),d0                           ; ship x position

  add.w      bgnd\_x,d0                              ; adds viewport position

  sub.w      #CLIP\_LEFT,d0                          ; subtracts CLIP\_LEFT

; because there is no

; invisible clipping edge

; on the collision plane

  move.w     d0,d6                                  ; copies the x

  lsr.w      #3,d0                                  ; offset x=x/8

  and.w      #$fffe,d0                              ; makes x even

  add.w      d0,a2                                  ; adds offset x to

; destination address

; calculates the shift value

  and.w      #$000f,d6                              ; selects the first 4 bits

; of the X

  lsl.w      #8,d6                                  ; shifts the shift value to

; the high nibble

  lsl.w      #4,d6                                  ; in order to have the

; value of shift to be

; inserted in BLTCON0

  or.w       #$0aa0,d6                              ; value to be inserted in

; BLTCON0: enables channels

; A and C, minterms = AND

; calculates the modulus of channel C

  move.w     #(PLSHIP\_WIDTH/8),d0                   ; ship width in bytes

  add.w      #2,d0                                  ; adds 2 to the width in

; bytes, due to the shift

  move.w     #PF1\_ROW\_SIZE,d4                       ; collision plane width in

; bytes

  sub.w      d0,d4                                  ; modulus = coll.plane

; width - bob width in d4

; calculates blit size

  move.w     #PLSHIP\_HEIGHT,d3                      ; ship height in px

  lsl.w      #6,d3                                  ; height\*64

  lsr.w      #1,d0                                  ; width/2 (in word)

  or         d0,d3                                  ; combines the dimensions

; into the value to be

; entered in BLTSIZE

  jsr        wait\_blitter

  move.w     #$ffff,BLTAFWM(a5)                     ; lets everything go

; through

  move.w     #$0000,BLTALWM(a5)                     ; clears the last word of

; channel A

  move.w     #0,BLTCON1(a5)

  move.w     d6,BLTCON0(a5)

  move.w     #$fffe,BLTAMOD(a5)                     ; modulus -2 to go back by

; 2 bytes due to the extra

; word introduced for the

; shift

  move.w     d4,BLTCMOD(a5)

  move.l     a1,BLTAPT(a5)                          ; channel A: ship mask

  move.l     a2,BLTCPT(a5)                          ; channel C: ship collision

; plane

  move.w     d3,BLTSIZE(a5)                         ; set the size and starts

; the blitter

  jsr        wait\_blitter

  move.w     DMACONR(a5),d0

  btst.l     #13,d0                                 ; tests the BZERO flag of

; DMACONR

  beq        .yes\_coll                              ; if it is zero then there

; has been a collision

  bra        .return

.yes\_coll:

  move.w     #1,d0                                  ; 1 indicates that there

; has been a collision

  lea        player\_ship,a0

  bsr        coll\_response\_plship\_map

.return:

  movem.l    (sp)+,d0-a6

  rts

### Collision response

The check\_coll\_plship\_map routine eventually calls the collision response routine, which we call coll\_response\_plship\_map.

This routine, if there is a collision, changes the player's ship's status to hit. Decreases the player's ship's energy by 5. If the energy becomes less than or equal to zero, it causes the ship to explode.

Below is the complete source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Responds to collisions between player's ship and map.

;

; parameters:

; d0.w - collision result: 1 if there is a collision, 0 otherwise

; a0 - pointer to player's ship instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

coll\_response\_plship\_map:

  tst.w     d0                                             ; d0 = 0?

  beq       .return                                        ; if yes, there is

; no collision and

;therefore returns

.collision:

  move.w    #PLSHIP\_STATE\_HIT,ship.state(a0)               ; changes player's

; ship state to

; hit

  move.w    #PLSHIP\_FLASH\_DURATION,ship.flash\_timer(a0)    ; resets flash timer

  move.w    #PLSHIP\_HIT\_DURATION,ship.hit\_timer(a0)        ; resets hit timer

  sub.w     #5,ship.energy(a0)                             ; subtracts energy

; from the player's

; ship

  ble       .explode                                       ; if energy <= 0

; then makes

; explode the player's ship

  bra       .return

.explode:

  move.l    a0,a1

  bsr       plship\_explode

.return:

  rts

The check\_coll\_plship\_map routine must be called in the mainloop, immediately after the check\_coll\_enemy\_plship routine, as shown in the following code snippet.

mainloop:

  jsr      wait\_vblank                 ; waits for vertical blank

  jsr      swap\_buffers

  jsr      scroll\_background

  jsr      plship\_update

  jsr      ship\_fire\_shot              ; fires shots from player's ship

  jsr      ship\_shots\_update           ; updates player's ship shots state

  jsr      enemy\_shots\_update          ; updates enemy shots state

  jsr      enemies\_activate

  jsr      enemies\_update

  jsr      check\_coll\_shots\_enemies    ; checks collisions between player's

; shots and enemies

  jsr      check\_coll\_shots\_plship     ; checks collisions between enemy shots

; and player's ship

  jsr      check\_coll\_enemy\_plship     ; checks collisions between enemy and

; player's ship

  jsr      check\_coll\_plship\_map       ; checks collision between player's ship

; and tilemap

  jsr      erase\_bgnds

  jsr      enemies\_draw

  jsr      plship\_draw

  jsr      ship\_shots\_draw             ; draws player's ship shots

  jsr      enemy\_shots\_draw            ; draws enemy shots

  btst     #6,CIAAPRA                  ; left mouse button pressed?

  bne.s    mainloop                    ; if not, repeats the loop

Running the program now, you can try to make the player's ship collide with the map and verify that it explodes.

Immagine che contiene schermata, illustrazione, arte

Descrizione generata automaticamente con attendibilità media

The complete source code for this chapter is available at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter16>

# 17. Text rendering

In this chapter, you will learn how to display text and numbers on the Amiga screen, which can be used to display the score, for the texts on the introductory screens, or to display debugging information.

## Bitmap font

The font of characters that we can use in an Amiga video game is of the bitmap type, that is, it specifies the pixels that make up the various characters.

In the case of our video game, we only need to display the score, so we'll create a font containing only numeric characters.

All characters must be the same size and space must be left between two characters.

In our case we will use only 1 color, but we could also create colored fonts.

The following image shows the bitmap font we will use.



The characters are 8x8 pixels in size and use only 1 bitplane. Between one character and the next there is a space of 1 pixel.

Convert the png image to raw format adding the following command to the “amigeconv\_commands.bat” file.

amigeconv.exe -f bitplane -d 1 .\numeric\_font.png numeric\_font.raw

Create a new "fonts.s" file that will host the font rendering routines and load the raw image of the font into a chip memory segment.

              SECTION    graphics\_data,DATA\_C

numeric\_font\_gfx  incbin     "gfx/numeric\_font.raw"

## Drawing a character

To draw a character on a playfield, you simply need to copy the character from the spritesheet over the playfield, row by row.

Since your font uses only 1 bitplane and the fonts are small (8x8), you can use the cpu directly for copying.

If you want to draw color fonts, with multiple bitplanes, and larger sizes, it might be convenient to use the Blitter for copying.

To make the copy you need to know the source and destination addresses. The latter must be provided as an input parameter.

To calculate the source address from which to start copying, you need to know the character index within the spritesheet. In this case, the index must range from 0 to 9.

This index can be easily obtained by subtracting the ascii code of the character '0', i.e. the number 48, from the ascii code of the character. The ascii code of the character to be drawn must be an input parameter.

The character index in this case corresponds to the offset to be added to the start address of the spritesheet, since each character has a width of 1 byte. In this way you get the source address from which start copying.

The copy is made row by row, which is equivalent to 1 byte.

After each row, the source and destination addresses should be updated, pointing them to the next rows.

Below is the source code of the "draw\_char" routine. Insert this routine in the “fonts.s” file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a character, using a given font.

;

; parameters:

; d0.b - character ascii code

; a1   - destination bitplane address

;

; The font must be 8x8 px, 1 bpp

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_char:

  movem.l    d0-a6,-(sp)

  lea        numeric\_font\_gfx,a0     ; font address

; since the font starts from '0', subtracts the ascii code of '0',

; in order to have an index starting from zero

  sub.b      #48,d0

; clears the high byte of d0, unused

  and.w      #$00FF,d0

; calculates the address of the character within the font spritesheet

  add.w      d0,a0

; copies the character data to the destination bitplane

  moveq      #8-1,d2

.loop:

  move.b     (a0),(a1)               ; copies a row of 8 px from font to

; bitplane

  add.l      #PF2\_ROW\_SIZE,a1        ; go to the next row of the bitplane

  add.l      #FONT\_SS\_ROW\_SIZE,a0    ; go to next row in the font spritesheet

  dbra       d2,.loop

  movem.l    (sp)+,d0-a6

  rts

## Drawing a string

To draw an entire string, you need to call the draw\_char routine by iterating over each character in the string.

Notice that an assembly string is terminated with a byte set to zero.

The routine has as input the address of the string and the x,y coordinates where it is drawn on the draw\_buffer.

The address of the draw\_buffer where to draw the string is calculated by adding two contributions, called offset\_x and offset\_y, to the starting address of the draw\_buffer.

The offset\_y indicates how many rows I must move vertically and is obtained by multiplying the y coordinate by the size of a row (in bytes).

The offset\_x indicates how many bytes I must move to the right and is obtained by dividing the x coordinate by 8.

Below is the complete source code of the "draw\_string" routine, to be inserted in the "fonts.s" file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a string using a given font.

;

; parameters:

; a2 - address of the string, zero terminated.

; d3.w,d4.w - x, y coordinates where to draw the string

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_string:

  movem.l    d0-a6,-(sp)

; calculates the destination address on the bitplane

  move.l     draw\_buffer,a1      ; playfield where to draw

  mulu.w     #PF2\_ROW\_SIZE,d4    ; offset\_y = y \* PF2\_ROW\_SIZE

  add.l      d4,a1               ; adds offset\_y to bitplane address

  lsr.w      #3,d3               ; offset\_x = x/8

  and.l      #$0000FFFF,d3       ; clears the high word of d2

  add.l      d3,a1               ; adds offset\_x to bitplane address

; for each character of the string:

;     drawChar

.loop:

  move.b     (a2)+,d0            ; current string character

  tst.b      d0                  ; if current character is zero

  beq        .return             ; returns because the string is finished

  bsr        draw\_char           ; else draws the character

  add.l      #1,a1               ; moves 8 pixel to the right

  bra        .loop               ; repeats the loop

.return:

  movem.l    (sp)+,d0-a6

  rts

## Converting a number to a string

If you want to display the score using the font you have created, you have a problem to overcome: the score is a numeric data, while you are only able to draw strings of characters. You need to write a routine that converts a number to a string, which you'll call "num2string."

The algorithm you will use is based on successive divisions by multiples of 10.

In input you have a 16-bit integer decimal number, therefore in the range 0-65535. Let's start by dividing that number by 10000. The quotient of this division represents the digit of tens of thousands. To turn it into ascii code, you need to add the ascii code of the character '0', i.e. 48. Now you copy this character into the string. You repeat the same process for thousands, dividing the rest of the division by 1000. So again, by the hundreds, dividing the rest by 100. Again, by tens, dividing by 10 and finally by units, dividing by 1. At the end you add the string terminator, i.e. byte 0.

Let's take an example with the number 643.

Division 643/100. The quotient is 6, with remainder 43. Enter 6 as the first character of the string.

Division 43/10. Quotient 4, with remainder 3. You enter 4 as the second character of the string.

Division 3/1. Quotient 3, with remainder 0. You insert 3 as the third character of the string.

Let's add byte 0 as the end-of-string terminator.

The complete source code of the "num2string" routine can be found below. Insert this routine into “fonts.s” file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Converts a 16bit number into a string.

;

; parameters:

; d0.w - 16 bit number

; a0   - address of the output string

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

num2string:

  movem.l    d0-a6,-(sp)

  moveq      #4,d2            ; number of iterations

  move.l     #10000,d1

.loop:

  and.l      #$0000FFFF,d0    ; clears high word of d0 because DIVU destination

; operand is always long

  divu       d1,d0            ; d0 = d0 / d1

  add.b      #'0',d0          ; the quotient is the digit, but must be

; converted into ascii code

  move.b     d0,(a0)+         ; copies the digit to the destination string

  divu       #10,d1           ; d1 = d1 / 10

  swap       d0               ; moves the remainder into the lower word of d0

  dbra       d2,.loop

  move.b     #0,(a0)          ; adds string terminator

  movem.l    (sp)+,d0-a6

  rts

## Example of drawing a string

To test the routines you just created, you can define in the "main.s" file, a constant string "test\_str", a string that will contain the score "score\_str" and a numeric variable "score" which represents the score.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

test\_str   dc.b       "0123456789",0,0

score      dc.w       655

score\_str  dcb.b      8,'0'

At the end of the mainloop, insert the calls to the string drawing routines, as in the following code snippet.

mainloop:

  ...

  lea       test\_str,a2                 ; draws a string

  move.w    #CLIP\_LEFT+8,d3

  move.w    #192,d4

  jsr       draw\_string

  move.w    score,d0                    ; converts score into a string

  lea       score\_str,a0

  jsr       num2string

  lea       score\_str,a2

  move.w    #CLIP\_LEFT,d3

  move.w    #192+9,d4

  jsr       draw\_string

  btst      #6,CIAAPRA                  ; left mouse button pressed?

  bne       mainloop

## Example of debugging using draw\_string

Suppose you want to display the x,y coordinates of the player's ship on the screen for debugging purposes.

In the file "plship.s", you define two new string variables to host the x and y coordinates, respectively.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

          SECTION    code\_section,CODE

          ...

posx\_str  dcb.b      6,0

posy\_str  dcb.b      6,0

You must enter the draw\_string call into the plship\_update routine. It is first necessary to convert the x coordinate into a string, calling the num2string routine, and then draw the string obtained on the screen, using draw\_string, as shown in the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the player's ship state

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

plship\_update:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a0

  bsr        plship\_move\_with\_joystick

  bsr        plship\_limit\_movement

  move.w     bob.x(a0),d0                 ; converts x position into a string

  lea        posx\_str,a0

  jsr        num2string

  lea        posx\_str,a2                  ; draws x position

  move.w     #CLIP\_LEFT,d3

  move.w     #192+9\*2,d4

  jsr        draw\_string

  lea        player\_ship,a0

  move.w     bob.y(a0),d0                 ; converts y position into a string

  lea        posy\_str,a0

  jsr        num2string

  lea        posy\_str,a2                  ; draws y position

  move.w     #CLIP\_LEFT+6\*8,d3

  move.w     #192+9\*2,d4

  jsr        draw\_string

  ...

When you run the program, you will see the strings displayed in the lower half of the screen.

From top to bottom, the first is a test string, the second shows the value of the score variable; the third shows, in real time, the x and y coordinates of the player’s ship.

Immagine che contiene testo, schermata

Descrizione generata automaticamente

The complete source code is available at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter17>

# 18. HUD

You may have noticed that on our video game screen we have left the lower part empty. In this area of ​​the screen, 64 pixels high, we want to display the Head Up Display, called HUD in jargon. This section displays the information needed by the player.

## HUD Graphics

For our video game, the vital information for the player is two:

* The score
* The amount of energy of the player's ship

Then draw a HUD with a box reserved for the score and a horizontal bar representing the energy of the spaceship.



To display the bar, you need to create all the frames needed for its animation. Suppose you divide the bar into 10 equal parts. Each part will represent 10% of the total energy. You need to draw 11 animation frames corresponding to the values ​​ranging from 100% to 0%. Put these animation frames in a single spritesheet. You also need to use a single 32-color palette for both the bar and the HUD background.

Here is the spritesheet of the bar:



At this point convert the png images to raw format and extract the palette adding the following commands to the “amigeconv\_commands.bat” file:

amigeconv.exe -f bitplane -d 5 .\hud\_bgnd.png hud\_bgnd.raw

amigeconv.exe -f palette -p pal4 -c 32 -x -n .\hud\_bgnd.png hud\_palette.pal

amigeconv.exe -f bitplane -d 5 .\bar.png bar.raw

## Copperlist dedicated to HUD

One of the features of Amiga is the ability to combine multiple video modes simultaneously on the screen, using the Copper WAIT instruction, which we have already seen in Chapter 6. We can use this feature to define a specific playfield for the HUD, using a new 32-color palette, independent from the one used for the background and sprites.

To do this, you need to modify the copperlist, located in the copperlist.s file.

Add a new section, starting with the WAIT instruction, that waits for line 236. Consider that the visible screen starts at line 44 and that the map is 192 pixels high. So, 44+192 = 236.

After the WAIT, we need to reset the DDFSTRT register, restoring the normal value $0038, in the absence of scrolling.

As video mode we set the lowres one, that is 320x256, with 5 bitplanes or 32 colors. To do this we set the bitplane number %101 (5) in bits 12-14 of BPLCON0.

We set the BPLCON1 register to zero since we do not have scroll.

We set the odd and even bitplane moduli to zero using BPL1MOD and BPL2MOD.

We then define new bitplane pointers, labeling them with “bplpointers\_hud”.

We load the previously extracted palette “hud\_palette.pal”, which is already in copperlist format.

Finally we insert the end copperlist instruction.

Below is the source code of the copperlist:

copperlist:

         ...

;HUD section

         dc.w      $ec01,$fffe                    ; wait for line 192+44=236

; ($ec)

         dc.w      DDFSTRT,$0038                  ; standard value for lowres

;                           5432109876543210

         dc.w      BPLCON0,%0101001000000000      ; lowres video mode , 5 bpp

         dc.w      BPLCON1,0                      ; no scroll

         dc.w      BPL1MOD,0                      ; odd planes modulo

         dc.w      BPL2MOD,0                      ; even planes modulo

bplpointers\_hud:

         dc.w      BPL1PT,$0000,BPL1PT+2,$0000    ; bitplane pointers

         dc.w      BPL2PT,$0000,BPL2PT+2,$0000

         dc.w      BPL3PT,$0000,BPL3PT+2,$0000

         dc.w      BPL4PT,$0000,BPL4PT+2,$0000

         dc.w      BPL5PT,$0000,BPL5PT+2,$0000

         dc.w      BPL6PT,$0000,BPL6PT+2,$0000

         dc.w      BPL7PT,$0000,BPL7PT+2,$0000

         dc.w      BPL8PT,$0000,BPL8PT+2,$0000

hud\_palette:

         incbin    "gfx/hud\_palette.pal"

         dc.w      $ffff,$fffe                    ; end of copperlist

## HUD initialization

Now we need to initialize the HUD. Create a "hud.s" file, which will contain the HUD management routines. In this file, create a chip memory segment to load the HUD background images and the bar spritesheet. Below is the code snippet.

          SECTION    graphics\_data,DATA\_C

hud\_bgnd     incbin     "gfx/hud\_bgnd.raw"

hud\_bar\_gfx  incbin     "gfx/bar.raw"

We need to create a routine to initialize the HUD, which we'll call "init\_hud."

This routine must set the bitplane pointers of the HUD with the address of the HUD background image. To do this we will use the init\_bplpointers routine created in the previous chapters.

Then the routine must draw the score and finally the energy bar, invoking routines that we will write in the following paragraphs.

Below is the source code of the routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the hud.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_hud:

                  movem.l    d0-a6,-(sp)

; sets bitplane pointers to hud background image

                  lea        bplpointers\_hud,a1

                  move.l     #hud\_bgnd,d0

                  move.l     #HUD\_PLANE\_SZ,d1

                  move.l     #HUD\_BPP,d7

                  jsr        init\_bplpointers

; draws score

                  jsr        draw\_score

; draws hud bar

                  move.w     #PLSHIP\_MAX\_ENERGY,d0

                  jsr        draw\_hud\_bar

                  movem.l    (sp)+,d0-a6

                  rts

## Game Score

In order to draw the game score on the HUD, we first need to define two variables: "score" contains the numerical value of the score, while "score\_str" is the string representation of the score, which is useful for drawing on the screen.

The following code snippet shows the definition of the two variables. Put this code into hud.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

             SECTION    code\_section,CODE

score        dc.w       0                        ; player score

score\_str    dc.b       '00000',0                ; string used to display score

To draw the score on the HUD, we create the "draw\_score" routine, in the hud.s file.

This routine reuses the routines created in the previous chapter.

In fact, it converts the score from integer to string using the "num2string" routine.

Draw the score on the HUD using the "draw\_string" routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the score on the HUD.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_score:

             movem.l    d0-a6,-(sp)

; converts the score into a string

             move.w     score,d0

             lea        score\_str,a0

             bsr        num2string

; draws the score string on the panel

             lea        score\_str,a2

             move.w     #88,d3                   ; x

             move.w     #19,d4                   ; y

             bsr        draw\_string

             movem.l    (sp)+,d0-a6

             rts

To increase the score, we create the "add\_to\_score" routine, which adds a given amount of points to the player's total score. Add this routine to hud.s file.

This routine calls the "draw\_score" routine to update the score display on the HUD.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Adds a given amount of points to score.

;

; parameters:

; d0.w - amount of points to add

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

add\_to\_score:

             movem.l    d0-a6,-(sp)

             add.w      d0,score

             bsr        draw\_score

             movem.l    (sp)+,d0-a6

             rts

The add\_to\_score routine must be called when an enemy explodes, that is, at the beginning of the enemy\_explode method, in the enemies.s file.

Notice that the score field of enemy is passed as a parameter, which represents the points received upon destroying the enemy.

enemy\_explode:

; adds points to score

                      move.w     enemy.score(a1),d0

                      jsr        add\_to\_score

## Energy bar

We must create a routine that draws the energy bar, receiving the energy value (between 0 and 20) as input. We call such a routine "draw\_hud\_bar". Add it to the hud.s file.

Since the bar has 11 frames representing values from 100% to 0%, we need to convert the energy value from the 0-20 scale into the corresponding number of frames.

We start by converting the energy into the range 0-100, with a multiplication by 5.

Let's convert it to the range 0-10, by dividing it by 10.

The number of frames to be selected will be 10 minus the energy in the range (0-10).

To draw the bar, we use an adapted version of the draw\_bob routine, which we have renamed to "draw\_bob\_hud".

We first need to define an instance of the bar bob, as shown in the following code snippet. Add this code into the variables section of hud.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

         SECTION    code\_section,CODE

         ...

hud\_bar  dc.w       143                  ; bob.x

         dc.w       42                   ; bob.y

         dc.w       0                    ; bob.speed

         dc.w       128                  ; bob.width

         dc.w       5                    ; bob.height

         dc.w       0                    ; bob.ssheet\_c

         dc.w       0                    ; bob.ssheet\_r

         dc.w       128                  ; bob.ssheet\_w

         dc.w       55                   ; bob.ssheet\_h

         dc.l       hud\_bar\_gfx          ; bob.imgdata

         dc.l       0                    ; bob.mask

         dc.l       hud\_bgnd             ; address of playfield where bob is

; drawn

         dc.w       HUD\_BPP              ; number of bitplanes

         dc.w       HUD\_ROW\_SIZE         ; playfield row size

         dc.l       HUD\_PLANE\_SZ         ; playfield plane size

Below is the source code of the draw\_hud\_bar routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the hud bar.

;

; parameters;

; d0.w - energy (0-20)

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_hud\_bar:

             movem.l    d0-a6,-(sp)

             lea        hud\_bar,a3

             mulu       #5,d0                    ; converts energy to range 0-

; 100

             and.l      #$0000ffff,d0            ; resets high word of d0,

; because divu takes a long

             divu       #10,d0                   ; bar\_length / 10

             move.w     #10,d1

             sub.w      d0,d1                    ; bar frame = 10 –

; bar\_length/10

             move.w     d1,bob.ssheet\_r(a3)      ; changes animation frame

             jsr        draw\_bob\_hud

             movem.l    (sp)+,d0-a6

             rts

The draw\_bob\_hud routine draws a bob using the Blitter, as seen in chapter 12. The only differences are that the mask is not used, because it is not necessary and therefore a copy D = A is made. In addition, the background is not saved, because the bar is always drawn in the same position and overwritten.

Below is the source code of this routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a Bob using the blitter, on the HUD.

;

; parameters:

; a3 - bob's data

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_bob\_hud:

             movem.l    d0-a6,-(sp)

             lea        hud\_bgnd,a2              ; destination playfield: HUD

; calculates destination address (D channel)

             move.w     bob.y(a3),d1

             mulu.w     #HUD\_ROW\_SIZE,d1         ; offset\_y = y \* HUD\_ROW\_SIZE

             add.l      d1,a2                    ; adds offset\_y to destination

; address

             move.w     bob.x(a3),d0

             lsr.w      #3,d0                    ; offset\_x = x/8

             and.w      #$fffe,d0                ; makes offset\_x even

             add.w      d0,a2                    ; adds offset\_x to destination

; address

; calculates source address (channel A)

             move.l     bob.imgdata(a3),a0

             move.w     bob.width(a3),d1

             lsr.w      #3,d1                    ; bob width in bytes

; (bob\_width/8)

             move.w     bob.ssheet\_c(a3),d4

             mulu       d1,d4                    ; offset\_x = column \*

; (bob\_width/8)

             add.w      d4,a0                    ; adds offset\_x to the base

; address of bob's image

             move.w     bob.height(a3),d3

             move.w     bob.ssheet\_r(a3),d5

             mulu       d3,d5                    ; bob\_height \* row

             move.w     bob.ssheet\_w(a3),d1

             asr.w      #3,d1                    ; spritesheet\_row\_size =

; spritesheet\_width / 8

             mulu       d1,d5                    ; offset\_y = row \* bob\_height

; \* spritesheet\_row\_size

             add.w      d5,a0                    ; adds offset\_y to the base

; address of bob's image

; calculates the modulus of channel A

             move.w     bob.ssheet\_w(a3),d1      ; copies spritesheet\_width in

; d1

             move.w     bob.width(a3),d2

             sub.w      d2,d1                    ; spritesheet\_width –

; bob\_width

             sub.w      #16,d1                   ; spritesheet\_width –

; bob\_width -16

             asr.w      #3,d1                    ; (spritesheet\_width –

; bob\_width -16)/8

; calculates the modulus of channel D

             move.w     bob.width(a3),d2

             lsr        #3,d2                    ; bob\_width/8

             add.w      #2,d2                    ; adds 2 to the sprite width

; in bytes, due to the shift

             move.w     #HUD\_ROW\_SIZE,d4         ; screen width in bytes

             sub.w      d2,d4                    ; modulus (d4) = screen\_width

; - bob\_width

; calculates the shift value for channel A and value of BLTCON0 (d5)

             move.w     bob.x(a3),d6

             and.w      #$000f,d6                ; selects the first 4 bits of

; x

             lsl.w      #8,d6                    ; moves the shift value to the

; upper nibble

             lsl.w      #4,d6                    ; so as to have the value to

; insert in BLTCON1

             move.w     d6,d5                    ; copy to calculate the value

; to insert in BLTCON0

             or.w       #$09f0,d5                ; value to insert in BLTCON0

                                                      ; logic function LF = $f0, D = A

; calculates the blit size (d3)

             move.w     bob.height(a3),d3

             lsl.w      #6,d3                    ; bob\_height<<6

             lsr.w      #1,d2                    ; bob\_width/2 (in word)

             or         d2,d3                    ; combines the dimensions into

; the value to be inserted

; into BLTSIZE

; calculates the size of a BOB spritesheet bitplane

             move.w     bob.ssheet\_w(a3),d2      ; copies spritesheet\_width in

; d2

             lsr.w      #3,d2                    ; spritesheet\_width/8

             and.w      #$fffe,d2                ; makes even

             move.w     bob.ssheet\_h(a3),d0      ; spritesheet\_height

             mulu       d0,d2                    ; multiplies by the height

; initializes the registers that remain constant

             jsr        wait\_blitter

             move.w     #$ffff,BLTAFWM(a5)       ; first word of channel A: no

; mask

             move.w     #$0000,BLTALWM(a5)       ; last word of channel A:

; reset all bits

             move.w     #0,BLTCON1(a5)           ; no shift for channel B

             move.w     d5,BLTCON0(a5)

             move.w     d1,BLTAMOD(a5)           ; modules for channels A,D

             move.w     d4,BLTDMOD(a5)

             moveq      #HUD\_BPP-1,d7            ; number of cycle repetitions

; copy cycle for each bitplane

.plane\_loop:

             jsr        wait\_blitter

             move.l     a0,BLTAPT(a5)            ; channel A: Bob's image

             move.l     a2,BLTDPT(a5)            ; channel D: draw buffer

             move.w     d3,BLTSIZE(a5)           ; blit size and starts blit

; operation

             add.l      d2,a0                    ; points to the next bitplane

             add.l      #HUD\_PLANE\_SZ,a2

             dbra       d7,.plane\_loop           ; repeats the cycle for each

; bitplane

             movem.l    (sp)+,d0-a6

             rts

The draw\_hud\_bar routine needs to be recalled each time the energy value is changed.

In the event of a collision between an enemy shot and the player's ship, in the coll\_response\_shots\_plship routine, energy is decreased. Immediately after this statement, you must call the draw\_hud\_bar routine to update the display of the bar, as shown in the following code snippet.

coll\_response\_shots\_plship:

  ...

; subtracts energy from the player's ship

  move.w    shot.damage(a0),d0

  sub.w     d0,ship.energy(a1)

  move.w    ship.energy(a1),d0

  jsr       draw\_hud\_bar

Another point where the player's ship energy is decremented is in the coll\_response\_enemy\_plship routine, which is invoked when a collision occurs between the enemy and the player's ship. Here too we need to add the call to the draw\_hud\_bar routine, as shown in the following code snippet.

coll\_response\_enemy\_plship:

  ...

  sub.w     #5,ship.energy(a1)    ; subtracts energy from the player's ship

  move.w    ship.energy(a1),d0

  jsr       draw\_hud\_bar

  ...

Finally, the player's ship's energy is decremented when a collision occurs between the player's ship and the map. In the coll\_response\_plship\_map routine, after the energy decreases, we need to add the call to the draw\_hud\_bar routine, as shown in the following code snippet.

coll\_response\_plship\_map:

  ...

  sub.w     #5,ship.energy(a0)    ; subtracts energy from the player's ship

  move.w    ship.energy(a0),d0

  jsr       draw\_hud\_bar

  ...

## Final result

If you run the program, you will get the display of the HUD at the bottom of the screen. You will also notice that if you destroy an enemy, the score will increase. Similarly, if your spaceship collides with the landscape, an enemy, or a shot, the energy will decrease and the bar will reduce its length.



You can download the full source code of this chapter at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter18>

# 19. Game states

At this point, we have completed the implementation of the gameplay of our video game. In fact, we can move the spaceship with the joystick, fire shots. The map scrolls to the left. We have enemies, which we can hit with the shots we fire. Our spaceship can collide with the map, with enemies or with enemy shots, losing energy. We have also implemented the HUD at the bottom of the screen, which shows the score and energy.

Now we have to add the concept of game over, when energy becomes zero. We also want the game to start with a title screen.

To implement these two features, it is necessary to introduce the concept of game state.

## Defining Game States

Let's start by defining the game states:

* **Playing**: The state we currently have implemented, where the player controls the spaceship and plays the game.
* **Game Over**: The state in which the game ended. The spaceship has exploded and is no longer displayed. The map continues to scroll. The text "Game Over" appears.
* **Title Screen**: The title screen is displayed.

Create a game\_state.i file and insert the constants that identify the game states into it, as shown in the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; game states:

GAME\_STATE\_PLAYING     equ 0 ; the state in which the game can be played

GAME\_STATE\_GAMEOVER    equ 1 ; the game is ended

GAME\_STATE\_TITLESCREEN equ 2 ; the title screen is shown

## State transitions

Now we need to define how transitions from one game state to another take place. A convenient graphical representation of state transitions is a state diagram.

The state diagram for our video game is shown below.

Immagine che contiene testo, schermata, Carattere, diagramma

Descrizione generata automaticamente

The initial state is the Title Screen state. Pressing the fire button on the joystick switches to the Playing state. When the player's ship energy becomes zero, it will switch to the Game Over state. After 5 seconds, you return to the Title Screen state. From any state, if you press the left mouse button, the program ends.

Let's start designing the implementation of that state diagram.

To change the state, we define the change\_gamestate routine, which receives as input a constant that represents the new state in which we want to bring the game. This routine will call a routine for initializing the new state, which we generically call init\_x\_state, where we will replace x with the name of the state.

Once the state initialization is complete, the update\_gamestate routine will be invoked, which, based on the current state, will call the corresponding state update routine, which we call update\_x\_state.

The update\_gamestate routine is called in a loop, as long as it remains in the current state. You can only exit the loop by calling the change\_gamestate to change state.

The following diagram illustrates the concepts expressed above.

Immagine che contiene testo, schermata, Carattere

Descrizione generata automaticamente

Let's start defining the code to handle game states. Create a game\_state.s file that will contain all the routines and variables.

In this file, create a section for defining variables and add the variable “game\_state” that represents the current game state. Initialize it with the playing state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

            SECTION    code\_section,CODE

game\_state  dc.w       GAME\_STATE\_PLAYING    ; current game state

Now let's see how to implement the “change\_gamestate” routine.

We could use a cascade of conditional constructs, such the following:

If state = x then init\_x\_state

Else If state = y then init\_y\_state

Else If state = z then init\_z\_state

...

but an elegant solution is to use a **jump table**. The following figure shows how this solution works.

Immagine che contiene testo, schermata, Carattere, design

Descrizione generata automaticamente

The jump table is a table that contains the addresses of the initialization routines of the various states, in the order in which they were defined by constants.

The constant that identifies the state must be transformed into the table access index. Since the constants are positive integers 0,1,2,... and that an element of the table has a size of one long, or 4 bytes, multiplying the constant by 4, we will get the table access index.

Once you have found the table element that matches the state, you can call the state initialization routine, because its address is contained in the table element.

Translating the above concepts into assembly language, you need to define the jump table, in the variables section. It is also advisable to define the jump table for updating the current state. The following code snippet shows the definitions.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

...

; jump table containing pointers to the game state processing routines

gamestate\_table:

            dc.l       update\_play\_state

            dc.l       0

            dc.l       0

            dc.l       0

; jump table containing pointers to the game state initialization routines

init\_gamestate\_table:

            dc.l       init\_play\_state

            dc.l       0

            dc.l       0

            dc.l       0

Below you will find the source code of the change\_gamestate routine. You can see that it uses indirect addressing to call the state initialization routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Changes the current game state.

;

; parameters:

; d0.w  - new game state

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

change\_gamestate:

  movem.l    d0/a0,-(sp)

; uses a jump table to call the init routine for the current game state

  lea        init\_gamestate\_table,a0

; the new game state is used as offset of the jump table

; multiplies it x4 because the jump table elements are long

  lsl.w      #2,d0

; calculates the address of the state update routine

  move.l     0(a0,d0.w),a0

; if the address is 0, returns

  move.l     (a0),d0

  tst.l      d0

  beq        .return

; calls the routine

  jsr        (a0)

.return:

  movem.l    (sp)+,d0/a0

  rts

## Updating the current state

Now you need to create the update\_gamestate routine, which based on the current state, calls the state update routine. This routine also uses a jump table. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the current game state

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

update\_gamestate:

  movem.l    d0/a0,-(sp)

; uses a jump table to call the update routine for the current game state

  lea        gamestate\_table,a0

; the current game state is used as offset of the jump table

  move.w     game\_state,d0

; multiplies it x4 because the jump table elements are long

  lsl.w      #2,d0

; calculates the address of the state update routine

  move.l     0(a0,d0.w),a0

; if the address is 0, returns

  move.l     (a0),d0

  tst.l      d0

  beq        .return

; calls the routine

  jsr        (a0)

.return:

  movem.l    (sp)+,d0/a0

  rts

## Playing state

We now have a framework for managing game states. We know that each state is managed through two routines: one for initialization and one for update.

We need to define these two routines for the playing state. Add these routines in a new file named “playing\_state.s”.

The init\_play\_state routine reuses some of the code we had before in the main.

Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the PLAYING game state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_play\_state:

  move.l    #copperlist,COP1LC(a5)            ; sets our copperlist address

; into Copper

  move.w    d0,COPJMP1(a5)                    ; reset Copper PC to the

; beginning of our copperlist

; sets bitplane pointers for dual playfield mode

  move.l    #BPP,d7

  lea       bplpointers1,a1                   ; bitplane pointers in a1

  move.l    #playfield1+8-2,d0                ; address of background playfield

  move.l    #PF1\_PLANE\_SZ,d1

  jsr       init\_bplpointers                  ; initializes bitplane pointers

; for background playfield

  lea       bplpointers2,a1                   ; bitplane pointers in a1

  move.l    #playfield2a,d0                   ; address of foreground playfield

  move.l    #PF2\_PLANE\_SZ,d1

  jsr       init\_bplpointers                  ; initializes bitplane pointers

; for foreground playfield

; initializes scrolling background state

  move.w    #0,map\_ptr

  move.w    #0,camera\_x

  move.w    map\_ptr,d0

  jsr       init\_background

  move.w    #TILE\_WIDTH,bgnd\_x                ; x position of the part of

; background to draw

; initializes player's ship state

  jsr       plship\_init

; initializes enemies array

  jsr       init\_enemies\_array

; initializes shots

  jsr       shots\_init

; initializes hud

  jsr       init\_hud

; changes the game state to PLAYING

  move.w    #GAME\_STATE\_PLAYING,game\_state

  rts

The other routine you need to create is update\_play\_state. You must copy all the calls that were previously in the mainloop to this routine. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the PLAYING game state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

update\_play\_state:

  jsr    swap\_buffers                ; swaps draw and view buffers for

; implementing double buffering

  jsr    scroll\_background           ; scrolls tilemap toward left

  jsr    plship\_update               ; updates player's ship state

  jsr    ship\_fire\_shot              ; fires shots from player's ship

  jsr    ship\_shots\_update           ; updates player's ship shots state

  jsr    enemy\_shots\_update          ; updates enemy shots state

  jsr    enemies\_activate            ; activates enemies based on their

; position on the map

  jsr    enemies\_update              ; updates enemies state

  jsr    check\_coll\_shots\_enemies    ; checks collisions between player's shots

; and enemies

  jsr    check\_coll\_shots\_plship     ; checks collisions between enemy shots

; and player's ship

  jsr    check\_coll\_enemy\_plship     ; checks collisions between enemy and

; player's ship

  jsr    check\_coll\_plship\_map       ; checks collisions between player's ship

; and tilemap

  jsr    erase\_bgnds                 ; erases bobs backgrounds

  jsr    enemies\_draw                ; draws enemies

  jsr    plship\_draw                 ; draws player's ship

  jsr    ship\_shots\_draw             ; draws player's ship shots

  jsr    enemy\_shots\_draw            ; draws enemy shots

  rts

## Changes to the main

The main code is greatly simplified. In fact, after taking control of the Amiga hardware, we will call the init\_play\_state routine to initialize this state.

The mainloop is also simplified, as only the update\_gamestate routine is called in the loop. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; MAIN PROGRAM

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

  SECTION    code\_section,CODE

main:

  jsr        take\_system                   ; takes the control of Amiga's

; hardware

  jsr        init\_play\_state

mainloop:

  jsr        wait\_vblank                   ; waits for vertical blank

  jsr        update\_gamestate              ; updates the game state

  btst       #6,CIAAPRA                    ; left mouse button pressed?

  bne        mainloop                      ; if not, repeats the loop

  jsr        release\_system                ; releases the hw control to the

; O.S.

  rts

Try running the program and check that everything works as before.

The complete source code for this chapter is available at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter19>

# 20. Game over

## Graphics

When the player's ship energy becomes zero, we want the game to go into the game over state, displaying the animated "game over" text.

This text will be drawn on the bobs playfield, so it must have the same 16-color palette as the bobs.

Below is the image of the spritesheet of this text, containing 2 animation frames. The image size is 176 x 44 pixels. A frame is 176 x 22 pixels in size.

Immagine che contiene Carattere, Elementi grafici, schermata, grafica

Descrizione generata automaticamente

Convert the image to raw format and create the mask, adding the following commands to the “amigeconv\_commands.bat” file.

amigeconv.exe -f bitplane -d 4 .\game\_over.png game\_over.raw

amigeconv.exe -f bitplane -m -d 1 .\game\_over.png game\_over.mask

Finally, create a gameover\_state.s file and insert the instructions for importing the graphics files, into chip memory, as shown by the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                SECTION    graphics\_data,DATA\_C

gameover\_gfx    incbin     "gfx/game\_over.raw"

gameover\_mask   incbin     "gfx/game\_over.mask"

## Initialization

Create a section for the variables in the gameover\_state.s. file. You must define a bob to display the text "game over". Also, define two timers: one for the flashing of the text and another to measure the time spent in this state. Below is the code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                SECTION    code\_section,CODE

gameover\_text   dc.w       CLIP\_LEFT+70         ; x position

                dc.w       90                   ; y position

                dc.w       1                    ; speed

                dc.w       176                  ; width

                dc.w       22                   ; height

                dc.w       0                    ; spritesheet column of the bob

                dc.w       0                    ; spritesheet row of the bob

                dc.w       176                  ; spritesheet width in pixels

                dc.w       44                   ; spritesheet height in pixels

                dc.l       gameover\_gfx         ; image data address

                dc.l       gameover\_mask

flash\_timer     dc.w       0

gameover\_timer  dc.w       0                    ; measures the permanence in

; this state

Also, in the gameover\_state.s file, define the state initialization routine, called init\_gameover\_state. This routine initializes the timers defined above and resets the currently displayed spritesheet row, used to animate the text "game over". Finally, change the current state to gameover.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the GAMEOVER game state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_gameover\_state:

  movem.l    d0-a6,-(sp)

  move.w     #STATE\_DURATION,gameover\_timer

  move.w     #FLASH\_DURATION,flash\_timer

  lea        gameover\_text,a0

  move.w     #0,bob.ssheet\_r(a0)

; changes the game state to GAMEOVER

  move.w     #GAME\_STATE\_GAMEOVER,game\_state

  movem.l    (sp)+,d0-a6

  rts

## Game over text drawing

To draw the "game over" text, we will use the draw\_bob routine. Below is the code snippet of the draw\_gameover\_text routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws the gameover text.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_gameover\_text:

                movem.l    d0-a6,-(sp)

                lea        gameover\_text,a3

                move.l     draw\_buffer,a2

                bsr        draw\_bob

.return:

                movem.l    (sp)+,d0-a6

                rts

## Game over text animation

To animate the "game over" text, we create the update\_gameover\_text routine.

This routine decreases the gameover\_timer. If it reaches zero, it means that the time spent in this state has ended and therefore changes the state to playing, using the change\_game\_state routine.

Then it decreases the flash\_timer. If it becomes zero, you need to change the animation frame, increasing the field ssheet\_r. If you reach the last frame of animation, you return the animation to the beginning. The flash\_timer is reset.

Below is the source code of the routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the gameover text, making it flash.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

update\_gameover\_text:

  movem.l    d0-a6,-(sp)

  sub.w      #1,gameover\_timer

  beq        .change\_state

  bra        .decr\_flash\_timer

.change\_state:

  move.w     #GAME\_STATE\_PLAYING,d0

  jsr        change\_gamestate

.decr\_flash\_timer:

  sub.w      #1,flash\_timer

  beq        .change\_frame

  bra        .return

.change\_frame:

  move.w     #FLASH\_DURATION,flash\_timer

  lea        gameover\_text,a0

  add.w      #1,bob.ssheet\_r(a0)

  cmp.w      #2,bob.ssheet\_r(a0)

  bge        .reset\_animation

  bra        .return

.reset\_animation:

  clr.w      bob.ssheet\_r(a0)

.return:

  movem.l    (sp)+,d0-a6

  rts

## Game over state update

Finally, you need to create the gameover state update routine, called update\_gameover\_state. This routine takes up that of updating the playing state, adding calls to update\_gameover\_text, draw\_gameover\_text routines to draw and animate the "game over" text.

Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the GAMEOVER game state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

update\_gameover\_state:

                movem.l    d0-a6,-(sp)

                jsr        swap\_buffers                       ; swaps draw and view buffers for implementing double buffering

                jsr        scroll\_background                  ; scrolls tilemap toward left

                jsr        plship\_update                      ; updates player's ship state

                jsr        ship\_fire\_shot                     ; fires shots from player's ship

                jsr        ship\_shots\_update                  ; updates player's ship shots state

                jsr        enemy\_shots\_update                 ; updates enemy shots state

                jsr        enemies\_activate                   ; activates enemies based on their position on the map

                jsr        enemies\_update                     ; updates enemies state

                jsr        check\_coll\_shots\_enemies           ; checks collisions between player's shots and enemies

                jsr        check\_coll\_shots\_plship            ; checks collisions between enemy shots and player's ship

                jsr        check\_coll\_enemy\_plship            ; checks collisions between enemy and player's ship

                jsr        check\_coll\_plship\_map              ; checks collisions between player's ship and tilemap

                jsr        erase\_bgnds                        ; erases bobs backgrounds

                jsr        enemies\_draw                       ; draws enemies

                jsr        plship\_draw                        ; draws player's ship

                jsr        ship\_shots\_draw                    ; draws player's ship shots

                jsr        enemy\_shots\_draw                   ; draws enemy shots

                jsr        update\_gameover\_text

                jsr        draw\_gameover\_text

                movem.l    (sp)+,d0-a6

                rts

## Switching to the game over state

To go into the game over state, you must add a call to the change\_gamestate routine in the plship\_update routine, at the point where the explosion animation ends, as shown by the following code snippet.

plship\_update:

  ...

.end\_animation:

  move.w    #PLSHIP\_STATE\_IDLE,ship.state(a0)

  move.w    #GAME\_STATE\_GAMEOVER,d0

  jsr       change\_gamestate

  bra       .return

## Final result

Try running the program and colliding the spaceship with the map. You will see the energy decrease to zero and the animated "Game Over" text appear. After 5 seconds, the game will return to the playing state.

Immagine che contiene testo, schermata, Carattere, design

Descrizione generata automaticamente

The complete source code for this chapter is available at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter20>

# 21. Title screen

In this chapter we will implement the title screen, shown at the beginning of our video game. I even came up with a name for the game: **X-Type**.

## Graphics

The image below shows the title screen, which contains the title of the game, information about the author, and a message saying to press the fire button to start. This message will be flashing.

Immagine che contiene testo, grafica, Elementi grafici, schermata

Descrizione generata automaticamente

This image has dimensions 320 x 256 pixels and uses a 32 color palette.

Since we want the text "press fire to start" to flash, we can use an animation based on the color change. We will periodically alternate two colors, directly modifying the palette. For this technique to work, you need to use a unique color for that lettering, so that it is used only by it. In this case we used the yellow color, corresponding to index 1 of the palette.

Export this image in raw format and extract the palette adding the following commands to the “amigeconv\_commands.bat” file:

amigeconv.exe -f bitplane -d 5 .\title\_screen.png title\_screen.raw

amigeconv.exe -f palette -p pal4 -c 32 -x -n .\title\_screen.png titlescreen\_palette.pal

## Initialization

Since we used a new palette of 32 colors for the title screen image, we need to create a copperlist dedicated to this screen.

In the copperlist.s file, add a new copperlist called coplist\_title, as in the following code snippet.

The video mode used is the lowres 320x256 pixels, with 5 bitplanes.

In the copperlist we include the palette.

; copperlist used for the title screen only

coplist\_title:

  dc.w      DIWSTRT,$2c81                    ; display window start at

; ($81,$2c)

  dc.w      DIWSTOP,$2cc1                    ; display window stop at

; ($1c1,$12c)

  dc.w      DDFSTRT,$38                      ; display data fetch start at $38

  dc.w      DDFSTOP,$d0                      ; display data fetch stop at $d0

  dc.w      BPLCON0,$5200                    ; lores video mode, 5 bpp

  dc.w      BPLCON1,0

  dc.w      BPL1MOD,0

  dc.w      BPL2MOD,0

bplpointers\_title:

  dc.w      BPL1PT,$0000,BPL1PT+2,$0000      ; bitplane pointers

  dc.w      BPL2PT,$0000,BPL2PT+2,$0000

  dc.w      BPL3PT,$0000,BPL3PT+2,$0000

  dc.w      BPL4PT,$0000,BPL4PT+2,$0000

  dc.w      BPL5PT,$0000,BPL5PT+2,$0000

  dc.w      BPL6PT,$0000,BPL6PT+2,$0000

  dc.w      BPL7PT,$0000,BPL7PT+2,$0000

  dc.w      BPL8PT,$0000,BPL8PT+2,$0000

title\_palette:

  incbin    "gfx/titlescreen\_palette.pal"

  dc.w      $ffff,$fffe                      ; end of copperlist

Create the titlescreen\_state.s file, in which you place:

1. Constants that characterize the size of the screen
2. Background graphics (in-memory chips)
3. Variables for color-based animation

Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

TITLE\_BPP       equ 5

TITLE\_WIDTH     equ 320

TITLE\_HEIGHT    equ 256

TITLE\_ROW\_SIZE  equ TITLE\_WIDTH/8

TITLE\_PLANE\_SZ  equ TITLE\_HEIGHT\*TITLE\_ROW\_SIZE

TITLE\_FLASH\_DUR equ 50/5                                    ; 5 fps

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                       SECTION    graphics\_data,DATA\_C

title\_static\_gfx       incbin     "gfx/title\_screen.raw"

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                       SECTION    code\_section,CODE

title\_flash\_timer      dc.w       0

title\_flash\_colors     dc.w       $0ee1

                       dc.w       $0112

title\_flash\_color\_idx  dc.w       0

To initialize the title screen, write the init\_titlescreen\_state routine.

This routine does the following:

1. Set the Title Screen Copperlist
2. Set the bitplane pointers to point to the title screen image
3. Initializes a timer for the "Press Fire to Start" animation
4. changes the current state to Titlescreen.

Below is the source code of the routine. Add this code to the titlescreen\_state.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the TITLE\_SCREEN game state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_titlescreen\_state:

  movem.l    d0-a6,-(sp)

; sets up the copperlist for title screen

  move.l     #coplist\_title,COP1LC(a5)

  move.w     d0,COPJMP1(a5)

; sets bitplane pointers to title\_static\_gfx image

  move.l     #TITLE\_BPP,d7

  lea        bplpointers\_title,a1

  move.l     #title\_static\_gfx,d0

  move.l     #TITLE\_PLANE\_SZ,d1

  jsr        init\_bplpointers

; initializes timer for flashing of "press fire to start" text

  move.w     #TITLE\_FLASH\_DUR,title\_flash\_timer

  clr.w      title\_flash\_color\_idx

; changes the game state to TITLESCREEN

  move.w     #GAME\_STATE\_TITLESCREEN,game\_state

  movem.l    (sp)+,d0-a6

  rts

## Title screen state update

The title screen state update routine should do the following:

1. Animation of the words "Press fire to start"
2. Control the joystick's Fire button press
3. If Fire is pressed, change the status to Playing.

Below is the source code of the routine. Add this code to the titlescreen\_state.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the TITLE\_SCREEN game state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

update\_titlescreen\_state:

  movem.l    d0-a6,-(sp)

  bsr        animate\_press\_fire\_text

 ; fire button of joystick #1 pressed?

  btst       #7,CIAAPRA

  beq        .change\_state

  bra        .return

.change\_state:

; changes state to PLAYING

  move.w     #GAME\_STATE\_PLAYING,d0

  jsr        change\_gamestate

.return:

  movem.l    (sp)+,d0-a6

  rts

To animate the text "press fire to start", we write the animate\_press\_fire\_text routine, which uses an animation technique called "**color cycling**". A timer is used. Whenever the timer reaches zero, the color of the text is changed.

The colors we want to cycle must be defined in an array, called title\_flash\_colors. In this case, only 2 colors are used. The color that is changed is identified by an index of that array, called title\_flash\_color\_idx.

The logic of this routine can be described using the following pseudo-code:

decrements flash timer

if timer = 0

resets timer

increases color index

if color index >= 2 then index = 0

palette[1] = title\_flash\_colors[index]

The assembly source code for this routine is as follows. Add this code to the titlescreen\_state.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Animates the "press fire..." text using color cycle.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

animate\_press\_fire\_text:

                       movem.l    d0-a6,-(sp)

; flashing of "press fire..." text

; this animation is color based:

; every time the timer reaches 0, the color of the text is changed

; the color is switched from an array of two colors

; decrements flash timer

                       sub.w      #1,title\_flash\_timer

; if timer = 0, jumps to change\_color

                       beq        .change\_color

                       bra        .return

.change\_color:

; resets flash timer

                       move.w     #TITLE\_FLASH\_DUR,title\_flash\_timer

; increases flash color index

                       add.w      #1,title\_flash\_color\_idx

; if flash color index >= 2, resets to 0

                       cmp.w      #2,title\_flash\_color\_idx

                       bge        .reset\_idx

                       bra        .update\_palette

.reset\_idx:

                       clr.w      title\_flash\_color\_idx

.update\_palette:

                       move.w     title\_flash\_color\_idx,d0

; multiplies index by array element length (2)

                       lsl.w      #1,d0

                       lea        title\_flash\_colors,a0

; reads array element pointed to index: contains new color

                       move.w     0(a0,d0.w),d1

; sets the new color in the palette

                       move.w     d1,title\_palette+$06

.return:

                       movem.l    (sp)+,d0-a6

                       rts

## Switching to title screen state

The "title screen" state must be the initial state and must be initialized via a call to the init\_titlescreen\_state routine on the main, as shown by the following code snippet.

main:

  jsr        take\_system                   ; takes the control of Amiga's hardware

  jsr        init\_titlescreen\_state

In addition, a transition to the title screen state is made when the game over ends. Therefore, you need to modify the update\_gameover\_text routine by adding the call to change the state to the title screen, as shown by the following code snippet.

update\_gameover\_text:

  ...

.change\_state:

  move.w    #GAME\_STATE\_TITLESCREEN,d0

  jsr       change\_gamestate

## Final result

If you try to run the program, you will see the title screen, with the text "press fire to start" flashing. Pressing the fire button on the joystick will switch to the playing state.



The complete source code for this chapter can be found at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter21>

# 22. Sound

## Amiga audio hardware

The following figure shows a schematic of the Amiga audio hardware.

The sound samples are stored in the chip ram memory.

The Amiga has 4 audio channels that read samples from memory via a dedicated DMA channel, with a width of 16 bits.

A digital analogue converter (DAC) is connected to each DMA audio channel that converts digital samples into analogue signals, capable of driving the speakers.

Channels 0 and 3 are connected to the left channel of the speakers while channels 1 and 2 are connected to the right channel of the speakers.

The DACs and sound engine are physically located in the custom Paula chip.



## Audio registers

To control each audio channel, the following 4 registers are used:

* AUDxLC: contains the address of the samples to be played
* AUDxLEN: length (in words) of samples to be played back
* AUDxPER: sampling period, which is the time the DMA must wait before transferring another sample.
* AUDxVOL: volume from 0 to 64.

The x indicates the channel number, from 0 to 3.

Period = clock constant/samples per second = 3.546.895/samples per second

The sound effects we use in this chapter use 8000 samples per second.

Period = 3.546.895 / 8000 = 443

## Loading sound effects into memory

Sound effects must be saved in RAW format, with 8-bit width, i.e. samples can take values between -128 and +127.

You can find all the sound effects in the “sfx” folder.

They must be included via incbin in a chip memory segment.

For a reason that we will explain later, each sound effect must start with a word to zero.

Define a sound\_data.s file and define a chip memory segment into it.

In this segment, include the sound effects files, as shown by the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; SOUND EFFECTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

           SECTION    sounds,DATA\_C

sfx\_start  dc.w       0

           incbin     "sfx/sfx\_start.raw"

           even

sfx\_start\_len equ (\*-sfx\_start)/2

Note the use of the even directive, which inserts bytes to zero so that the next address is even.

Also note the way the length of a sound effect is calculated in word: the \* symbol indicates the current memory address. The starting point of the sound effect is subtracted from this address. This gives you the size in bytes of the sound effect itself. It is divided by 2 because the AUDxLEN register accepts a dimension in word.

## Data structures for sound effects

To manage sound effects, we need to define a custom data structure, which must be inserted in a file called sound.i. Below is the definition of this data structure.

; Sound effects structure

            rsreset

sfx\_ptr     rs.l       1    ; pointer to samples

sfx\_len     rs.w       1    ; samples length in word

sfx\_per     rs.w       1    ; samples period

sfx\_vol     rs.w       1    ; volume 0-64

sfx\_cha     rs.b       1    ; channel 0-3

sfx\_pri     rs.b       1    ; priority

sfx\_sizeof  rs.b       0

## Sound Effects Table

In the sound\_data.s file, we define an array of previously defined sfx structures, which contains all the information about all the sound effects that we will use in our game. Below is a code snippet showing the beginning of the table.

sfx\_table:

  ; 0 - start

  dc.l    sfx\_start            ; samples pointer

  dc.w    sfx\_start\_len        ; samples length (bytes)

  dc.w    SFX\_PERIOD           ; period

  dc.w    SFX\_VOLUME           ; volume

  dc.b    -1                   ; channel

  dc.b    SFX\_PRI\_START        ; priority

  ; 1 - base\_fire

  dc.l    sfx\_base\_fire        ; samples pointer

  dc.w    sfx\_base\_fire\_len    ; samples length (bytes)

  dc.w    SFX\_PERIOD           ; period

  dc.w    SFX\_VOLUME           ; volume

  dc.b    -1                   ; channel

  dc.b    SFX\_PRI\_BULLET       ; priority

...

For convenience, we will identify sound effects by constants, which we define in the sound.i file, as shown below.

; sound effects id

SFX\_ID\_START      equ 0

SFX\_ID\_BASE\_FIRE  equ 1

SFX\_ID\_RLASER     equ 2

SFX\_ID\_AALASER    equ 3

SFX\_ID\_BEAMFIRE   equ 4

SFX\_ID\_EXPLOSION  equ 5

SFX\_ID\_HIT        equ 6

SFX\_ID\_POWERUP    equ 7

SFX\_ID\_GAMEOVER   equ 8

SFX\_ID\_LEVELMUSIC equ 9

SFX\_ID\_TITLEMUSIC equ 10

## Playing a sound effect

To play a sound effect, we write the play\_sample routine, which must be inserted into the sound.s file.

This routine receives as input a constant that represents the id of the sound effect to be played.

The sound effect information is contained in the sfx\_table array, whose base address is loaded into a0.

To calculate the offset of the sound effect from the base, simply multiply the effect id (which is an integer between 0 and 10) by the length (sfx\_sizeof) of the data structure. Adding the offset to the base address, we get in a0 the address of the data structure of the sound effect.

We now use the information contained in the data structure to initialize the audio registers of channel 0, in this case.

To start playing the sound, just enable the corresponding DMA channel by setting bit 0 of the DMACON register.

Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Plays a sound effect.

;

; parameters:

; d0.w - sound effect id

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

play\_sample:

  movem.l    d0-a6,-(sp)

; calculates the offset of the sfx\_table using the sound effect id

  lea        sfx\_table,a0                     ; base address of sfx table

  mulu       #sfx\_sizeof,d0                   ; offset = sfx\_id \* sfx\_sizeof

  add.l      d0,a0                            ; pointer to sfx item = base

; address + offset

  move.l     sfx\_ptr(a0),AUD0LC(a5)           ; sets sound registers

  move.w     sfx\_len(a0),AUD0LEN(a5)

  move.w     sfx\_per(a0),AUD0PER(a5)

  move.w     #SFX\_VOLUME,AUD0VOL(a5)

  move.w     #%1000000000000001,DMACON(a5)    ; enables DMA channel

.return:

  movem.l    (sp)+,d0-a6

  rts

## Interrupts

If you try to use the play\_sample routine, you will notice that the sound effect is played repeatedly, in a loop.

To stop playback, simply disable the DMA channel that is playing the sound effect. To do this we should know when the sound effect is finished.

The Amiga audio hardware emits an interrupt every time it loads AUDxLC values into internal pointers. This happens the first time when you start playing the effect and a second time when you repeat the playback. If we count the number of times the interrupt is launched, we can then know when the sound effect has finished playing and stop it.

Before implementing the mechanism to stop the playback of a sound effect, let's explain the concept of interrupt better.

An interrupt is a signal that tells the CPU to stop the running program and jump to an interrupt routine. When this routine is complete, the program resumes execution from the point at which it was interrupted.

How do I specify which interrupt routine to execute?

There is a table in the Amiga memory that contains the addresses of the interrupt routines, based on the various types of interrupts generated.

There are 7 interrupt levels, from minimum priority 1 to maximum 7.

The following table indicates the interrupt levels and the address of the interrupt table.

|  |  |  |
| --- | --- | --- |
| Level | Address | Description |
| 1 | $64 | Transmission buffer empty, soft interrupt |
| 2 | $68 | External ports |
| 3 | $6c | Copper, vertical blank, Blitter |
| 4 | $70 | Audio channel |
| 5 | $74 | Disk sync found |
| 6 | $78 | CIAB |
| 7 | $7c | External boards |

In our case we are interested in level 4, i.e. the interrupt launched by the audio channels. The address of the routine must be stored at the $70 location.

### INTENA Register

The INTENA register ($dff09a) allows you to enable or disable certain interrupts.

This register is write-only, while the INTENAR register ($dff01c) is used for reading.

The following table shows the meaning of the bits in these registers.

|  |  |  |
| --- | --- | --- |
| Bit no. | Name | Description |
| 15 | SET/CLR | The value 1 indicates that the bits to 1 must be set. The value 0 indicates that bits to 1 must be cleared. |
| 14 | INTEN | Master enable. Set to 1 to enable all interrupts, 0 to disable. |
| 13 | EXTER | External interrupts |
| 12 | DSKSYNC | Interrupt generated when dsksync happens. |
| 11 | RBF | Buffer of serial port full |
| 10 | AUD3 | Reading a data block of audio channel 3 started |
| 9 | AUD2 | Reading a data block of audio channel 2 started |
| 8 | AUD1 | Reading a data block of audio channel 1 started |
| 7 | AUD0 | Reading a data block of audio channel 0 started |
| 6 | BLIT | Set to 1 when Blitter operation finished. |
| 5 | VERTB | Vertical Blank |
| 4 | COPER | Interrupt generated by Copper |
| 3 | PORTS | Interrupt generated by I/O ports and timers |
| 2 | SOFT | Interrupt software generated |
| 1 | DSKBLK | End of disk block transfer. |
| 0 | TBE | Transmission buffer empty |

Let's put these concepts into practice right away, writing a routine that initializes the sound subsystem, which we will call init\_sound and must be inserted in the "sound.s" file.

This routine installs our Level 4 interrupt handling routine, writing the address to the $70 location.

Then enable the interrupts of audio channels 0-3, setting bits 7-10 of the INTENA register. Note that you must also set bits 15 (SET/CLR) and 14 (INTEN).

Below is the complete source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the sound subsystem.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_sound:

  movem.l    d0-a6,-(sp)

  move.l     #0,a0

; installs the level 4 interrupt routine

  move.l     #interrupt\_lev4,$70(a0)

; enables audio channel interrupts (bits 7-10)

;              5432109876543210

  move.w     #%1100011110000000,INTENA(A5)

  movem.l    (sp)+,d0-a6

  rts

You need to make a change to the take\_system, release\_system routines located in the takeover.s file.

First, add the following variables to store the previous values of the INTENA and INTREQ registers.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

...

old\_intena  dc.w    0    ; saved value of INTENA

old\_intreq  dc.w    0    ; saved value of INTREQ

In the take\_system routine, immediately after setting the DMA channels, add the following instructions (highlighted with a green background) that save the state of the interrupts and thus disable all interrupts. This guarantees that only the interrupts that we will enable later will be generated.

take\_system:

  ...

  move.w    DMACONR(a5),old\_dma       ; saves state of DMA channels in a variable

  move.w    #$7fff,DMACON(a5)         ; disables all DMA channels

  move.w    #DMASET,DMACON(a5)        ; sets only dma channels that we will use

  move.w    INTENAR(a5),old\_intena    ; save interrupts state

  move.w    INTREQR(a5),old\_intreq

  move.w    ADKCONR(a5),old\_adkcon    ; save ADKCON

  move.w    #$7fff,INTENA(a5)         ; disable all interrupts

  move.w    #$7fff,INTREQ(a5)

In the release\_system routine, immediately after restoring the DMA state, add the following instructions (highlighted by a green background).

These instructions restore the interrupt state that was previously saved in the take\_system.

release\_system:

  move.l    sys\_coplist,COP1LC(a5)    ; restores the system copperlist

  move.w    d0,COPJMP1(a5)            ; starts the system copperlist

  or.w      #$8000,old\_dma            ; sets bit 15

  move.w    old\_dma,DMACON(a5)        ; restores saved DMA state

  move.w    #$7fff,INTENA(a5)         ; disable all interrupts

  move.w    #$7fff,INTREQ(a5)

  move.w    #$7fff,ADKCON(a5)         ; clears ADKCON

  or.w      #$8000,old\_intena         ; sets bit 15

  or.w      #$8000,old\_intreq

  or.w      #$8000,old\_adkcon

  move.w    old\_intena,INTENA(a5)     ; restores saved interrupts state

  move.w    old\_intreq,INTREQ(a5)

  move.w    old\_adkcon,ADKCON(a5)     ; restores old value of ADKCON

### INTREQ Register

The INTREQ register ($dff09c) is used to request a software interrupt, or to cancel the interrupt request, since once an interrupt is launched, the request is not automatically canceled and therefore this interrupt would continue to be launched always.

The INTREQR read-only register ($dff01e) is used to know which chip requested the interrupt. In fact, if the level 3 interrupt ($6c) is executed, it may have been requested by the Blitter, the vertical blank or the Copper. By testing the bits of INTREQR we understand which of these 3 is the cause.

The meaning of the bits in this register is identical to that of the INTENA register.

### Interrupt Routine

Now that we know how to use the INTENA and INTREQ registers, we can write our Level 4 interrupt routine.

This routine will be invoked automatically whenever the internal pointer to the samples is initialized in an audio channel, with the value contained in the AUDxLC register.

The first thing it does is figure out which audio channel has been initialized, by testing bits 7-10 of the INTREQR register.

Once the audio channel is located, the length of the samples is set to 1. This way, when the current playback is complete, the initial two samples will be played in a loop, set to zero. The effect is therefore to mute the channel. This workaround is necessary because it is not possible to disable the channel in time to avoid a repetition of the sound effect.

In addition, a counter, called sfx\_ch0\_counter, is incremented, which indicates how many times that channel has been initialized. This counter has a dual utility:

1. It makes us understand what channel is in use, if it has a value other than zero. Conversely, a channel is free if the counter has a value equal to zero.
2. When the counter is equal to or greater than 2, it means that the first playback of the samples has been terminated and therefore we can disable DMA. Remember that the counter takes on a value of 1 at the beginning of the first playback.

When finished, the interrupt routine must cancel the interrupt request to prevent it from continuing to be invoked. To do this, bits 7-10 of the INTREQ register must be zeroed. Below is the complete source code of this procedure, which must be inserted in the sound.s file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Interrupt handler level 4.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

interrupt\_lev4:

  movem.l    d0-a6,-(sp)

; tests bits 7-10 of INTREQR to see which audio channel initialized

; the internal sample pointers

  move.w     INTREQR(a5),d0

  btst.l     #7,d0

  bne        .ch0\_read\_end

.check\_ch1:

  btst.l     #8,d0

  bne        .ch1\_read\_end

.check\_ch2:

  btst.l     #9,d0

  bne        .ch2\_read\_end

  bra        .clear\_irq

.check\_ch3:

  btst.l     #10,d0

  bne        .ch3\_read\_end

  bra        .clear\_irq

.ch0\_read\_end:

; sets sample length to 1 word

  move.w     #1,AUD0LEN(a5)

; increments the channel reset counter

  lea        ch\_counters,a0

  add.w      #1,sfx\_ch0\_counter(a0)

  bra        .check\_ch1

.ch1\_read\_end:

  move.w     #1,AUD1LEN(a5)

  lea        ch\_counters,a0

  add.w      #1,sfx\_ch1\_counter(a0)

  bra        .check\_ch2

.ch2\_read\_end:

  move.w     #1,AUD2LEN(a5)

  lea        ch\_counters,a0

  add.w      #1,sfx\_ch2\_counter(a0)

  bra        .check\_ch3

.ch3\_read\_end:

  move.w     #1,AUD3LEN(a5)

  lea        ch\_counters,a0

  add.w      #1,sfx\_ch3\_counter(a0)

.clear\_irq:

; cancels audio channel interrupt request

;              5432109876543210

  move.w     #%0000011110000000,INTREQ(a5)

  movem.l    (sp)+,d0-a6

  rte

## Stop a sound effect from playing

To stop a sound effect from playing, we need to check the counter of each channel. If the counter is greater than or equal to 2, the effect has ended. Then we disable the audio DMA channel by zeroing out the corresponding bit in the DMACON register. We also reset the counter of that channel to zero.

These operations must be performed at each frame, so the routine must be invoked in the main loop. Below is the complete source code of the update\_sound\_engine routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates sound engine state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

update\_sound\_engine:

  movem.l    d0-a6,-(sp)

; checks if a channel counter is greater than or equal to 2

  lea        ch\_counters,a0

  cmp.w      #2,sfx\_ch0\_counter(a0)

  bge        .stop\_ch0

.check\_ch1:

  cmp.w      #2,sfx\_ch1\_counter(a0)

  bge        .stop\_ch1

.check\_ch2:

  cmp.w      #2,sfx\_ch2\_counter(a0)

  bge        .stop\_ch2

.check\_ch3:

  cmp.w      #2,sfx\_ch3\_counter(a0)

  bge        .stop\_ch3

  bra        .return

.stop\_ch0:

; disables audio DMA channel

  move.w     #%0000000000000001,DMACON(a5)

; clears channel counter

  clr.w      sfx\_ch0\_counter(a0)

  bra        .check\_ch1

.stop\_ch1:

  move.w     #%0000000000000010,DMACON(a5)

  clr.w      sfx\_ch1\_counter(a0)

  bra        .check\_ch2

.stop\_ch2:

  and.w      #%0000000000000100,DMACON(a5)

  clr.w      sfx\_ch2\_counter(a0)

  bra        .check\_ch3

.stop\_ch3:

  and.w      #%0000000000001000,DMACON(a5)

  clr.w      sfx\_ch3\_counter(a0)

  bra        .return

.return:

  movem.l    (sp)+,d0-a6

  rts

In the main.s module, add the call to the update\_sound\_engine routine in the main loop, as per the following code snippet.

mainloop:

  jsr     wait\_vblank            ; waits for vertical blank

  jsr     update\_gamestate       ; updates the game state

  jsr     update\_sound\_engine

  btst    #6,CIAAPRA             ; left mouse button pressed?

  bne     mainloop               ; if not, repeats the loop

## Add calls to play sound effects

Now we need to add calls to the play\_sample routine in our code to play the sound effects.

A first sound effect must be played when you press the fire button on the joystick on the title screen, to start the game.

Then add the call to play\_sample, passing the start sound id as a parameter, in the update\_titlescreen\_state routine, as shown in the following code snippet.

update\_titlescreen\_state:

  movem.l    d0-a6,-(sp)

  bsr        animate\_press\_fire\_text

 ; fire button of joystick #1 pressed?

  btst       #7,CIAAPRA

  beq        .change\_state

  bra        .return

.change\_state:

; plays sound fx

  move.w     #SFX\_ID\_START,d0

  jsr        play\_sample

; changes state to PLAYING

  move.w     #GAME\_STATE\_PLAYING,d0

  jsr        change\_gamestate

.return:

  movem.l    (sp)+,d0-a6

  rts

When the player fires shots from his spaceship, we want to play a sound effect for the shot fired. Add the play\_sample call in the ship\_fire\_shot routine, as shown in the following code snippet.

ship\_fire\_shot:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a0

  sub.w      #1,ship.fire\_timer(a0)    ; decreases fire timer, time interval between two shots

  tst.w      ship.fire\_timer(a0)       ; fire\_timer < 0?

  blt        .avoid\_neg

  bra        .check\_fire\_btn

.avoid\_neg:

  clr.w      ship.fire\_timer(a0)

.check\_fire\_btn:

  btst       #7,CIAAPRA                ; fire button of joystick #1 pressed?

  beq        .check\_prev\_state

  bra        .fire\_not\_pressed

.check\_prev\_state:

  cmp.w      #1,fire\_prev\_frame        ; fire button pressed previous frame?

  bne        .check\_timer

  bra        .prev\_frame

.check\_timer:

  tst.w      ship.fire\_timer(a0)       ; fire\_timer = 0?

  beq        .create\_shot

  bra        .prev\_frame

.create\_shot:

  move.w     ship.fire\_delay(a0),d0    ; fire\_timer = fire\_delay

  move.w     d0,ship.fire\_timer(a0)

  jsr        ship\_shot\_create

; plays sound fx

  move.w     #SFX\_ID\_BASE\_FIRE,d0

  jsr        play\_sample

  bra        .prev\_frame

.fire\_not\_pressed:

  clr.w      fire\_prev\_frame

  bra        .return

.prev\_frame:

  move.w     #1,fire\_prev\_frame

.return:

  movem.l    (sp)+,d0-a6

  rts

When the player's spaceship explodes, we want to play a sound effect of the explosion. You must add a call to the play\_sample routine in the plship\_explode routine, as shown in the following code snippet.

plship\_explode:

  move.w    #PLSHIP\_STATE\_EXPLOSION,ship.state(a1)

  move.l    #ship\_explosion\_gfx,bob.imgdata(a1)

  move.l    #ship\_explosion\_mask,bob.mask(a1)

  move.w    #64,bob.width(a1)

  move.w    #42,bob.height(a1)

  move.w    #0,bob.ssheet\_c(a1)

  move.w    #0,bob.ssheet\_r(a1)

  move.w    #640,bob.ssheet\_w(a1)

  move.w    #42,bob.ssheet\_h(a1)

  move.w    #1,ship.anim\_duration(a1)

  move.w    #1,ship.anim\_timer(a1)

; plays sound fx

  move.w    #SFX\_ID\_EXPLOSION,d0

  jsr       play\_sample

.return:

  rts

When an enemy explodes, we want to play a sound effect. To do this, you need to add a call to play\_sample in the enemy\_explode routine, as shown in the following code snippet.

enemy\_explode:

; adds points to score

  move.w    enemy.score(a1),d0

  jsr       add\_to\_score

; changes enemy state to explosion

  move.w    #ENEMY\_STATE\_EXPLOSION,enemy.state(a1)

; setups explosion graphics data and mask

  move.l    #enemy\_explosion\_gfx,bob.imgdata(a1)

  move.l    #enemy\_explosion\_mask,bob.mask(a1)

; adjusts bob position for explosion animation

  sub.w     #3,bob.x(a1)

  sub.w     #12,bob.y(a1)

; setups explosion animation data

  move.w    #64,bob.width(a1)

  move.w    #64,bob.height(a1)

  move.w    #0,bob.ssheet\_c(a1)

  move.w    #0,bob.ssheet\_r(a1)

  move.w    #512,bob.ssheet\_w(a1)

  move.w    #64,bob.ssheet\_h(a1)

  move.w    #3,enemy.anim\_duration(a1)

  move.w    #3,enemy.anim\_timer(a1)

  move.w    #8,enemy.num\_frames(a1)

; plays sound fx

  move.w    #SFX\_ID\_EXPLOSION,d0

  jsr       play\_sample

  rts

When the text "Game over" appears, we want to play a short music. To do this, add a play\_sample call in the init\_gameover\_state routine, as shown in the following code snippet.

init\_gameover\_state:

  movem.l    d0-a6,-(sp)

  move.w     #STATE\_DURATION,gameover\_timer

  move.w     #FLASH\_DURATION,flash\_timer

  lea        gameover\_text,a0

  move.w     #0,bob.ssheet\_r(a0)

; changes the game state to GAMEOVER

  move.w     #GAME\_STATE\_GAMEOVER,game\_state

; plays sound fx

  move.w     #SFX\_ID\_GAMEOVER,d0

  jsr        play\_sample

  movem.l    (sp)+,d0-a6

  rts

If you try to run the program now, you will be able to hear the sound effects.

## Play ProTracker Modules

To play music, you could sample the entire song. However, this process requires a lot of memory, especially if the song is long.

Back in the days of the Amiga, the so-called music trackers were created. These software store the notes to be played and the instruments in tracks. Each track is played on a different audio channel. Samples of real instruments are used to play the notes. This saves a lot of memory because you only sample the notes of the instruments.

The most popular format at the time was the "ProTracker" software.

If you want to play songs in this format, you can use a library called ptplayer, available at the following url:

<https://aminet.net/package/mus/play/ptplayer>

Let's see how to integrate this library into our video game.

First, you need to include the ptplayer.s module, copying it to the project folder.

Use the version that came with the source of this chapter, because I modified it to be compatible with the includes of our project.

Then add the following routine to the sound.s module to initialize the library.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the Pro Tracker sound engine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_ptplayer:

  movem.l    d0/a0/a6,-(sp)

; installs a CIA-B interrupt for calling \_mt\_music

  lea        CUSTOM,a6

  move.l     #0,a0                     ; vectorBase

  moveq      #1,d0                     ; PAL clock

  jsr        \_mt\_install\_cia

; reserves channel 0 for music.

  lea        CUSTOM,a6

  move.b     #$01,d0

  jsr        \_mt\_musicmask

  movem.l    (sp)+,d0/a0/a6

  rts

To close the Pro Tracker library, define the quit\_ptplayer routine. Below is the source code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Quits the Pro Tracker sound engine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

quit\_ptplayer:

  movem.l    a6,-(sp)

  lea        CUSTOM,a6

  jsr        \_mt\_end

  jsr        \_mt\_remove\_cia

  movem.l    (sp)+,a6

  rts

To play a song in Pro-Tracker format, we need to write the routine play\_pt\_module. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Plays a Pro-Tracker module.

;

; parameters:

; a0 - module address

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

play\_pt\_module:

; plays pro-tracker music

  lea       CUSTOM,a6

  move.l    #0,a1

  move.b    #0,d0

  jsr       \_mt\_init

  move.b    #1,\_mt\_Enable

; sets master volume to 8 for music

  lea       CUSTOM,a6

  move.w    #8,d0

  jsr       \_mt\_mastervol

  rts

When we use the Pro Tracker library, to avoid conflicts, we use the routine of this library to play the sound effects. We then define a play\_sfx routine, as in the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Plays a sound effect.

;

; parameters:

; d0.w - sound effect id

; d1.w - flag 1 loop 0 no loop

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

play\_sfx:

  movem.l    d0-d1/a0-a1/a6,-(sp)

  lea        CUSTOM,a6

  lea        curr\_sfx,a0

    ; calculates the offset of the sfx\_table using the sound effect id

  lea        sfx\_table,a1

  mulu       #sfx\_sizeof,d0             ; offset = sfx\_id \* sfx\_sizeof

  add.l      d0,a1                      ; pointer to sfx item in the table

    ; initializes the sfx structure fields using data from the sfx\_table

  move.l     sfx\_ptr(a1),sfx\_ptr(a0)

  move.w     sfx\_len(a1),sfx\_len(a0)

  move.w     sfx\_per(a1),sfx\_per(a0)

  move.w     sfx\_vol(a1),sfx\_vol(a0)

  move.b     sfx\_cha(a1),sfx\_cha(a0)

  move.b     sfx\_pri(a1),sfx\_pri(a0)

    ; plays the sound effect

  tst.w      d1

  beq        .no\_loop

  jsr        \_mt\_loopfx

  bra        .return

.no\_loop:

  jsr        \_mt\_playfx

.return:

  movem.l    (sp)+,d0-d1/a0-a1/a6

  rts

When we use the Pro Tracker library, we comment out all calls to init\_sound routines, update\_sound\_engine and instead of calls to play\_sample we put calls to play\_sfx.

This way you will be able to play both music in Pro Tracker format and sound effects at the same time.

The complete source code for this chapter is available at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter22>

# 23. Keyboard and mouse input

## Keyboard input

When a key (e.g. ESC) is pressed or released on the keyboard, what happens at the hardware level?

The keyboard sends an 8-bit code through the serial line connected to the 8520 CIAA chip. This code is stored in the CIAA's SDR register.

The CIAA sends a level 2 interrupt to the CPU, to signal it that a character has been read from the keyboard.

The following figure illustrates this process.

Immagine che contiene testo, schermata, Carattere, Rettangolo

Descrizione generata automaticamente

The interrupt management routine, after checking that it was an interrupt coming from the keyboard, must store the data contained in SDR, corresponding to the code of the character pressed.

Then it must confirm that the keyboard has been read. To do this, it must switch the direction of the serial port to output, setting bit 6 of the CRA register. Then it must write the $FF value to the SDR register. It must therefore wait for at least 4 raster lines before putting the direction of the input serial port back on.

The following figure illustrates this process.

Immagine che contiene testo, schermata, Rettangolo, diagramma

Descrizione generata automaticamente

### CIAA Registers

The **SDR** register ($bfec01) is an 8-bit shift register connected to the keyboard. It can work in two ways. In INPUT mode, the data generated by the keyboard is entered into the register, bit by bit. When all 8 bits that make up the keystroke code have been transmitted, a level 2 interrupt is generated.

In OUTPUT mode, you write to the register. The switching between these two modes takes place via bit 6 of the CRA register that we will see in the next sections.

The **ICR** register ($bfed01) controls the interrupts that can be generated by the CIAA. If a bit is set to 1, it means that the corresponding interrupt is enabled. Bit 7 acts as a main switch. If you read the register, its bits are reset. This is useful for clearing the interrupt request.

The **CRA** register ($bfee01) is called "control". The only bit we are interested in is bit 6 (SPMODE), which set to 1 enables the OTPUT mode of SDR, while if it is 0 it enables the INPUT mode.

### Initializing the keyboard

To implement keyboard reading, create a file named keyboard.s.

In this file, create the init\_keyboard routine.

This routine disables all CIAA interrupts and leaves only the keyboard interrupt enabled.

Then install our level 2 interrupt routine, the address of which is contained at the $68 location.

Finally, enable keyboard interrupts (bit 3) and audio channel interrupts (bits 7-10) in the INTENA register.

The complete source code is as follows.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes the keyboard input.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

init\_keyboard:

; disables all CIAA IRQs

;             76543210

  move.b    #%01111111,CIAAICR

; enables only keyboard IRQ

;             76543210

  move.b    #%10001000,CIAAICR

; installs level 2 keyboard interrupt routine

  move.l    #keyb\_interrupt,$68

; enables audio channel interrupts (bits 7-10)

; enables keyboard interrupts (bit 3)

;             5432109876543210

  move.w    #%1100000000001000,INTENA(A5)

  rts

In the keyboard.s file, create a section for variables and define a variable that contains the key currently pressed on the keyboard, as shown in the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

current\_key  dc.b    0    ; current key pressed on the keyboard

             even

### Keyboard Interrupt Routine

The routine that handles level 2 interrupt generated by the keyboard must first clear the CIAA interrupt by reading the contents of the ICR register.

Then it must verify that bits 7 (IR) and 3 (SP) of the ICR register are set. This means that it is an interrupt generated by the CIAA as a result of the keyboard read.

The INTENAR register is read and bits 14 (MASTER) and 3 (SP) are set to make sure that they are set. This is to be sure that it is an interrupt generated by the keyboard.

At this point the byte sent by the keyboard, from the SDR register, is read.

To get the keystroke code, the entire byte is negated and rotated to the right by 1 bit. Now the code is stored in a variable, current\_key.

Now we need to notify the keyboard that we have read the character. To do this, the SDR register output mode is enabled, by setting bit 6 of the CRA register. The $ff value is then written to the SDR register. This value will be sent to the keyboard to notify that the character has been read.

Wait about 90 microseconds, equal to 4 raster lines. After that, the SDR register is put back into input mode, setting bit 6 of the CRA register to zero.

Finally, the interrupt request is cancelled, zeroing bit 3 of INTREQ.

Below is the complete source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Keyboard interrupt routine.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

keyb\_interrupt:

  movem.l    d0-a6,-(sp)

; reading the icr we also cause its reset, so the int is "cancelled" as in intreq

  move.b     CIAAICR,d0

; if bit IR = 0, returns

  btst.l     #7,d0

  beq        .return

; if bit SP = 0, returns

  btst.l     #3,d0

  beq        .return

; reads INTENAR register

  move.w     INTENAR(a5),d0

; if bit MASTER = 0, returns

  btst.l     #14,d0

  beq        .return

; if bit 3 (SP) = 0, returns

  and.w      INTREQR(a5),d0

  btst.l     #3,d0

  beq        .return

; reads the key pressed on the keyboard from CIAA serial register

  moveq      #0,d0

  move.b     CIAASDR,d0

; inverts all bits

  not.b      d0

; rotates right

  ror.b      #1,d0

; saves into a variable

  move.b     d0,current\_key

; sets the KDAT line to confirm that we have received the character

  bset.b     #6,CIAACRA

  move.b     #$ff,CIAASDR

; wait 90 microseconds (4 raster lines)

  moveq      #4-1,d0

.waitlines:

; reads actual raster line

  move.b     VHPOSR(a5),d1

.stepline:

; waits a line

  cmp.b      VHPOSR(a5),d1

  beq        .stepline

; waits other lines

  dbra       d0,.waitlines

; clears KDAT line to enable input mode

  bclr.b     #6,CIAACRA

.return:

; clears interrupt request

  move.w     #%1000,INTREQ(a5)

  movem.l    (sp)+,d0-a6

  rte

### Changes to main module

If we want to exit the game by pressing the ESC key on the keyboard, we need to make changes to the main.s file.

The keyboard initialization should be invoked immediately after the take\_system, as shown in the following code snippet.

main:

  jsr    take\_system      ; takes the control of Amiga's hardware

  jsr    init\_keyboard

  jsr    init\_sound

In the mainloop, we need to check if the pressed key is ESC and if so, exit the loop, as shown in the following code snippet.

mainloop:

  jsr      wait\_vblank             ; waits for vertical blank

  jsr      update\_gamestate        ; updates the game state

  jsr      update\_sound\_engine

  cmp.b    #KEY\_ESC,current\_key    ; ESC pressed?

  bne      mainloop                ; if not, repeats the loop

## Mouse input

Now we want to read the mouse inputs, connected to port 0.

Define a mouse.s file and define the following variables in it.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

            SECTION    code\_section,CODE

mouse\_x     dc.b       0 ; old mouse position

mouse\_y     dc.b       0

mouse\_dx    dc.w       0 ; difference between current and old position of mouse

mouse\_dy    dc.w       0

mouse\_lbtn  dc.w       0 ; state of left mouse button: 1 pressed, 0 not pressed

mouse\_rbtn  dc.w       0 ; state of left right button: 1 pressed, 0 not pressed

To read mouse inputs, we define the read\_mouse routine, also in the mouse.s file.

This routine reads the vertical position of the mouse, reading the first byte of JOY0DAT.

Then it makes the difference between the current position and the previous one, which we call delta\_y.

Save the mouse y position for the next iteration.

The same steps are repeated for the horizontal position.

To detect the left key press, bit 6 of the CIAAPRA register is tested. If that bit is 0, the key is pressed and then assigns the value 1 to the variable mouse\_lbtn.

To detect the right button press, bit 2 of the POTINP register is tested. If that bit is zero, the key is pressed and then assigns the value 1 to the variable mouse\_rbtn.

Below is the complete source code of the procedure.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Reads the mouse position.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

read\_mouse:

  movem.l    d0-a6,-(sp)

  move.b     JOY0DAT(a5),d1      ; reads mouse vertical position

  move.b     d1,d0               ; copy

  sub.b      mouse\_y,d1          ; subtracts old position

  ext.w      d1                  ; extends d0 to word

  move.w     d1,mouse\_dy         ; saves mouse\_dy

  move.b     d0,mouse\_y          ; saves position

  move.b     JOY0DAT+1(a5),d1    ; reads mouse vertical position

  move.b     d1,d0               ; copy

  sub.b      mouse\_x,d1          ; subtracts old position

  ext.w      d1                  ; extends d0 to word

  move.w     d1,mouse\_dx         ; saves mouse\_dx

  move.b     d0,mouse\_x          ; saves position

; if bit 6 of CIAAPRA = 0, then left mouse button is pressed

  btst       #6,CIAAPRA

  beq        .lbtn\_pressed

  clr.w      mouse\_lbtn

  bra        .check\_rbtn

.lbtn\_pressed:

  move.w     #1,mouse\_lbtn

; if bit 2 of POTINP = 0, then right mouse button is pressed

.check\_rbtn:

  btst       #2,potinp(a5)

  beq        .rbtn\_pressed

  clr.w      mouse\_rbtn

  bra        .return

.rbtn\_pressed:

  move.w     #1,mouse\_rbtn

.return:

  movem.l    (sp)+,d0-a6

  rts

If we want to use the left mouse button to fire the bullets, we must modify the routine ship\_fire\_shot, in the plship.s file.

Add the instructions highlighted with a green background in the following code snippet.

ship\_fire\_shot:

  movem.l    d0-a6,-(sp)

  lea        player\_ship,a0

  sub.w      #1,ship.fire\_timer(a0)    ; decreases fire timer, time interval between two shots

  tst.w      ship.fire\_timer(a0)       ; fire\_timer < 0?

  blt        .avoid\_neg

  bra        .check\_fire\_btn

.avoid\_neg:

  clr.w      ship.fire\_timer(a0)

.check\_fire\_btn:

  cmp.w      #1,mouse\_lbtn             ; left mouse button pressed?

  beq        .check\_timer

If you want to exit the game by pressing the right mouse button, you must add to the mainloop the instructions highlighted by a green background in the following code snippet.

mainloop:

  jsr      wait\_vblank             ; waits for vertical blank

  jsr      read\_mouse              ; reads mouse position

  jsr      update\_gamestate        ; updates the game state

  jsr      update\_sound\_engine

  cmp.w    #1,mouse\_rbtn           ; right mouse button pressed?

  beq      .quit                   ; if yes, exits the mainloop

  cmp.b    #KEY\_ESC,current\_key    ; ESC pressed?

  bne      mainloop                ; if not, repeats the loop

.quit:

  jsr      release\_system          ; releases the hw control to the O.S.

  rts

You can download the complete source code of this chapter at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter23>

# 24. Power-ups

Our shoot'em up game is complete, however we can add some tweaks that make the gameplay more interesting. For example, we can add an upgrade to the player's ship's fire capacity. This upgrade will be obtained by collecting a particular item, which will be released by an enemy after its explosion.

## Data structure

Let's start by creating a new data structure for the power-up. Below is a UML diagram showing that data structure.

Notice that it inherits all fields from bob.

There are only 2 possible states:

1. Idle: Not visible, collisions disabled
2. Active: Visible, collisions enabled.

The type can be:

* None: the enemy does not release any powerups
* Fire2: Enhanced Fire



The diagram also shows the routines that we will have to write to create, draw, update the state and check the collisions between player's ship and powerups.

Create a powerup.i file and insert the definition of the data structure into it, as in the following code snippet.

; powerup

                   rsreset

powerup.x          rs.w       1

powerup.y          rs.w       1

powerup.speed      rs.w       1

powerup.width      rs.w       1

powerup.height     rs.w       1

powerup.ssheet\_c   rs.w       1    ; spritesheet column of the bob

powerup.ssheet\_r   rs.w       1    ; spritesheet row of the bob

powerup.ssheet\_w   rs.w       1    ; spritesheet width in pixels

powerup.ssheet\_h   rs.w       1    ; spritesheet height in pixels

powerup.imgdata    rs.l       1    ; image data address

powerup.mask       rs.l       1    ; mask address

powerup.state      rs.w       1    ; current state: active, inactive

powerup.type       rs.w       1    ; type of powerup: none, fire2

powerup.vis\_timer  rs.w       1    ; timer to count the time the powerup is

; visible

powerup.length     rs.b       0

To indicate whether an enemy drops a powerup, we need to add a powerup field to the enemy data structure, as shown in the following code snippet. This field can take the same values as the type field of the powerup.

; enemy

                     rsreset

enemy.bob            rs.b       bob.length

enemy.anim\_duration  rs.w       1    ; duration of animation in frames

enemy.anim\_timer     rs.w       1    ; timer for animation

enemy.num\_frames     rs.w       1    ; number of animation frames

enemy.state          rs.w       1

enemy.score          rs.w       1    ; score given when enemy is destroyed by

; the player

enemy.energy         rs.w       1    ; amount of energy. When reaches zero, the

; alien is destroyed.

enemy.map\_position   rs.w       1    ; when the camera reaches this position on

; the map, the enemy will activate

enemy.tx             rs.w       1    ; target x coordinate

enemy.ty             rs.w       1    ; target y coordinate

enemy.cmd\_pointer    rs.w       1    ; pointer to the next command

enemy.pause\_timer    rs.w       1

enemy.bbox           rs.b       rect.length ; bounding box

enemy.flash\_timer    rs.w       1

enemy.hit\_timer      rs.w       1    ; timer used to measure hit state duration

enemy.visible        rs.w       1

enemy.fire\_offx      rs.w       1    ; x offset where to place the fire shot

enemy.fire\_offy      rs.w       1    ; y offset where to place the fire shot

enemy.powerup        rs.w       1    ; type of powerup released

enemy.cmd\_list       rs.b       ENEMY\_CMD\_LIST\_SIZE ; commands list

enemy.length         rs.b       0

Consequently, you need to update the enemies\_model array, adding the powerup field. The default value of this field is PU\_TYPE\_NONE. For the second enemy only, we'll set the PU\_TYPE\_FIRE2 value, so that it releases the fire boost.

## Creating a powerup object

Create a powerup.s file. In this file, add the create\_powerup routine, which initializes a powerup instance. As an input parameter, it accepts the address of the enemy's data structure. In fact, the powerup object is created at the same coordinates that the enemy had before exploding.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Creates a powerup object.

;

; parameters:

; a0 - address of the enemy data structure

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

create\_powerup:

  movem.l    d0-a6,-(sp)

  cmp.w      #PU\_TYPE\_NONE,enemy.powerup(a0)       ; if powerup type is none,

  beq        .return                               ; returns immediately

  lea        powerup,a1                            ; else initializes the

; current

  move.w     bob.x(a0),powerup.x(a1)               ; powerup instance

  move.w     bob.y(a0),powerup.y(a1)

  move.w     #PU\_WIDTH,powerup.width(a1)

  move.w     #PU\_HEIGHT,powerup.height(a1)

  move.w     #0,powerup.ssheet\_c(a1)

  move.w     #0,powerup.ssheet\_r(a1)

  move.w     #PU\_WIDTH,powerup.ssheet\_w(a1)

  move.w     #PU\_HEIGHT,powerup.ssheet\_h(a1)

  move.l     #powerup\_gfx,powerup.imgdata(a1)

  move.l     #powerup\_mask,powerup.mask(a1)

  move.w     #PU\_S\_ACTIVE,powerup.state(a1)

  move.w     enemy.powerup(a0),powerup.type(a1)

  move.w     #PU\_VIS\_DUR,powerup.vis\_timer(a1)

.return:

  movem.l    (sp)+,d0-a6

  rts

When to create a powerup? When the animation of an enemy's explosion ends, in the enemies\_update routine, you must enter the call to the create\_powerup routine, as shown in the following code snippet.

enemies\_update:

  movem.l    d0-a6,-(sp)

  lea        enemies\_array,a0

  move.l     #NUM\_ENEMIES-1,d7

; iterates over the enemies array

.loop:

  cmp.w      #ENEMY\_STATE\_INACTIVE,enemy.state(a0)           ; enemy state is

; inactive?

  beq        .next\_element                                   ; if yes, doesn't

; update state and

; skips to next

; enemy

  cmp.w      #ENEMY\_STATE\_HIT,enemy.state(a0)                ; enemy state is

; hit?

  beq        .state\_hit

  cmp.w      #ENEMY\_STATE\_EXPLOSION,enemy.state(a0)          ; enemy state is

; explosion?

  beq        .state\_explosion

  cmp.w      #ENEMY\_STATE\_GOTOXY,enemy.state(a0)             ; enemy state is

; gotoxy?

  beq        .state\_gotoxy

  bra        .exec\_command

.state\_hit:

  sub.w      #1,enemy.flash\_timer(a0)

  beq        .toggle\_visibility                              ; if

; flash\_timer=0,

; toggles

; visibility

  bra        .decrease\_hit\_timer

.toggle\_visibility:

  not.w      enemy.visible(a0)

  move.w     #ENEMY\_FLASH\_DURATION,enemy.flash\_timer(a0)     ; resets

; flash\_timer

.decrease\_hit\_timer:

  sub.w      #1,enemy.hit\_timer(a0)                          ; decreases

; hit\_timer

  bne        .next\_element                                   ; if hit\_timer <>

; 0, goes to next

; element

  move.w     #ENEMY\_STATE\_ACTIVE,enemy.state(a0)             ; else changes

; state to active

  move.w     #$ffff,enemy.visible(a0)                        ; makes the enemy

; visible

  bra        .exec\_command

.state\_explosion:

  sub.w      #1,enemy.anim\_timer(a0)                         ; decreases

; anim\_timer

  beq        .frame\_advance                                  ; if anim\_timer =

; 0, advances

; animation frame

  bra        .next\_element

.frame\_advance:

  add.w      #1,bob.ssheet\_c(a0)                             ; advances to next

; frame

  move.w     enemy.anim\_duration(a0),enemy.anim\_timer(a0)    ; resets anim

; timer

  move.w     bob.ssheet\_c(a0),d0

  cmp.w      enemy.num\_frames(a0),d0                         ; ssheet\_c >=

; num\_frames?

  bge        .end\_animation

  bra        .next\_element

.end\_animation:

  move.w     #ENEMY\_STATE\_INACTIVE,enemy.state(a0)

  clr.w      enemy.cmd\_pointer(a0)                           ; resets

; cmd\_pointer

  jsr        create\_powerup

  bra        .next\_element

...

## Powerup graphics

The powerup object will use the following png image.



Convert the png image to raw format and create the mask adding the following commands to the “amigeconv\_commands.bat” file.

amigeconv.exe -f bitplane -d 4 .\powerup2.png powerup.raw

amigeconv.exe -f bitplane -m -d 1 .\powerup2.png powerup.mask

To include the images in the game, create a segment of chip memory in the powerup.s file and include them with incbin, as in the following code snippet.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; GRAPHICS DATA in chip ram

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

              SECTION    graphics\_data,DATA\_C

powerup\_gfx   incbin     "gfx/powerup.raw"

powerup\_mask  incbin     "gfx/powerup.mask"

## Powerup drawing

To draw the powerup, since it is a bob, we will use the draw\_bob routine.

If the state is idle, the powerup should not be drawn.

Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Draws a powerup object.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

draw\_powerup:

  movem.l    d0-a6,-(sp)

  lea        powerup,a3        ; pointer to current powerup object

  cmp.w      #PU\_S\_INACTIVE,powerup.state(a3) ; if powerup is inactive,

  beq        .return           ; doesn't draw it

  move.l     draw\_buffer,a2

  jsr        draw\_bob

.return:

  movem.l    (sp)+,d0-a6

  rts

## Powerup state update

The routine that updates the powerup state must decrement the visibility timer. If this reaches zero, it must change the state to inactive. In this way, the powerup remains visible only for a set time. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Updates the powerup object state.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

update\_powerup:

  movem.l    d0-a6,-(sp)

  lea        powerup,a3        ; pointer to current powerup object

  cmp.w      #PU\_S\_INACTIVE,powerup.state(a3) ; if powerup is inactive,

  beq        .return           ; doesn't update it

  sub.w      #1,powerup.vis\_timer(a3) ; decreases visibility timer

  beq        .make\_inactive    ; if timer reaches zero, makes the powerup

; inactive

  bra        .return

.make\_inactive:

  move.w     #PU\_S\_INACTIVE,powerup.state(a3)

.return:

  movem.l    (sp)+,d0-a6

  rts

## Collisions between player's ship and powerups

For the player's ship to get a power up, it is necessary to check for collisions between the player's ship and the powerup.

First, you check that both player's ship and powerup are in the active state.

Then the bounding rectangles of both the player's ship and the powerup are initialized.

Check if the bounding rectangles intersect.

If there is a collision, you change the powerup state to idle, call the routine activate\_powerup, and play the sound effect again.

Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Checks the collision between ship and powerup.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

check\_coll\_ship\_powerup:

; pseudocode:

;

; if ship and powerup are both in active state

;     if ship collides with current powerup

;         make the powerup inactive

;         activate powerup

  movem.l    d0-a6,-(sp)

  lea        powerup,a0

  lea        player\_ship,a1

  cmp.w      #PU\_S\_INACTIVE,powerup.state(a0)       ; if powerup is inactive,

  beq        .return                                ; returns immediately

  cmp.w      #PLSHIP\_STATE\_NORMAL,ship.state(a1)    ; if ship isn't in normal

; state,

  bne        .return                                ; returns immediately

  lea        rect1,a2                               ; initializes ship bounding

; rectangle

  lea        ship.bbox(a1),a4

  move.w     bob.x(a1),rect.x(a2)

  move.w     rect.x(a4),d0

  add.w      d0,rect.x(a2)

  move.w     bob.y(a1),rect.y(a2)

  move.w     rect.y(a4),d0

  add.w      d0,rect.y(a2)

  move.w     rect.width(a4),rect.width(a2)

  move.w     rect.height(a4),rect.height(a2)

  lea        rect2,a3                               ; initializes powerup

; bounding rectangle

  move.w     powerup.x(a0),rect.x(a3)

  move.w     powerup.y(a0),rect.y(a3)

  move.w     #PU\_WIDTH,rect.width(a3)

  move.w     #PU\_HEIGHT,rect.height(a3)

  jsr        rect\_intersects                        ; checks if ship and

; powerup bounding

; rectangles intersects

  tst.w      d0                                     ; if d0=0 there is no

; collision

  beq        .return                                ; so returns immediately

  move.w     #PU\_S\_INACTIVE,powerup.state(a0)       ; else makes powerup

; inactive

  bsr        activate\_powerup                       ; activates powerup

  move.w     #SFX\_ID\_POWERUP,d0                     ; plays sound effect

  clr.w      d1                                     ; no loop

  ;jsr        play\_sfx

  jsr        play\_sample

.return:

  movem.l    (sp)+,d0-a6

  rts

## Activating a powerup

The routine activate\_powerup changes the player's ship's fire type to "fire2".

Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Activates a powerup.

;

; parameters:

; a0 - pointer to powerup instance

; a1 - pointer to ship instance

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

activate\_powerup:

              movem.l    d0-a6,-(sp)

              move.w     #PLSHIP\_FIRE\_2,ship.fire\_type(a1)      ; changes ship

; fire type to

; fire2

.return:

              movem.l    (sp)+,d0-a6

              rts

## Adding a new type of fire to the player's ship

We need to add a new type of shot to the player's ship. To do this, we add two lines with the animation frames of the new fire to the ship\_shots.png image, shown below.



We need to modify the routine ship\_shot\_create, in the shots.s file.

If "fire2" is fire\_type valid, then we will use row 2 of the spritesheet, and the damage will be higher than the base type.

If fire\_type "base" applies, then we'll use row 0 of the spritesheet.

Below is the code snippet with the added instructions.

ship\_shot\_create:

  ...

  cmp.w     #PLSHIP\_FIRE\_2,ship.fire\_type(a1)

  beq       .fire2

  move.w    #0,shot.ssheet\_r(a0)

  move.w    #SHIP\_SHOT\_DAMAGE1,shot.damage(a0)

  bra       .continue

.fire2:

  move.w    #2,shot.ssheet\_r(a0)

  move.w    #SHIP\_SHOT\_DAMAGE2,shot.damage(a0)

...

Another change concerns the plship\_init routine, in the plship.s file, in which the initialization of the fire\_type field with the base type must be added.

plship\_init:

  ...

  move.w    #PLSHIP\_FIRE\_BASE,ship.fire\_type(a0)

  ...

If you now run the program, destroying the second enemy, it will release a powerup. To activate it, you need to tap it with your spaceship. Once the powerup is activated, you will have a more powerful fire, which deals double damage to enemies.



The complete source code of this chapter can be downloaded from the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter24>

# 25. End level boss

In any self-respecting shoot'em up, at the end of a level there is a boss, that is, a larger enemy that needs more hits to be destroyed. Destroying the boss allows access to the next level.

We will not implement a second level, since the game is purely for educational purposes, but with the notions learned you can do it yourself.

We limit ourselves here to adding the boss at the end of the level.

## Graphics

The following image shows the boss at the end of the level, using the same 16-color palette as all the sprites. In this case it is not animated, but you could animate the mouth for example.

Immagine che contiene cartone animato, testo, pixel

Descrizione generata automaticamente

Export the raw artwork and generate the mask adding the following commands to the “amigeconv\_commands.bat” file:

amigeconv.exe -f bitplane -d 4 .\boss.png boss.raw

amigeconv.exe -f bitplane -m -d 1 .\boss.png boss.mask

The graphics files must be included in the source code, in the enemies\_model.s file, in a section of chip memory, as in the following code snippet:

            SECTION    graphics\_data,DATA\_C

enemies\_gfx    incbin     "gfx/enemies.raw"

enemies\_mask   incbin     "gfx/enemies.mask"

boss\_gfx       incbin     "gfx/boss.raw"

boss\_mask      incbin     "gfx/boss.mask"

## Boss data structure

Thanks to the flexible data structure we designed for enemies, we can handle the boss with the same structure we already created.

Next, add an enemy to the enemies\_model array, located in the enemies\_model.s file, as shown in the following code snippet.

boss           dc.w       0                               ; enemy.x

               dc.w       0                               ; enemy.y

               dc.w       2                               ; enemy.speed

               dc.w       128                             ; enemy.width

               dc.w       74                              ; enemy.height

               dc.w       0                               ; enemy.ssheet\_c

               dc.w       0                               ; enemy.ssheet\_r

               dc.w       128                             ; enemy.ssheet\_w

               dc.w       74                              ; enemy.ssheet\_h

               dc.l       boss\_gfx                        ; enemy.imgdata

               dc.l       boss\_mask                       ; enemy.mask

               dc.w       0                               ; enemy.anim\_duration

               dc.w       0                               ; enemy.anim\_timer

               dc.w       0                               ; enemy.num\_frames

               dc.w       ENEMY\_STATE\_INACTIVE            ; enemy.state

               dc.w       5000                            ; enemy.score

               dc.w       20                              ; enemy.energy

               dc.w       6016                            ; enemy.map\_position

               dc.w       0                               ; enemy.tx

               dc.w       0                               ; enemy.ty

               dc.w       0                               ; enemy.cmd\_pointer

               dc.w       0                               ; enemy.pause\_timer

               dc.w       0                               ; rect.x

               dc.w       0                               ; rect.y

               dc.w       128                             ; rect.width

               dc.w       74                              ; rect.height

               dc.w       0                               ; enemy.flash\_timer

               dc.w       0                               ; enemy.hit\_timer

               dc.w       $ffff                             ; enemy.visible

               dc.w       0                                 ; fire\_offx

               dc.w       50                                ; fire\_offy

               dc.w       PU\_TYPE\_NONE                      ; enemy.powerup

               dc.w       ENEMY\_CMD\_SETPOS,CLIP\_LEFT+320,45 ; enemy.cmd\_list

               dc.w       ENEMY\_CMD\_PAUSE,50

               dc.w       ENEMY\_CMD\_SETPOS,CLIP\_LEFT+192,45

               dc.w       ENEMY\_CMD\_PAUSE,50

               dc.w       ENEMY\_CMD\_FIRE

               dc.w       ENEMY\_CMD\_PAUSE,30

               dc.w       ENEMY\_CMD\_FIRE

               dc.w       ENEMY\_CMD\_PAUSE,30

               dc.w       ENEMY\_CMD\_FIRE

               dc.w       ENEMY\_CMD\_PAUSE,30

               dc.w       ENEMY\_CMD\_FIRE

               dc.w       ENEMY\_CMD\_PAUSE,500

               dc.w       ENEMY\_CMD\_END

               dcb.b      ENEMY\_CMD\_LIST\_SIZE-23\*2,0

Note that we have assigned a score of 5000 points to the destruction of the boss. To destroy it you will need at least 4 base shots of 5 units of energy.

The boss activates at the end of the map.

It is made to appear off the screen first. After about 1 second, it is shown on the screen.

Thanks to the FIRE command we can make it fire, alternating shots with pauses.

If you try to run the program, you'll get something similar to the following screenshot.



You can find the complete source code for this level at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter25>

# 26. Loading assets from disk

So far, all images have been included directly in the program's executable file via the incbin directive of the VASM assembler. This approach is very simple, but it has some limitations.

Suppose you want to implement different levels of gameplay. It is unthinkable that the graphics of all levels can be loaded into memory via incbin. The memory would not be enough.

It is more reasonable to load only the graphics of the current level into memory. At the end of one level, the graphics of the next will be loaded.

To implement this loading mechanism, we need to learn how to read data from a file.

## File Module

Create a file named "file.s" that will contain the routines for handling the files.

Within it, define the constants and variables shown below.

The constants are the offsets of the functions of the dos.library of the Amiga OS and a constant for the mode of opening a file for reading.

The variables are the name of the dos.library, its base address, and a handle file.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

MODE\_OLDFILE equ $3ed

LVOOpen      equ -$1e

LVORead      equ -$2A

LVOClose     equ -$24

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

             SECTION    code\_section,CODE

dos\_name     dc.b       "dos.library",0

             even

dos\_base     dc.l       0

file\_handle  dc.l       0

             even

For file management we will use the routines of the Amiga OS. These routines are contained in the library named "dos.library". This library must be loaded into memory using the OldOpenLibrary routine. Its base address, contained in d0, must be saved in a variable. To do this, create the init\_file routine, which must be invoked before working with files. Below is the complete source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Initializes file module.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

             xdef       init\_file

init\_file:

             movem.l    d0-a6,-(sp)

             move.l     ExecBase,a6               ; base address of Exec

             lea        dos\_name,a1

             jsr        \_LVOOldOpenLibrary(a6)    ; opens dos.library

             move.l     d0,dos\_base               ; saves base address of

; dos.library in a variable

.return:

             movem.l    (sp)+,d0-a6

             rts

Each system library must be closed when it is finished using it. Therefore, create a quit\_file routine, which closes the dos.library using the Amiga O.S. CloseLibrary routine. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Quits file module.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

             xdef       quit\_file

quit\_file:

             movem.l    d0-a6,-(sp)

             move.l     ExecBase,a6               ; base address of Exec

             move.l     dos\_base,a1

             jsr        \_LVOCloseLibrary(a6)      ; closes dos.library

.return:

             movem.l    (sp)+,d0-a6

             rts

## File loading

After initializing the dos.library by invoking the init\_file routine, we are ready to read a file. It is necessary to open the file first, using the LVOOpen routine of AmigaDOS. This routine takes as input a pointer to the file name (contained in a string) in d1 and the way the file is opened in d2. To open an existing file for reading, we use the constant MODE\_OLDFILE. The LVOOpen routine returns a file\_handle into d0. If the latter is zero, then there was an error.

To read the contents of the file, we use the AmigaDOS LVORead routine, which requires as input the file handle in d1, a pointer to the buffer where to load the data in d2.

Finally, it is necessary to close the previously opened file using the AmigaDOS LVOClose routine, which requires the file handle in d1 as input.

Below is the complete source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Loads a file from disk using AmigaDOS.

;

; parameters:

; d1.l - pointer to filename (specify the entire path)

; d2.l - address of buffer where to load the file content

; d3.l - file length in bytes

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

load\_file:

  movem.l    d0-a6,-(sp)

  move.l     d2,d4               ; makes a copy

  move.l     #MODE\_OLDFILE,d2    ; read mode

  move.l     dos\_base,a6

  jsr        LVOOpen(a6)         ; opens file

  move.l     d0,file\_handle      ; saves file handle

  beq        .return             ; if handle = 0 there is an error

  move.l     d0,d1

  move.l     d4,d2

  jsr        LVORead(a6)         ; reads the file

  move.l     file\_handle,d1

  move.l     dos\_base,a6

  jsr        LVOClose(a6)        ; closes the file

.return:

  movem.l    (sp)+,d0-a6

  rts

## Asset management

In the jargon of video game programmers, an **asset** refers to any graphic or sound resource.

We define a module for asset management.

Let's start by creating an asset.i file, which contains a data structure to represent an asset.

As you can see from the following code snippet, an asset is characterized by:

1. filename (24-byte string)
2. asset address
3. length in bytes

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; Assets management

;

; (c) 2024 Stefano Coppi

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

                    IFND       ASSETS\_I

ASSETS\_I            SET        1

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; DATA STRUCTURES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; graphic or sound asset

                    rsreset

asset.filename      rs.b       24          ; string

asset.dest\_address  rs.l       1           ; destination address of asset

asset.length        rs.w       1           ; length in bytes

asset.size          rs.b       0

                    ENDC

Now let's create an assets.s file, containing a constant representing the number of assets and an array containing all the assets. Below is the source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; CONSTANTS

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

NUM\_ASSETS equ 4

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

; VARIABLES

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

        SECTION    code\_section,CODE

assets\_array:

asset1  dc.b       "gfx/bar.raw",0

        dcb.b      24-12,0

        dc.l       hud\_bar\_gfx

        dc.w       4400

asset2  dc.b       "gfx/bar.mask",0

        dcb.b      24-13,0

        dc.l       hud\_bar\_gfx\_mask

        dc.w       880

asset3  dc.b       "gfx/ship.raw",0

        dcb.b      24-13,0

        dc.l       player\_ship\_gfx

        dc.w       896

asset4  dc.b       "gfx/ship.mask",0

        dcb.b      24-14,0

        dc.l       player\_ship\_mask

        dc.w       224

To load the defined assets into the array, we need to create a routine, which we call load\_assets.

We have seen that the routine load\_file uses the Amiga operating system. Since at the beginning of our program we took control away from the OS, before we can use the files, we must give it back, recalling the release\_system routine.

At this point we initialize the file module by calling init\_file.

Now let's create a cycle on the assets\_array.

We load the data onto the current asset and invoke the load\_file routine to load it.

Then we advance to the next element of the array and repeat the loop.

At the end of the loop, close the file module, invoking the quit\_file procedure.

Then we regain control of the system, disabling the OS, calling the take\_system routine. Since keyboard and sound management use interrupt routines, we need to reinitialize these modules after performing the take\_system, calling the init\_keyboard and init\_sound routines.

Below is the complete source code.

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;  Load assets

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

load\_assets:

  movem.l    d0-a6,-(sp)

  jsr        release\_system               ; releases the system to Amiga O.S.

  jsr        init\_file                    ; initializes file module

  move.l     #NUM\_ASSETS-1,d7

  lea        assets\_array,a0

.loop:

  move.l     a0,d1

  move.l     asset.dest\_address(a0),d2

  move.w     asset.length(a0),d3

  jsr        load\_file                    ; loads asset from file

  add.l      #asset.size,a0               ; points to next element

  dbra       d7,.loop

  jsr        quit\_file                    ; quits file module

  jsr        take\_system                  ; takes control of hardware

  jsr        init\_keyboard                ; initializes keyboard IRQ

  jsr        init\_sound                   ; initializes sound IRQ

  movem.l    (sp)+,d0-a6

  rts

Now we can call the load\_assets routine in the title screen, while is being initialized. Add the highlighted green line to the init\_titlescreen\_state routine, as shown in the following code snippet.

init\_titlescreen\_state:

  ...

; changes the game state to TITLESCREEN

  move.w    #GAME\_STATE\_TITLESCREEN,game\_state

; loads assets from file

  jsr       load\_assets

  ...

If you want to load a second game level, the load\_assets routine must be called in the initialization phase of the second level. Maybe you show a loading screen first.

The complete source code of this chapter can be found at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter26>

# 27. Fixed Point Math

In some video games, you may need to use more advanced physics, which requires calculations with fractional numbers. Floating point notation is usually used, which is implemented by high level programming language routines or directly by dedicated processor instructions.

Since the Motorola 68000 processor that originally powered the Amiga does not have floating-point instructions, I suggest you use the fixed-point format.

In this format, the number of bits of the integer and fractional parts is fixed.

Since the Motorola 68000 processor performs operations on 16-bit numbers, it is convenient to use the 10.6 format, i.e. 10 bits for the integer part and 6 for the decimal part. In this way, the largest number that can be represented without sign is 2^10, or 1024. The smallest number is 2^-6, which is 0.015625.

To convert a floating-point number to a fixed-point number, simply multiply it by 64.

For example, 12.4 \* 64 = 793.6 = 794

Since you can't put fractional numbers in the registers, you have to approximate to the integer, so 794.

The operations of adding and subtracting between two fixed point numbers take place normally and result in another fixed point number.

Below is an example of addition and subtraction.

    ; sum of two fixed point numbers

        move.w     #794,d0              ; 12.4\*64

        move.w     #38,d1               ; 0.6\*64

        add.w      d1,d0                ; result in fixed notation = 13

    ; subtraction of two fixed point numbers

        move.w     #640,d0              ; 10\*64

        move.w     #13,d1               ; 0.2\*64

        sub.w      d1,d0                ; result in fixed notation = 9.8

Multiplication between two fixed point numbers requires the result to be divided by 64 to obtain a fixed point number.

Multiplying between a fixed point number and an integer produces a fixed point number and does not require dividing the result by 64.

Below are examples of multiplication.

; multiplication of two fixed point numbers

        move.w     #224,d0              ; 3.5

        move.w     #134,d1              ; 2.1

        mulu       d1,d0

        divu       #64,d0               ; result = 7.33

    ; multiplication of a fixed point number by an integer

        move.w     #160,d0              ; 2.5

        move.w     #2,d1

        mulu       d1,d0                ; result = 5

Dividing between two fixed point numbers requires the dividend to be multiplied by 64. The result is a fixed point number. Below is an example.

; division of two fixed point numbers

        move.l     #326,d0              ; 5.1

        mulu       #64,d0               ; multiplies the dividend by 64

        move.w     #141,d1              ; 2.2

        divu       d1,d0                ; result = 2.3

The complete source code for this chapter can be found at the following url:

<https://github.com/stefanocoppi/amiga_game_prog_assembly/tree/main/chapter27>