Add Ubuntu backend with langpack support

source/backends/debian/debpkg.d

@@ -35,7 +35,7 @@ import utils : isRemote, downloadFile;
 
 class DebPackage : Package
 {
-private:
+protected:
     string pkgname;
     string pkgver;
     string pkgarch;
@@ -61,7 +61,7 @@ public:
     override
     @property string filename () const {
         if (debFname.isRemote) {
-            immutable path = buildPath (tmpDir, debFname.baseName);
+            immutable path = buildNormalizedPath (tmpDir, debFname.baseName);
             downloadFile (debFname, path);
             return path;
         }
@@ -121,6 +121,19 @@ public:
         return pa;
     }
 
+    protected void extractPackage (const string dest = buildPath (tmpDir, name))
+    {
+        import std.file : exists;
+        import std.regex : ctRegex;
+
+        if (!dest.exists)
+            mkdirRecurse (dest);
+
+        auto pa = openPayloadArchive ();
+
+        pa.extractArchive (dest);
+    }
+
     private auto openControlArchive ()
     {
         auto ca = new ArchiveDecompressor ();

source/backends/debian/debpkgindex.d

@@ -39,7 +39,7 @@ import utils : escapeXml, getFileContents, isRemote;
 class DebianPackageIndex : PackageIndex
 {
 
-private:
+protected:
     string rootDir;
     Package[][string] pkgCache;
     bool[string] indexChanged;
@@ -175,6 +175,11 @@ public:
         return downloadIfNecessary (rootDir, tmpDir, buildPath (path, "Packages.%s"));
     }
 
+    protected DebPackage newPackage (string name, string ver, string arch)
+    {
+        return new DebPackage (name, ver, arch);
+    }
+
     private DebPackage[] loadPackages (string suite, string section, string arch)
     {
         auto indexFname = getIndexFile (suite, section, arch);
@@ -195,7 +200,7 @@ public:
             if (!name)
                 continue;
 
-            auto pkg = new DebPackage (name, ver, arch);
+            auto pkg = newPackage (name, ver, arch);
             pkg.filename = buildPath (rootDir, fname);
             pkg.maintainer = tagf.readField ("Maintainer");
 

source/backends/interfaces.d

@@ -19,6 +19,9 @@
 
 module backends.interfaces;
 
+import appstream.Component;
+import glib.KeyFile;
+
 import std.string;
 import std.container;
 public import datastore;
@@ -33,6 +36,7 @@ abstract class Package
     @property string ver () const @safe pure;
     @property string arch () const @safe pure;
     @property string maintainer () const;
+    @property Package[] otherPackages;
 
     /**
      * A associative array containing package descriptions.
@@ -59,6 +63,11 @@ abstract class Package
      */
     abstract const(ubyte)[] getFileData (string fname);
 
+    /**
+     * Retrieve backend-specific translations.
+     */
+    string[string] getDesktopFileTranslations (KeyFile desktopFile, const string text) { return null; }
+
     /**
      * Close the package. This function is called when we will
      * no longer request any file data from this package.

source/backends/ubuntu/package.d

@@ -0,0 +1,23 @@
+/*
+ * Copyright (C) 2016 Matthias Klumpp <matthias@tenstral.net>
+ *
+ * Licensed under the GNU Lesser General Public License Version 3
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU Lesser General Public License as published by
+ * the Free Software Foundation, either version 3 of the license, or
+ * (at your option) any later version.
+ *
+ * This software is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public License
+ * along with this software.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+module backends.ubuntu;
+
+public import backends.ubuntu.ubupkg;
+public import backends.ubuntu.ubupkgindex;

source/backends/ubuntu/ubupkg.d

@@ -0,0 +1,191 @@
+/*
+ * Copyright (C) 2016 Canonical Ltd
+ * Author: Iain Lane <iain.lane@canonical.com>
+ *
+ * Licensed under the GNU Lesser General Public License Version 3
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU Lesser General Public License as published by
+ * the Free Software Foundation, either version 3 of the license, or
+ * (at your option) any later version.
+ *
+ * This software is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public License
+ * along with this software.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+module backends.ubuntu.ubupkg;
+
+import appstream.Component;
+
+import backends.debian.debpkg;
+import backends.interfaces;
+
+import glib.Internationalization;
+import glib.KeyFile;
+
+import std.container : Array;
+
+import logging;
+
+import utils : DESKTOP_GROUP;
+
+extern (C) char *bindtextdomain (const char *domainname, const char *dirName) nothrow @nogc;
+
+class UbuntuPackage : DebPackage
+{
+    this (string pname, string pver, string parch, string globalTmpDir, ref Array!Package allPackages)
+    {
+        this.globalTmpDir = globalTmpDir;
+        this.langpackDir = buildPath (globalTmpDir, "langpacks");
+        this.localeDir = buildPath (langpackDir, "locales");
+        this.allPackages = allPackages;
+        super (pname, pver, parch);
+    }
+
+    override string[string] getDesktopFileTranslations (KeyFile desktopFile, const string text)
+    {
+        string langpackdomain;
+
+        try {
+            langpackdomain = desktopFile.getString (DESKTOP_GROUP,
+                                                    "X-Ubuntu-Gettext-Domain");
+        } catch {
+            try {
+                langpackdomain = desktopFile.getString (DESKTOP_GROUP,
+                                                        "X-GNOME-Gettext-Domain");
+            } catch {
+                return null;
+            }
+        }
+
+        logDebug ("%s has langpack domain %s", name, langpackdomain);
+
+        synchronized {
+            extractLangpacks ();
+            return getTranslations (langpackdomain, text);
+        }
+    }
+
+private:
+    string globalTmpDir;
+    string langpackDir;
+    string localeDir;
+    string[] langpackLocales;
+    Array!Package allPackages;
+
+    private void extractLangpacks ()
+    {
+        import std.algorithm : filter, map;
+        import std.array : appender, array, split;
+        import std.file : dirEntries, exists, SpanMode, readText;
+        import std.parallelism : parallel;
+        import std.path : baseName;
+        import std.process : Pid, spawnProcess, wait;
+        import std.string : splitLines, startsWith;
+
+        auto path = buildPath (langpackDir, "usr", "share", "locale-langpack");
+
+        if (!langpackDir.exists) {
+            bool[string] extracted;
+
+            langpackDir.mkdirRecurse ();
+
+            foreach (pkg; allPackages) {
+                if (!pkg.name.startsWith ("language-pack") || pkg.name in extracted)
+                    continue;
+
+                UbuntuPackage upkg = to!UbuntuPackage (pkg);
+
+                logDebug ("Extracting %s", pkg.name);
+                upkg.extractPackage (langpackDir);
+
+                extracted[pkg.name] = true;
+            }
+
+            auto supportedd = buildPath (langpackDir, "var", "lib", "locales", "supported.d");
+
+            localeDir.mkdirRecurse ();
+
+            foreach (locale; parallel (supportedd.dirEntries (SpanMode.shallow), 5))
+            {
+                    foreach (ref line; locale.readText.splitLines) {
+                            auto components = line.split (" ");
+                            auto localecharset = components[0].split (".");
+
+                            auto outdir = buildPath (localeDir, components[0]);
+                            logDebug ("Generating locale in %s", outdir);
+
+                            auto pid = spawnProcess (["/usr/bin/localedef",
+                                                      "--no-archive",
+                                                      "-i",
+                                                      localecharset[0],
+                                                      "-c",
+                                                      "-f",
+                                                      components[1],
+                                                      outdir]);
+
+                            scope (exit) wait (pid);
+                    }
+            }
+
+        }
+
+        if (langpackLocales is null)
+            langpackLocales = localeDir.dirEntries (SpanMode.shallow)
+                .filter!(f => f.isDir)
+                .map!(f => f.name.baseName)
+                .array;
+    }
+
+    string[string] getTranslations (const string domain, const string text)
+    {
+        import core.stdc.locale;
+        import core.stdc.string : strdup;
+
+        import std.c.stdlib : getenv, setenv, unsetenv;
+        import std.string : fromStringz, toStringz;
+
+        char *[char *] env;
+
+        foreach (ref var; ["LC_ALL", "LANG", "LANGUAGE", "LC_MESSAGES"]) {
+            auto value = getenv (var.toStringz);
+            if (value !is null) {
+                env[var.toStringz] = getenv (var.toStringz).strdup;
+                unsetenv (var.toStringz);
+            }
+        }
+
+        scope (exit) {
+            foreach (key, val; env)
+                setenv (key, val, false);
+        }
+
+        setenv ("LOCPATH", localeDir.toStringz, true);
+
+        auto initialLocale = setlocale (LC_ALL, "");
+        scope(exit) setlocale (LC_ALL, initialLocale);
+
+        auto dir = buildPath (langpackDir,
+                              "usr",
+                              "share",
+                              "locale-langpack");
+
+        string[string] ret;
+
+        foreach (ref locale; langpackLocales) {
+            setlocale (LC_ALL, locale.toStringz);
+            bindtextdomain (domain.toStringz, dir.toStringz);
+            auto translatedtext = Internationalization.dgettext (domain, text);
+
+            if (text != translatedtext)
+                ret[locale] = translatedtext;
+        }
+
+        return ret;
+    }
+}

source/backends/ubuntu/ubupkgindex.d

@@ -0,0 +1,62 @@
+/*
+ * Copyright (C) 2016 Canonical Ltd
+ * Author: Iain Lane <iain.lane@canonical.com>
+ *
+ * Licensed under the GNU Lesser General Public License Version 3
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU Lesser General Public License as published by
+ * the Free Software Foundation, either version 3 of the license, or
+ * (at your option) any later version.
+ *
+ * This software is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public License
+ * along with this software.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+module backends.ubuntu.ubupkgindex;
+
+import backends.debian;
+import backends.interfaces;
+import backends.ubuntu.ubupkg;
+
+import std.container : Array, make;
+
+class UbuntuPackageIndex : DebianPackageIndex
+{
+
+public:
+    this (string dir)
+    {
+        /*
+         * UbuntuPackage needs to extract the langpacks, so we give it an array
+         * of all packages. We don't do this here, as you migh think makes
+         * sense, because it is a very expensive operation and we want to avoid
+         * doing it if it's not necessary (when no packages being processed are
+         * using langpacks).
+         */
+        allPackages = make!(Array!Package);
+        super (dir);
+    }
+
+    override DebPackage newPackage (string name, string ver, string arch)
+    {
+        return new UbuntuPackage (name, ver, arch, tmpDir, allPackages);
+    }
+
+    override Package[] packagesFor (string suite, string section, string arch)
+    {
+        auto pkgs = super.packagesFor (suite, section, arch);
+
+        allPackages ~= pkgs;
+
+        return pkgs;
+    }
+}
+
+private:
+    Array!Package allPackages;

source/config.d

@@ -65,6 +65,7 @@ enum Backend
     Unknown,
     Dummy,
     Debian,
+    Ubuntu,
     Archlinux,
     RpmMd
 }
@@ -276,6 +277,10 @@ class Config
                 this.backend = Backend.Debian;
                 this.metadataType = DataType.YAML;
                 break;
+            case "ubuntu":
+                this.backend = Backend.Ubuntu;
+                this.metadataType = DataType.YAML;
+                break;
             case "arch":
             case "archlinux":
                 this.backend = Backend.Archlinux;