**Часть 1 – Модель рабочего колеса**

Двухмерная осесимметричная модель конструкции состоит из трех частей: перо лопатки (мелкая штриховка), замковое соединение диска с лопаткой (крупная штриховка) и диск (без штриховки) – рисунок 1. В работе предполагается, что перо лопатки уже спрофилировано. Замковое соединение не рассматривается.

该结构的二维轴对称模型由三部分组成：叶片（细阴影）、圆盘与叶片的锁定连接（粗阴影）和圆盘（无阴影）--图 1。本文假定叶片羽翼已经成型。不考虑锁紧连接。

Для каждого из вариантов даны следующие исходные геометрические параметры: радиус начала проточной части – *R*\*airfoil, радиус ступицы диска – *R*\*hub, радиус периферийного сечения лопатки – *R*\*blade, толщина замкового соединения – *H*\*interlock, усредненная толщина одной лопатки – *H*\*blade, число лопаток – *n*\*blade. Задаются нагрузки: частота вращения – *w* и температуры *T*1, *T*2, *T*3, *T*4 в соответствующих им сечениях на радиусах *R*\*hub, *R*rim, *R*\*airfoil, *R*\*blade. Задаются механические характеристики материалов диска и лопатки: модули упругости *E*, коэффициенты Пуассона m, коэффициенты линейного термического расширения α, плотности r.

每个变体的初始几何参数如下：流动部分的起始半径 - R\*气叶，盘毂半 径 - R\*盘毂，叶片外围半径 - R\*叶片，锁节厚度 - H\*锁节，一个叶片的平均厚度 - H\*叶片，叶片数 - n\*叶片。载荷设定为：转速 - w，半径 R\*hub, Rrim, R\*airfoil, R\*blade 处相应部分的温度 T1, T2, T3, T4。设置了圆盘和叶片材料的机械特性：弹性模量 E、泊松比系数 m、线性热膨胀系数 α、密度 r。

Варьируемыми параметрами являются: *L*interlock, *X*1, *X*2, *X*3, *X*4, *Y*2, *Y*3, *Y*4, *R*1, *R*2, *R*3, *R*4, *R*5. Ограничение – не превышение в диске эквивалентного напряжения по Мизесу заданного предела пропорциональности материала σПЦ. Цель – минимизация массы диска.

可变参数为 间隙锁、X1、X2、X3、X4、Y2、Y3、Y4、R1、R2、R3、R4、R5。限制条件是圆盘中的米塞斯等效应力不超过给定的材料比例限制 σPC。目的是使圆盘的质量最小。

**В предыдущем семестре были получены коэффициенты для оптимальной конструкции. Необходимо использовать их.**

**优化设计的系数已在上学期获得。有必要使用它们。**

**Задание:**

**1) Построить матрицу коэффициентов корреляции параметров: w, T1, T2, T3, T4, Smax.**

**2) Построить плотность распределения Smax из условия, что параметры w, T1, T2, T3, T4 могут меняться «вниз» и «вверх» на 5%.**

**3) Найти значения Smax, соответствующие доверительному интервалу 99%.**

**任务**

**1) 构建参数相关系数矩阵：w、T1、T2、T3、T4、Smax。**

**2) 在参数 w、T1、T2、T3、T4 可以 "下降 "和 "上升 "5% 的条件下，构建分布密度 Smax。**

**3) 找出与 99% 置信区间相对应的 Smax 值。**

|  |
| --- |
|  |
| Рисунок 1 – Модельное рабочее колесо |

|  |
| --- |
|  |
| Рисунок 2 – Граничные условия |

**Полный код для оптимальной конструкции (в примере) приведен ниже (красным цветом выделены строки для тех, у кого студенческая версия Ansys):**

**优化设计（示例中）的完整代码如下所示（使用学生版 Ansys 的行用红色标出）：**

!ПОСТРОЕНИЕ 2-D МОДЕЛИ ДИСКА

/PREP7

/REP,FAST

/ANG,1,30,ZS,1

/REP,FAST

/ANG,1,30,ZS,1

/REP,FAST

/ANG,1,30,ZS,1

/REP,FAST

/ANG,1,-30,YS,1

/REP,FAST

/ANG,1,-30,YS,1

/REP,FAST

/ANG,1,-30,YS,1

/REP,FAST

/ANG,1,-30,YS,1

/REP,FAST

/ANG,1,-30,YS,1

/REP,FAST

/ANG,1,-30,YS,1

/REP,FAST

