# Significance: Deliverable 1

Author: (Tripp) Milton Lamb

Date: 9/23/2025

Class: CS-524-01 Fall

E-mail: [mal0004@uah.edu](mailto:mal0004@uah.edu)

## Introduction

Significance is a language designed for CS-524. It was born out of curiosity for a way to hold onto uncertainty in values during modeling and simulation. After a slight amount of research it became clear how unhelpful this would be in an iterative dynamical simulation due to compounding error without appropriate covariance, and this covariance would be difficult to determine in practice. Nonetheless having the language parse uncertainty still seemed like a reasonable addition to fulfill the requirements of the project.

## Environment

I'll am using Windows and Rust to write the interpreter. I am using <https://www.bottlecaps.de/rr/ui> to generate railroad diagrams for the grammar. These railroad diagrams are included below. I think these are more helpful the raw EBNF when writing a parser.

## Notes

The project includes a tokenizer, an AST parser, a semantic analyzer, and an executor. I will implement a REPL (and also likely a file interpreter since I'm using that for testing). I have elected to make variables in Significance immutable (signified by := as the only current assignment operator), this feels in line with it being a simple expression language.

## Status

Currently, the project

* tokenizes a file
* creates an AST
* semantically parses for variable declaration (since there are only double precision numbers type checking is unnecessary)
* executes an abstract syntax

## Work Left

* Abstract some portions to work as a REPL as well as a source file interpreter, including passing in an existing symbol table
* Figure out how I want to implement functions. I think I am going to pre-load the standard library (sin, cos, sqrt) them into the symbol table before calling the semantic analyzer.

## Syntax Example

#This is an example program in significance  
  
{x : real} # this is the `x` variable  
{y : real} # this represents a change in `x`  
{z : real} # z is the next iteration of `x`  
  
x := 12.3 +/- 0.5  
y := 2.6 +/- 0.2  
z := x + y  
z  
w := x\*x + y\*\*2  
w

## Grammar

Below is the complete EBNF grammar of Significance, following the ISO/IEC 14977 standard, by R. S. Scowen.

R. S. Scowen, "Extended BNF — A generic base standard," in *Proc. Software Engineering Standards Symposium (SESS'93)*, 1993.


(\* Extended Backus-Naur Form for Significance Language \*)  
(\* Supports arithmetic operations with uncertainty, variables, assignments, and comments \*)  
  
(\* Entry point \*)  
program = { statement };  
  
(\* Statements \*)  
statement = variable\_declaration  
 | assignment  
 | expression\_statement  
 | comment;  
  
(\* Variable declaration \*)  
variable\_declaration = "{", identifier, ":", type, "}";  
  
(\* Type system \*)  
type = "real";  
  
(\* Assignment \*)  
assignment = identifier, ":=", expression;  
  
(\* Expression statement (gets printed to console) \*)  
expression\_statement = expression;  
  
(\* Comments \*)  
comment = "#", [ comment\_text ], newline;  
  
comment\_text = { letter | digit | whitespace\_char | symbol };  
  
(\* Expressions \*)  
expression = term;  
  
(\* Addition and Subtraction (lowest precedence) \*)  
term = factor, { term\_op, factor };  
  
  
(\* Multiplication, Division, and Modulus \*)  
factor = power, { factor\_op, power };  
  
  
(\* Exponentiation and Root (right-associative) \*)  
power = unary, [ power\_op, unary ];  
  
  
(\* Unary operations (unary minus/plus) \*)  
unary = [ unary\_op ], primary;  
  
  
(\* Primary expressions (highest precedence) \*)  
primary = number\_with\_uncertainty  
 | variable  
 | function\_call  
 | "(", expression, ")";  
  
(\* Numbers with optional uncertainty \*)  
number\_with\_uncertainty = number\_scientific, [ uncertainty\_op, number\_scientific ];  
  
(\* Uncertainty Operator \*)  
uncertainty\_op = "+/-";  
  
(\* Function calls \*)  
function\_call = identifier, "(", [ argument\_list ], ")";  
  
(\* Function arguments \*)  
argument\_list = expression, { ",", expression };  
  
(\* Variables and function names \*)  
variable = identifier;  
  
(\* Identifier definition \*)  
identifier = letter, { letter | digit | "\_" };  
  
(\* Numbers \*)  
number = integer\_part, [ ".", fractional\_part ];  
  
(\* Scientific notation numbers \*)  
number\_scientific = number, [ exponent\_part ];  
  
exponent\_part = ( "e" | "E" ), [ unary\_op ], digit, { digit };  
  
integer\_part = digit, { digit };  
  
fractional\_part = digit, { digit };  
  
(\* Terminating Non-terminals \*)  
  
(\* Operators for the term non-terminal\*)  
term\_op = "+" | "-";  
  
(\* Operators for the factor non-terminal\*)  
factor\_op = "\*" | "/" | "%";  
  
(\* Operators for the power non-terminal\*)  
power\_op = "\*\*" | "//";  
  
(\* Operators for the unary non-terminal\*)  
unary\_op = "+" | "-";  
  
letter = "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" | "j"   
 | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" | "s" | "t"   
 | "u" | "v" | "w" | "x" | "y" | "z"  
 | "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J"   
 | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" | "S" | "T"   
 | "U" | "V" | "W" | "X" | "Y" | "Z";  
  
digit = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9";  
  
  
newline = "\n" | "\r\n" | "\r";  
  
whitespace\_char = " " | "\t";  
  
symbol = "!" | "@" | "$" | "^" | "&" | "?" | ":" | ";" | "," | "." | "<" | ">" | "~" | "`"  
 | "[" | "]" | "{" | "}" | "|" | "\" | "'" | '"' | "+" | "-" | "\*" | "/" | "%" | "=" | "(" | ")";  
  
(\* Whitespace \*)  
whitespace = whitespace\_char | newline;

## Railroad Diagrams

### program:

fig:

### statement:



referenced by:

* [program](#program)

### variable\_declaration:

fig:

referenced by:

* [statement](#statement)

### assignment:

fig:

referenced by:

* [statement](#statement)


### expression\_statement:

fig:

referenced by:

* [statement](#statement)


### comment:



referenced by:

* [statement](#statement)

### comment\_text:



referenced by:

* [comment](#comment)


### expression:

fig:

referenced by:

* [argument\_list](#argumentlist)
* [assignment](#assignment)
* [expression\_statement](#expressionstatement)
* [primary](#primary)


### term:



referenced by:

* [expression](#expression)


### term\_op:



referenced by:

* [term](#term)


### factor:



referenced by:

* [term](#term)


### factor\_op:



referenced by:

* [factor](#factor)


### power:



referenced by:

* [factor](#factor)


### power\_ops:



referenced by:

* [power](#power)


### unary:



referenced by:

* [power](#power)


### unary\_ops:



referenced by:

* [unary](#unary)


### primary:



referenced by:

* [unary](#unary)


### number\_with\_uncertainty:



referenced by:

* [primary](#primary)


### function\_call:



referenced by:

* [primary](#primary)

### argument\_list:



referenced by:

* [function\_call](#functioncall)


### variable:

fig:

referenced by:

* [primary](#primary)


### identifier:



referenced by:

* [assignment](#assignment)
* [function\_call](#functioncall)
* [variable](#variable)
* [variable\_declaration](#variabledeclaration)


### number:



referenced by:

* [number\_scientific](#numberscientific)


### number\_scientific:



referenced by:

* [number\_with\_uncertainty](#numberwithuncertainty)

### exponent\_part:



referenced by:

* [number\_scientific](#numberscientific)

### integer\_part:

fig:

referenced by:

* [number](#number)


### fractional\_part:

fig:

referenced by:

* [number](#number)


### letter:



referenced by:

* [comment\_text](#commenttext)
* [identifier](#identifier)


### digit:



referenced by:

* [comment\_text](#commenttext)
* [exponent\_part](#exponentpart)
* [fractional\_part](#fractionalpart)
* [identifier](#identifier)
* [integer\_part](#integerpart)


### newline:



referenced by:

* [comment](#comment)
* [whitespace](#whitespace)


### whitespace\_char:



referenced by:

* [comment\_text](#commenttext)
* [whitespace](#whitespace)

### symbol:



referenced by:

* [comment\_text](#commenttext)

### whitespace:

