flake.nix: init

Author: vaibhavsagar

default.nix

@@ -1,38 +1,10 @@
-{ nixpkgs ? import (import ./pkgs.nix).nixpkgs {} }:
-let
-  inherit (nixpkgs) pkgs;
-  inherit (pkgs) lib;
-  tex = pkgs.texlive.combine {
-    inherit (pkgs.texlive) scheme-basic booktabs ec lm preprint titling xcolor;
-  };
-  filter = ls: src: name: type: let
-    relPath = lib.removePrefix (toString src + "/") (toString name);
-  in lib.cleanSourceFilter name type && (builtins.any (lib.flip lib.hasPrefix relPath) ls);
-  src = builtins.filterSource (filter [ "resume.md" "templates" ] ./.) ./.;
-in rec {
-  html   = pkgs.runCommand "html" {
-    inherit src;
-    buildInputs = [ pkgs.haskellPackages.pandoc-cli ];
-  } ''
-    mkdir -p $out
-    pandoc $src/resume.md -s -H $src/templates/header.css -A $src/templates/tracking.html -t html -o $out/index.html
-  '';
-  pdf    = pkgs.runCommand "pdf" {
-    inherit src;
-    buildInputs = [ pkgs.haskellPackages.pandoc-cli tex ];
-  } ''
-    mkdir -p $out
-    pandoc $src/resume.md -H $src/templates/header.tex -o $out/Vaibhav_Sagar_resume.pdf
-  '';
-  readme = pkgs.runCommand "readme" {
-    inherit src;
-    buildInputs = [ pkgs.haskellPackages.pandoc-cli ];
-  } ''
-    mkdir -p $out
-    pandoc $src/resume.md -t gfm -o $out/readme.md
-  '';
-  travis = pkgs.buildEnv {
-    name = "travis";
-    paths = [ html readme ];
-  };
-}
+(import
+  (
+    let lock = builtins.fromJSON (builtins.readFile ./flake.lock); in
+    fetchTarball {
+      url = lock.nodes.flake-compat.locked.url or "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+      sha256 = lock.nodes.flake-compat.locked.narHash;
+    }
+  )
+  { src = ./.; }
+).defaultNix

flake.lock

@@ -0,0 +1,48 @@
+{
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/release-23.11";
+  inputs.flake-utils.url = "github:numtide/flake-utils";
+  inputs.nix-filter.url = "github:numtide/nix-filter";
+  inputs.flake-compat.url = "github:edolstra/flake-compat";
+
+  outputs = {self, nixpkgs, flake-utils, nix-filter, ...}:
+    flake-utils.lib.eachDefaultSystem (system: let
+      pkgs = import nixpkgs { inherit system; };
+      inherit (pkgs) lib;
+      src = nix-filter {
+        root = ./.;
+        include = [ "resume.md" "templates"];
+      };
+      tex = pkgs.texlive.combine {
+        inherit (pkgs.texlive) scheme-basic booktabs ec lm preprint titling xcolor;
+      };
+    in {
+      packages = rec {
+        html   = pkgs.runCommand "html" {
+          inherit src;
+          buildInputs = [ pkgs.haskellPackages.pandoc-cli ];
+        } ''
+          mkdir -p $out
+          pandoc $src/resume.md -s -H $src/templates/header.css -A $src/templates/tracking.html -t html -o $out/index.html
+        '';
+        pdf    = pkgs.runCommand "pdf" {
+          inherit src;
+          buildInputs = [ pkgs.haskellPackages.pandoc-cli tex ];
+        } ''
+          mkdir -p $out
+          pandoc $src/resume.md -H $src/templates/header.tex -o $out/Vaibhav_Sagar_resume.pdf
+        '';
+        readme = pkgs.runCommand "readme" {
+          inherit src;
+          buildInputs = [ pkgs.haskellPackages.pandoc-cli ];
+        } ''
+          mkdir -p $out
+          pandoc $src/resume.md -t gfm -o $out/readme.md
+        '';
+        ci = pkgs.buildEnv {
+          name = "ci";
+          paths = [ html readme ];
+        };
+      };
+      defaultPackage = self.packages.${system}.ci;
+    });
+}