!!!!!!ИСХОДНЫЕ ДАННЫЕ, ЗАДАЮТСЯ ПОЛЬЗОВАТЕЛЕМ

R\_AIRFOIL=210

R\_HUB=40

R\_BLADE=240

H\_INTERLOCK=30

H\_BLADE=2

n\_blade=72

! Частота вращения, рад/с

w=900

!Температуры конструкции

T1=350 !! Температура в ступице диска

T2=650 !! Температура в ободе диска

T3=750 !! Температура в начале проточной части лопатки

T4=900 !! Температура в периферии лопатки

!!!4. Модули упругости при исследуемых температурах, МПа

E\_1\_T1=200000

E\_1\_T4=180000

E\_2\_T1=150000

E\_2\_T4=120000

!!!5. Коэффициенты Пуассона при исследуемых температурах

MU\_1\_T1=0.3

MU\_1\_T4=0.3

MU\_2\_T1=0.3

MU\_2\_T4=0.3

!!!6. Коэффициенты линейного термического расширения

ALPH\_1\_T1=10e-6

ALPH\_1\_T4=12e-6

ALPH\_2\_T1=10e-6

ALPH\_2\_T4=12e-6

!!!7. Плотность материала

po\_1=8.3e-9

po\_2=8.7e-9

!!!8. Предел пропорциональности, МПа

Sigm\_pc\_1=700

K\_INTERLOCK=0.1

K\_X1=0.062223

K\_X2=0.011

K\_X3=0.499

K\_X4=0.4546

K\_Y2=0.79858

K\_Y3=0.10798

K\_Y4=0.12126

K\_R1=0.54815

K\_R2=0.58489

K\_R3=0.4

K\_R4=0.4

K\_R5=0.4

csys, 0 ! Работаем в декартовой системе координат

L\_INTERLOCK=(R\_AIRFOIL-R\_HUB)\*K\_INTERLOCK

R\_RIM=R\_AIRFOIL-L\_INTERLOCK

L\_DISK=R\_RIM-R\_HUB

L\_BLADE=R\_BLADE-R\_AIRFOIL

K, , R\_RIM, , ,

K, , R\_RIM, H\_INTERLOCK/2

delta\_X1=K\_X1\*L\_DISK

Kgen,2,2,,, -delta\_X1

delta\_X2=K\_X2\*(L\_DISK-delta\_X1)

delta\_Y2=K\_Y2\*H\_INTERLOCK/2

Kgen,2,3,,, -delta\_X2, -delta\_Y2

delta\_X3=K\_X3\*(L\_DISK-delta\_X1-delta\_X2)

delta\_Y3=K\_Y3\*H\_INTERLOCK/2

Kgen,2,4,,, -delta\_X3, delta\_Y3

delta\_X4=K\_X4\*(L\_DISK-delta\_X1-delta\_X2-delta\_X3)

delta\_Y4=K\_Y4\*H\_INTERLOCK/2

Kgen,2,5,,, -delta\_X4, delta\_Y4

K, next, R\_HUB

\*GET, Y6, KP, 6, LOC, Y

Kgen,2,7,,,, Y6

LSTR, 1, 2 !! линия 1

LSTR, 2, 3 !! линия 2

LSTR, 3, 4 !! линия 3

LSTR, 4, 5 !! линия 4

LSTR, 5, 6 !! линия 5

LSTR, 6, 8 !! линия 6

LSTR, 8, 7 !! линия 7

LSTR, 1, 7 !! линия 8

!!!Сопряжение R1

\*GET, X\_2, KP, 2, LOC, X

\*GET, Y\_2, KP, 2, LOC, Y

\*GET, X\_3, KP, 3, LOC, X

\*GET, Y\_3, KP, 3, LOC, Y

\*GET, X\_4, KP, 4, LOC, X

\*GET, Y\_4, KP, 4, LOC, Y

Lr1\_disk=sqrt((X\_2-X\_3)\*\*2+(Y\_2-Y\_3)\*\*2)

Lr2\_disk=sqrt((X\_3-X\_4)\*\*2+(Y\_3-Y\_4)\*\*2)

La\_disk=sqrt((X\_4-X\_2)\*\*2+(Y\_4-Y\_2)\*\*2)

cos\_a\_disk=(Lr1\_disk\*\*2+Lr2\_disk\*\*2-La\_disk\*\*2)/(2\*Lr1\_disk\*Lr2\_disk)

a\_disk=acos(cos\_a\_disk)

a\_disk\_05=a\_disk/2

