Merging mappings together

[rohan-datar]

I'm currently writing a template in pkl that needs to take several Mappings that are contained in a Listing and merge them together to form a single Mapping that contains all the data from the original Mappings. Here's a very minimal example of what I want to do:

map1 = new Mapping {
    ["foo"] {
        "a"
        "b"
        "c"
    }
    ["bar"] {
        "d"
        "e"
        "f"
    }
}

map2 = new Mapping {
    ["foo"] {
        "p"
        "q"
        "r"
    }
    ["baz"] {
        "x"
        "y"
        "z"
    }
}

l1 = new Listing {
    map1
    map2
}

result = mergeMaps(l1)

where result becomes:

result {
    ["foo"] {
        "a"
        "b"
        "c"
        "p"
        "q"
        "r"
    }

    ["bar"] {
        "d"
        "e"
        "f"
    }

    ["baz"] {
        "x"
        "y"
        "z"
    }
}

This is my best attempt at writing mergeMaps so far:

function mergeMaps(l: Listing<Mapping>): Mapping =
    l.fold(Map(), (m, maps) ->
        maps.toMap().map((k, v) ->
            if (m.containsKey(k)) (m[k]) { ...v } else m.put(k, v))).toMapping()

But this results in an evaluation error:

–– Pkl Error ––
Expected value of type `Pair`, but got type `Map`.
Value: Map("foo", new Dynamic { ?; ?; ? })

34 | maps.toMap().map((k, v) ->
     ^^^^^^^^^^^^^^^^^^^^^^^^^^
at merge#mergeMaps.<function#1> (file:///home/rdatar/test/pkl/mappings/merge.pkl, line 34)

33 | l.fold(Map(), (m, maps) ->
     ^^^^^^^^^^^^^^^^^^^^^^^^^^
at merge#mergeMaps (file:///home/rdatar/test/pkl/mappings/merge.pkl, line 33)

37 | result = mergeMaps(l1)
              ^^^^^^^^^^^^^
at merge#result (file:///home/rdatar/test/pkl/mappings/merge.pkl, line 37)

106 | text = renderer.renderDocument(value)
             ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
at pkl.base#Module.output.text (https://github.com/apple/pkl/blob/0.27.2/stdlib/base.pkl#L106)

I'm not sure how to proceed at this point. Any suggestions?

[HT154]

Give this a shot:

function mergeMaps(l: Listing<Mapping<Any, Listing>>): Mapping<Any, Listing> =
  l.fold(new Mapping<Any, Listing> {}, (acc, elem) ->
    elem.fold(acc, (acc, k, v) ->
      (acc) { [k] { ...v } }
    )
  )

Shadowing acc here is a little naughty, but it does work. You also need a little more typing on your input, see https://pkl-playground.vercel.app/?share=these-hearing-bee for everything together.

[rohan-datar]

This worked, thanks! I would not have thought of using acc like that, it's clever.