reaper-sws-extension: init at 2.14.0.3

Author: pancaek

pkgs/by-name/re/reaper-sws-extension/darwin.nix

@@ -0,0 +1,52 @@
+{
+  stdenvNoCC,
+  fetchurl,
+  pname,
+  version,
+  meta,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  inherit
+    pname
+    version
+    meta
+    ;
+  srcs =
+
+    let
+      plugin = fetchurl {
+        url =
+          let
+            arch = if stdenvNoCC.hostPlatform.system == "x86_64-darwin" then "x86_64" else "arm64";
+          in
+          "https://github.com/reaper-oss/sws/releases/download/v${finalAttrs.version}/reaper_sws-${arch}.dylib";
+        hash =
+          {
+            x86_64-darwin = "sha256-12w70z2xxl53glnf5w5dcfxp7gw2bd0cbqbhs6zs05dxci0kjpq7";
+            aarch64-darwin = "sha256-12zfg8hay3k23g9x8ygqxn20k9yd66yqz01z92nxapf8b4zg41pj";
+          }
+          .${stdenvNoCC.hostPlatform.system};
+      };
+    in
+    [
+      plugin
+      (fetchurl {
+        url = "https://github.com/reaper-oss/sws/releases/download/v${finalAttrs.version}/sws_python64.py";
+        hash = "sha256-0pb18gh6nacjhk48yzpn2bnj26jv6lap3y4y97flff539zmy7s32";
+      })
+      (fetchurl {
+        url = "https://github.com/reaper-oss/sws/releases/download/v${finalAttrs.version}/sws_python32.py";
+        hash = "sha256-0cj9aayai8jfqcm7fhzf8w3cid78i0ryviwaying6kp9h1s76js2";
+      })
+    ];
+
+  dontUnpack = true;
+
+  installPhase = ''
+    runHook preInstall
+    install -D *.py -t $out/Scripts
+    install -D *.dylib -t $out/UserPlugins
+    runHook postInstall
+  '';
+})

pkgs/by-name/re/reaper-sws-extension/linux.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  php,
+  perl,
+  git,
+  pkg-config,
+  gtk3,
+
+  pname,
+  version,
+  meta,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  inherit pname version meta;
+
+  src = fetchFromGitHub {
+    owner = "reaper-oss";
+    repo = "sws";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-37pBbNACQuuEk1HJTiUHdb0mDiR2+ZsEQUOhz7mrPPg=";
+    fetchSubmodules = true;
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+    git
+    perl
+    php
+    pkg-config
+  ];
+
+  buildInputs = [ gtk3 ];
+
+})

pkgs/by-name/re/reaper-sws-extension/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  stdenvNoCC,
+  callPackage,
+}:
+let
+  p = if stdenvNoCC.hostPlatform.isDarwin then ./darwin.nix else ./linux.nix;
+in
+callPackage p {
+
+  pname = "reaper-sws-extension";
+  version = "2.14.0.3";
+  meta = {
+    description = "Reaper Plugin Extension";
+    longDescription = ''
+      The SWS / S&M extension is a collection of features that seamlessly integrate into REAPER, the Digital Audio Workstation (DAW) software by Cockos, Inc.
+      It is a collaborative and open source project.
+    '';
+    homepage = "https://www.sws-extension.org/";
+    maintainers = with lib.maintainers; [ pancaek ];
+    license = lib.licenses.mit;
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "x86_64-darwin"
+      "aarch64-darwin"
+    ];
+  };
+}