La\_disk\_rad\_min=Lr1\_disk

\*if, Lr2\_disk, le, La\_disk\_rad\_min, then

La\_disk\_rad\_min=Lr2\_disk

\*endif

R1\_rad\_disk=La\_disk\_rad\_min\*tan(a\_disk\_05)

LFILLT, 2, 3, R1\_rad\_disk\*K\_R1

!!!Сопряжение R2

\*GET, X\_10, KP, 10, LOC, X

\*GET, Y\_10, KP, 10, LOC, Y

\*GET, X\_4, KP, 4, LOC, X

\*GET, Y\_4, KP, 4, LOC, Y

\*GET, X\_5, KP, 5, LOC, X

\*GET, Y\_5, KP, 5, LOC, Y

Lr3\_disk=sqrt((X\_10-X\_4)\*\*2+(Y\_10-Y\_4)\*\*2)

Lr4\_disk=sqrt((X\_4-X\_5)\*\*2+(Y\_4-Y\_5)\*\*2)

Lb\_disk=sqrt((X\_10-X\_5)\*\*2+(Y\_10-Y\_5)\*\*2)

cos\_b\_disk=(Lr3\_disk\*\*2+Lr4\_disk\*\*2-Lb\_disk\*\*2)/(2\*Lr3\_disk\*Lr4\_disk)

b\_disk=acos(cos\_b\_disk)

b\_disk\_05=b\_disk/2

Lb\_disk\_rad\_min=Lr3\_disk

\*if, Lr4\_disk, le, Lb\_disk\_rad\_min, then

Lb\_disk\_rad\_min=Lr4\_disk

\*endif

R2\_rad\_disk=Lb\_disk\_rad\_min\*tan(b\_disk\_05)

LFILLT, 3, 4, R2\_rad\_disk\*K\_R2

!!!Сопряжение R3

\*GET, X\_12, KP, 12, LOC, X

\*GET, Y\_12, KP, 12, LOC,Y

\*GET, X\_5, KP, 5, LOC, X

\*GET, Y\_5, KP, 5, LOC, Y

\*GET, X\_6, KP, 6, LOC, X

\*GET, Y\_6, KP, 6, LOC, Y

Lr5\_disk=sqrt((X\_12-X\_5)\*\*2+(Y\_12-Y\_5)\*\*2)

Lr6\_disk=sqrt((X\_5-X\_6)\*\*2+(Y\_5-Y\_6)\*\*2)

Lc\_disk=sqrt((X\_6-X\_12)\*\*2+(Y\_6-Y\_12)\*\*2)

cos\_c\_disk=(Lr5\_disk\*\*2+Lr6\_disk\*\*2-Lc\_disk\*\*2)/(2\*Lr5\_disk\*Lr6\_disk)

c\_disk=acos(cos\_c\_disk)

c\_disk\_05=c\_disk/2

Lc\_disk\_rad\_min=Lr5\_disk

\*if, Lr6\_disk, le, Lc\_disk\_rad\_min, then

Lc\_disk\_rad\_min=Lr6\_disk

\*endif

R3\_rad\_disk=Lc\_disk\_rad\_min\*tan(c\_disk\_05)

LFILLT, 4, 5, R3\_rad\_disk\*K\_R3

!!!Сопряжение R4

\*GET, X\_14, KP, 14, LOC, X

\*GET, Y\_14, KP, 14, LOC, Y

\*GET, X\_6, KP, 6, LOC, X

\*GET, Y\_6, KP, 6, LOC, Y

\*GET, X\_8, KP, 8, LOC, X

\*GET, Y\_8, KP, 8, LOC, Y

Lr7\_disk=sqrt((X\_14-X\_6)\*\*2+(Y\_14-Y\_6)\*\*2)

Lr8\_disk=sqrt((X\_6-X\_8)\*\*2+(Y\_6-Y\_8)\*\*2)

Ld\_disk=sqrt((X\_8-X\_14)\*\*2+(Y\_8-Y\_14)\*\*2)

cos\_d\_disk=(Lr7\_disk\*\*2+Lr8\_disk\*\*2-Ld\_disk\*\*2)/(2\*Lr7\_disk\*Lr8\_disk)

d\_disk=acos(cos\_d\_disk)

d\_disk\_05=d\_disk/2

Ld\_disk\_rad\_min=Lr7\_disk

\*if, Lr8\_disk, le, Ld\_disk\_rad\_min, then

Ld\_disk\_rad\_min=Lr8\_disk

