% COMPILE WITH: synframe
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% This file contains the syntactic trees of our grammar    %
% and connects them to their frames. Individual slots of   %
% these frames will be filled with frames from the frame   %
% lexicon (frame_dimension.mg), according to the tokens    %
% that are being parsed.                                   %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

type MARK = {subst, nadj, anchor, coanchor, lex, foot}
type CAT = {n, np, v, vp, s, pp, p, d, det}
type LABEL !

property mark : MARK

% Syntactic Features
feature cat : CAT

% Interface Features
feature argsubject : LABEL
feature argobject : LABEL
feature argprep : LABEL

feature i : LABEL
feature e : LABEL

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% FRAME HIERARCHY                                          %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
frame-types = {event, causation, activity, translocation,
               entity, animate, person, name, animal, horse,
               physical_object, door, fence, stage, 
               laughing, dancing, jumping, pushing, feeding,
               actor, mover, undergoer, 
               path, landmark, trajectory}

frame-constraints = {
  % Subtype relations:
  door -> physical_object,
  fence -> physical_object,
  stage -> physical_object,

  horse -> animal,
  animal -> animate,
  person -> animate,
  actor -> animate,

  animate -> entity,
  % landmark -> entity,
  
  causation -> event,
  translocation -> event,
  activity -> event,

  laughing -> activity,
  jumping -> activity,
  dancing -> activity,
  feeding -> activity,
  pushing -> activity,

  % Attribute constraints:
  activity -> actor: +,
  person ->  name: +,

  % Incompatibilities between these subtypes:
  animate physical_object -> -,
  actor physical_object -> -,
  animal person -> -,
  event entity -> -,


  door fence -> -,
  door stage -> -,
  fence stage -> -,

  laughing jumping -> -,
  laughing dancing -> -,
  laughing feeding -> -,
  laughing pushing -> -,

  jumping dancing -> -,
  jumping feeding -> -,
  jumping pushing -> -,

  dancing feeding -> -,
  dancing pushing -> -,

  feeding pushing -> -
}


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% TREE FRAGMENTS:                                          %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

class Subject
export ?VP ?A
declare ?S ?VP ?SubjNP ?A
{
  <syn>{
    node ?S [cat=s] {
      node ?SubjNP (mark=subst) [cat=np, i=?A]
      node ?VP [cat=vp]
	  }
  };
  <iface>{
    [argsubject=?A]
  }
  % The argsubject feature in the interface dimension makes
  % the frame associated with the SubjNP available to trees
  % including this fragment. This is necessary in order to
  % compose larger frames in which this element is included
  % in different positions.
  % The frame for the SubjNP node is determined by whatever
  % tree substitutes to that node during derivation.
}

class VerbForm
export ?VP ?V ?F
declare ?VP ?V ?F ?X
{
  <syn> {
    node ?VP [cat=vp]{
		  node ?V (mark=anchor) [cat=v, e=?F]
	  }
  };
  <iface>{
    [e=?F, argsubject=?X]
  }
}

class propernoun
declare ?NP ?N ?X0
{
  <syn>{
    node ?NP [cat=np, i=?X0];
    node ?N (mark=anchor) [cat=n];
    ?NP -> ?N
  };
  <iface>{
    [i=?X0]
  }
}

class commonnoun
declare ?NP ?N ?X0
{
  <syn>{
    node ?NP [cat=np, i=?X0];
    node ?N (mark=anchor) [cat=n];
    ?NP -> ?N
  };
  <iface>{
    [i=?X0]
  }
}

class determiner
declare ?NP1 ?NP2 ?Det ?X0
{<syn>{
  node ?NP1 [cat=np, i=?X0];
  node ?Det (mark=anchor) [cat=det, i=?X0];  
  node ?NP2 (mark=foot) [cat=np, i=?X0];
  ?NP1 -> ?Det;
  ?NP1 -> ?NP2;
  ?Det >> ?NP2
  };
  <iface>{
    [i=?X0]
  }
}

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% TREE TEMPLATES:                                          %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

%%% Templates involving regular verbs %%%

class IntransitiveDiathesis
export ?VP ?V ?VPTree ?A ?F
declare ?VP ?V ?SubjTree ?VPTree ?A ?F
{
  <syn>{
    ?SubjTree = Subject[];
    ?VPTree = VerbForm[];
    ?VPTree.?F = ?F;
    ?SubjTree.?VP = ?VP;
    ?VPTree.?VP = ?VP;
    ?VPTree.?V = ?V;
    ?SubjTree.?A = ?A
  }
}

class RegularIntransitiveConstruction
import IntransitiveDiathesis[]
{
  <frame>{
    ?F[activity,
    actor:?A[animate]]
  }
}


class IntransitiveNondirectedVerbFamily
{
  RegularIntransitiveConstruction[] 
}

class IntransitiveVerbFamily
{
  IntransitiveNondirectedVerbFamily[] 
}



%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% EVALUATION: 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

value propernoun
value commonnoun
value determiner

value Subject
value VerbForm

value IntransitiveDiathesis
value RegularIntransitiveConstruction

value IntransitiveNondirectedVerbFamily
value IntransitiveVerbFamily