Add "Behind" blend mode

This allows you to paint "behind" the active layer, effectively painting a background onto layers with transparency data.

I've also updated the GIMP (XCF) file importer to recognize "Behind" mode in layers, allowing those "Behind"-mode layers to render correctly in PD.

Author: tannerhelland

Classes/pdDIB.cls

@@ -883,7 +883,47 @@ CouldNotCreateDIB:
 
 End Function
 
-'Replace the entire DIB's contents with some solid color
+'Replace a rectangle of the DIB with a fixed RGBA value.
+' IMPORTANTLY: it is up to the caller to handle alpha premultiplication on the passed color + alpha value,
+' based on the underlying premultiplied alpha state of the target DIB.
+Friend Sub FillRectWithColor(ByRef dstRectF As RectF, Optional ByVal fillColor As Long = vbBlack, Optional ByVal fillAlpha As Single = 0!)
+
+    'Unsuspend this DIB (as necessary)
+    If m_IsSuspended Then UnsuspendDIB
+        
+    'If the DIB is 24bpp, apply the color using GDI
+    If (m_dibColorDepth = 24) Then
+        
+        GDI.FillRectToDC Me.GetDIBDC, Int(dstRectF.Left), Int(dstRectF.Top), Int(dstRectF.Width) + 1, Int(dstRectF.Height) + 1, fillColor
+        
+        'Alpha premultiplication technically doesn't matter in 24-bpp mode, so reset it to its default value (FALSE)
+        m_IsAlphaPremultiplied = False
+        
+    '32-bpp requires GDI+
+    Else
+        
+        Dim fillAlphaL As Long
+        fillAlphaL = Int(fillAlpha * 2.55! + 0.5!)
+        
+        Dim tmpSurface As Long, tmpBrush As Long
+        tmpSurface = GDI_Plus.GetGDIPlusGraphicsFromDC(Me.GetDIBDC)
+        tmpBrush = GDI_Plus.GetGDIPlusSolidBrushHandle(fillColor, fillAlphaL)
+        
+        GDI_Plus.GDIPlus_GraphicsSetCompositingMode tmpSurface, GP_CM_SourceCopy
+        GDI_Plus.GDIPlus_FillRectI tmpSurface, tmpBrush, Int(dstRectF.Left), Int(dstRectF.Top), Int(dstRectF.Width + 0.5!), Int(dstRectF.Height + 0.5!)
+        GDI_Plus.ReleaseGDIPlusBrush tmpBrush
+        GDI_Plus.ReleaseGDIPlusGraphics tmpSurface
+        
+        m_IsAlphaPremultiplied = (fillAlphaL = 255) Or ((fillAlphaL = 0) And (fillColor = 0))
+        
+    End If
+    
+    'Minimize GDI resources by freeing our DC
+    Me.FreeFromDC
+    
+End Sub
+
+'Replace the entire DIB's contents with a fixed RGBA value
 Friend Sub FillWithColor(Optional ByVal fillColor As Long = vbBlack, Optional ByVal fillAlpha As Single = 0!)
 
     'Unsuspend this DIB (as necessary)
