[24.11] py7zr: init at 0.22.0; pyppmd: init at 1.1.1; pybcj: init at 1.0.3; multivolumefile: init at 0.2.3; inflate64: init at 1.0.1; pyzstd: init at 0.16.2

pkgs/development/python-modules/inflate64/default.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitea,
+  setuptools,
+  setuptools-scm,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "inflate64";
+  version = "1.0.1";
+  pyproject = true;
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "miurahr";
+    repo = "inflate64";
+    tag = "v${version}";
+    hash = "sha256-deFx8NMbGLP51CdNvmZ25LQ5FLPBb1PB3QhGhIfTMfc=";
+  };
+
+  build-system = [
+    setuptools
+    setuptools-scm
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [
+    "inflate64"
+  ];
+
+  meta = {
+    description = "Compress and decompress with Enhanced Deflate compression algorithm";
+    homepage = "https://codeberg.org/miurahr/inflate64";
+    changelog = "https://codeberg.org/miurahr/inflate64/src/tag/v${version}/docs/Changelog.rst#v${version}";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      pitkling
+      PopeRigby
+    ];
+  };
+
+}

pkgs/development/python-modules/multivolumefile/default.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitea,
+  setuptools,
+  setuptools-scm,
+  hypothesis,
+  pytest-timeout,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "multivolumefile";
+  version = "0.2.3";
+  pyproject = true;
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "miurahr";
+    repo = "multivolume";
+    tag = "v${version}";
+    hash = "sha256-7gjfF7biQZOcph2dfwi2ouDn/uIYik/KBQ0k6u5Ne+Q=";
+  };
+
+  postPatch =
+    # Fix typo: `tools` -> `tool`
+    # upstream PR: https://codeberg.org/miurahr/multivolume/pulls/9
+    ''
+      substituteInPlace pyproject.toml \
+        --replace-fail 'tools.setuptools_scm' 'tool.setuptools_scm'
+    '';
+
+  build-system = [
+    setuptools
+    setuptools-scm
+  ];
+
+  nativeCheckInputs = [
+    hypothesis
+    pytest-timeout
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [
+    "multivolumefile"
+  ];
+
+  meta = {
+    description = "Library to provide a file-object wrapping multiple files as virtually like as a single file";
+    homepage = "https://codeberg.org/miurahr/multivolume";
+    changelog = "https://codeberg.org/miurahr/multivolume/src/tag/v${version}/Changelog.rst#v${version}";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      pitkling
+      PopeRigby
+    ];
+  };
+}

pkgs/development/python-modules/py7zr/default.nix

@@ -0,0 +1,84 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  setuptools-scm,
+  brotli,
+  inflate64,
+  multivolumefile,
+  psutil,
+  pybcj,
+  pycryptodomex,
+  pyppmd,
+  pyzstd,
+  texttable,
+  py-cpuinfo,
+  pytest-benchmark,
+  pytest-remotedata,
+  pytest-timeout,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "py7zr";
+  version = "0.22.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "miurahr";
+    repo = "py7zr";
+    tag = "v${version}";
+    hash = "sha256-YR2cuHZWwqrytidAMbNvRV1/N4UZG8AMMmzcTcG9FvY=";
+  };
+
+  postPatch =
+    # Replace inaccessible mirror (qt.mirrors.tds.net):
+    # upstream PR: https://github.com/miurahr/py7zr/pull/637
+    ''
+      substituteInPlace tests/test_concurrent.py \
+        --replace-fail 'http://qt.mirrors.tds.net/qt/' 'https://download.qt.io/'
+    '';
+
+  build-system = [
+    setuptools
+    setuptools-scm
+  ];
+
+  dependencies = [
+    brotli
+    inflate64
+    multivolumefile
+    psutil
+    pybcj
+    pycryptodomex
+    pyppmd
+    pyzstd
+    texttable
+  ];
+
+  nativeCheckInputs = [
+    py-cpuinfo
+    pytest-benchmark
+    pytest-remotedata
+    pytest-timeout
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [
+    "py7zr"
+  ];
+
+  meta = {
+    description = "7zip in Python 3 with ZStandard, PPMd, LZMA2, LZMA1, Delta, BCJ, BZip2";
+    homepage = "https://github.com/miurahr/py7zr";
+    changelog = "https://github.com/miurahr/py7zr/blob/v${version}/docs/Changelog.rst#v${
+      builtins.replaceStrings [ "." ] [ "" ] version
+    }";
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [
+      pitkling
+      PopeRigby
+    ];
+  };
+}

