meta_methods.cos

use * from "assert"

class IntSet {
  public mut int[] vec

  public IntSet fn construct(int[]? vec = []) {
    $->vec = vec
  }

  public void fn push(int value) {
    $->vec << value
  }

  public void fn display {
    puts($->vec)
  }

  public IntSet fn add$(IntSet other) {
    IntSet resultant = new IntSet($->vec)
    every int n in other->vec
      resultant->push(n)

    resultant
  }

  public IntSet fn mul$(int x) {
    IntSet resultant = new IntSet
    every int i in 1..x
      every int n in $->vec
        resultant->push(n)

    resultant
  }

  public bool fn is_in$(int x) {
    x is in $->vec
  }

  public int fn size$ {
    #$->vec
  }

  public string fn to_string {
    <string>$->vec
  }
}

IntSet set_x = new IntSet([1,2,3])
IntSet set_y = new IntSet([4,5,6])
IntSet set_z = set_x + set_y
IntSet set_w = set_x * 3
set_z->display ## 1,2,3,4,5,6
set_w->display ## 1,2,3,1,2,3,1,2,3

Assert::eq(#set_z, 6)
Assert::eq(#set_w, 9)

Assert::eq(set_z->vec, [1,2,3,4,5,6])
Assert::truthy(4 is in set_z)
Assert::falsey(7 is in set_z)

Assert::eq(set_w->vec, [1,2,3,1,2,3,1,2,3])
Assert::truthy(3 is in set_w)
Assert::falsey(4 is in set_w)