



**Programmable Output Driver**

S10682014 陳盈豪



結構





程式碼

#Programmable\_Output\_Driver

.lib "C:\synopsys\lib\cic018.l" tt

.global vdd gnd

.subckt inv in out

MP1 out in vdd vdd p\_18 l=0.18u w=0.82u

MN1 out in gnd gnd n\_18 l=0.18u w=0.18u

.ends inv

.subckt nor2 A B out

MP1 s\_1 A vdd vdd p\_18 l=0.18u w=0.88u

MP2 out B s\_1 vdd p\_18 l=0.18u w=0.88u

MN1 out A gnd gnd n\_18 l=0.18u w=0.18u

MN2 out B gnd gnd n\_18 l=0.18u w=0.18u

.ends nor2

.subckt nand2 A B out

MP1 out A vdd vdd p\_18 l=0.18u w=0.56u

MP2 out B vdd vdd p\_18 l=0.18u w=0.56u

MN1 out A s\_1 gnd n\_18 l=0.18u w=0.18u

MN2 s\_1 B gnd gnd n\_18 l=0.18u w=0.18u

.ends nand2

.subckt decoder S0 S1 E0 E1 E2

X1 S0 S1 E0 nor2

V1 E1 S1 0

V2 E2 S0 0

.ends decoder

.subckt pre\_driver IN E GP GN

X1 IN E GP nand2

X2 E iE inv

X3 IN iE GN nor2

.ends pre\_driver

.subckt output\_stage1 GP GN out

MP1 out GP vdd vdd p\_18 l=0.18u w=0.55u m=100

MN1 out GN gnd gnd n\_18 l=0.18u w=0.18u m=100

.ends output\_stage1

.subckt output\_stage2 GP GN out

MP1 out GP vdd vdd p\_18 l=0.18u w=0.9u m=125

MN1 out GN gnd gnd n\_18 l=0.18u w=0.36u m=125

.ends output\_stage2

.subckt output\_stage3 GP GN out

MP1 out GP vdd vdd p\_18 l=0.18u w=0.65u m=75

MN1 out GN gnd gnd n\_18 l=0.18u w=0.18u m=75

.ends output\_stage3

.subckt output\_stage1\_buffer GP GN GPout GNout

MP1\_P in1P GP vdd vdd p\_18 l=0.18u w=1.64u m=5

MN1\_P in1P GP gnd gnd n\_18 l=0.18u w=0.4u m=5

MP1\_N in1N GN vdd vdd p\_18 l=0.18u w=1.64u m=5

MN1\_N in1N GN gnd gnd n\_18 l=0.18u w=0.4u m=5

MP2\_P GPout in1P vdd vdd p\_18 l=0.18u w=1.64u m=25

MN2\_P GPout in1P gnd gnd n\_18 l=0.18u w=0.4u m=25

MP2\_N GNout in1N vdd vdd p\_18 l=0.18u w=1.64u m=25

MN2\_N GNout in1N gnd gnd n\_18 l=0.18u w=0.4u m=25

.ends output\_stage1\_buffer

.subckt output\_stage2\_buffer GP GN GPout GNout

MP1\_P in1P GP vdd vdd p\_18 l=0.18u w=1.64u m=5

MN1\_P in1P GP gnd gnd n\_18 l=0.18u w=0.4u m=5

MP1\_N in1N GN vdd vdd p\_18 l=0.18u w=1.64u m=5

MN1\_N in1N GN gnd gnd n\_18 l=0.18u w=0.4u m=5

MP2\_P GPout in1P vdd vdd p\_18 l=0.18u w=1.64u m=25

MN2\_P GPout in1P gnd gnd n\_18 l=0.18u w=0.4u m=25

MP2\_N GNout in1N vdd vdd p\_18 l=0.18u w=1.64u m=25

MN2\_N GNout in1N gnd gnd n\_18 l=0.18u w=0.4u m=25

.ends output\_stage2\_buffer

.subckt output\_stage3\_buffer GP GN GPout GNout

MP1\_P in1P GP vdd vdd p\_18 l=0.18u w=1.64u m=5

MN1\_P in1P GP gnd gnd n\_18 l=0.18u w=0.4u m=5

MP1\_N in1N GN vdd vdd p\_18 l=0.18u w=1.64u m=5

MN1\_N in1N GN gnd gnd n\_18 l=0.18u w=0.4u m=5

MP2\_P GPout in1P vdd vdd p\_18 l=0.18u w=1.64u m=25

MN2\_P GPout in1P gnd gnd n\_18 l=0.18u w=0.4u m=25

MP2\_N GNout in1N vdd vdd p\_18 l=0.18u w=1.64u m=25

MN2\_N GNout in1N gnd gnd n\_18 l=0.18u w=0.4u m=25

.ends output\_stage3\_buffer

X1 S0 S1 E0 E1 E2 decoder

X2 IN E0 GP0 GN0 pre\_driver

X3 IN E1 GP1 GN1 pre\_driver

X4 IN E2 GP2 GN2 pre\_driver

X5 GP0 GN0 GP0out GN0out output\_stage1\_buffer

X6 GP1 GN1 GP1out GN1out output\_stage2\_buffer

X7 GP2 GN2 GP2out GN2out output\_stage3\_buffer

X8 GP0out GN0out out output\_stage1

X9 GP1out GN1out out output\_stage2

X10 GP2out GN2out out output\_stage3

\*X8 out1 out buffer

.param S0=0 S1=0

vdd vdd gnd 1.8

VIN IN 0 PULSE (0 1.8 1U 0.5U 0.5U 4.5U 10U)

VS0 S0 gnd dc S0

VS1 S1 gnd dc S1

CL out gnd 100pf

.measure tran tr trig v(out) val=0.18 td=0 rise=1 targ v(out) val=1.62 td=0 rise=1

.measure tran tf trig v(out) val=1.62 td=0 fall=1 targ v(out) val=0.18 td=0 fall=1

.measure tran tmis param='abs(tr-tf)'

.measure tran MAXI MAX i(CL) from=1u to=25u

.option accurate=1

.temp 25

.param S0=0 S1=0

.tran 1u 25u

.dc vin 0,1.8,0.05

.alter

.lib "C:\synopsys\lib\cic018.l" ff

.temp 0

.param S0=1.8 S1=0

.dc vin 0,1.8,0.05

.alter

.lib "C:\synopsys\lib\cic018.l" ss


.temp 75

.param S0=0 S1=1.8

.dc vin 0,1.8,0.05

.end

SPICE Avanwaves結果



圖形由上而下的參數

1. S0 = 0, S1 = 0
2. S0 = 1, S1 = 0
3. S0 = 0, S1 = 1

SPICE measure結果