\*endif

R4\_rad\_disk=Ld\_disk\_rad\_min\*tan(d\_disk\_05)

LFILLT, 5, 6, R4\_rad\_disk\*K\_R4

!!!Сопряжение R5

\*GET, X\_16, KP, 16, LOC, X

\*GET, Y\_16, KP, 16, LOC, Y

\*GET, X\_8, KP, 8, LOC, X

\*GET, Y\_8, KP, 8, LOC, Y

\*GET, X\_7, KP, 7, LOC, X

\*GET, Y\_7, KP, 7, LOC, Y

Lr9\_disk=sqrt((X\_16-X\_8)\*\*2+(Y\_16-Y\_8)\*\*2)

Lr10\_disk=sqrt((X\_8-X\_7)\*\*2+(Y\_8-Y\_7)\*\*2)

Lf\_disk=sqrt((X\_7-X\_16)\*\*2+(Y\_7-Y\_16)\*\*2)

cos\_f\_disk=(Lr9\_disk\*\*2+Lr10\_disk\*\*2-Lf\_disk\*\*2)/(2\*Lr9\_disk\*Lr10\_disk)

f\_disk=acos(cos\_f\_disk)

f\_disk\_05=f\_disk/2

Lf\_disk\_rad\_min=Lr9\_disk

\*if, Lr10\_disk, le, Lf\_disk\_rad\_min, then

Lf\_disk\_rad\_min=Lr10\_disk

\*endif

R5\_rad\_disk=Lf\_disk\_rad\_min\*tan(f\_disk\_05)

LFILLT, 6, 7, R5\_rad\_disk\*K\_R5

Al, ALL

LGEN,2,1, , ,L\_INTERLOCK, , , ,0

LSTR, 1, 19

LSTR, 2, 20

AL, 1, 14, 15, 16

LGEN,2,14, , ,L\_BLADE, , , ,0

LDIV,17, , ,2,0

LDELE, 18, , ,1

LSTR, 19, 21

LSTR, 23, 20

AL, 14, 18, 17, 19

ARSYM,Y, ALL

NUMMRG,KP, , , ,LOW

!!!!!!!!!! ЗАДАНИЕ СВОЙСТВ МАТЕРИАЛОВ

!!!Материал 1

MPTEMP,,,,,,,,

MPTEMP,1,T1

MPTEMP,2,T4

MPDATA,EX,1,,E\_1\_T1

MPDATA,EX,1,,E\_1\_T4

MPDATA,PRXY,1,,MU\_1\_T1

MPDATA,PRXY,1,,MU\_1\_T4

UIMP,1,REFT,,,20

MPDATA,ALPX,1,,ALPH\_1\_T1

MPDATA,ALPX,1,,ALPH\_1\_T4

MPDATA,DENS,1,, po\_1

!!!Материал 2

MPTEMP,,,,,,,,

MPTEMP,1,T1

MPTEMP,2,T4

MPDATA,EX,2,,E\_2\_T1

MPDATA,EX,2,,E\_2\_T4

MPDATA,PRXY,2,,MU\_2\_T1

MPDATA,PRXY,2,,MU\_2\_T4

UIMP,1,REFT,,,20

MPDATA,ALPX,2,,ALPH\_2\_T1

MPDATA,ALPX,2,,ALPH\_2\_T4

MPDATA,DENS,2,, po\_2

!!!!!!!!!! ЗАДАНИЕ ТИПОВ ЭЛЕМЕНТОВ

ET,1,PLANE182

KEYOPT,1,1,0

KEYOPT,1,3,1

KEYOPT,1,6,0

KEYOPT,1,10,0

ET,2,PLANE182

KEYOPT,2,1,0

KEYOPT,2,3,3

KEYOPT,2,6,0

R,1,n\_blade\*H\_BLADE,

!!!!! ПОСТРОЕНИЕ СЕТКИ

LESIZE, ALL, 1.5

mat, 1

type,1

AMESH, 1

AMESH, 4

AMESH, 5

AMESH, 2

mat, 2

type, 2

AMESH, 3

AMESH, 6

!!!!! ПРИЛОЖЕНИЕ ГРАНИЧНЫХ УСЛОВИЙ

!Закрепление в узле по осевому направлению

KSEL,S, , , 7

NSLK,S

D, ALL, ,0, , , ,UY, , , , ,

ALLSEL,ALL

!Задание частоты вращения

OMEGA,0, w, 0,

!Теперь нам необходимо задать линейное распределение температур

