globalplatform: init at 2.4.0-unreleased

Author: StarGate01

pkgs/by-name/gl/globalplatform/package.nix

@@ -0,0 +1,87 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pcsclite,
+  PCSC,
+  pkg-config,
+  cmake,
+  zlib,
+  pandoc,
+  doxygen,
+  graphviz,
+  openssl,
+  cmocka,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "globalplatform";
+  version = "2.4.0-unreleased";
+
+  src = fetchFromGitHub {
+    owner = "kaoh";
+    repo = "globalplatform";
+    rev = "c901eabd771379e43ebd71bcf8071398b868a591";
+    sha256 = "sha256-dGbGDDlQ01crqS9J1cTd9xNpagKgdV+ha4HtnPK8SZo=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    cmake
+    pandoc
+    doxygen
+    graphviz
+    makeWrapper
+  ];
+
+  buildInputs =
+    [
+      zlib
+      openssl
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isLinux [
+      pcsclite
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [
+      PCSC
+    ];
+
+  cmakeFlags = [
+    "-DTESTING=ON"
+  ];
+
+  doCheck = true;
+
+  nativeCheckInputs = [
+    cmocka
+  ];
+
+  preCheck = ''
+    cp "$src/gpshell/helloworld.cap" globalplatform/src
+    cp "$src/globalplatform/src/rsa_pub_key_test.pem" globalplatform/src
+  '';
+
+  # gpshell uses dlopen() to load libgppcscconnectionplugin.so at runtime
+
+  wrapperArgs =
+    lib.optionals stdenv.hostPlatform.isLinux [
+      "--prefix LD_LIBRARY_PATH : ${placeholder "out"}/lib"
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [
+      "--prefix DYLD_LIBRARY_PATH : ${placeholder "out"}/lib"
+    ];
+
+  preFixup = ''
+    wrapProgram $out/bin/gpshell $wrapperArgs
+  '';
+
+  meta = {
+    description = "C library + command-line for Open- / GlobalPlatform smart cards";
+    mainProgram = "gpshell";
+    homepage = "https://github.com/kaoh/globalplatform";
+    license = lib.licenses.gpl3Only;
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+    maintainers = with lib.maintainers; [ stargate01 ];
+  };
+})

pkgs/top-level/all-packages.nix

@@ -3375,6 +3375,10 @@ with pkgs;
 
   gitqlient = libsForQt5.callPackage ../applications/version-management/gitqlient { };
 
+  globalplatform = callPackage ../by-name/gl/globalplatform/package.nix {
+    inherit (darwin.apple_sdk.frameworks) PCSC;
+  };
+
   glogg = libsForQt5.callPackage ../tools/text/glogg { };
 
   gmrender-resurrect = callPackage ../tools/networking/gmrender-resurrect {