pkgs/development/python-modules/pybcj/default.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitea,
+  setuptools,
+  setuptools-scm,
+  hypothesis,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "pybcj";
+  version = "1.0.3";
+  pyproject = true;
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "miurahr";
+    repo = "pybcj";
+    tag = "v${version}";
+    hash = "sha256-ExSt7E7ZaVEa0NwAQHU0fOaXJW9jYmEUUy/1iUilGz8=";
+  };
+
+  build-system = [
+    setuptools
+    setuptools-scm
+  ];
+
+  nativeCheckInputs = [
+    hypothesis
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [
+    "bcj"
+  ];
+
+  meta = {
+    description = "BCJ (Branch-Call-Jump) filter for Python";
+    homepage = "https://codeberg.org/miurahr/pybcj";
+    changelog = "https://codeberg.org/miurahr/pybcj/src/tag/v${version}/Changelog.rst#v${version}";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      pitkling
+      PopeRigby
+    ];
+  };
+}

pkgs/development/python-modules/pyppmd/default.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitea,
+  setuptools,
+  setuptools-scm,
+  hypothesis,
+  pytest-benchmark,
+  pytest-timeout,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "pyppmd";
+  version = "1.1.1";
+  pyproject = true;
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "miurahr";
+    repo = "pyppmd";
+    tag = "v${version}";
+    hash = "sha256-0t1vyVMtmhb38C2teJ/Lq7dx4usm4Bzx+k7Zalf/nXE=";
+  };
+
+  build-system = [
+    setuptools
+    setuptools-scm
+  ];
+
+  nativeCheckInputs = [
+    hypothesis
+    pytest-benchmark
+    pytest-timeout
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [
+    "pyppmd"
+  ];
+
+  meta = {
+    description = "PPMd compression/decompression library";
+    homepage = "https://codeberg.org/miurahr/pyppmd";
+    changelog = "https://codeberg.org/miurahr/pyppmd/src/tag/v${version}/Changelog.rst#v${version}";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      pitkling
+      PopeRigby
+    ];
+  };
+}

pkgs/development/python-modules/pyzstd/default.nix

@@ -0,0 +1,63 @@
+{
+  buildPythonPackage,
+  fetchFromGitHub,
+  lib,
+  pytestCheckHook,
+  setuptools,
+  zstd-c,
+}:
+buildPythonPackage rec {
+  pname = "pyzstd";
+  version = "0.16.2";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "Rogdham";
+    repo = "pyzstd";
+    tag = version;
+    hash = "sha256-Az+0m1XUFxExBZK8bcjK54Zt2d5ZlAKRMZRdr7rPcss=";
+  };
+
+  postPatch = ''
+    # pyzst specifies setuptools<74 because 74+ drops `distutils.msvc9compiler`,
+    # required for Python 3.9 under Windows
+    substituteInPlace pyproject.toml \
+        --replace-fail '"setuptools>=64,<74"' '"setuptools"'
+  '';
+
+  nativeBuildInputs = [
+    setuptools
+  ];
+
+  build-system = [
+    setuptools
+  ];
+
+  buildInputs = [
+    zstd-c
+  ];
+
+  pypaBuildFlags = [
+    "--config-setting=--global-option=--dynamic-link-zstd"
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [
+    "pyzstd"
+  ];
+
+  meta = {
+    description = "Python bindings to Zstandard (zstd) compression library";
+    homepage = "https://pyzstd.readthedocs.io";
+    changelog = "https://github.com/Rogdham/pyzstd/blob/${version}/CHANGELOG.md";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [
+      MattSturgeon
+      pitkling
+      PopeRigby
+    ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -1092,6 +1092,8 @@ with pkgs;
 
   pricehist = python3Packages.callPackage ../tools/misc/pricehist { };
 
+  py7zr = with python3Packages; toPythonApplication py7zr;
+
   q = callPackage ../tools/networking/q { };
 
   qFlipper = libsForQt5.callPackage ../tools/misc/qflipper { };