kol\_temp=4 !Число точек, в которых задается температура

\*dim, temp\_func\_axi, table, kol\_temp, 1 !Создаем массив данных

!---ЗНАЧЕНИЯ Координат по оси X в таблице---

temp\_func\_axi(1, 0)=R\_HUB !ступица

temp\_func\_axi(2, 0)=R\_RIM !обод

temp\_func\_axi(3, 0)=R\_AIRFOIL !корневое сечение

temp\_func\_axi(4, 0)=R\_BLADE !крайняя точка детали по x

!---ЗНАЧЕНИЯ Температур для соответствующих координат по оси X

temp\_func\_axi(1, 1)=T1

temp\_func\_axi(2, 1)=T2

temp\_func\_axi(3, 1)=T3

temp\_func\_axi(4, 1)=T4

\*get, node\_count, node, , count ! Определяем число узлов в модели

\*get, node\_max, node, , num, max ! Определяем максимальный номер

\*get, x\_coord, node, node\_max, loc, x ! Определяем координату по X

bf, node\_max, temp\_x, temp\_func\_axi(x\_coord) ! интерполируем

\*do,i,2,node\_count,1 !проходим цикл со всеми остальными узлами

\*get,node\_max1,node,node\_max,nxtl !определяем узел

node\_max=node\_max1 !работаем теперь с этим новым узлом

\*get, x\_coord, node, node\_max, loc, x

bf, node\_max, temp\_x, temp\_func\_axi(x\_coord)

\*enddo

ALLSEL, ALL

!Запуск на решение

FINISH

/SOL

/STATUS,SOLU

SOLVE

!Работа с полученными результатами

/POST1

\*GET, AREA\_Plosh\_1, AREA, 1, AREA

\*GET, AREA\_Plosh\_2, AREA, 4, AREA

AREA\_Plosh=AREA\_Plosh\_1+AREA\_Plosh\_2

ASEL,S, , ,1

ASEL,A, , ,4

ALLSEL,BELOW,AREA

PRNSOL,S,PRIN

SET,FIRST

NSORT, S,Eqv

!\*

\*GET,Smax,SORT,,MAX

ALLSEL,ALL

С целью сокращения временных затрат на вычисления может быть полезным выделение параметров, которые наиболее сильно влияют на целевую функцию.

为了减少计算时间，可以将对目标函数影响最大的参数分离出来。

При функциональной зависимости между переменными величинами каждому допустимому значению независимого переменного аргумента *x* соответствует определенное значение другой переменной *y*. Очевидно, что для случайных величин такого соответствия нет. В этом случае существуют связи особого вида, называемые стохастическими (вероятностными), при которых одна случайная величина реагирует на изменение другой изменением своего распределения.

在变量之间存在函数依赖关系的情况下，自变量参数 x 的每个允许值都对应着另一个变量 y 的某个值。显然，随机变量不存在这种对应关系。在这种情况下，存在一种特殊的联系，称为随机（概率）联系，其中一个随机变量通过改变其分布对另一个随机变量的变化做出反应。

Большинство задач при анализе результатов испытаний может быть решено в рамках линейной зависимости между нормально распределенными величинами. При этом в качестве количественной оценки силы связи между случайными величинами используют коэффициент корреляции:

分析测试结果的大多数问题都可以在正态分布变量之间的线性关系框架内解决。在这种情况下，相关系数被用作随机变量之间关系强度的定量评估：

|  |  |
| --- | --- |
|  | (22) |

где σX, σY – генеральные средние квадратические отклонения случайных величин *X* и *Y* ; µ1/1 – генеральный смешанный центральный момент второго порядка.

其中，σX、σY 是随机变量 X 和 Y 的一般均方差；μ1/1 是一般混合二阶中心矩。

Для определения степени влияния наших экспериментальных параметров на максимальное напряжение автоматизируем многократность выполнения расчета. Красным цветом – новая часть программного кода:

为了确定实验参数对最大电压的影响程度，我们自动执行了多次计算。红色为程序代码的新部分：

!Задайте число генерируемых моделей

N=200

!Создание массива для записи расчетных данных

\*dim, Massiv\_dannye, array, N, 6

\*do, j, 1, N, 1

!!!!!!ИСХОДНЫЕ ДАННЫЕ, ЗАДАЮТСЯ ПОЛЬЗОВАТЕЛЕМ

R\_AIRFOIL=210

R\_HUB=40

R\_BLADE=240

H\_INTERLOCK=30

H\_BLADE=2

