Add macro for debug output to console

[menb111]

Hi,
I'm currently learning Arm64 assembly and I find it quiet cumbersome to get gdb ready for debugging.
I guess on native ARM hardware it shouldn't be that hard but unfortunatly I'm doing the exercises on my x86 machine.

.macro debug reg fmt_str=""
    .pushsection .rodata
    .ifeqs "\fmt_str", "" 
            l_fmt_str\@: .asciz "Register \reg: %d\n"
    .else
            l_fmt_str\@: .asciz "\fmt_str"
    .endif
    .popsection

    sub sp, sp, #16
    stp x29, x30, [sp]
    mov x29, sp   // FP points to frame record

    mov x1, \reg
    ldr x0, =l_fmt_str\@
    bl printf

    ldp x29, x30, [sp]
    add sp, sp, #16
.endm

I know, it's not perfect and there is a lot of room for improvement.
For example the register x0 and x1 are modified when the macro is used (the user might not expect this).
But I posted it so you get the idea what I have in mind.

An additional file like debug.s could be provided with the exercises which can be included by the user with .include "debug.s"

The macro is then called like so:
debug x1 which give an output like Register x1: 42.

It can also be called with a user defined format string:
debug x1 "My custom debug message: Register x1 is now set to %d\n" which will give something like "My custom debug message: Register x1 is now set to 42".

[github-actions]

Hello. Thanks for opening an issue on Exercism 🙂

At Exercism we use our Community Forum, not GitHub issues, as the primary place for discussion. That allows maintainers and contributors from across Exercism's ecosystem to discuss your problems/ideas/suggestions without them having to subscribe to hundreds of repositories.

This issue will be automatically closed. Please use this link to copy your GitHub Issue into a new topic on the forum, where we look forward to chatting with you!

If you're interested in learning more about this auto-responder, please read this blog post.

[keiravillekode]

If we call printf, it might modify x0...x15, so a macro should also preserve them.

[menb111]

This is the next iteration:

.macro debug reg fmt_str=""
    .pushsection .rodata
    .ifeqs "\fmt_str", "" 
            l_fmt_str\@: .asciz "Register \reg: %d\n"
    .else
            l_fmt_str\@: .asciz "\fmt_str"
    .endif
    .popsection

    stp x29, x30, [sp, #-16]! // Save frame pointer and link register

    // save registers x0 to x15
    stp x0, x1, [sp, #-16]!
    stp x2, x3, [sp, #-16]!
    stp x4, x5, [sp, #-16]!
    stp x6, x7, [sp, #-16]!
    stp x8, x9, [sp, #-16]!
    stp x10, x11, [sp, #-16]!
    stp x12, x13, [sp, #-16]!
    stp x14, x15, [sp, #-16]!    

    // save conditon flags NZCV
    mrs x0, nzcv         // Move NZCV flags to x0
    stp x0, xzr, [sp, #-16]!   // Push x0 to stack, keep alignment with xzr as padding

    // fp points to the frame record
    mov x29, sp 

    // call printf to print the register value
    mov x1, \reg
    ldr x0, =l_fmt_str\@
    bl printf

    // restore NZCV flags
    ldp x0, xzr, [sp], #16 // Restore NZCV flags from stack
    msr nzcv, x0 // Move x0 back to NZCV flags

    // restore registers x0 to x15
    ldp x14, x15, [sp], #16
    ldp x12, x13, [sp], #16
    ldp x10, x11, [sp], #16
    ldp x8, x9, [sp], #16
    ldp x6, x7, [sp], #16
    ldp x4, x5, [sp], #16
    ldp x2, x3, [sp], #16
    ldp x0, x1, [sp], #16

    ldp x29, x30, [sp], #16 // Restore frame pointer and link register
.endm

I did a quick test, running the following loop and verifying that the register values are the same:

    .loop:
        debug x0 "Test message with register x0: %d\n"
        debug x1 "Test message with register x1: %d\n"
        debug x2 "Test message with register x2: %d\n"
        debug x3 "Test message with register x3: %d\n"
        debug x4 "Test message with register x4: %d\n"
        debug x5 "Test message with register x5: %d\n"
        debug x6 "Test message with register x6: %d\n"
        debug x7 "Test message with register x7: %d\n"
        debug x8 "Test message with register x8: %d\n"
        debug x9 "Test message with register x9: %d\n"
        debug x10 "Test message with register x10: %d\n"
        debug x11 "Test message with register x11: %d\n"
        debug x12 "Test message with register x12: %d\n"
        debug x13 "Test message with register x13: %d\n"
        debug x14 "Test message with register x14: %d\n"
        debug x15 "Test message with register x15: %d\n"
    b .loop

Edit: Also stored the condition flags NZCV to stack before calling printf and restored it afterwards. Otherwise the users comparison instructions might be influenced when debug macro is used at the "wrong" location.

[ahans]

I generally like the idea of having some debugging macro like this, but I'm not sure we should include it with all exercises. I think I would find it more appropriate to have it as part of the documentation, so that people can copy it themselves if they want it.

Regarding gdb, however, that also seems to be quite usable even with emulation on x86-64. You need to pass something like -g 9000 to qemu-aarch64 so that it listens for GDB. Then you need to use gdb-multiarch so that it understands aarch64 and tell it a bit about your environment. But from there, it's normal gdb debugging.

More details:

1. Install gdb: sudo apt install gdb-multiarch
2. Tell qemu to listen for gdb on port 9000: qemu-aarch64 -L /usr/aarch64-linux-gnu -g 9000 ./tests
3. Then, in another terminal window:

gdb-multiarch \
    -ex 'set architecture aarch64' \
    -ex 'set sysroot /usr/aarch64-linux-gnu' \
    -ex 'file ./tests' \
    -ex 'target remote localhost:9000'`

I don't have that much experience with plain gdb, but an additional -ex 'layout asm' -ex 'layout regs' seems useful. Then you can break find_anagrams (or whatever your function) and cont to run the program.

We could add this to the documentation as well. Having a make target debug could also be helpful and would be less intrusive than a debugging macro.

[ahans]

I quickly tried this out, this extra target in the makefile seems to be working:

debug: tests
	(qemu-aarch64 -L /usr/aarch64-linux-gnu -g 9000 ./tests &)
	gdb-multiarch \
		-ex 'set architecture aarch64' \
		-ex 'set sysroot /usr/aarch64-linux-gnu' \
		-ex 'file ./tests' \
		-ex 'target remote localhost:9000' \
		-ex 'layout asm' \
		-ex 'layout regs'