redis: refactor

- use `fetchFromGitHub` instead of downloading from redis.io
- use `fetchpatch2` instead of `fetchurl` and `fetchpatch`
- use `optional` instead of `optionals` in several places
- remove `with lib;`
- enable `tlsSupport` by default
- format with `nixfmt-rfc-style`
- remove `preBuild` which does not have any motivation behind
- add `which` and `python3` to `nativeBuildInputs`

Author: thecaralice

pkgs/by-name/re/redis/package.nix

@@ -1,53 +1,72 @@
-{ lib, stdenv, fetchurl, fetchpatch, lua, jemalloc, pkg-config, nixosTests
-, tcl, which, ps, getconf
-, withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd, systemd
-# dependency ordering is broken at the moment when building with openssl
-, tlsSupport ? !stdenv.hostPlatform.isStatic, openssl
-
-# Using system jemalloc fixes cross-compilation and various setups.
-# However the experimental 'active defragmentation' feature of redis requires
-# their custom patched version of jemalloc.
-, useSystemJemalloc ? true
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch2,
+  lua,
+  jemalloc,
+  pkg-config,
+  nixosTests,
+  tcl,
+  which,
+  ps,
+  getconf,
+  systemd,
+  openssl,
+  python3,
+
+  withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
+  tlsSupport ? true,
+  # Using system jemalloc fixes cross-compilation and various setups.
+  # However the experimental 'active defragmentation' feature of redis requires
+  # their custom patched version of jemalloc.
+  useSystemJemalloc ? true,
 }:
 
 stdenv.mkDerivation (finalAttrs: {
   pname = "redis";
   version = "7.2.5";
 
-  src = fetchurl {
-    url = "https://download.redis.io/releases/redis-${finalAttrs.version}.tar.gz";
-    hash = "sha256-WYEXlwb4OR8DvpHZUayvrtqRr3+sVr7/snAZYxA+Qj0=";
+  src = fetchFromGitHub {
+    owner = "redis";
+    repo = "redis";
+    rev = finalAttrs.version;
+    hash = "sha256-CHtCtyy/dzyXwwLKVqOCV9SPTybYGbSTWHTaiPGAVIQ=";
   };
 
-  patches = [
-    # fixes: make test [exception]: Executing test client: permission denied
-    # https://github.com/redis/redis/issues/12792
-    (fetchpatch {
-      url = "https://github.com/redis/redis/pull/12887.diff";
-      hash = "sha256-VZEMShW7Ckn5hLJHffQvE94Uly41WZW1bwvxny+Y3W8=";
-    })
-  ] ++ lib.optionals useSystemJemalloc [
-    # use system jemalloc
-    (fetchurl {
+  patches =
+    [
+      # fixes: make test [exception]: Executing test client: permission denied
+      # https://github.com/redis/redis/issues/12792
+      (fetchpatch2 {
+        url = "https://github.com/redis/redis/pull/12887.diff";
+        hash = "sha256-cv+EcVTz8j93E4ON0NpxwQiEPmt6/cWrmAsonvvYVfQ=";
+      })
+    ]
+    ++ lib.optional useSystemJemalloc (fetchpatch2 {
       url = "https://gitlab.archlinux.org/archlinux/packaging/packages/redis/-/raw/102cc861713c796756abd541bf341a4512eb06e6/redis-5.0-use-system-jemalloc.patch";
-      hash = "sha256-VPRfoSnctkkkzLrXEWQX3Lh5HmZaCXoJafyOG007KzM=";
-    })
-  ];
+      hash = "sha256-A9qp+PWQRuNy/xmv9KLM7/XAyL7Tzkyn0scpVCGngcc=";
+    });
 
-  nativeBuildInputs = [ pkg-config ];
+  nativeBuildInputs = [
+    pkg-config
+    which
+    python3
+  ];
 
-  buildInputs = [ lua ]
+  buildInputs =
+    [ lua ]
     ++ lib.optional useSystemJemalloc jemalloc
     ++ lib.optional withSystemd systemd
-    ++ lib.optionals tlsSupport [ openssl ];
-
-  preBuild = lib.optionalString stdenv.hostPlatform.isDarwin ''
-    substituteInPlace src/Makefile --replace "-flto" ""
-  '';
+    ++ lib.optional tlsSupport openssl;
 
   # More cross-compiling fixes.
-  makeFlags = [ "PREFIX=${placeholder "out"}" ]
-    ++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [ "AR=${stdenv.cc.targetPrefix}ar" "RANLIB=${stdenv.cc.targetPrefix}ranlib" ]
+  makeFlags =
+    [ "PREFIX=${placeholder "out"}" ]
+    ++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
+      "AR=${stdenv.cc.targetPrefix}ar"
+      "RANLIB=${stdenv.cc.targetPrefix}ranlib"
+    ]
     ++ lib.optionals withSystemd [ "USE_SYSTEMD=yes" ]
     ++ lib.optionals tlsSupport [ "BUILD_TLS=yes" ];
 
@@ -59,7 +78,11 @@ stdenv.mkDerivation (finalAttrs: {
 
   # darwin currently lacks a pure `pgrep` which is extensively used here
   doCheck = !stdenv.hostPlatform.isDarwin;
-  nativeCheckInputs = [ which tcl ps ] ++ lib.optionals stdenv.hostPlatform.isStatic [ getconf ];
+  nativeCheckInputs = [
+    which
+    tcl
+    ps
+  ] ++ lib.optionals stdenv.hostPlatform.isStatic [ getconf ];
   checkPhase = ''
     runHook preCheck
 
@@ -87,13 +110,16 @@ stdenv.mkDerivation (finalAttrs: {
   passthru.tests.redis = nixosTests.redis;
   passthru.serverBin = "redis-server";
 
-  meta = with lib; {
+  meta = {
     homepage = "https://redis.io";
     description = "Open source, advanced key-value store";
-    license = licenses.bsd3;
-    platforms = platforms.all;
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.all;
     changelog = "https://github.com/redis/redis/raw/${finalAttrs.version}/00-RELEASENOTES";
-    maintainers = with maintainers; [ berdario globin ];
+    maintainers = with lib.maintainers; [
+      berdario
+      globin
+    ];
     mainProgram = "redis-cli";
   };
 })