Skip to content
This repository
tree: d7723d1090
Fetching contributors…

Cannot retrieve contributors at this time

file 124 lines (107 sloc) 2.77 kb
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

PROTOCOL_IUSE="+aim gadu +icq +irc +jabber lj +msn rss +yahoo"
IUSE="${PROTOCOL_IUSE} bidi nls ssl crypt jpeg otr"

DESCRIPTION="CenterIM is a fork of CenterICQ - a ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
SRC_URI="http://www.centerim.org/download/mobshots/${P}.tar.gz"
RESTRICT="mirror"
HOMEPAGE="http://www.centerim.org/"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"

DEPEND=">=sys-libs/ncurses-5.2
bidi? ( dev-libs/fribidi )
ssl? ( >=dev-libs/openssl-0.9.6g )
jpeg? ( media-libs/jpeg )
jabber? (
otr? ( net-libs/libotr )
crypt? ( >=app-crypt/gpgme-1.0.2 )
)
msn? (
|| (
>=net-misc/curl-7.19.6[ssl]
>=net-misc/curl-7.19.6[gnutls]
>=net-misc/curl-7.19.6[nss]
)
)
yahoo? (
|| (
>=net-misc/curl-7.19.6[ssl]
>=net-misc/curl-7.19.6[gnutls]
>=net-misc/curl-7.19.6[nss]
)
)"

RDEPEND="${DEPEND}
nls? ( sys-devel/gettext )"

check_protocol_iuse() {
local flag

for flag in ${PROTOCOL_IUSE}
do
use ${flag#+} && return 0
done

return 1
}

pkg_setup() {
if ! check_protocol_iuse
then
eerror
eerror "Please activate at least one of the following protocol USE flags:"
eerror "${PROTOCOL_IUSE//+}"
eerror
die "Please activate at least one protocol USE flag!"
fi

if use otr && ! use jabber
then
ewarn
ewarn "Support for OTR is only supported with Jabber!"
ewarn
fi

if use gadu && ! use jpeg
then
ewarn
ewarn "You need jpeg support to be able to register Gadu-Gadu accounts!"
ewarn
fi
}

src_prepare() {
default

# Don't execute git commands, bug #228151
cat >"${S}"/misc/git-version-gen <<-EOF
#!/bin/sh
echo -n "${PVR}"
EOF
}

src_configure() {
econf \
$(use_with ssl) \
$(use_enable aim) \
$(use_with bidi fribidi) \
$(use_with jpeg libjpeg) \
$(use_with otr libotr) \
$(use_enable gadu gg) \
$(use_enable icq) \
$(use_enable irc) \
$(use_enable jabber) \
$(use_enable lj) \
$(use_enable msn) \
$(use_enable nls locales-fix) \
$(use_enable nls) \
$(use_enable rss) \
$(use_enable yahoo) \
|| die "econf failed"
}

src_install () {
emake DESTDIR="${D}" install || die "emake install failed"

dodoc AUTHORS ChangeLog FAQ README THANKS TODO
}

pkg_postinst() {
ewarn "This version of centerim is a snapshot of the mob branch."
ewarn "That means it is under development und just for testing"
ewarn "please report any bugs to http://bugzilla.centerim.org/"
ewarn "in addition please also report to the devel mailing list as"
ewarn "described at http://centerim.org or join us in #centerim on freenode."
ewarn ""
ewarn "Direct question about the overlay to transacid@centerim.org"
}
Something went wrong with that request. Please try again.