Add support for :disallow-mock metadata.

README.md

@@ -92,6 +92,20 @@ and `with-stub-ns` which can spy/stub every function in a namespace in one go:
     (is (= :baz (bar)))))
 ```
 
+Sometimes you have functions which you want to prevent from being
+mocked. You can attach `:disallow-mock` functions to prevent Bond from
+mocking these. (They can still be replaced using `with-redefs` of course.)
+
+```clojure
+(defn ^:disallow-mock important-fn [x]
+  (spec-check x)
+  (send-over-network! x))
+```
+
+In the case above, you want to make sure that `send-over-network!`
+gets mocked, not `important-fn`, since mocking `important-fn` means
+that the tests will not run the spec checks.
+
 Releasing
 ---------
 

src/bond/james.clj

@@ -1,5 +1,11 @@
 (ns bond.james)
 
+(defn- check-allowed [n v]
+  (when (and (even? n) (:disallow-mock (meta (resolve v))))
+    (throw (IllegalArgumentException.
+            (str "Tried to mock " v ", which is disallowed."))))
+  v)
+
 (defn spy
   "wrap f, returning a new fn that keeps track of its call count and arguments."
   [f]
@@ -67,7 +73,9 @@
   `(with-redefs ~(->> (mapcat (fn [v]
                                 (if (vector? v)
                                   [(first v) `(spy ~(second v))]
-                                  [v `(spy (constantly nil))])) vs)
+                                  [v `(spy (constantly nil))]))
+                              vs)
+                      (map-indexed check-allowed)
                       (vec))
      ~@body))
 
@@ -101,6 +109,7 @@
                                   [(first v) `(stub! (var ~(first v))
                                                      ~(second v))]
                                   [v `(stub! (var ~v) (constantly nil))])) vs)
+                      (map-indexed check-allowed)
                       (vec))
      ~@body))
 

test/bond/james_test.clj

@@ -2,6 +2,7 @@
   {:clj-kondo/config {:linters {:private-call {:level :off}
                                 :invalid-arity {:level :off}}}}
   (:require [clojure.test :refer (deftest is testing)]
+            [clojure.stacktrace :as stacktrace]
             [bond.james :as bond :include-macros true]
             [bond.target-data :as target]))
 
@@ -107,3 +108,20 @@
     (bond/with-stub-ns [[bond.target-data (constantly 3)]]
       (is (= 3 (target/foo 10)))
       (is (= [10] (-> target/foo bond/calls first :args))))))
+
+(defn ^:disallow-mock no-mock [x]
+  (+ x 3))
+
+(defn disallowed? [form]
+  (try (eval form)
+       false
+       (catch Exception e
+         (re-find #"disallowed" (str (stacktrace/root-cause e))))))
+
+(deftest disallow-mock-works
+  (is (disallowed? `(bond/with-stub [no-mock]
+                      (println (no-mock 33)))))
+  (is (disallowed? `(bond/with-stub [[no-mock #(+ 2 %)]]
+                      (println (no-mock 33)))))
+  (is (disallowed? `(bond/with-stub! [[no-mock #(+ 2 %)]]
+                      (println (no-mock 33))))))