Conditional logic

Dataset: world\_bank\_trust\_funds.xlsx

* Basic TRUE/FALSE flag:

=[@[Contributions Outstanding (USD)]]=0

* To check if the 'Contributions Outstanding (USD)' in a row is greater than 0:

=IF(D2 > 0, "Outstanding", "No Outstanding")

AND/OR/NOT logic

* To check if both 'Contributions Paid In (USD)' is above $1,000,000 and 'Fiscal Year of Agreement' is after 2000:

=IF(AND(C2 > 1000000, B2 > 2000), "High Contribution & Recent", "Other")

* To check if 'Fiscal Year of Agreement' is 2000 and 'Donor Name' is "Canada":

=IF(AND(B2 = 2000, E2 = "Canada"), "Year 2000, Canada", "Other")

* To check if either 'Donor Name' is Canada or Sweden:

=IF(OR(E2 = "Canada", E2 = "Sweden"), "Canada or Sweden", "Other")

* To check if the 'Status' is not 'LCLS':

=IF(NOT(F2 = "LCLS"), "Not LCLS", "LCLS")

IFS function

* To categorize based on 'Total Contribution (USD)':

=IFS(G2 > 5000000, "Very High", G2 > 1000000, "High", G2 > 500000, "Medium", TRUE, "Low")

* To categorize records based on 'Fiscal Year of Agreement':

=IFS(B2 >= 2005, "Post-2005", B2 >= 2000, "2000-2004", TRUE, "Pre-2000")

Conditional logic practice questions

Dataset: ceo\_dismissals.xlsx

1. Write an Excel formula to identify rows where the CEO was involuntarily dismissed (i.e., ceo\_dismissal equals 1). Place this formula in a new column and label it Involuntary Dismissal Status.
2. Use an IF function to categorize the tenure\_no\_ceodb into "First Term" or "Second Term" based on whether the value is 1 or 2, respectively.
3. Create a formula using IF and AND functions to check if the coname is "AAR CORP" and the departure\_code is equal to 5. Label the results as "AAR Corp, Code > 5" or "Other".
4. Employ the IFS function to categorize the fyear into three groups: "Before 2000", "2000-2010", and "After 2010".
5. Write an IF formula to identify if the CEO was either an interim CEO or a co-CEO based on the interim\_coceo column. Label the results as "Interim/Co-CEO" or "Regular CEO".
   1. Hint! Use the ISBLANK() function

Conditional logic practice questions SOLUTIONS

1. =IF([@[ceo\_dismissal]] = 1, "Involuntarily Dismissed", "Not Involuntarily Dismissed")
2. =IF([@[tenure\_no\_ceodb]] = 1, "First Term", IF([@[tenure\_no\_ceodb]] = 2, "Second Term", "Other"))
3. =IF(AND([@coname] = "AAR CORP", [@[departure\_code]] = 5), "AAR Corp, Code = 5", "Other")
4. =IFS([@fyear] < 2000, "Before 2000", [@fyear] <= 2010, "2000-2010", [@fyear] > 2010, "After 2010")
5. =IF(ISBLANK([@[interim\_coceo]]), "Regular CEO", "Interim/Co-CEO")

Lookup functions

Dataset: world\_bank\_trust\_funds.xlsx

Our goal is to retrieve the Trustee Fund Name based on the Trustee Fund Number and the Donor Name based on the Donor Code

Looking up with VLOOKUP:

* =VLOOKUP([@[Trustee Fund Number]], trustees, 2, FALSE)
* =VLOOKUP([@[Donor Code]], donors, 2, FALSE)

Looking up with XLOOKUP:

* =XLOOKUP([@[Trustee Fund Number]], trustees[Trustee Fund Number], trustees[Trustee Fund Name])
* =XLOOKUP([@[Donor Code]], donors[Donor Code], donors[[Donor Name ]])

We will cover approximate matches, error handling, and other topics as time and interest permits

Lookup functions practice questions  
Dataset: ceo\_dismissals.xlsx

1. Use VLOOKUP and then XLOOKUP to retrieve the dismissal code description from the readme worksheet
2. Can the gvkey column be used as a lookup value for company name? Why or why not?

Lookup functions practice questions SOLUTIONS

1. Using lookup functions to find descriptions for each departure code:
   1. =VLOOKUP([@[departure\_code]], departure\_codes, 2, FALSE)
   2. =XLOOKUP([@[departure\_code]], departure\_codes[Code], departure\_codes[Title])

For some more interesting uses of XLOOKUP, check out <https://exceljet.net/functions/xlookup-function>. Please note that XLOOKUP makes use of dynamic array functions. To understand how dynamic array functions, head to <https://stringfestanalytics.com/how-to-understand-dynamic-arrays-in-excel/>. Check out <https://exceljet.net/articles/dynamic-array-formulas-in-excel> for more examples.

1. This concerns the issue of slowly changing dimensions, where company names may vary from year to year. To address this, it's necessary to establish rules enabling lookup functions to operate effectively over time. One approach could involve concatenating the year and GVKEY, thereby facilitating the lookup of a company's name for a specific fiscal year.

SUMPRODUCT

Check the sumproduct\_examples.xlsx workbook for some simple examples.

This is most commonly used to come up with a weight-adjusted average.

For some more exotic examples of SUMPRODUCT, check out <https://exceljet.net/functions/sumproduct-function>. Please note that many of these can be done with SUMIF, COUNTIF and now, FILTER.