@@ -926,7 +966,7 @@ Friend Sub FillWithColor(Optional ByVal fillColor As Long = vbBlack, Optional By
             Dim tmpSurface As Long, tmpBrush As Long
             tmpSurface = GDI_Plus.GetGDIPlusGraphicsFromDC(Me.GetDIBDC)
             tmpBrush = GDI_Plus.GetGDIPlusSolidBrushHandle(fillColor, fillAlpha * 2.55)
-                
+            
             GDI_Plus.GDIPlus_GraphicsSetCompositingMode tmpSurface, GP_CM_SourceCopy
             GDI_Plus.GDIPlus_FillRectI tmpSurface, tmpBrush, -1, -1, m_dibWidth + 2, m_dibHeight + 2
             GDI_Plus.ReleaseGDIPlusBrush tmpBrush

Classes/pdPixelBlender.cls

@@ -59,20 +59,23 @@ Friend Sub BlendDIBs(ByRef topDIB As pdDIB, ByRef bottomDIB As pdDIB, ByVal blen
 
         'With loop bounds safely calculated, we can now proceed with blending.
 
-        'Because we are potentially doing a *lot* of calculations here, we need to make a temporary copy of the top DIB.  (Our copy will
-        ' be a beaten, mangled mess by the end of this function, and we aren't allowed to make changes to the caller's copy.)
+        'Because we are potentially doing a *lot* of calculations here, we need to make a temporary copy of the top DIB.
+        ' (Our copy will be a beaten, mangled mess by the end of this function, and we aren't allowed to make changes
+        ' to the caller's copy.)
         If (m_topDIBCopy.GetDIBWidth <> topDIB.GetDIBWidth) Or (m_topDIBCopy.GetDIBHeight <> topDIB.GetDIBHeight) Then
             m_topDIBCopy.CreateBlank topDIB.GetDIBWidth, topDIB.GetDIBHeight, 32, 0, 0
         End If
+        
         GDI.BitBltWrapper m_topDIBCopy.GetDIBDC, 0, 0, topDIB.GetDIBWidth, topDIB.GetDIBHeight, topDIB.GetDIBDC, 0, 0, vbSrcCopy
         m_topDIBCopy.SetInitialAlphaPremultiplicationState topDIB.GetAlphaPremultiplication
 
-        'To keep our individual blend functions as simple as possible, we apply a pre-processing alpha pass that handles several things:
+        'To keep our individual blend functions as simple as possible, we apply a pre-processing alpha pass
+        ' that handles several things:
         ' 1) Apply layer masks (if any)
         ' 2) Apply alpha inheritance (if any)
+        ' 3) Overwrite blend mode on paintbrush (identified by presence of a top layer mask)
 
         'Note that we can skip these steps if none of these special alpha modes are active for the top DIB.
-        
         If (topAlphaMode <> AM_Normal) Or (bottomAlphaMode <> AM_Normal) Or (Not topLayerMask Is Nothing) Then
             PreProcessAlphaEffects m_topDIBCopy, bottomDIB, bottomAlphaMode, topAlphaMode, initX, initY, finalX, finalY, xOffsetBottom, yOffsetBottom, False, ptrToTopLayerAlternateRectF, topLayerMask
         End If
@@ -167,6 +170,13 @@ Friend Sub BlendDIBs(ByRef topDIB As pdDIB, ByRef bottomDIB As pdDIB, ByVal blen
                     ApplyBlendMode_Erase m_topDIBCopy, bottomDIB, initX, initY, finalX, finalY, xOffsetBottom, yOffsetBottom, alphaModifier
                 End If
 
+            Case BM_Behind
+                '"Behind" mode is handled by the final blend step (see below)
+                
+            Case BM_Overwrite
+                'Note that overwrite mode also requires a mask - this is so that paint strokes can be correctly composited.
+                'TODO
+            
             'Some blendmodes don't have dedicated, optimized subs just yet.  This catch-all function handles their code for now.
             Case Else
                 PDDebug.LogAction "WARNING: UNKNOWN BLEND MODE REQUESTED IN pdPixelBlender.BlendDIBs!"
@@ -176,9 +186,45 @@ Friend Sub BlendDIBs(ByRef topDIB As pdDIB, ByRef bottomDIB As pdDIB, ByVal blen
         'Composited results will have been placed inside the temporary top DIB copy.  Apply the final blend now!
         If applyFinalBlend Then
 
-            'Some blend modes ignore this step (Erase, at present)
-            If (blendMode <> BM_Erase) Then m_topDIBCopy.AlphaBlendToDCEx bottomDIB.GetDIBDC, xOffsetBottom + initX, yOffsetBottom + initY, finalX - initX + 1, finalY - initY + 1, initX, initY, finalX - initX + 1, finalY - initY + 1, Int(alphaModifier * 255! + 0.5!)
-            'Debug.Print "Blending this many pixels: " & CStr((finalX - initX + 1) * (finalY - initY + 1))
+            'In "behind" blend mode, this step is different.
+            If (blendMode = BM_Behind) Then
+                
+                'In "Behind" blend mode, we actually blend the bottom DIB "atop" the top DIB.  Instead of making a
+                ' temporary copy of the top DIB, we actually need to make a copy of the *bottom* one.
+                If (m_topDIBCopy.GetDIBWidth <> bottomDIB.GetDIBWidth) Or (m_topDIBCopy.GetDIBHeight <> bottomDIB.GetDIBHeight) Then
+                    m_topDIBCopy.CreateBlank bottomDIB.GetDIBWidth, bottomDIB.GetDIBHeight, 32, 0, 0
+                End If
+                
+                GDI.BitBltWrapper m_topDIBCopy.GetDIBDC, 0, 0, bottomDIB.GetDIBWidth, bottomDIB.GetDIBHeight, bottomDIB.GetDIBDC, 0, 0, vbSrcCopy
+                m_topDIBCopy.SetInitialAlphaPremultiplicationState bottomDIB.GetAlphaPremultiplication
+                
+                'm_topDIBCopy now contains a copy of the *bottom* DIB's data.  Next we want to "cut out" the
+                ' merge region in the *bottom* DIB, and replace it with the top DIB's pixels.  (We also need
+                ' to blank out the target region first, so that the layer's opacity - if any - is reflected
+                ' correctly in the blend.)
+                Dim tmpFillRectF As RectF
+                With tmpFillRectF
+                    .Left = xOffsetBottom + initX
+                    .Top = yOffsetBottom + initY
+                    .Width = finalX - initX + 1
+                    .Height = finalY - initY + 1
+                End With
+                
+                bottomDIB.FillRectWithColor tmpFillRectF, 0, 0
+                topDIB.AlphaBlendToDCEx bottomDIB.GetDIBDC, xOffsetBottom + initX, yOffsetBottom + initY, finalX - initX + 1, finalY - initY + 1, initX, initY, finalX - initX + 1, finalY - initY + 1, Int(alphaModifier * 255! + 0.5!)
+                
+                'Now, blend the *copy* of the bottom layer onto the space where we just "chopped out"
+                ' the bottom layer's pixels and replaced them with the top layer's
+                m_topDIBCopy.AlphaBlendToDCEx bottomDIB.GetDIBDC, xOffsetBottom + initX, yOffsetBottom + initY, finalX - initX + 1, finalY - initY + 1, xOffsetBottom + initX, yOffsetBottom + initY, finalX - initX + 1, finalY - initY + 1, 255!
+            
+            'All other blend modes behave normally
+            Else
+            
+                'Some blend modes ignore this step (Erase, at present)
+                If (blendMode <> BM_Erase) Then m_topDIBCopy.AlphaBlendToDCEx bottomDIB.GetDIBDC, xOffsetBottom + initX, yOffsetBottom + initY, finalX - initX + 1, finalY - initY + 1, initX, initY, finalX - initX + 1, finalY - initY + 1, Int(alphaModifier * 255! + 0.5!)
+                'Debug.Print "Blending this many pixels: " & CStr((finalX - initX + 1) * (finalY - initY + 1))
+            
+            End If
 
             'Also, locked alpha requires us to restore the original bottom layer alpha values now
             If (bottomAlphaMode = AM_Locked) Then PostProcessAlphaEffects m_topDIBCopy, bottomDIB, bottomAlphaMode, topAlphaMode, initX, initY, finalX, finalY, xOffsetBottom, yOffsetBottom, False, ptrToTopLayerAlternateRectF
@@ -365,8 +411,9 @@ Friend Sub ApplyMaskToTopDIB(ByRef dstDIB As pdDIB, ByRef maskDIB As pdDIB, Opti
 
 End Sub
 
-'Prior to blending two DIBs, call this function preprocess any alpha-specific effects (masks, inheritance, etc).  This greatly simplifies
-' the actual blending code inside each blend function, because special alpha handling is never required.
+'Prior to blending two DIBs, call this function preprocess any alpha-specific effects (masks, inheritance, etc).
+' This greatly simplifies the actual blending code inside each blend function, because special alpha handling
+' is never required.
 Private Sub PreProcessAlphaEffects(ByRef topDIB As pdDIB, ByRef bottomDIB As pdDIB, ByVal bottomAlphaMode As PD_AlphaMode, ByVal topAlphaMode As PD_AlphaMode, ByVal initX As Long, ByVal initY As Long, ByVal finalX As Long, ByVal finalY As Long, ByVal xOffset As Long, ByVal yOffset As Long, Optional ByVal returnResultsUnpremultiplied As Boolean = False, Optional ByVal ptrToTopLayerAlternateRectF As Long = 0, Optional ByRef topLayerMask As pdDIB = Nothing)
 
     'Only some settings require us to use this function.
@@ -406,8 +453,8 @@ Private Sub PreProcessAlphaEffects(ByRef topDIB As pdDIB, ByRef bottomDIB As pdD
             If (tmpFinalX > topLayerMask.GetDIBStride - 1) Then tmpFinalX = topLayerMask.GetDIBStride - 1
             If (tmpFinalY > topLayerMask.GetDIBHeight - 1) Then tmpFinalY = topLayerMask.GetDIBHeight - 1
 
-            '2D array access is slow (because VB must apply multiplication "behind-the-scenes" on each access), so we cheat and use 1D arrays,
-            ' which we reset between scanlines.
+            '2D array access is slow (because VB must apply multiplication "behind-the-scenes" on each access),
+            ' so we cheat and use 1D arrays, which we reset between scanlines.
             bottomScanlineSize = topDIB.GetDIBStride:  bottomDIBPointer = topDIB.GetDIBPointer
             topScanlineSize = topLayerMask.GetDIBStride:  topDIBPointer = topLayerMask.GetDIBPointer
 
@@ -1199,7 +1246,7 @@ Private Sub ApplyBlendMode_Difference(ByRef topDIB As pdDIB, ByRef bottomDIB As
                 If (newG < 0!) Then newG = -newG
                 newB = (bottomB - topB)
                 If (newB < 0!) Then newB = -newB
-                    
+                
                 'If the bottom layer contains transparency, mix the newly calculated RGB values against the original top layer
                 ' RGB values.  This reduces the strength of the blend mode result, proportional to the bottom layer's alpha.
                 If (bottomA <> 1!) Then

Classes/pdXCF.cls

@@ -1333,7 +1333,7 @@ Private Function GetPDBlendFromGIMPBlend(ByVal srcGIMPBlend As Long) As PD_Blend
             GetPDBlendFromGIMPBlend = BM_Normal
         'Behind
         Case 29
-            GetPDBlendFromGIMPBlend = BM_Normal
+            GetPDBlendFromGIMPBlend = BM_Behind
         'Multiply
         Case 30
             GetPDBlendFromGIMPBlend = BM_Multiply

Modules/Colors.bas

@@ -62,6 +62,8 @@ Public Enum PD_BlendMode
     BM_GrainExtract = 24
     BM_GrainMerge = 25
     BM_Erase = 26
+    BM_Behind = 27
+    BM_Overwrite = 28
 End Enum
 
 #If False Then
@@ -70,7 +72,7 @@ End Enum
     Const BM_SoftLight = 10, BM_HardLight = 11, BM_VividLight = 12, BM_LinearLight = 13, BM_PinLight = 14
     Const BM_HardMix = 15, BM_Difference = 16, BM_Exclusion = 17, BM_Subtract = 18, BM_Divide = 19
     Const BM_Hue = 20, BM_Saturation = 21, BM_Color = 22, BM_Luminosity = 23, BM_GrainExtract = 24
-    Const BM_GrainMerge = 25, BM_Erase = 26
+    Const BM_GrainMerge = 25, BM_Erase = 26, BM_Behind = 27, BM_Overwrite = 28
 #End If
 
 'PD supports the notion "alpha modes", including "inheritance," where a layer "inherits" the alpha of a layer beneath it,
@@ -1013,6 +1015,10 @@ Public Function GetBlendModeIDFromString(ByRef srcString As String) As PD_BlendM
             GetBlendModeIDFromString = BM_GrainMerge
         Case "eras"
             GetBlendModeIDFromString = BM_Erase
+        Case "bhnd"
+            GetBlendModeIDFromString = BM_Behind
+        Case "copy"
+            GetBlendModeIDFromString = BM_Overwrite
         Case Else
             GetBlendModeIDFromString = BM_Normal
             PDDebug.LogAction "WARNING! Colors.GetBlendModeStringFromID received a bad value: " & srcString
@@ -1079,10 +1085,13 @@ Public Function GetBlendModeStringFromID(ByVal srcMode As PD_BlendMode) As Strin
             GetBlendModeStringFromID = "gmrg"
         Case BM_Erase
             GetBlendModeStringFromID = "eras"
+        Case BM_Behind
+            GetBlendModeStringFromID = "bhnd"
+        Case BM_Overwrite
+            GetBlendModeStringFromID = "copy"
         Case Else
             GetBlendModeStringFromID = "    "
             PDDebug.LogAction "WARNING! Colors.GetBlendModeStringFromID received a bad value: " & srcMode
     End Select
 
 End Function
-

Modules/Interface.bas

@@ -1738,7 +1738,9 @@ Public Sub PopulateBlendModeDropDown(ByRef dstCombo As pdDropDown, Optional ByVa
     dstCombo.AddItem "Luminosity", , True
     dstCombo.AddItem "Grain extract"
     dstCombo.AddItem "Grain merge", , True
-    dstCombo.AddItem "Erase"
+    dstCombo.AddItem "Erase", , True
+    dstCombo.AddItem "Behind"
+    dstCombo.AddItem "Overwrite"
 
     dstCombo.ListIndex = blendIndex
 

PhotoDemon.vbp

@@ -1,6 +1,6 @@
 Type=Exe
-Reference=*\G{50A7E9B0-70EF-11D1-B75A-00A0C90564FE}#1.0#0#..\..\Windows\SysWOW64\shell32.dll#Microsoft Shell Controls And Automation
-Reference=*\G{00020430-0000-0000-C000-000000000046}#2.0#0#..\..\Windows\SysWOW64\stdole2.tlb#OLE Automation
+Reference=*\G{50A7E9B0-70EF-11D1-B75A-00A0C90564FE}#1.0#0#\\?\C:\Windows\SysWOW64\shell32.dll#Microsoft Shell Controls And Automation
+Reference=*\G{00020430-0000-0000-C000-000000000046}#2.0#0#\\?\C:\Windows\SysWOW64\stdole2.tlb#OLE Automation
 Module=PDMain; Modules\Main.bas
 Module=Public_Constants; Modules\PublicConstants.bas
 Module=Public_EnumsAndTypes; Modules\PublicEnumsAndTypes.bas
@@ -524,7 +524,7 @@ Description="PhotoDemon Photo Editor"
 CompatibleMode="0"
 MajorVer=9
 MinorVer=1
-RevisionVer=311
+RevisionVer=315
 AutoIncrementVer=1
 ServerSupportFiles=0
 VersionComments="Copyright 2000-2024 Tanner Helland - photodemon.org"