-
-
Notifications
You must be signed in to change notification settings - Fork 24
/
Copy pathCMLEXEC
1769 lines (1531 loc) · 91.8 KB
/
CMLEXEC
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(DEFINE-FILE-INFO PACKAGE "INTERLISP" READTABLE "INTERLISP" BASE 10)
(FILECREATED "24-May-2024 20:54:49" {MEDLEY}<SOURCES>CMLEXEC.;3 92134
:EDIT-BY "mth"
:CHANGES-TO (FUNCTIONS PRINT-ALL-DOCUMENTATION)
(VARS CMLEXECCOMS)
:PREVIOUS-DATE "20-May-2024 21:28:00" {MEDLEY}<SOURCES>CMLEXEC.;2)
(* ; "
Copyright (c) 1985-1988, 1990-1991, 1993, 2021, 2024 by Venue & Xerox Corporation.
")
(PRETTYCOMPRINT CMLEXECCOMS)
(RPAQQ CMLEXECCOMS
[(FILES CMLUNDO PROFILE)
(XCL:PROFILES "EXEC")
(STRUCTURES COMMAND-ENTRY EXEC-EVENT-ID EXEC-EVENT HISTORY)
(* ;
"These are public except for command-entry.")
(FUNCTIONS XCL::EXEC-CLOSEFN XCL::EXEC-SHRINKFN XCL::SETUP-EXEC-WINDOW
XCL::EXEC-TITLE-FUNCTION FIX-FORM XCL::GET-PROCESS-PROFILE
XCL::SAVE-CURRENT-EXEC-PROFILE XCL::SETF-GET-PROCESS-PROFILE XCL:SET-EXEC-TYPE
XCL:SET-DEFAULT-EXEC-TYPE XCL::ENTER-EXEC-FUNCTION)
(SETFS XCL::GET-PROCESS-PROFILE)
(FUNCTIONS DO-EVENT EXEC EXEC-EVAL PRINT-ALL-DOCUMENTATION PRINT-DOCUMENTATION VALUE-OF
ADD-EXEC EXEC-READ-LINE EXEC-EVENT-ID-PROMPT FIND-EXEC-COMMAND)
(FUNCTIONS CIRCLAR-COPYER)
(FNS COPY-CIRCLE)
(* ;
"CIRCLAR-COPYER and COPY-CIRCLE are the solution for AR#11172")
(FNS EXEC-READ DIR)
(VARIABLES *PER-EXEC-VARIABLES* CL:* CL:** CL:*** + CL:++ CL:+++ - / CL:// CL:///
*CURRENT-EVENT* *EXEC-ID* XCL:*EXEC-PROMPT* XCL:*EVAL-FUNCTION* *NOT-YET-EVALUATED*
*THIS-EXEC-COMMANDS* *EXEC-COMMAND-TABLE* *DEBUGGER-COMMAND-TABLE* *CURRENT-EXEC-TYPE*
*EXEC-MAKE-UNDOABLE-P*)
(VARIABLES *EDIT-INPUT-WITH-TTYIN*)
(FNS DO-APPLY-EVENT DO-HISTORY-SEARCH EVAL-INPUT EVENTS-INPUT EXEC-PRIN1 EXEC-VALUE-OF
GET-NEXT-HISTORY-EVENT HISTORY-ADD-TO-SPELLING-LISTS HISTORY-NTH PRINT-HISTORY
FIND-HISTORY-EVENTS PRINT-EVENT PRINT-EVENT-PROMPT PROCESS-EXEC-ID
SEARCH-FOR-EVENT-NUMBER \PICK.EVALQT LISPXREPRINT)
(DECLARE%: DONTEVAL@LOAD DOCOPY (P (MOVD? 'READ 'TTYINREAD)
(MOVD '\PICK.EVALQT '\PROC.REPEATEDLYEVALQT)
(SETQ BackgroundMenu)))
(FUNCTIONS CASE-EQUALP EXEC-EVENT-PROPS EXEC-PRINT EXEC-FORMAT)
(ALISTS (BackgroundMenuCommands EXEC))
(ALISTS (SYSTEMINITVARS LISPXHISTORY GREETHIST))
(* ;; "Exec Commands")
(DEFINE-TYPES COMMANDS)
(FUNCTIONS DEFCOMMAND)
(COMMANDS "?" "??" "CONN" "DA" "DIR" "DO-EVENTS" "FIX" "FORGET" "NAME" "NDIR" "PL" "REDO"
"REMEMBER" "SHH" "UNDO" "USE" "PP")
(* ;; "Arrange to use the correct compiler")
(PROP FILETYPE CMLEXEC)
(DECLARE%: DONTEVAL@LOAD DOEVAL@COMPILE DONTCOPY COMPILERVARS
(ADDVARS (NLAMA DIR)
(NLAML)
(LAMA PROCESS-EXEC-ID PRINT-EVENT PRINT-HISTORY EXEC-PRIN1 EVENTS-INPUT
EVAL-INPUT EXEC-READ])
(FILESLOAD CMLUNDO PROFILE)
(XCL:DEFPROFILE "EXEC" (XCL:*DEBUGGER-PROMPT* "")
(XCL:*EXEC-PROMPT* "")
(*READTABLE* "XCL")
(*PACKAGE* "XCL")
(XCL:*EVAL-FUNCTION* 'CL:EVAL))
(CL:DEFSTRUCT (COMMAND-ENTRY (:TYPE LIST))
ARGUMENTS
FUNCTION
MODE)
(CL:DEFSTRUCT (EXEC-EVENT-ID (:TYPE LIST))
NUMBER
NAME
dummy)
(CL:DEFSTRUCT (EXEC-EVENT (:TYPE LIST))
INPUT
ID
(VALUE *NOT-YET-EVALUATED*)
dummy)
(CL:DEFSTRUCT (HISTORY (:TYPE LIST))
(EVENTS NIL)
(INDEX 0)
(SIZE 100)
(MOD 100))
(* ; "These are public except for command-entry.")
(CL:DEFUN XCL::EXEC-CLOSEFN (XCL::WINDOW)
[LET [(XCL::PROCESS (WINDOWPROP XCL::WINDOW 'PROCESS]
(COND
((EQ (THIS.PROCESS)
XCL::PROCESS)
[ADD.PROCESS `(CLOSEW ',XCL::WINDOW]
'DON'T)
((PROCESSP XCL::PROCESS)
(CL:IF (TTY.PROCESSP XCL::PROCESS)
(TTY.PROCESS T))
(DEL.PROCESS XCL::PROCESS])
(CL:DEFUN XCL::EXEC-SHRINKFN (XCL::WINDOW)
(LET [(XCL::PROCESS (WINDOWPROP XCL::WINDOW 'PROCESS]
(COND
((EQ (THIS.PROCESS)
XCL::PROCESS)
[ADD.PROCESS `(SHRINKW ',XCL::WINDOW]
'DON'T)
((TTY.PROCESSP XCL::PROCESS)
(TTY.PROCESS T)
NIL))))
(CL:DEFUN XCL::SETUP-EXEC-WINDOW (XCL::WINDOW)
"Add (non-title) properties to a new exec window."
(WINDOWADDPROP XCL::WINDOW 'CLOSEFN 'XCL::EXEC-CLOSEFN)
(WINDOWADDPROP XCL::WINDOW 'SHRINKFN 'XCL::EXEC-SHRINKFN)
XCL::WINDOW)
(CL:DEFUN XCL::EXEC-TITLE-FUNCTION (XCL::WINDOW EXEC-ID)
[WINDOWPROP XCL::WINDOW 'TITLE (CL:FORMAT NIL "Exec ~A (~A)" EXEC-ID (READTABLEPROP *READTABLE*
'NAME])
(CL:DEFUN FIX-FORM (INPUT &OPTIONAL (CIRCLE-FLAG NIL))
(* ;;; "Edits a form, in the current window if it is shorter than ttyinfixlimit, or if longer in the display editor using edite. Returns the newly edited form.")
(* ; "Edited by Tomoru Teruuchi")
[COND
((OR (NOT *EDIT-INPUT-WITH-TTYIN*)
(NOT (IMAGESTREAMP (TTYDISPLAYSTREAM)))
(AND (NOT CIRCLE-FLAG)
(EQUAL 0 (COUNTDOWN INPUT TTYINFIXLIMIT))) (* ; "(IGEQ (COUNT INPUT) TTYINFIXLIMIT) is Original Code. But This Codecan't accept circler. Edited by TT (31-May-1990)")
)
(EDITE (CL:IF (AND (EQ 1 (LENGTH INPUT))
(CL:CONSP (CAR INPUT)))
(CAR INPUT)
INPUT)
NIL NIL T NIL :CLOSE-ON-COMPLETION)
INPUT)
(T (PRINT-EVENT-PROMPT *CURRENT-EVENT*)
(DSPFONT INPUTFONT T)
(CURSOR T) (* ;
"make sure can edit (in case cursor smashed somehow?)")
(CL:WHEN NIL (* ; "Old expression")
(TTYIN "" NIL NIL 'LISPXREAD NIL NIL BUFFER-EXPR-FROM-BELOW *READTABLE*))
(EXEC-READ-LINE (LET ((%#RPARS NIL)
(FONTCHANGEFLG NIL)
(*PRINT-ESCAPE* T)
(*PRINT-RADIX* (NOT (= *READ-BASE* 10)))
(*PRINT-BASE* *READ-BASE*)
(*PRINT-LEVEL* NIL)
(*PRINT-LENGTH* NIL)
(*PRINT-GENSYM* ':REREAD)
(*PRINT-ARRAY* T)
(*PRINT-STRUCTURE* T))
(DECLARE (CL:SPECIAL %#RPARS FONTCHANGEFLG)
(* ;
"others are already globally special "))
(CL:WITH-OUTPUT-TO-STRING (STR)
(FOR X ON INPUT
DO (IF CIRCLE-FLAG
THEN (* ;
"Edited by TT (31-May-1990) CL:PRIN1 can print circlar")
(CL:PRIN1 (CAR X)
STR)
ELSEIF (LISTP (CAR X))
THEN (PRINTDEF (CAR X)
(POSITION STR)
NIL NIL NIL STR)
ELSE (PRIN2 (CAR X)
STR))
(AND (CDR X)
(PRIN1 " " STR])
(CL:DEFUN XCL::GET-PROCESS-PROFILE (&OPTIONAL (XCL::PROCESS (THIS.PROCESS)))
(PROCESSPROP XCL::PROCESS 'PROFILE))
(CL:DEFUN XCL::SAVE-CURRENT-EXEC-PROFILE ()
"Resave the profiled bindings of the exec process into their cache."
(LET [(XCL::PROFILE (XCL::GET-PROCESS-PROFILE (THIS.PROCESS]
(CL:IF (XCL:PROFILE-P XCL::PROFILE)
(XCL:SAVE-PROFILE XCL::PROFILE))))
(CL:DEFUN XCL::SETF-GET-PROCESS-PROFILE (&OPTIONAL (XCL::PROCESS (THIS.PROCESS))
(XCL::PROFILE XCL:*PROFILE*))
(CL:SETQ XCL::PROFILE (XCL::PROFILIZE XCL::PROFILE))
(PROCESSPROP XCL::PROCESS 'PROFILE XCL::PROFILE)
XCL::PROFILE)
(CL:DEFUN XCL:SET-EXEC-TYPE (TYPE)
"Set the current Exec's type to TYPE"
(* ;; "The EXECA-FRAME bit is a gross hack to make this function work inside init files. The problem is that you want to affect the EXEC, regardless of who has bound the per-exec variables between here an the EXEC frame. Yech.")
[LET [(XCL::EXECA-FRAME (STKPOS 'XCL::EXECA0001]
(COND
(XCL::EXECA-FRAME (ENVEVAL `(XCL:RESTORE-PROFILE ',TYPE)
XCL::EXECA-FRAME XCL::EXECA-FRAME))
(T (XCL:RESTORE-PROFILE TYPE])
(CL:DEFUN XCL:SET-DEFAULT-EXEC-TYPE (TYPE)
(SETTOPVAL 'XCL:*PROFILE* TYPE))
(CL:DEFUN XCL::ENTER-EXEC-FUNCTION (XCL::EXEC-FUNCTION XCL::PROFILE XCL::ID)
"Start up an exec function in the proper profile, setting the default window title properly."
(XCL:WITH-PROFILE (XCL:COPY-PROFILE XCL::PROFILE)
(XCL::EXEC-TITLE-FUNCTION T (PROCESS-EXEC-ID (THIS.PROCESS)
XCL::ID))
(CL:FUNCALL XCL::EXEC-FUNCTION)))
(CL:DEFSETF XCL::GET-PROCESS-PROFILE XCL::SETF-GET-PROCESS-PROFILE)
(CL:DEFUN DO-EVENT (ORIGINAL-INPUT ENVIRONMENT &OPTIONAL (FUNCTION (FUNCTION EVAL-INPUT)))
(* ; "Edited by Tomoru Teruuchi")
(PROG (TODO INPUT VALUES COM (ADD-TO-SPELLING-LIST ADDSPELLFLG)
STR
(RETRYFLAG NIL) (* ; "A really gross hack for RETRY to always break. It exists because: users can setq HELPFLAG anywhere (can't bind it in DO-EVENTand set it in RETRY), RETRY operates on commands (can't wrap the form with a binding of HELPFLAG).")
)
(DECLARE (CL:SPECIAL RETRYFLAG)) (* ;
"RETRY command sets this variable if it wants to be sure to break.")
(DSPFONT PRINTOUTFONT T)
(SETQ INPUT ORIGINAL-INPUT)
RETRY
(SETQ TODO (COPY-CIRCLE INPUT)) (* ;
"Break EQ link between input and evaluated form (todo), so that in-place mods don't affect history.")
[COND
[[AND (OR (STRINGP (CAR INPUT))
(CL:SYMBOLP (CAR INPUT)))
(PROGN (SETQ STR (STRING (CAR INPUT)))
(SOME *THIS-EXEC-COMMANDS* (FUNCTION (LAMBDA (TABLE)
(SETQ COM (GETHASH STR TABLE]
(* ;; "Handle exec commands.")
(CL:ECASE (COMMAND-ENTRY-MODE COM)
(:QUIET
[MAPC (SETQ VALUES (CL:MULTIPLE-VALUE-LIST (CL:FUNCALL (COMMAND-ENTRY-FUNCTION
COM)
INPUT ENVIRONMENT)))
(FUNCTION (LAMBDA (X)
(EXEC-PRINT X]
(SETQ IT (CAR VALUES)) (* ; "just do it and return")
(RETURN))
((:HISTORY :INPUT) (* ; " create new input. If an error occurs while handling the command, the INPUT will be left as the original input.")
(CL:WHEN *CURRENT-EVENT*
(CL:SETF (EXEC-EVENT-INPUT *CURRENT-EVENT*)
INPUT))
(SETQ INPUT (CL:FUNCALL (COMMAND-ENTRY-FUNCTION COM)
INPUT ENVIRONMENT))
(CL:WHEN *CURRENT-EVENT*
(CL:SETF (EXEC-EVENT-INPUT *CURRENT-EVENT*)
INPUT) (* ;
" Overwrite the original input with the newly generated one.")
(CL:SETF (EXEC-EVENT-PROPS *CURRENT-EVENT*)
(LIST* '*HISTORY* ORIGINAL-INPUT (EXEC-EVENT-PROPS *CURRENT-EVENT*))))
(GO RETRY) (* ; " could have generated a command")
)
((NIL :EVAL) (* ;
" normal kind of command, just apply")
[SETQ TODO `((CL:FUNCALL ',(COMMAND-ENTRY-FUNCTION COM)
',INPUT
',ENVIRONMENT]
(SETQ ADD-TO-SPELLING-LIST NIL)
(CL:WHEN *CURRENT-EVENT*
(CL:SETF (EXEC-EVENT-INPUT *CURRENT-EVENT*)
INPUT))))]
(T
(* ;; "Handle non-exec commands (fns, functions, macros, etc.).")
(CL:WHEN *CURRENT-EVENT*
(CL:SETF (EXEC-EVENT-INPUT *CURRENT-EVENT*)
INPUT))
(CL:WHEN *EXEC-MAKE-UNDOABLE-P*
[if (CDR TODO)
then (SETQ TODO (CONS (OR (CDR (ASSOC (CAR TODO)
LISPXFNS))
(CAR TODO))
(CDR TODO)))
else (SETQ TODO (LIST (XCL::MAKE-UNDOABLE (CAR TODO)
NIL])]
(AND ADD-TO-SPELLING-LIST (HISTORY-ADD-TO-SPELLING-LISTS TODO))
(SETQ LISPXHIST *CURRENT-EVENT*)
(DSPFONT PRINTOUTFONT T)
(RETURN (LET ((HELPCLOCK (CLOCK 2))
VALUES)
(DECLARE (CL:SPECIAL HELPCLOCK))
(CL:SETQ CL:+++ CL:++ CL:++ + + - - (CAR INPUT))
(* ;; "the book doesn't define what - and friends should be when input is in APPLY format. Here it says it is just the function name.")
[SETQ VALUES (CL:MULTIPLE-VALUE-LIST (CL:IF RETRYFLAG
(LET ((HELPFLAG 'BREAK!))
(DECLARE (CL:SPECIAL HELPFLAG))
(CL:FUNCALL FUNCTION TODO
ENVIRONMENT))
(CL:FUNCALL FUNCTION TODO ENVIRONMENT))
]
(CL:SETQ CL:/// CL:// CL:// / / VALUES)
(CL:UNLESS (EQ 'NOBIND (CAR VALUES)) (* ; "Be a bit careful about NOBIND.")
(CL:SETQ CL:*** CL:** CL:** CL:* CL:* (SETQ IT (CAR VALUES))))
(CL:WHEN *CURRENT-EVENT*
(CL:SETF (EXEC-EVENT-VALUE *CURRENT-EVENT*)
(CAR VALUES))
(CL:SETF (EXEC-EVENT-PROPS *CURRENT-EVENT*)
(LIST* 'LISPXVALUES VALUES (EXEC-EVENT-PROPS *CURRENT-EVENT*))))
(DSPFONT VALUEFONT T)
(for X in VALUES do (EXEC-PRINT X))
VALUES))))
(CL:DEFUN EXEC (&KEY XCL::TOP-LEVEL-P (* ;
"True of top level execs. Used for event number restarting and profile caching.")
(XCL::WINDOW (WFROMDS (TTYDISPLAYSTREAM)))
(* ; "Window for this exec, if any.")
(XCL::TITLE NIL XCL::TITLE-SUPPLIED) (* ;
"If given, specific title for this window.")
((:COMMAND-TABLES *THIS-EXEC-COMMANDS*)
(LIST *EXEC-COMMAND-TABLE*)) (* ;
"List of hash tables to look up commands in.")
XCL::ENVIRONMENT (* ;
"Lexical environment to evaluate things in, default NIL.")
XCL::PROMPT (* ; "Special prompt to use (optional).")
((:FUNCTION XCL::FN)
'EVAL-INPUT) (* ; "Function for processing input.")
XCL::PROFILE (* ;
"Optional profile, sets the exec's bindings.")
XCL::ID (* ; "A handle on the exec.")
&ALLOW-OTHER-KEYS (* ; "To catch obsolete calls")
&AUX
(*EXEC-ID* (PROCESS-EXEC-ID (THIS.PROCESS)
XCL::ID))
(XCL::PROFILE-CACHE (XCL::GET-PROCESS-PROFILE (THIS.PROCESS)))
(* ;
"The exec's cached profile (if entering from a hardreset).")
)
[CL:PROGV (MAPCAR *PER-EXEC-VARIABLES* (FUNCTION CAR))
[MAPCAR *PER-EXEC-VARIABLES* (FUNCTION (LAMBDA (XCL::X)
(EVAL (CADR XCL::X]
(CL:WHEN (OR (NULL XCL::TOP-LEVEL-P)
(NULL XCL::PROFILE-CACHE)) (* ; "If not hardresetting...")
(CL:WHEN XCL::PROFILE (* ; "then initialize the profile vars.")
(XCL:RESTORE-PROFILE XCL::PROFILE))
(CL:WHEN XCL::PROMPT (* ;
"If a special prompt was provided (as from the debugger)...")
(CL:SETQ XCL:*EXEC-PROMPT* XCL::PROMPT) (* ; "...use it.")
))
(CL:WHEN XCL::TOP-LEVEL-P
(CL:IF (NULL XCL::PROFILE-CACHE) (* ;
"This was a new entry into top level exec.")
(CL:SETF (XCL::GET-PROCESS-PROFILE (THIS.PROCESS))
(XCL:SAVE-PROFILE (XCL:COPY-PROFILE "EXEC")))
(* ;
"...make a fresh cache and save bindings into it.")
(XCL:RESTORE-PROFILE XCL::PROFILE-CACHE) (* ; "...otherwise it was a HARDRESET.")
))
(CL:WHEN XCL::WINDOW
(COND
((NOT XCL::TITLE-SUPPLIED) (* ;
"If no title was supplied, set it to the default.")
(XCL::EXEC-TITLE-FUNCTION XCL::WINDOW *EXEC-ID*))
(XCL::TITLE (* ;
"If a non-nil title was supplied, set the title to it.")
(WINDOWPROP XCL::WINDOW 'TITLE XCL::TITLE)))
(TTYDISPLAYSTREAM (DECODE/WINDOW/OR/DISPLAYSTREAM XCL::WINDOW)))
(LET [(*CURRENT-EVENT* NIL) (* ;
"the event being processed. Used by some commands")
(XCL::OLD-DS (CL:IF XCL::WINDOW
(TTYDISPLAYSTREAM (DECODE/WINDOW/OR/DISPLAYSTREAM XCL::WINDOW)))]
(CL:LOOP (CL:FORMAT T "~&~%%") (* ;
"newlines to notice that this is a new instance of the exec")
(PROG1 [ERSETQ (CL:LOOP (* ; "loop until errors out")
(CL:SETQ *CURRENT-EVENT* (GET-NEXT-HISTORY-EVENT
LISPXHISTORY *EXEC-ID*
XCL:*EXEC-PROMPT* (NOT
XCL::TOP-LEVEL-P
)))
(* ; "This optimization keeps HARDRESET from generating all new event numbers for all execs that are open.")
(PRINT-EVENT-PROMPT *CURRENT-EVENT*)
(DSPFONT INPUTFONT T)
(LET ((XCL::ORIGINAL-INPUT (EXEC-READ-LINE))
(LISPXHIST LISPXHIST)
(HELPCLOCK 0))
(DECLARE (CL:SPECIAL LISPXHIST HELPCLOCK))
(CL:UNLESS (CL:EQUAL XCL::ORIGINAL-INPUT
'(NIL))
(DO-EVENT XCL::ORIGINAL-INPUT XCL::ENVIRONMENT
XCL::FN)
(CL:WHEN XCL::TOP-LEVEL-P
(* ; "Used to determine whether to cache the settings of the profile back into the process (for retrieval in case of hardreset).")
(XCL::SAVE-CURRENT-EXEC-PROFILE)))]
(CL:WHEN XCL::WINDOW (TTYDISPLAYSTREAM XCL::OLD-DS)))])
(CL:DEFUN EXEC-EVAL (FORM &OPTIONAL ENVIRONMENT &KEY (PROMPT ">")
(ID "eval/")
((:TYPE *CURRENT-EXEC-TYPE*)
'COMMON-LISP)) (* ; "Edited by JDS 16-Aug-90 12:55.")
(LET ((*CURRENT-EVENT* (GET-NEXT-HISTORY-EVENT LISPXHISTORY ID PROMPT T))
(LISPXHIST LISPXHIST)
(HELPCLOCK 0)
VALUES)
(DECLARE (CL:SPECIAL *CURRENT-EVENT* LISPXHIST HELPCLOCK))
(SETQ VALUES (CL:MULTIPLE-VALUE-LIST (EVAL-INPUT (CL:SETF (EXEC-EVENT-INPUT *CURRENT-EVENT*)
(LIST FORM))
ENVIRONMENT)))
(SETQ IT (CAR VALUES))
(COND
(*CURRENT-EVENT*
(* ;; "Only update the current event if it's not NIL. This might happen, e.g., if LISPXHIST has been set to NIL by the user.")
(CL:SETF (EXEC-EVENT-PROPS *CURRENT-EVENT*)
(LIST* 'LISPXVALUES VALUES (EXEC-EVENT-PROPS *CURRENT-EVENT*)))
(CL:SETF (EXEC-EVENT-VALUE *CURRENT-EVENT*)
IT)))
(CL:VALUES-LIST VALUES)))
(CL:DEFUN PRINT-ALL-DOCUMENTATION (NAME) (* ; "Edited 24-May-2024 20:52 by mth")
"Print all documentation strings for NAME (as symbol and string)."
(LET ((FOUND NIL))
(CL:DOLIST (TYPE FILEPKGTYPES)
(CL:WHEN (AND (CL:SYMBOLP TYPE)
(OR (GET TYPE :DEFINED-BY)
(GET TYPE 'DEFINED-BY))
(HASH-TABLE-FOR-DOC-TYPE TYPE))
(SETQ FOUND (OR (PRINT-DOCUMENTATION NAME TYPE)
FOUND))
(CL:WHEN (CL:SYMBOLP NAME)
(SETQ FOUND (OR (PRINT-DOCUMENTATION (STRING NAME)
TYPE)
FOUND)))))
(CL:UNLESS FOUND (CL:FORMAT *TERMINAL-IO* "No documentation found.~%%"))))
(CL:DEFUN PRINT-DOCUMENTATION (NAME TYPE)
"If it exists, print documentation for NAME as TYPE. Returns T if doc was found, else NIL."
[LET ((DOC (CL:DOCUMENTATION NAME TYPE)))
(AND DOC (TRUE (CL:FORMAT *TERMINAL-IO* "~&~A (~A)" DOC (OR (CL:DOCUMENTATION NAME
'DEFINE-TYPES)
TYPE])
(DEFMACRO VALUE-OF (&REST EVENT-SPEC)
`(EXEC-VALUE-OF ',EVENT-SPEC))
(CL:DEFUN ADD-EXEC (&KEY (XCL::PROFILE XCL:*PROFILE*)
XCL::REGION XCL::TTY (EXEC 'EXEC)
XCL::ID &ALLOW-OTHER-KEYS)
(LET* [(XCL::WINDOW (XCL::SETUP-EXEC-WINDOW (CREATEW XCL::REGION "Exec")))
(XCL::HANDLE (ADD.PROCESS
`[PROGN (TTYDISPLAYSTREAM ',XCL::WINDOW)
(PROCESSPROP (THIS.PROCESS)
'WINDOW
',XCL::WINDOW)
,(CASE EXEC
(EXEC `(EXEC :TOP-LEVEL-P T :PROFILE ',XCL::PROFILE :ID
',XCL::ID))
(T `(XCL::ENTER-EXEC-FUNCTION ',EXEC ',XCL::PROFILE
',XCL::ID)))]
'NAME
'EXEC
'RESTARTABLE T 'INTERRUPTS (LISPINTERRUPTS]
(AND XCL::TTY (TTY.PROCESS XCL::HANDLE))
XCL::HANDLE))
(CL:DEFUN EXEC-READ-LINE (&OPTIONAL BUFFER-STRING)
(* ;; "Code stolen from READLINE, and not cleaned up. ")
[PROG (LINE SPACEFLG CHRCODE (*IN-THE-DEBUGGER* NIL))
(COND
((AND (READP T)
(SYNTAXP (PEEKCCODE T T)
'EOL)) (* ;
"Avoid picking up end of line as a NIL.")
(READC T)))
(SETQ LINE (LIST (EXEC-READ BUFFER-STRING)))
TOP (COND
((LISTP (CAR LINE)) (* ;
"If we got a list, return right away--it's a standard EVAL form of input")
(GO OUT)))
LP (SETQ SPACEFLG NIL) (* ; "to distinguish between")
(* ; "FOO (A B)")
(* ; "FOO(A B)")
(* ;
"the latter has no space and returns right away")
LP1 (COND
((NOT (READP T)) (* ;
"nothing more in line buffer, so must have consumed last thing on the line")
(GO OUT))
((NULL (SETQ CHRCODE (PEEKCCODE T T))) (* ; "PEEKCCODE can return NIL when stream is at EOF. However, we already checked for READP before getting here.")
(GO OUT))
((SYNTAXP CHRCODE 'EOL)
(READC T)
(GO OUT))
((OR (SYNTAXP CHRCODE 'RIGHTPAREN *READTABLE*)
(SYNTAXP CHRCODE 'RIGHTBRACKET *READTABLE*))
(AND (READ T *READTABLE*)
(SHOULDNT))
(AND (NULL (CDR LINE))
(SETQ LINE (NCONC1 LINE NIL))) (* ;
" A %")%" is treated as NIL if it is the second thing on the line when EXEC-READ-LINE is called")
(GO OUT))
((EQ CHRCODE (CHARCODE SPACE))
(SETQ SPACEFLG T)
(READC T)
(GO LP1)))
(SETQ LINE (NCONC1 LINE (EXEC-READ)))
(COND
((NULL (OR (SYNTAXP (SETQ CHRCODE (CHCON1 (LASTC T)))
'RIGHTPAREN *READTABLE*)
(SYNTAXP CHRCODE 'RIGHTBRACKET *READTABLE*)))
(GO LP))
((NOT SPACEFLG) (* ;
"A list terminates the line if it is the second element on the line, not preceded by a space.")
(* ;; "[JDS 1/12/88: This used to test (AND (NOT SPACEFLG) (READP T)), and loop if there were more input pending. This seems wrong, because when you type it should throw the carriage at once, and not depend on how fast you're typing. Further, when there's type-ahead, it's often followed by a SPACE, to prevent output pausing. With the old test here, that would hang up a final eval-quote form without executing it.]")
(GO OUT))
(T (GO LP)))
(GO LP)
OUT (RETURN (COND
((AND (LISTP LINE)
CTRLUFLG) (* ;
"Edit interrupt during reading--forces structure editor use.")
(SETQ CTRLUFLG NIL)
(LET ((*EDIT-INPUT-WITH-TTYIN* NIL))
(FIX-FORM LINE)))
(T LINE])
(DEFMACRO EXEC-EVENT-ID-PROMPT (EVENT-ID)
`(CDDR ,EVENT-ID))
(CL:DEFUN FIND-EXEC-COMMAND (NAME TABLE)
"Find an exec command based on its name (either a string or a symbol). Returns the command entry or NIL if not found."
(CL:WHEN (OR (CL:STRINGP NAME)
(CL:SYMBOLP NAME))
(LET ((STR (CL:IF (CL:SYMBOLP NAME)
(CL:SYMBOL-NAME NAME)
NAME)))
(CL:SOME #'(CL:LAMBDA (TABLE)
(SETQ COM (GETHASH STR TABLE)))
TABLE))))
(CL:DEFUN CIRCLAR-COPYER (INPUT) (* ; "Edited by TT 31-May-1990")
(PROG (SCANBUF REST VAL NEW BODY ID AUX (CIRCLAR-FLAG NIL))
(COND
((NLISTP INPUT)
(RETURN INPUT))
(T [push SCANBUF (CONS INPUT (SETQ VAL (CONS NIL NIL]
(push REST VAL)
(RPLACA VAL (CAR INPUT))
(RPLACD VAL (CDR INPUT))
(* ;;; "(COND ((EQ X (CAR X)) (RPLACA VAL VAL)) (T (RPLACA VAL (CAR X)))) (COND ((EQ X (CDR X)) (RPLACD VAL VAL)) (T (RPLACD VAL (CDR X))))")
)) (* ; "Initialization is over")
LP (SETQ BODY (pop REST))
LP0 [COND
((NULL BODY)
(RETURN (CL:VALUES VAL CIRCLAR-FLAG)))
((NLISTP BODY)
(GO LP))
(T (SETQ NEW BODY)
(COND
((NLISTP (CDR NEW)))
((SETQ ID (FASSOC (CDR NEW)
SCANBUF))
(SETQ CIRCLAR-FLAG T)
(RPLACD NEW (CDR ID)))
(T [push REST (SETQ AUX (CONS (CADR NEW)
(CDDR NEW]
(push SCANBUF (CONS (CDR NEW)
AUX))
(RPLACD NEW AUX)))
(COND
((NLISTP (CAR NEW)))
((SETQ ID (FASSOC (CAR NEW)
SCANBUF))
(SETQ CIRCLAR-FLAG T)
(RPLACA NEW (CDR ID)))
(T [push REST (SETQ AUX (CONS (CAAR NEW)
(CDAR NEW]
(push SCANBUF (CONS (CAR NEW)
AUX))
(RPLACA NEW AUX]
(GO LP)))
(DEFINEQ
(COPY-CIRCLE
(LAMBDA (X) (* ; "Edited 23-May-90 15:02 by Tomtom") (PROG (SCANBUF REST VAL NEW BODY ID AUX) (COND ((NLISTP X) (RETURN X)) (T (push SCANBUF (CONS X (SETQ VAL (CONS NIL NIL)))) (push REST VAL) (RPLACA VAL (CAR X)) (RPLACD VAL (CDR X)) (* ;;; "(COND ((EQ X (CAR X)) (RPLACA VAL VAL)) (T (RPLACA VAL (CAR X)))) (COND ((EQ X (CDR X)) (RPLACD VAL VAL)) (T (RPLACD VAL (CDR X))))"))) (* ; "Initialization is over") LP (SETQ BODY (pop REST)) LP0 (COND ((NULL BODY) (RETURN VAL)) ((NLISTP BODY) (GO LP)) (T (SETQ NEW BODY) (COND ((NLISTP (CDR NEW))) ((SETQ ID (FASSOC (CDR NEW) SCANBUF)) (RPLACD NEW (CDR ID))) (T (push REST (SETQ AUX (CONS (CADR NEW) (CDDR NEW)))) (push SCANBUF (CONS (CDR NEW) AUX)) (RPLACD NEW AUX))) (COND ((NLISTP (CAR NEW))) ((SETQ ID (FASSOC (CAR NEW) SCANBUF)) (RPLACA NEW (CDR ID))) (T (push REST (SETQ AUX (CONS (CAAR NEW) (CDAR NEW)))) (push SCANBUF (CONS (CAR NEW) AUX)) (RPLACA NEW AUX))))) (GO LP)))
)
)
(* ; "CIRCLAR-COPYER and COPY-CIRCLE are the solution for AR#11172")
(DEFINEQ
(EXEC-READ
[CL:LAMBDA (&OPTIONAL BUFFER-STRING) (* ; "Edited 4-Feb-88 18:22 by amd")
(* ;;; "Reads structure from the user (in the exec), taking care to handle read errors so that they will be edited and fixed.")
(HANDLER-BIND [[XCL:SYMBOL-COLON-ERROR #'(LAMBDA (CONDITION)
(DECLARE (CL:SPECIAL CTRLUFLG))
(CL:FORMAT *TERMINAL-IO* "~a~%%" CONDITION)
(SETQ CTRLUFLG T)
(XCL::ESCAPE-COLONS-PROCEED)
(SHOULDNT
"Didn't find XCL::ESCAPE-COLONS-PROCEED"]
[XCL:MISSING-EXTERNAL-SYMBOL #'(LAMBDA (CONDITION)
(DECLARE (CL:SPECIAL CTRLUFLG))
(CL:FORMAT *TERMINAL-IO* "~a~%%" CONDITION)
(SETQ CTRLUFLG T)
(XCL:MAKE-INTERNAL-PROCEED)
(SHOULDNT
"Didn't find XCL:MAKE-INTERNAL-PROCEED"
]
(XCL:MISSING-PACKAGE #'(LAMBDA (CONDITION)
(DECLARE (CL:SPECIAL CTRLUFLG))
(CL:FORMAT *TERMINAL-IO* "~a~%%" CONDITION)
(SETQ CTRLUFLG T)
(XCL:UGLY-SYMBOL-PROCEED)
(SHOULDNT "Didn't find XCL:UGLY-SYMBOL-PROCEED"]
(COND
([OR (NOT (GETD 'TTYIN))
(NOT *EDIT-INPUT-WITH-TTYIN*)
(NOT (DISPLAYSTREAMP (GETSTREAM T 'OUTPUT]
(* ;
"If debugging and TTYIN breaks, don't want to die")
(CL:READ T))
(T (LET (X)
(COND
((OR (LINEBUFFER-SKIPSEPRS T *READTABLE*)
(until (SETQ X (TTYIN "" NIL NIL '(EVALQT FILLBUFFER NOPROMPT)
NIL NIL BUFFER-STRING *READTABLE*))
do
(* ;; "Until he types something at all, keep printing the event-number prompt.")
(PRINT-EVENT-PROMPT *CURRENT-EVENT*)
(DSPFONT INPUTFONT T))
(EQ X T))
(CL:READ-PRESERVING-WHITESPACE T))
(T (CAR X])
(DIR
[NLAMBDA ARGS (* ; "Edited 12-Mar-87 16:08 by raf")
(DODIR ARGS])
)
(CL:DEFPARAMETER *PER-EXEC-VARIABLES*
'((CL:* CL:*)
(CL:** CL:**)
(CL:*** CL:***)
(+ +)
(CL:++ CL:++)
(CL:+++ CL:+++)
(- -)
(/ /)
(CL:// CL://)
(CL:/// CL:///)
(HELPFLAG T)
(*EVALHOOK* NIL)
(*APPLYHOOK* NIL)
(*ERROR-OUTPUT* *TERMINAL-IO*)
(*READTABLE* *READTABLE*)
(*PACKAGE* *PACKAGE*)
(XCL:*EVAL-FUNCTION* XCL:*EVAL-FUNCTION*)
(XCL:*EXEC-PROMPT* XCL:*EXEC-PROMPT*)
(XCL:*DEBUGGER-PROMPT* XCL:*DEBUGGER-PROMPT*))
"List of (non-profile) variables rebound for each Exec")
(CL:DEFVAR CL:* NIL)
(CL:DEFVAR CL:** NIL)
(CL:DEFVAR CL:*** NIL)
(CL:DEFVAR + NIL)
(CL:DEFVAR CL:++ NIL)
(CL:DEFVAR CL:+++ NIL)
(CL:DEFVAR - NIL)
(CL:DEFVAR / NIL
"Holds a list of all the values returned by the most recent top-level EVAL.")
(CL:DEFVAR CL:// NIL
"Gets the previous value of / when a new value is computed.")
(CL:DEFVAR CL:/// NIL
"Gets the previous value of // when a new value is computed.")
(CL:DEFVAR *CURRENT-EVENT* NIL
"contains the current event being processed. Used for communicating between Exec and commands")
(CL:DEFVAR *EXEC-ID* NIL
"A unique per-exec-process ID so that commands that search the history list can find this Exec's events"
)
(CL:DEFVAR XCL:*EXEC-PROMPT* "> "
"Default prompt used by exec")
(CL:DEFPARAMETER XCL:*EVAL-FUNCTION* 'CL:EVAL "The evaluator to use in the exec")
(CL:DEFVAR *NOT-YET-EVALUATED* "<not yet evaluated>")
(CL:DEFVAR *THIS-EXEC-COMMANDS* NIL
"List of command hash-tables for the current executive")
(DEFGLOBALVAR *EXEC-COMMAND-TABLE* (HASHARRAY 30 NIL 'STRING-EQUAL-HASHBITS 'STRING-EQUAL)
"hash-table for top level exec commands")
(DEFGLOBALVAR *DEBUGGER-COMMAND-TABLE* (HASHARRAY 20 NIL 'STRING-EQUAL-HASHBITS 'STRING-EQUAL)
"string-equal hash-table for debugger commands")
(CL:DEFVAR *CURRENT-EXEC-TYPE* NIL
"Rebound under Exec; if NIL, means use default")
(CL:DEFPARAMETER *EXEC-MAKE-UNDOABLE-P* T
"global parameter controls whether the exec makes input undoable")
(CL:DEFVAR *EDIT-INPUT-WITH-TTYIN* T)
(DEFINEQ
(DO-APPLY-EVENT
[LAMBDA (TODO) (* lmm "31-Jul-86 03:22")
(CL:IF (CL:MACRO-FUNCTION (CAR TODO))
(CL:IF (EQ (ARGTYPE (CAR TODO))
3)
(CL:FUNCALL (CAR TODO)
(CL:IF (CDDR TODO)
(CDR TODO)
(CADR TODO)))
(CL:EVAL TODO))
(CL:APPLY (CAR TODO)
(CADR TODO])
(DO-HISTORY-SEARCH
[LAMBDA (SPEC PRED-P VALUE-P) (* ; "Edited 10-Mar-87 18:53 by raf")
(* ;;
"SEARCHES HISTORY LIST, LOOKING FOR SPEC AND RESETTING *EVENTS* TO THE CORRESPONDING TAIL.")
(PROG (PAT1 PAT2 TEM PRED)
(DECLARE (CL:SPECIAL *EVENTS*)) (* ; "Setup by FIND-HISTORY-EVENTS")
[COND
((NOT PRED-P)
(SETQ PAT2 (EDITFPAT SPEC T]
LP [COND
((EQ (CAR *EVENTS*)
*CURRENT-EVENT*)
(SETQ *EVENTS* (CDR *EVENTS*]
[COND
((COND
(PRED-P (APPLY* SPEC (CAR *EVENTS*)))
[PAT1 (EDIT4E PAT1 (CAR (EXEC-EVENT-INPUT (CAR *EVENTS*]
(T (EDITFINDP [COND
(VALUE-P (CL:GETF (EXEC-EVENT-PROPS (CAR *EVENTS*))
'LISPXVALUES))
(T (EXEC-EVENT-INPUT (CAR *EVENTS*]
PAT2 T)))
(RETURN *EVENTS*))
(T (SETQ *EVENTS* (CDR *EVENTS*]
LP1 (COND
((NULL *EVENTS*)
(RETURN NIL)))
(GO LP])
(EVAL-INPUT
[CL:LAMBDA
(TODO ENV) (* ; "Edited 23-Nov-87 13:07 by raf")
(CASE XCL:*EVAL-FUNCTION*
[EVAL (* ; "Interlisp EVAL")
(COND
[(CDR TODO) (* ; "this is the 'apply' case")
(* ;; "we first check for input of things like macros in apply format or Interlisp NLAMBDA functions (which have a MACRO-FUNCTION)")
(if [OR (CDDR TODO)
(AND (CADR TODO)
(NLISTP (CADR TODO]
then
(if (FMEMB (ARGTYPE (CAR TODO))
'(1 3))
then (* ;
"this is an Interlisp NLAMBDA function (1 = spread, 3 = nospread).")
[if (AND (EQ (ARGTYPE (CAR TODO))
3)
(CDDR TODO))
then
(APPLY (CAR TODO)
(CDR TODO))
else
(if (CDDR TODO)
then
(PRIN1 "... = ")
(PRINT TODO)
(APPLY (CAR TODO)
(CDR TODO))
else
(APPLY (CAR TODO)
(CADR TODO]
else
(* ;; "evaluate the entire input list as if it were typed in with parens around it, e.g. a 'FOR I FROM 1 TO 10 DO ...' possibly bogus 'DWIM' case")
(EVAL TODO))
else (* ; "a normal apply case")
(if (CDDR TODO)
then
(PRIN1 "... = ")
(PRINT TODO)
(APPLY (CAR TODO)
(MAPCAR (CDR TODO)
(FUNCTION EVAL)))
else
(APPLY (CAR TODO)
(CADR TODO]
(T (* ; "a normal eval case")
(EVAL (CAR TODO]
(T (* ; "Common Lisp EVAL")
(* ;; "maybe should have used ECASE and checked for Common-Lisp explicitly, but could get recursive errors if *current-exec-type* was rebound")
(COND
[(CDR TODO) (* ; "this is the 'apply' case")
(* ;; "we first check for input of things like macros in apply format or Interlisp NLAMBDA functions (which have a MACRO-FUNCTION)")
(COND
[(CL:MACRO-FUNCTION (CAR TODO))
(COND
[(FMEMB (ARGTYPE (CAR TODO))
'(1 3)) (* ;
"this is an Interlisp NLAMBDA function (1 = spread, 3 = nospread).")
(COND
((AND (EQ (ARGTYPE (CAR TODO))
3)
(CDDR TODO))
(APPLY (CAR TODO)
(CDR TODO)))
(T (COND
((CDDR TODO)
(PRIN1 "... = ")
(PRINT TODO)
(APPLY (CAR TODO)
(CDR TODO)))
(T (APPLY (CAR TODO)
(CADR TODO]
(T
(* ;; "evaluate the entire input list as if it were typed in with parens around it, e.g. a 'FOR I FROM 1 TO 10 DO ...' possibly bogus 'DWIM' case")
(CL:EVAL TODO ENV]
(T (* ; "a normal apply case")
(COND
[(CDDR TODO)
(PRIN1 "... = ")
(PRINT TODO)
(CL:APPLY (CAR TODO)
(CL:MAPCAR #'(CL:LAMBDA (A)
(CL:EVAL A ENV)) (CDR TODO]
(T (CL:APPLY (CAR TODO)
(CADR TODO]
(T (* ; "a normal eval case")
(CL:EVAL (CAR TODO)
ENV])
(EVENTS-INPUT
[CL:LAMBDA (EVENTS) (* ; "Edited 26-Nov-86 11:16 by lmm")
(* ;
"takes a list of events and returns the input concatenated into a single event, as appropriate ")
(IF (CDR EVENTS)
THEN
[CONS 'DO-EVENTS (FOR EVENT IN EVENTS COLLECT (IF (CDR (EXEC-EVENT-INPUT
EVENT))
THEN
(CONS 'EVENT (
EXEC-EVENT-INPUT
EVENT))
ELSE
(CAR (EXEC-EVENT-INPUT
EVENT]
ELSE
(LET* ((INPUT (EXEC-EVENT-INPUT (CAR EVENTS)))
(TAIL (FMEMB HISTSTR0 INPUT)))
(IF TAIL THEN (LDIFF INPUT TAIL)
ELSE INPUT])
(EXEC-PRIN1
(CL:LAMBDA (VALUE) (* ; "Edited 23-Feb-87 18:15 by raf")
(WRITE VALUE :STREAM *TERMINAL-IO* :ESCAPE T)))
(EXEC-VALUE-OF
[LAMBDA (EVENT-SPEC) (* lmm "11-Sep-86 17:28")
(CL:VALUES-LIST (LISTGET (EXEC-EVENT-PROPS (CAR (FIND-HISTORY-EVENTS EVENT-SPEC
LISPXHISTORY)))
'LISPXVALUES])
(GET-NEXT-HISTORY-EVENT
[LAMBDA (HISTORY ID PROMPT FIRST-ONLY) (* ; "Edited 2-Mar-87 15:34 by raf")
(for EVENT in (HISTORY-EVENTS HISTORY)
do
(CL:WHEN (EQ (CADR (LISTP (EXEC-EVENT-ID EVENT)))
ID)
(CL:IF (AND (NULL (EXEC-EVENT-INPUT EVENT))
(NULL (EXEC-EVENT-PROPS EVENT)))
(PROGN (CL:SETF (CDDR (EXEC-EVENT-ID EVENT))
PROMPT)
(RETURN EVENT))
(GO $$OUT)))
(if FIRST-ONLY then (* ; "only do this for the first event")
(GO $$OUT))
finally
(COND
(HISTORY (* ; "Watch out for NIL LISPXHISTORY")
(SETQ EVENT (MAKE-EXEC-EVENT :ID (LIST* (CL:INCF (HISTORY-INDEX
HISTORY))
ID PROMPT)))
(CL:PUSH EVENT (HISTORY-EVENTS HISTORY))
(CL:SETF (CDR (CL:NTHCDR (CL:1- (HISTORY-SIZE HISTORY))
(HISTORY-EVENTS HISTORY)))
NIL)
(RETURN EVENT])
(HISTORY-ADD-TO-SPELLING-LISTS
[LAMBDA (INPUT) (* lmm "31-Jul-86 02:22")
(COND
((CDR INPUT) (* ;
"Add to the spelling list if it has a definition")
(AND (LITATOM (CAR INPUT))
(FGETD (CAR INPUT))
(ADDSPELL (CAR INPUT)
2)))
([AND (CL:CONSP (CAR INPUT))
(LITATOM (CAR (CAR INPUT] (* ; "looks like a valid function")
(AND [OR (CL:FBOUNDP (CAR (CAR INPUT)))
(CL:SPECIAL-FORM-P (CAR (CAR INPUT]
(ADDSPELL (CAR (CAR INPUT))
2)))
((AND (CL:SYMBOLP (CAR INPUT))
(BOUNDP (CAR INPUT)))
(ADDSPELL (CAR INPUT)
3])
(HISTORY-NTH
[LAMBDA (LST N ID) (* lmm " 6-Nov-86 01:40")
(bind EVENT while LST do (if (<= N 0)
then
(RETURN))
(SETQ EVENT (CAR LST))
(CL:IF (AND (EXEC-EVENT-INPUT EVENT)
(NEQ EVENT *CURRENT-EVENT*)
(OR (NOT (STRINGP ID))
(EQ (CADR (LISTP (EXEC-EVENT-ID EVENT)))
ID)))
(if (<= (CL:DECF N)
0)
then
(RETURN LST)))
(pop LST])
(PRINT-HISTORY
[CL:LAMBDA (HISTORY EVENT-SPECS &OPTIONAL NOVALUES) (* lmm " 5-Nov-86 23:29")
(PROG [HELPCLOCK (EVENTS (CL:IF EVENT-SPECS (FIND-HISTORY-EVENTS EVENT-SPECS
HISTORY)
(HISTORY-EVENTS HISTORY]