-
Notifications
You must be signed in to change notification settings - Fork 8
/
own elm2b.txt
814 lines (694 loc) · 29.7 KB
/
own elm2b.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
{$CLEO .cs}
{$NOSOURCE}
thread 'OWNELM2'
0000: NOP
const
LIGHT_FL = 0
LIGHT_FR = 1
LIGHT_BL = 2
LIGHT_BR = 3
end
:ELM
// makes rear lights controllable separately
0A8C: write_memory 0x6E1D4F size 1 value 2 vp 0
//temp = 33@
/*
0 = NO ACTION
1 = DAMAGE L&R //B
2 = REPAIR L
3 = REPAIR R
4 = REPAIR L&R //B
*/
/*
1 strobe 6@
2 strobe B
3 hazard > normal 6@+2
4 hazard > fast
5 hazard > fastest
6 full > half 6@+5
7 full > quarter
8 full > eigth
9 full > sixteenth
10 static > on 6@+9
11 static > off
*/
/*
1 strobe 7@
2 strobe B
3 strobe C
4 strobe D
5 full > half 7@+4
6 full > quarter
7 full > eigth
8 full > sixteenth
9 static > on 7@+8
10 static > off
*/
0006: 0@ = 1 //is menu interactive
0006: 10@ = 0 //current shown menu: 0=lights,1=pattern front,2=pattern rear,3=front hazard,4=front full,5=rear full,6=front static,7=rear static
0006: 20@ = 1 //menu 0 row
0006: 21@ = 1 //menu 1 row
0006: 22@ = 1 //menu 2 row
0006: 23@ = 1 //menu 3 row
0006: 24@ = 1 //menu 4 row
0006: 25@ = 1 //menu 5 row
0006: 26@ = 1 //menu 6 row
0006: 27@ = 1 //menu 7 row
0006: 2@ = 0 //to be destroyed/repaired
0006: 3@ = 0 //enabled
0006: 4@ = 0 //incar
0006: 5@ = 0 //current index
0006: 6@ = 1 //front pattern
0006: 7@ = 1 //rear pattern
0006: 8@ = 1 //car
0006: 9@ = 1 //struct
:OWNELM_START
wait 0
gosub @INCAR
if
0039: 4@ == 0 //incar
jf @OWNELM_MAIN
0006: 5@ = 0 //current index
if
0AB0: key_pressed 122
jf @OWNELM_START
jump @OWNELM_MENU_JUMPER
//############################################################################################################## MENU LOGIC
//=============================================== menu jumper
:OWNELM_MENU_JUMPER
//0AD1: show_formatted_text_highpriority "front is %d back is %d" time 2000 6@ 5@
0871: init_jump_table 10@ total_jumps 8 default_jump -1 @OWNELM_START jumps 0 @OWNELM_MENU_0 1 @OWNELM_MENU_1 2 @OWNELM_MENU_2 3 @OWNELM_MENU_3 4 @OWNELM_MENU_4 5 @OWNELM_MENU_5 6 @OWNELM_MENU_6
0872: jump_table_jumps 7 @OWNELM_MENU_7 -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START
//=============================================== menu loop
:OWNELM_MENU_LOOP_DELAY //begin loop hier, delay voor keydelay
wait 300
:OWNELM_MENU_LOOP
wait 0
if or
0AB0: key_pressed 37 // left arrow
0AB0: key_pressed 122 // F11
then
gosub @OWNELM_MENU_HIDE
jump @OWNELM_MENU_LOOP_EXIT
end
if or
0AB0: key_pressed 39 //right arrow
0AB0: key_pressed 32 //spacebar
jf @OWNELM_MENU_LOOP
//select item
:OWNELM_MENU_LOOP_1 //alleen gebruikt in jump table
gosub @OWNELM_MENU_CHOICE
gosub @OWNELM_MENU_HIDE
0871: init_jump_table 10@ total_jumps 8 default_jump -1 @OWNELM_START jumps 0 @OWNELM_MENU_01 1 @OWNELM_MENU_11 2 @OWNELM_MENU_21 3 @OWNELM_MENU_31 4 @OWNELM_MENU_41 5 @OWNELM_MENU_51 6 @OWNELM_MENU_61
0872: jump_table_jumps 7 @OWNELM_MENU_71 -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START
:OWNELM_MENU_LOOP_EXIT
if 0AB0: key_pressed 37 // left arrow (terug naar vorig menu)
jf @OWNELM_MENU_LOOP_EXIT_9 //exit menu
0871: init_jump_table 10@ total_jumps 8 default_jump -1 @OWNELM_START jumps 0 @OWNELM_START 1 @OWNELM_MENU_0 2 @OWNELM_MENU_0 3 @OWNELM_MENU_1 4 @OWNELM_MENU_1 5 @OWNELM_MENU_2 6 @OWNELM_MENU_1
0872: jump_table_jumps 7 @OWNELM_MENU_2 -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START
:OWNELM_MENU_LOOP_EXIT_9
wait 300
jump @OWNELM_START //exit menu
//=============================================== hide menus
:OWNELM_MENU_HIDE
0871: init_jump_table 10@ total_jumps 8 default_jump -1 @OWNELM_START jumps 0 @OWNELM_MENU_HIDE_0 1 @OWNELM_MENU_HIDE_1 2 @OWNELM_MENU_HIDE_2 3 @OWNELM_MENU_HIDE_3 4 @OWNELM_MENU_HIDE_4 5 @OWNELM_MENU_HIDE_5 6 @OWNELM_MENU_HIDE_6
0872: jump_table_jumps 7 @OWNELM_MENU_HIDE_7 -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START
:OWNELM_MENU_HIDE_0
08DA: remove_panel 11@
return
:OWNELM_MENU_HIDE_1
08DA: remove_panel 11@
08DA: remove_panel 13@
return
:OWNELM_MENU_HIDE_2
08DA: remove_panel 11@
08DA: remove_panel 14@
return
:OWNELM_MENU_HIDE_3
08DA: remove_panel 12@ //lights + front patterns
08DA: remove_panel 15@
return
:OWNELM_MENU_HIDE_4
08DA: remove_panel 12@ //lights + front patterns
08DA: remove_panel 16@
return
:OWNELM_MENU_HIDE_5
08DA: remove_panel 12@ //lights + rear patterns
08DA: remove_panel 17@
return
:OWNELM_MENU_HIDE_6
08DA: remove_panel 12@ //lights + front patterns
08DA: remove_panel 18@
return
:OWNELM_MENU_HIDE_7
08DA: remove_panel 12@ //lights + rear patterns
08DA: remove_panel 19@
return
//=============================================== get choice
:OWNELM_MENU_CHOICE
0871: init_jump_table 10@ total_jumps 8 default_jump -1 @OWNELM_START jumps 0 @OWNELM_MENU_CHOICE_0 1 @OWNELM_MENU_CHOICE_1 2 @OWNELM_MENU_CHOICE_2 3 @OWNELM_MENU_CHOICE_3 4 @OWNELM_MENU_CHOICE_4 5 @OWNELM_MENU_CHOICE_5 6 @OWNELM_MENU_CHOICE_6
0872: jump_table_jumps 7 @OWNELM_MENU_CHOICE_7 -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START -1 @OWNELM_START
:OWNELM_MENU_CHOICE_0
08D7: $choice = panel 11@ active_row
008B: 20@ = $choice // (int)
return
:OWNELM_MENU_CHOICE_1
08D7: $choice = panel 13@ active_row
008B: 21@ = $choice // (int)
return
:OWNELM_MENU_CHOICE_2
08D7: $choice = panel 14@ active_row
008B: 22@ = $choice // (int)
return
:OWNELM_MENU_CHOICE_3
08D7: $choice = panel 15@ active_row
008B: 23@ = $choice // (int)
return
:OWNELM_MENU_CHOICE_4
08D7: $choice = panel 16@ active_row
008B: 24@ = $choice // (int)
return
:OWNELM_MENU_CHOICE_5
08D7: $choice = panel 17@ active_row
008B: 25@ = $choice // (int)
return
:OWNELM_MENU_CHOICE_6
08D7: $choice = panel 18@ active_row
008B: 26@ = $choice // (int)
return
:OWNELM_MENU_CHOICE_7
08D7: $choice = panel 19@ active_row
008B: 27@ = $choice // (int)
return
//############################################################################################################## MENUS
//=============================================== menu 0: lights
:OWNELM_MENU_0 //lights
0006: 10@ = 0
gosub @OWNELM_SHOWMENU_0 //show menu
jump @OWNELM_MENU_LOOP_DELAY //menu loop
:OWNELM_MENU_01
if
0038: $choice == 1 //0 = empty, 1 = front, 2 = rear
jf @OWNELM_MENU_2
jump @OWNELM_MENU_1
//=============================================== menu 1: pattern front
:OWNELM_MENU_1 //patterns front
0006: 10@ = 1
06D1: v$EDITSTRING = "REM0I1"
06D1: v$EDITSTRINGVAL = "Front >"
gosub @OWNELM_SHOWMENU_1 //show menu
jump @OWNELM_MENU_LOOP_DELAY //menu loop
:OWNELM_MENU_11
0871: init_jump_table $choice total_jumps 3 default_jump -1 @OWNELM_MENU_12 jumps 3 @OWNELM_MENU_3 4 @OWNELM_MENU_4 5 @OWNELM_MENU_6 -1 @OWNELM_MENU_12 -1 @OWNELM_MENU_12 -1 @OWNELM_MENU_12 -1 @OWNELM_MENU_12
:OWNELM_MENU_12
0085: 6@ = 21@ // (int)
jump @OWNELM_START
//=============================================== menu 2: pattern rear
:OWNELM_MENU_2 //patterns rear
0006: 10@ = 2
06D1: v$EDITSTRING = "REM0I2"
06D1: v$EDITSTRINGVAL = "Rear >"
gosub @OWNELM_SHOWMENU_2 //show menu
jump @OWNELM_MENU_LOOP_DELAY //menu loop
:OWNELM_MENU_21
0871: init_jump_table $choice total_jumps 2 default_jump -1 @OWNELM_MENU_22 jumps 5 @OWNELM_MENU_5 6 @OWNELM_MENU_7 -1 @OWNELM_MENU_22 -1 @OWNELM_MENU_22 -1 @OWNELM_MENU_22 -1 @OWNELM_MENU_12 -1 @OWNELM_MENU_12
:OWNELM_MENU_22
0085: 7@ = 22@ // (int)
jump @OWNELM_START
//=============================================== menu 3: front hazard
:OWNELM_MENU_3 //front hazard
0006: 10@ = 3
06D1: v$EDITSTRING = "REM1I3"
06D1: v$EDITSTRINGVAL = "Hazard >"
gosub @OWNELM_SHOWMENU_3 //show menu
jump @OWNELM_MENU_LOOP_DELAY //menu loop
:OWNELM_MENU_31
0006: 6@ = 2
005A: 6@ += 23@ // (int)
jump @OWNELM_START
//=============================================== menu 4: front full
:OWNELM_MENU_4 //front full
0006: 10@ = 4
06D1: v$EDITSTRING = "REM1I4"
06D1: v$EDITSTRINGVAL = "Full >"
gosub @OWNELM_SHOWMENU_4 //show menu
jump @OWNELM_MENU_LOOP_DELAY //menu loop
:OWNELM_MENU_41
0006: 6@ = 5
005A: 6@ += 24@ // (int)
jump @OWNELM_START
//=============================================== menu 5: rear full
:OWNELM_MENU_5 //rear full
0006: 10@ = 5
06D1: v$EDITSTRING = "REM2I5"
06D1: v$EDITSTRINGVAL = "Full >"
gosub @OWNELM_SHOWMENU_5 //show menu
jump @OWNELM_MENU_LOOP_DELAY //menu loop
:OWNELM_MENU_51
0006: 7@ = 4
005A: 7@ += 25@ // (int)
jump @OWNELM_START
//=============================================== menu 6: front static
:OWNELM_MENU_6 //rear full
0006: 10@ = 6
06D1: v$EDITSTRING = "REM1I5"
06D1: v$EDITSTRINGVAL = "Static >"
gosub @OWNELM_SHOWMENU_6 //show menu
jump @OWNELM_MENU_LOOP_DELAY //menu loop
:OWNELM_MENU_61
0006: 6@ = 9
005A: 6@ += 26@ // (int)
jump @OWNELM_START
//=============================================== menu 7: rear static
:OWNELM_MENU_7 //rear full
0006: 10@ = 7
06D1: v$EDITSTRING = "REM2I6"
06D1: v$EDITSTRINGVAL = "Static >"
gosub @OWNELM_SHOWMENU_7 //show menu
jump @OWNELM_MENU_LOOP_DELAY //menu loop
:OWNELM_MENU_71
0006: 7@ = 8
005A: 7@ += 27@ // (int)
jump @OWNELM_START
//############################################################################################################## SHOW MENUS
//=============================================== show menu 0 (lights)
:OWNELM_SHOWMENU_0
08D4: 11@ = create_panel_with_title 'DUMMY' position 30.0 120.0 width 155.0 columns 1 interactive 0@ background 1 alignment 1
if
0039: 10@ == 1
jf @OWNELM_SHOWMENU_02
08DB: set_panel 11@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1A' 'REM0I2' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
jump @OWNELM_SHOWMENU_04
:OWNELM_SHOWMENU_02
if
0039: 10@ == 2
jf @OWNELM_SHOWMENU_03
08DB: set_panel 11@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1' 'REM0I2A' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
jump @OWNELM_SHOWMENU_04
:OWNELM_SHOWMENU_03
08DB: set_panel 11@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1' 'REM0I2' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
:OWNELM_SHOWMENU_04
if
0039: 0@ == 1
jf @OWNELM_SHOWMENU_01
08D9: set_panel 11@ row 0 enable 0
08D9: set_panel 11@ row 3 enable 0
08D9: set_panel 11@ row 4 enable 0
08D9: set_panel 11@ row 5 enable 0
08D9: set_panel 11@ row 6 enable 0
090E: set_panel 11@ active_row 20@
:OWNELM_SHOWMENU_01
return
//=============================================== show menu 0 (lights) ### ALT1 (front) ###
:OWNELM_SHOWMENU_0_ALT1
08D4: 12@ = create_panel_with_title 'DUMMY' position 30.0 120.0 width 175.0 columns 2 interactive 0 background 1 alignment 1
if
0039: 10@ == 3
jf @OWNELM_SHOWMENU_0_ALT1_01
08DB: set_panel 12@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1A' 'REM0I2' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
08DB: set_panel 12@ column 1 header 'REM1T' data 'DUMMY' 'REM1I1' 'REM1I2' 'REM1I3A' 'REM1I4' 'REM1I5' 'REM1I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
return
:OWNELM_SHOWMENU_0_ALT1_01
if
0039: 10@ == 4
jf @OWNELM_SHOWMENU_0_ALT1_02
08DB: set_panel 12@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1A' 'REM0I2' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
08DB: set_panel 12@ column 1 header 'REM1T' data 'DUMMY' 'REM1I1' 'REM1I2' 'REM1I3' 'REM1I4A' 'REM1I5' 'REM1I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
return
:OWNELM_SHOWMENU_0_ALT1_02
if
0039: 10@ == 6
jf @OWNELM_SHOWMENU_0_ALT1_03
08DB: set_panel 12@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1A' 'REM0I2' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
08DB: set_panel 12@ column 1 header 'REM1T' data 'DUMMY' 'REM1I1' 'REM1I2' 'REM1I3' 'REM1I4' 'REM1I5A' 'REM1I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
return
:OWNELM_SHOWMENU_0_ALT1_03
08DB: set_panel 12@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1A' 'REM0I2' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
08DB: set_panel 12@ column 1 header 'REM1T' data 'DUMMY' 'REM1I1' 'REM1I2' 'REM1I3' 'REM1I4' 'REM1I5' 'REM1I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
return
//=============================================== show menu 0 (lights) ### ALT2 (rear) ###
:OWNELM_SHOWMENU_0_ALT2
08D4: 12@ = create_panel_with_title 'DUMMY' position 30.0 120.0 width 175.0 columns 2 interactive 0 background 1 alignment 1
if
0039: 10@ == 7
jf @OWNELM_SHOWMENU_0_ALT2_01
08DB: set_panel 12@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1' 'REM0I2A' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
08DB: set_panel 12@ column 1 header 'REM2T' data 'DUMMY' 'REM2I1' 'REM2I2' 'REM2I3' 'REM2I4' 'REM2I5' 'REM2I6A' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
return
:OWNELM_SHOWMENU_0_ALT2_01
if
0039: 10@ == 5
jf @OWNELM_SHOWMENU_0_ALT2_02
08DB: set_panel 12@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1' 'REM0I2A' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
08DB: set_panel 12@ column 1 header 'REM2T' data 'DUMMY' 'REM2I1' 'REM2I2' 'REM2I3' 'REM2I4' 'REM2I5A' 'REM2I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
return
:OWNELM_SHOWMENU_0_ALT2_02
08DB: set_panel 12@ column 0 header 'REM0T' data 'DUMMY' 'REM0I1' 'REM0I2' 'DUMMY' 'REM0I4' 'REM0I5' 'REM0I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
08DB: set_panel 12@ column 1 header 'REM2T' data 'DUMMY' 'REM2I1' 'REM2I2' 'REM2I3' 'REM2I4' 'REM2I5' 'REM2I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
return
//=============================================== show menu 1 (front patterns)
:OWNELM_SHOWMENU_1
08D4: 13@ = create_panel_with_title 'DUMMY' position 204.5 120.0 width 175.0 columns 1 interactive 0@ background 1 alignment 1
08DB: set_panel 13@ column 0 header 'REM1T' data 'DUMMY' 'REM1I1' 'REM1I2' 'REM1I3' 'REM1I4' 'REM1I5' 'REM1I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
if
0039: 0@ == 1
jf @OWNELM_SHOWMENU_11
08D9: set_panel 13@ row 0 enable 0
08D9: set_panel 13@ row 6 enable 0
090E: set_panel 13@ active_row 21@
//show prev menus (max 1)
0085: 33@ = 0@ // (int)
0006: 0@ = 0
gosub @OWNELM_SHOWMENU_0
0085: 0@ = 33@ // (int)
:OWNELM_SHOWMENU_11
return
//=============================================== show menu 2 (rear patterns)
:OWNELM_SHOWMENU_2
08D4: 14@ = create_panel_with_title 'DUMMY' position 204.5 120.0 width 175.0 columns 1 interactive 0@ background 1 alignment 1
08DB: set_panel 14@ column 0 header 'REM2T' data 'DUMMY' 'REM2I1' 'REM2I2' 'REM2I3' 'REM2I4' 'REM2I5' 'REM2I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
if
0039: 0@ == 1
jf @OWNELM_SHOWMENU_21
08D9: set_panel 14@ row 0 enable 0
090E: set_panel 14@ active_row 22@
//show prev menus (max 1)
0085: 33@ = 0@ // (int)
0006: 0@ = 0
gosub @OWNELM_SHOWMENU_0 //lights
0085: 0@ = 33@ // (int)
:OWNELM_SHOWMENU_21
return
//=============================================== show menu 3 (front hazard)
:OWNELM_SHOWMENU_3
08D4: 15@ = create_panel_with_title 'DUMMY' position 398.5 120.0 width 175.0 columns 1 interactive 0@ background 1 alignment 1
08DB: set_panel 15@ column 0 header 'REM3T' data 'DUMMY' 'REM3I1' 'REM3I2' 'REM3I3' 'DUMMY' 'DUMMY' 'REM3I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
if
0039: 0@ == 1
jf @OWNELM_SHOWMENU_31
08D9: set_panel 15@ row 0 enable 0
08D9: set_panel 15@ row 6 enable 0
090E: set_panel 15@ active_row 23@
//show prev menus (max 1)
0085: 33@ = 0@ // (int)
0006: 0@ = 0
gosub @OWNELM_SHOWMENU_0_ALT1 //lights + front patterns
0085: 0@ = 33@ // (int)
return
:OWNELM_SHOWMENU_31
return
//=============================================== show menu 4 (front full)
:OWNELM_SHOWMENU_4
08D4: 16@ = create_panel_with_title 'DUMMY' position 398.5 120.0 width 175.0 columns 1 interactive 0@ background 1 alignment 1
08DB: set_panel 16@ column 0 header 'REM4T' data 'DUMMY' 'REM4I1' 'REM4I2' 'REM4I3' 'REM4I4' 'REM4I5' 'REM4I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
if
0039: 0@ == 1
jf @OWNELM_SHOWMENU_41
08D9: set_panel 16@ row 0 enable 0
08D9: set_panel 16@ row 5 enable 0
08D9: set_panel 16@ row 6 enable 0
090E: set_panel 16@ active_row 24@
//show prev menus (max 1)
0085: 33@ = 0@ // (int)
0006: 0@ = 0
gosub @OWNELM_SHOWMENU_0_ALT1 //lights + front patterns
0085: 0@ = 33@ // (int)
:OWNELM_SHOWMENU_41
return
//=============================================== show menu 5 (rear full)
:OWNELM_SHOWMENU_5
08D4: 17@ = create_panel_with_title 'DUMMY' position 398.5 120.0 width 175.0 columns 1 interactive 0@ background 1 alignment 1
08DB: set_panel 17@ column 0 header 'REM5T' data 'DUMMY' 'REM5I1' 'REM5I2' 'REM5I3' 'REM5I4' 'DUMMY' 'REM5I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
if
0039: 0@ == 1
jf @OWNELM_SHOWMENU_51
08D9: set_panel 17@ row 0 enable 0
08D9: set_panel 17@ row 6 enable 0
090E: set_panel 17@ active_row 25@
//show prev menus (max 1)
0085: 33@ = 0@ // (int)
0006: 0@ = 0
gosub @OWNELM_SHOWMENU_0_ALT2 //lights + rear patterns
0085: 0@ = 33@ // (int)
:OWNELM_SHOWMENU_51
return
//=============================================== show menu 6 (front static)
:OWNELM_SHOWMENU_6
08D4: 18@ = create_panel_with_title 'DUMMY' position 398.5 120.0 width 175.0 columns 1 interactive 0@ background 1 alignment 1
08DB: set_panel 18@ column 0 header 'REM6T' data 'DUMMY' 'REM6I1' 'REM6I2' 'DUMMY' 'DUMMY' 'DUMMY' 'REM6I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
if
0039: 0@ == 1
jf @OWNELM_SHOWMENU_61
08D9: set_panel 18@ row 0 enable 0
08D9: set_panel 18@ row 6 enable 0
090E: set_panel 18@ active_row 26@
//show prev menus (max 1)
0085: 33@ = 0@ // (int)
0006: 0@ = 0
gosub @OWNELM_SHOWMENU_0_ALT1 //lights + front patterns
0085: 0@ = 33@ // (int)
:OWNELM_SHOWMENU_61
return
//=============================================== show menu 7 (rear static)
:OWNELM_SHOWMENU_7
08D4: 19@ = create_panel_with_title 'DUMMY' position 398.5 120.0 width 175.0 columns 1 interactive 0@ background 1 alignment 1
08DB: set_panel 19@ column 0 header 'REM7T' data 'DUMMY' 'REM7I1' 'REM7I2' 'DUMMY' 'DUMMY' 'DUMMY' 'REM7I6' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
if
0039: 0@ == 1
jf @OWNELM_SHOWMENU_71
08D9: set_panel 19@ row 0 enable 0
08D9: set_panel 19@ row 6 enable 0
090E: set_panel 19@ active_row 27@
//show prev menus (max 1)
0085: 33@ = 0@ // (int)
0006: 0@ = 0
gosub @OWNELM_SHOWMENU_0_ALT2 //lights + rear patterns
0085: 0@ = 33@ // (int)
:OWNELM_SHOWMENU_71
return
//############################################################################################################## MAIN
//=============================================== dim
:OWNELM_DIM
0006: 3@ = 0 //enabled
00BC: show_text_highpriority GXT 'ELS0' time 250 flag 1
wait 250
gosub @ALL_OFF
jump @OWNELM_START
//=============================================== toggle
:OWNELM_TOGGLE
000A: 3@ += 1 //enabled
018C: play_sound 1052 at 0.0 0.0 0.0
if
0019: 3@ > 1 //enabled
jf @OWNELM_TOGGLE_1
0006: 3@ = 0 //enabled
00BC: show_text_highpriority GXT 'ELS0' time 250 flag 1
wait 250
gosub @ALL_ON
jump @OWNELM_START
:OWNELM_TOGGLE_1
00BC: show_text_highpriority GXT 'ELS1' time 250 flag 1
wait 250
jump @OWNELM_START
//=============================================== main jumps (lights on)
:OWNELM_MAIN_MENU
gosub @ALL_ON
jump @OWNELM_MENU_JUMPER
:OWNELM_MAIN_TOGGLE
gosub @ALL_ON
jump @OWNELM_TOGGLE
//=============================================== main
:OWNELM_MAIN
if
8AB0: not key_pressed 122
jf @OWNELM_MAIN_MENU
if
8AB0: not key_pressed 123
jf @OWNELM_MAIN_TOGGLE
if
8AB0: not key_pressed 121
jf @OWNELM_DIM
if
0039: 3@ == 1 //enabled
jf @OWNELM_START
067F: force_car_lights 8@ to 2
//patterns start
:PAT_START
0871: init_jump_table 6@ total_jumps 11 default_jump -1 @PAT_START_REAR jumps 1 @PAT_F_STROBE_A 2 @PAT_F_STROBE_B 3 @PAT_F_HAZARD_NORMAL 4 @PAT_F_HAZARD_FAST 5 @PAT_F_HAZARD_FASTEST 6 @PAT_F_FULL_HALF 7 @PAT_F_FULL_QUARTER
0872: jump_table_jumps 8 @PAT_F_FULL_EIGTH 9 @PAT_F_FULL_SIXTEENTH 10 @PAT_F_STATIC_ON 11 @PAT_F_STATIC_OFF -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_START_REAR
0871: init_jump_table 7@ total_jumps 10 default_jump -1 @PAT_END jumps 1 @PAT_R_STROBE_A 2 @PAT_R_STROBE_B 3 @PAT_R_STROBE_C 4 @PAT_R_STROBE_D 5 @PAT_R_FULL_HALF 6 @PAT_R_FULL_QUARTER 7 @PAT_R_FULL_EIGTH
0872: jump_table_jumps 8 @PAT_R_FULL_SIXTEENTH 9 @PAT_R_STATIC_ON 10 @PAT_R_STATIC_OFF -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END
//pattern end
:PAT_END
000A: 5@ += 1 //index
if
0019: 5@ > 23
jf @PAT_END_1
0006: 5@ = 0 //index
:PAT_END_1
wait 75
jump @OWNELM_START
//############################################################################################################## PATTERNS
//=============================================== FRONT
:PAT_F_STROBE_A
0871: init_jump_table 5@ total_jumps 16 default_jump -1 @PAT_START_REAR jumps 0 @F_L 1 @F_ 2 @F_L 3 @F_ 6 @F_R 7 @F_ 8 @F_R
0872: jump_table_jumps 9 @F_ 12 @F_L 13 @F_ 14 @F_L 15 @F_ 18 @F_R 19 @F_ 20 @F_R 21 @F_
:PAT_F_STROBE_B
0871: init_jump_table 5@ total_jumps 16 default_jump -1 @PAT_START_REAR jumps 0 @F_LR 1 @F_ 2 @F_LR 3 @F_ 6 @F_LR 7 @F_ 8 @F_LR
0872: jump_table_jumps 9 @F_ 12 @F_LR 13 @F_ 14 @F_LR 15 @F_ 18 @F_LR 19 @F_ 20 @F_LR 21 @F_
:PAT_F_HAZARD_NORMAL
0871: init_jump_table 5@ total_jumps 4 default_jump -1 @PAT_START_REAR jumps 0 @F_L 6 @F_R 12 @F_L 18 @F_R -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_F_HAZARD_FAST
0871: init_jump_table 5@ total_jumps 8 default_jump -1 @PAT_START_REAR jumps 0 @F_L 3 @F_R 6 @F_L 9 @F_R 12 @F_L 15 @F_R 18 @F_L
0872: jump_table_jumps 21 @F_R -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_F_HAZARD_FASTEST
0871: init_jump_table 5@ total_jumps 12 default_jump -1 @PAT_START_REAR jumps 0 @F_L 2 @F_R 4 @F_L 6 @F_R 8 @F_L 10 @F_R 12 @F_L
0872: jump_table_jumps 14 @F_R 16 @F_L 18 @F_R 20 @F_L 22 @F_R -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_F_FULL_HALF
0871: init_jump_table 5@ total_jumps 3 default_jump -1 @PAT_START_REAR jumps 0 @F_ 6 @F_LR 18 @F_ -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_F_FULL_QUARTER
0871: init_jump_table 5@ total_jumps 5 default_jump -1 @PAT_START_REAR jumps 0 @F_LR 3 @F_ 9 @F_LR 15 @F_ 21 @F_LR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_F_FULL_EIGTH
0871: init_jump_table 5@ total_jumps 8 default_jump -1 @PAT_START_REAR jumps 0 @F_LR 3 @F_ 6 @F_LR 9 @F_ 12 @F_LR 15 @F_ 18 @F_LR
0872: jump_table_jumps 21 @F_ -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_F_FULL_SIXTEENTH
0871: init_jump_table 5@ total_jumps 12 default_jump -1 @PAT_START_REAR jumps 0 @F_LR 2 @F_ 4 @F_LR 6 @F_ 8 @F_LR 10 @F_ 12 @F_LR
0872: jump_table_jumps 14 @F_ 16 @F_LR 18 @F_ 20 @F_LR 22 @F_ -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_F_STATIC_ON
0871: init_jump_table 5@ total_jumps 2 default_jump -1 @PAT_START_REAR jumps 0 @F_LR 12 @F_LR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
:PAT_F_STATIC_OFF
0871: init_jump_table 5@ total_jumps 2 default_jump -1 @PAT_START_REAR jumps 0 @F_ 12 @F_ -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR -1 @PAT_START_REAR
//=============================================== REAR
:PAT_R_STROBE_A
0871: init_jump_table 5@ total_jumps 16 default_jump -1 @PAT_END jumps 0 @B_L 1 @B_ 2 @B_L 3 @B_ 6 @B_R 7 @B_ 8 @B_R
0872: jump_table_jumps 9 @B_ 12 @B_L 13 @B_ 14 @B_L 15 @B_ 18 @B_R 19 @B_ 20 @B_R 21 @B_
:PAT_R_STROBE_B
0871: init_jump_table 5@ total_jumps 16 default_jump -1 @PAT_END jumps 0 @B_LR 1 @B_ 2 @B_LR 3 @B_ 6 @B_LR 7 @B_ 8 @B_LR
0872: jump_table_jumps 9 @B_ 12 @B_LR 13 @B_ 14 @B_LR 15 @B_ 18 @B_LR 19 @B_ 20 @B_LR 21 @B_
:PAT_R_STROBE_C
0871: init_jump_table 5@ total_jumps 16 default_jump -1 @PAT_END jumps 0 @B_L 1 @B_LR 2 @B_L 3 @B_LR 6 @B_R 7 @B_LR 8 @B_R
0872: jump_table_jumps 9 @B_LR 12 @B_L 13 @B_LR 14 @B_L 15 @B_LR 18 @B_R 19 @B_LR 20 @B_R 21 @B_LR
:PAT_R_STROBE_D
0871: init_jump_table 5@ total_jumps 8 default_jump -1 @PAT_END jumps 0 @B_ 3 @B_LR 6 @B_ 9 @B_LR 12 @B_ 15 @B_LR 18 @B_
0872: jump_table_jumps 21 @B_LR -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END
:PAT_R_FULL_HALF
0871: init_jump_table 5@ total_jumps 3 default_jump -1 @PAT_END jumps 0 @B_ 6 @B_LR 18 @B_ -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END
:PAT_R_FULL_QUARTER
0871: init_jump_table 5@ total_jumps 5 default_jump -1 @PAT_END jumps 0 @B_ 3 @B_LR 9 @B_ 15 @B_LR 21 @B_ -1 @PAT_END -1 @PAT_END
:PAT_R_FULL_EIGTH
0871: init_jump_table 5@ total_jumps 8 default_jump -1 @PAT_END jumps 0 @B_ 3 @B_LR 6 @B_ 9 @B_LR 12 @B_ 15 @B_LR 18 @B_
0872: jump_table_jumps 21 @B_LR -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END
:PAT_R_FULL_SIXTEENTH
0871: init_jump_table 5@ total_jumps 12 default_jump -1 @PAT_END jumps 0 @B_ 2 @B_LR 4 @B_ 6 @B_LR 8 @B_ 10 @B_LR 12 @B_
0872: jump_table_jumps 14 @B_LR 16 @B_ 18 @B_LR 20 @B_ 22 @B_LR -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END
:PAT_R_STATIC_ON
0871: init_jump_table 5@ total_jumps 2 default_jump -1 @PAT_END jumps 0 @B_LR 12 @B_LR -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END
:PAT_R_STATIC_OFF
0871: init_jump_table 5@ total_jumps 2 default_jump -1 @PAT_END jumps 0 @B_ 12 @B_ -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END -1 @PAT_END
//############################################################################################################## LIGHT CONTROL
//=============================================== FRONT
:F_L
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light LIGHT_FL
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_FR
jump @PAT_START_REAR
:F_R
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_FL
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light LIGHT_FR
jump @PAT_START_REAR
:F_LR
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_FL
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_FR
jump @PAT_START_REAR
:F_
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_FL
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_FR
jump @PAT_START_REAR
:B_L
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_BL
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light LIGHT_BR
jump @PAT_END
:B_R
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light LIGHT_BL
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_BR
jump @PAT_END
:B_LR
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light LIGHT_BL
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light LIGHT_BR
jump @PAT_END
:B_
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_BL
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light LIGHT_BR
jump @PAT_END
//=============================================== turn lights on
//0006: 2@ = 0 //to be destroyed/repaired
:ALL_ON
0006: 2@ = -1
gosub @REPAIR
067F: force_car_lights 8@ to 2
/*
067f:
param 2:
0 = NO_CAR_LIGHT_OVERRIDE
1 = FORCE_CAR_LIGHTS_OFF
2 = FORCE_CAR_LIGHTS_ON
*/
return
//=============================================== turn lights off
//0006: 2@ = 0 //to be destroyed/repaired
:ALL_OFF
0006: 2@ = -1
gosub @DESTROY
067F: force_car_lights 8@ to 1
return
//=============================================== repair
//0006: 2@ = 0 //to be destroyed/repaired
:REPAIR
if
0029: 2@ >= 0
jf @REPAIR_1
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light 2@
067F: force_car_lights 8@ to 2
return
:REPAIR_1
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light 0
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light 1
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light 2
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 0 light 3
067F: set_car 8@ lights 2
return
//=============================================== destroy
//0006: 2@ = 0 //to be destroyed/repaired
:DESTROY
if
0029: 2@ >= 0
jf @DESTROY_1
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light 2@
return
:DESTROY_1
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light 0
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light 1
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light 2
0AA6: call_method 0x6C2100 struct 9@ num_params 2 pop flag 0 destroyed 1 light 3
return
//=============================================== car
:INCAR
0006: 4@ = 0 //incar
00D6: if and
00DF: actor $PLAYER_ACTOR driving
84C8: not actor $PLAYER_ACTOR driving_flying_vehicle
84A9: not actor $PLAYER_ACTOR driving_heli
84A7: not actor $PLAYER_ACTOR driving_boat
847A: not actor $PLAYER_ACTOR driving_bike
jf @INCAR_1
//00D9: 8@ = actor $PLAYER_ACTOR car CRASH
8@ = Actor.CurrentCar($PLAYER_ACTOR)
046C: 33@ = car 8@ driver //33@ = temp
if
003A: $PLAYER_ACTOR == 33@ // (int)
jf @INCAR_1
0006: 4@ = 1 //incar
0A97: 9@ = car 8@ pointer
000A: 9@ += 0x5A0
:INCAR_1
return