python312Packages.conduit[-mpi]: init at 0.9.3

Author: GaetanLepage

pkgs/by-name/co/conduit/package.nix

@@ -7,6 +7,7 @@
 
   # passthru
   conduit,
+  python3Packages,
   nix-update-script,
 
   mpiSupport ? false,
@@ -50,6 +51,8 @@ stdenv.mkDerivation (finalAttrs: {
   passthru = {
     tests = {
       withMpi = conduit.override { mpiSupport = true; };
+      pythonModule = python3Packages.conduit;
+      pythonModuleWithMpi = python3Packages.conduit.override { mpiSupport = true; };
     };
     updateScript = nix-update-script { };
   };

pkgs/development/python-modules/conduit/default.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  pkgs,
+  buildPythonPackage,
+  setuptools,
+  numpy,
+  pip,
+  openmpi,
+
+  mpiSupport ? false,
+}:
+let
+  conduit = pkgs.conduit.override { inherit mpiSupport; };
+
+  # As cmake is invoked by setup.py, adding openmpi to buildInputs is not enough for it to be found.
+  # It is necessary to explicitly provide openmpi's location through cmake flags.
+  mpi = lib.getDev openmpi;
+  mpiCmakeFlags = lib.concatStringsSep "', '" [
+    (lib.cmakeFeature "MPI_C_COMPILER" (lib.getExe' mpi "mpicc"))
+    (lib.cmakeFeature "MPI_CXX_COMPILER" (lib.getExe' mpi "mpicxx"))
+  ];
+in
+buildPythonPackage {
+  inherit (conduit)
+    pname
+    version
+    src
+    nativeBuildInputs
+    buildInputs
+    ;
+
+  postPatch =
+    ''
+      substituteInPlace setup.py \
+        --replace-fail \
+          "'-j2'" \
+          "f'-j{os.environ.get(\"NIX_BUILD_CORES\")}'"
+    ''
+    + lib.optionalString mpiSupport ''
+      substituteInPlace setup.py \
+        --replace-fail \
+          "cmake_args = [" \
+          "cmake_args = ['${mpiCmakeFlags}', "
+    '';
+
+  pyproject = true;
+  dontUseCmakeConfigure = true;
+
+  env.ENABLE_MPI = mpiSupport;
+
+  build-system = [
+    setuptools
+    numpy
+    pip
+  ];
+
+  pythonImportsCheck = [ "conduit" ];
+
+  # No python tests
+  doCheck = false;
+
+  meta = {
+    description = "Python bindings for the conduit library";
+    inherit (conduit.meta)
+      homepage
+      changelog
+      license
+      platforms
+      ;
+    maintainers = with lib.maintainers; [ GaetanLepage ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -2646,6 +2646,10 @@ self: super: with self; {
 
   conda-package-streaming = callPackage ../development/python-modules/conda-package-streaming { };
 
+  conduit = callPackage ../development/python-modules/conduit { };
+
+  conduit-mpi = callPackage ../development/python-modules/conduit { mpiSupport = true; };
+
   confection = callPackage ../development/python-modules/confection { };
 
   configargparse = callPackage ../development/python-modules/configargparse { };