n\_blade=72

! Частота вращения, рад/с

w= RAND(855, 945)

Massiv\_dannye(j,1)=w

!Температуры конструкции

T1= RAND(330, 370) !! Температура в ступице диска

Massiv\_dannye(j,2)= T1

T2= RAND(620, 680) !! Температура в ободе диска

Massiv\_dannye(j,3)= T2

T3= RAND(710, 790) !! Температура в начале проточной части лопатки

Massiv\_dannye(j,4)= T3

T4= RAND(855, 945)!! Температура в периферии лопатки

Massiv\_dannye(j,5)= T4

!!!!!!!!!!!!!!!!!далее изменения только в конце кода:

/SOL

/STATUS,SOLU

SOLVE

!Работа с полученными результатами

/POST1

\*GET, AREA\_Plosh\_1, AREA, 1, AREA

\*GET, AREA\_Plosh\_2, AREA, 4, AREA

AREA\_Plosh=AREA\_Plosh\_1+AREA\_Plosh\_2

ASEL,S, , ,1

ASEL,A, , ,4

ALLSEL,BELOW,AREA

PRNSOL,S,PRIN

SET,FIRST

NSORT, S,Eqv

!\*

\*GET,Smax,SORT,,MAX

Massiv\_dannye(j,6)= Smax

ALLSEL,ALL

FINISH

!Удаление сетки и геометрии

/PREP7

ACLEAR, ALL

ADELE, ALL, , NINC, 1

CWZDELE,3,1,''

NDELE,ALL

KDELE, ALL

MPDE,ALL,1

TBDE,ALL,1

MPTEMP,,,,,,,

MPDE,ALL,2

TBDE,ALL,2

MPTEMP,,,,,,,

!\*

ETDEL,1

!\*

\*DEL,TEMP\_FUNC\_AXI

\*DEL, dannye

\*enddo

! Запись результатов в файл Rezults.txt

\*cfopen, Rezults, txt

\*vwrite, Massiv\_dannye(1,1)

('w=', F10.5)

\*vwrite, Massiv\_dannye(1,2)

('T1=', F10.5)

\*vwrite, Massiv\_dannye(1,3)

('T2=', F10.5)

\*vwrite, Massiv\_dannye(1,4)

('T3=', F10.5)

\*vwrite, Massiv\_dannye(1,5)

('T4=', F10.5)

\*vwrite, Massiv\_dannye(1,6)

('Smax=', F10.5)

\*cfclose, Rezults, txt

В полученном текстовом файле Rezults.txt, расположенном в рабочей директории, будут результаты каждого произвольного шага. Загрузим полученные данные для дальнейшей обработки в Python.

结果文本文件 Rezults.txt 位于工作目录中，将包含每个任意步骤的结果。让我们加载获得的数据，以便在 Python 中进一步处理。

|  |  |
| --- | --- |
|  |  |
| Рисунок 3 – Импорт библиотек и загрузка данных | |

Далее разобьем данные из одного столбца в столбцы с каждым из параметров:

接下来，让我们将一列中的数据拆分成包含每个参数的列：

|  |
| --- |
|  |
| Рисунок 4 – Разбиение столбцов с данными |

Размерность и тип полученных данных:

所获数据的维度和类型：

|  |
| --- |
|  |
| Рисунок 5 – Полученные данные |

Для расчета коэффициентов корреляции воспользуемся встроенными возможностями Python:

为了计算相关系数，我们将使用 Python 的内置功能：

|  |
| --- |
|  |
| Рисунок 6 – Расчет коэффициентов корреляции |

Из полученных результатов видно, что наиболее сильно на «Smax» влияют параметры w и T1.

从获得的结果可以看出，参数 w 和 T1 对 "Smax "的影响最大。

Сначала проверим гипотезу о нормальности распределенных данных S\_max. Воспользуемся статистическим тестом Шапиро:

首先，我们来检验分布数据 S\_max 的正态性假设。让我们使用夏皮罗统计检验：

|  |
| --- |
|  |
| Рисунок 7 – Проверка гипотезы о нормальности распределения |

Далее проводим вычисление среднего значения и среднеквадратического отклонения нашего нормального распределения и проводим визуализацию данных:

接下来，我们计算正态分布的平均值和标准差，并将数据可视化：

|  |
| --- |
|  |
| Рисунок 8 – Визуализация данных |

Наконец, определим границы доверительного интервала 99%:

|  |
| --- |
|  |
| Рисунок 9 – Доверительный интервал 99% |