Permalink
Browse files

[bitlbee] 1.2.8

  • Loading branch information...
1 parent 06d401d commit 9870fc36bd7ccdfb4eaa6720cd0a150ab65642ba @wired committed Sep 8, 2010
View
@@ -0,0 +1,5 @@
+AUX bitlbee.confd 62 RMD160 f71fff4ab4fe49eebc071d693896f567291bee54 SHA1 80beb974922b2ff6cf9732a7bce1eb03cc10d870 SHA256 105afc0382fc5adc03ed644dba4e78817015a55432349f259a286ac3c1b06628
+AUX bitlbee.initd 605 RMD160 183c4a8117556cb474c01ba4038b357a6716f98e SHA1 3427fa5f558b2957046ef1a6afdd4bc2bb8807e3 SHA256 037091df1746b9a477f07cdac52d99f9310055646ce0e10f859835ba105e3fb4
+DIST bitlbee-1.2.8.tar.gz 513768 RMD160 151b7d9b854b1199edd8ef08a2e6a90b8dcbb545 SHA1 9c8cfea597d28604aa99c32c2a57b0087f42e6af SHA256 3a061b88776699001b774bc323e0a0ffdcd5cde6dec2dda965bc1aa2f2ee8e86
+EBUILD bitlbee-1.2.8.ebuild 4704 RMD160 c69363e88e8c3ed07bec66aba56da65cb9d58200 SHA1 0aa95765317badef28dace00f56397eb93d39f32 SHA256 972d43f725bce07c554df9f7dd0e481135c8d30365e3a5b1fd83d1f87f0df7bc
+MISC metadata.xml 587 RMD160 20ac87a5a0392d197ae790b77be20b531de93f16 SHA1 32889c50a5d5ee8d79d45f8ce8b2648f0bd7c6a5 SHA256 bc5d22992d81c5e34fbb374ebf39e2e396f3dd239c6a3ae8d83c3b1fd25cf0a5
@@ -0,0 +1,163 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/bitlbee/bitlbee-1.2.7.ebuild,v 1.2 2010/08/10 17:56:57 hwoarang Exp $
+
+EAPI="3"
+inherit eutils toolchain-funcs confutils
+
+DESCRIPTION="irc to IM gateway that support multiple IM protocols"
+HOMEPAGE="http://www.bitlbee.org/"
+SRC_URI="http://get.bitlbee.org/src/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
+IUSE="debug gnutls ipv6 +jabber msn nss +oscar ssl test twitter +yahoo xinetd" # ldap - Bug 195758
+
+COMMON_DEPEND=">=dev-libs/glib-2.4
+ msn? ( gnutls? ( net-libs/gnutls )
+ !gnutls? ( nss? ( dev-libs/nss ) )
+ !gnutls? ( !nss? ( ssl? ( dev-libs/openssl ) ) )
+ )
+ jabber? ( gnutls? ( net-libs/gnutls )
+ !gnutls? ( nss? ( dev-libs/nss ) )
+ !gnutls? ( !nss? ( ssl? ( dev-libs/openssl ) ) )
+ )"
+ # ldap? ( net-nds/openldap )"
+DEPEND="${COMMON_DEPEND}
+ dev-util/pkgconfig
+ test? ( dev-libs/check )"
+
+RDEPEND="${COMMON_DEPEND}
+ virtual/logger
+ xinetd? ( sys-apps/xinetd )"
+
+pkg_setup() {
+ elog "Note: Support for all IM protocols are controlled by use flags."
+ elog " Make sure you've enabled the flags you want."
+ elog
+ confutils_require_any jabber msn oscar twitter yahoo
+
+ # At the request of upstream, die if MSN Messenger support is enabled
+ # but no SSL support has been enabled
+ confutils_use_depend_any msn gnutls nss ssl
+
+ if use jabber && ! use gnutls && ! use ssl ; then
+ if use nss; then
+ ewarn ""
+ ewarn "You have enabled nss and jabber"
+ ewarn "but nss doesn't work with jabber"
+ ewarn "Enable ONE of the following use instead"
+ ewarn "flags: gnutls or ssl"
+ ewarn ""
+ die "nss with jabber doesn't work"
+ fi
+ elog ""
+ elog "You have enabled support for Jabber but do not have SSL"
+ elog "support enabled. This *will* prevent bitlbee from being"
+ elog "able to connect to SSL enabled Jabber servers. If you need to"
+ elog "connect to Jabber over SSL, enable ONE of the following use"
+ elog "flags: gnutls or ssl"
+ elog ""
+ fi
+
+ enewgroup bitlbee
+ enewuser bitlbee -1 -1 /var/lib/bitlbee bitlbee
+}
+
+src_prepare() {
+ sed -i \
+ -e "s@/usr/local/sbin/bitlbee@/usr/sbin/bitlbee@" \
+ -e "s/nobody/bitlbee/" \
+ -e "s/}/ disable = yes\n}/" \
+ doc/bitlbee.xinetd || die "sed failed in xinetd"
+
+ sed -i \
+ -e "s@mozilla-nss@nss@g" \
+ configure || die "sed failed in configure"
+}
+
+src_configure() {
+ # ldap hard-disabled for now
+ local myconf="--ldap=0"
+
+ # setup protocol, ipv6 and debug
+ for flag in debug ipv6 msn jabber oscar twitter yahoo ; do
+ if use ${flag} ; then
+ myconf="${myconf} --${flag}=1"
+ else
+ myconf="${myconf} --${flag}=0"
+ fi
+ done
+
+ # setup ssl use flags
+ if use gnutls ; then
+ myconf="${myconf} --ssl=gnutls"
+ einfo "Use gnutls as SSL support"
+ elif use ssl ; then
+ myconf="${myconf} --ssl=openssl"
+ einfo "Use openssl as SSL support"
+ elif use nss ; then
+ myconf="${myconf} --ssl=nss"
+ einfo "Use nss as SSL support"
+ else
+ myconf="${myconf} --ssl=bogus"
+ einfo "You will not have any encryption support enabled."
+ fi
+
+ # NOTE: bitlbee's configure script is not an autotool creation,
+ # so that is why we don't use econf.
+ ./configure --prefix=/usr --datadir=/usr/share/bitlbee \
+ --etcdir=/etc/bitlbee --strip=0 ${myconf} || die "econf failed"
+
+ sed -i \
+ -e "s/CFLAGS=.*$/CFLAGS=${CFLAGS}/" \
+ -e "/^EFLAGS/s:=:&${LDFLAGS} :" \
+ Makefile.settings || die "sed failed"
+}
+
+src_install() {
+ emake install install-etc install-doc install-dev DESTDIR="${D}" ||
+ die "install failed"
+
+ keepdir /var/lib/bitlbee
+ fperms 700 /var/lib/bitlbee
+ fowners bitlbee:bitlbee /var/lib/bitlbee
+
+ dodoc doc/{AUTHORS,CHANGES,CREDITS,FAQ,README}
+ dodoc doc/user-guide/user-guide.txt
+ dohtml -A xml doc/user-guide/*.xml
+ dohtml -A xsl doc/user-guide/*.xsl
+ dohtml doc/user-guide/*.html
+
+ doman doc/bitlbee.8 doc/bitlbee.conf.5
+
+ if use xinetd; then
+ insinto /etc/xinetd.d
+ newins doc/bitlbee.xinetd bitlbee
+ fi
+
+ newinitd "${FILESDIR}"/bitlbee.initd bitlbee || die
+ newconfd "${FILESDIR}"/bitlbee.confd bitlbee || die
+
+ keepdir /var/run/bitlbee
+ fowners bitlbee:bitlbee /var/run/bitlbee
+
+ dodir /usr/share/bitlbee
+ insinto /usr/share/bitlbee
+ cd utils
+ doins centericq2bitlbee.sh convert_gnomeicu.txt create_nicksfile.pl
+ doins bitlbee-ctl.pl
+}
+
+pkg_postinst() {
+ chown -R bitlbee:bitlbee "${ROOT}"/var/lib/bitlbee
+ chown -R bitlbee:bitlbee "${ROOT}"/var/run/bitlbee
+
+ elog "The utils included in bitlbee are now located in /usr/share/bitlbee"
+ elog
+ elog "NOTE: The IRSSI script is no longer provided by BitlBee."
+ elog
+ elog "The bitlbeed init script has been replaced by bitlbee."
+ elog "You must update your configuration."
+}
@@ -0,0 +1,2 @@
+#Bitlbee options (see /usr/sbin/bitlbee -h)
+BITLBEE_OPTS="-F"
@@ -0,0 +1,27 @@
+#!/sbin/runscript
+# Copyright 1999-2004 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License, v2 or
+# later
+# $Header: /var/cvsroot/gentoo-x86/net-im/bitlbee/files/bitlbee.initd,v 1.2 2010/03/04 17:47:00 cedk Exp $
+
+DAEMON=/usr/sbin/bitlbee
+PIDFILE=/var/run/bitlbee/bitlbee.pid
+
+depend() {
+ need logger net
+}
+
+start () {
+ ebegin "Starting bitlbee"
+ start-stop-daemon --start --quiet \
+ -c bitlbee:bitlbee --exec ${DAEMON} -- -P ${PIDFILE} \
+ ${BITLBEE_OPTS}
+ eend $?
+}
+
+stop() {
+ ebegin "Stopping bitlbee"
+ start-stop-daemon --stop --quiet --pidfile ${PIDFILE}
+ eend $?
+}
+
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <herd>no-herd</herd>
+ <maintainer>
+ <email>wired@gentoo.org</email>
+ </maintainer>
+ <use>
+ <flag name='nss'>Use NSS for SSL support in MSN and Jabber</flag>
+ <flag name='twitter'>Enabel Twitter protocol support</flag>
+ </use>
+ <longdescription>
+ Bitlbee as an IRC to IM gateway. It provides an irc server that allows
+ you to log on and then connect to various instant messaging protocols
+ (AIM, MSN, Yahoo, Jabber, etc).
+ </longdescription>
+</pkgmetadata>

0 comments on commit 9870fc3

Please sign in to comment.