Skip to content
Permalink
Browse files

patch 8.1.0311: filtering entries in a quickfix list is not easy

Problem:    Filtering entries in a quickfix list is not easy.
Solution:   Add the cfilter plugin. (Yegappan Lakshmanan)
  • Loading branch information...
brammool committed Aug 21, 2018
1 parent 2f0f871 commit 8c5e0093c9badced73e382915fb024a5c3ea463b
Showing with 61 additions and 0 deletions.
  1. +16 −0 runtime/doc/quickfix.txt
  2. +43 −0 runtime/pack/dist/opt/cfilter/plugin/cfilter.vim
  3. +2 −0 src/version.c
@@ -1551,6 +1551,22 @@ The backslashes before the pipe character are required to avoid it to be
recognized as a command separator. The backslash before each space is
required for the set command.

*cfilter-plugin*
If you have too many matching messages, you can use the cfilter plugin to
reduce the number of entries. Load the plugin with: >
packadd cfilter

Then you can use these command: >
:Cfilter[!] {pat}
:Lfilter[!] {pat}

:Cfilter creates a new quickfix list from entries matching {pat} in the
current quickfix list. Both the file name and the text of the entries are
matched against {pat}. If ! is supplied, then entries not matching {pat} are
used.

:Lfilter does the same as :Cfilter but operates on the current location list.

=============================================================================
8. The directory stack *quickfix-directory-stack*

@@ -0,0 +1,43 @@
" cfilter.vim: Plugin to filter entries from a quickfix/location list
" Last Change: May 12, 2018
" Maintainer: Yegappan Lakshmanan (yegappan AT yahoo DOT com)
" Version: 1.0
"
" Commands to filter the quickfix list:
" :Cfilter[!] {pat}
" Create a new quickfix list from entries matching {pat} in the current
" quickfix list. Both the file name and the text of the entries are
" matched against {pat}. If ! is supplied, then entries not matching
" {pat} are used.
" :Lfilter[!] {pat}
" Same as :Cfilter but operates on the current location list.
"
if exists("loaded_cfilter")
finish
endif
let loaded_cfilter = 1

func s:Qf_filter(qf, pat, bang)
if a:qf
let Xgetlist = function('getqflist')
let Xsetlist = function('setqflist')
let cmd = ':Cfilter' . a:bang
else
let Xgetlist = function('getloclist', [0])
let Xsetlist = function('setloclist', [0])
let cmd = ':Lfilter' . a:bang
endif

if a:bang == '!'
let cond = 'v:val.text !~# a:pat && bufname(v:val.bufnr) !~# a:pat'
else
let cond = 'v:val.text =~# a:pat || bufname(v:val.bufnr) =~# a:pat'
endif

let items = filter(Xgetlist(), cond)
let title = cmd . ' ' . a:pat
call Xsetlist([], ' ', {'title' : title, 'items' : items})
endfunc

com! -nargs=+ -bang Cfilter call s:Qf_filter(1, <q-args>, <q-bang>)
com! -nargs=+ -bang Lfilter call s:Qf_filter(0, <q-args>, <q-bang>)
@@ -794,6 +794,8 @@ static char *(features[]) =

static int included_patches[] =
{ /* Add new patch number below this line */
/**/
311,
/**/
310,
/**/

0 comments on commit 8c5e009

Please sign in to comment.
You can’t perform that action at this time.