## bat结合vbs实现创建快捷方式

@echo off

::设置程序或文件的路径（必选）

set Program=D:\Program Files\Microvirt\MEmu\MEmu.exe

::设置启动参数（可选）

set Arguments=

::设置快捷方式名称（必选）

set LnkName=test

::设置程序的工作路径，一般为程序主目录，此项若留空，脚本将自行分析路径

set WorkDir=

::设置快捷方式显示的说明（可选）

set Desc=

if not defined WorkDir call:GetWorkDir "%Program%"

(echo Set WshShell=CreateObject("WScript.Shell"^)

echo strDesKtop=WshShell.SpecialFolders("DesKtop"^)

echo Set oShellLink=WshShell.CreateShortcut(strDesKtop^&"\%LnkName%.lnk"^)

echo oShellLink.TargetPath="%Program%"

echo oShellLink.Arguments="%Arguments%"

echo oShellLink.WorkingDirectory="%WorkDir%"

echo oShellLink.WindowStyle=1

echo oShellLink.Description="%Desc%"

echo oShellLink.Save)>makelnk.vbs

echo 桌面快捷方式创建成功！

makelnk.vbs

del /f /q makelnk.vbs

exit

goto :eof

:GetWorkDir

set WorkDir=%~dp1

set WorkDir=%WorkDir:~,-1%

goto :eof

## vbs创建ink

Set WshShell = WScript.CreateObject("WScript.Shell")

strDesktop = WshShell.SpecialFolders("Desktop") :'特殊文件夹“桌面”

set oShellLink = WshShell.CreateShortcut(strDesktop & "\计算器.lnk")

oShellLink.TargetPath = "C:\Windows\System32\Calc.exe" : '目标

oShellLink.WindowStyle = 3 :'参数1默认窗口激活，参数3最大化激活，参数7最小化

oShellLink.Hotkey = "Ctrl+Alt+C" : '快捷键

oShellLink.IconLocation = "C:\Windows\System32\Calc.exe" : '图标

oShellLink.Description = "系统默认计算器" : '备注

oShellLink.WorkingDirectory = strDesktop : '起始位置

oShellLink.Save : '创建保存快捷方式