[flang] runtime crash when optional arguments are passed as arguments to another function

[shivaramaarao]

consider the following program

module optional_class_module
    implicit none

    type :: MyType
        integer :: value
    contains
        procedure :: show
    end type MyType

contains

    ! Type-bound procedure for MyType
    subroutine show(this)
        class(MyType), intent(inout) :: this
        print *, "MyType value is:", this%value
    end subroutine show

    subroutine process_data_2(obj)
        class(MyType), intent(inout) :: obj
                call process_data_3(obj)
    end subroutine

    subroutine process_data_3(obj)
        class(MyType), intent(inout) :: obj
    end subroutine

    subroutine process_data(obj)
        class(MyType), intent(inout), optional :: obj

        if (present(obj)) then
            select type(obj)
            type is (MyType)
                print *, "Optional object is present."
                call obj%show()
            class default
                print *, "Unknown type passed."
            end select
        else
            print *, "No object was passed."
        end if
        call process_data_2(obj)
    end subroutine process_data

end module optional_class_module


program test_optional_class
    use optional_class_module
    implicit none

    type(MyType) :: a

    a%value = 42

    print *, "--- Call with object ---"
    call process_data(a)

    print *, "--- Call without object ---"
    call process_data()
end program test_optional_class

The program crashes at runtime with flang. It passes with other compilers

 --- Call with object ---
 Optional object is present.
 MyType value is: 42
 --- Call without object ---
 No object was passed.
Segmentation fault (core dumped)

[shivaramaarao]

In process_data_2 function, there is explicit load from obj. The program crashes since obj is null.

I am not sure if this code is standard complaint. However, I have seen a similar code in a weather application and other compilers seem to handle the code.

as per my understanding of the standard, an optional dummy argument can not be passed as non optional dummy arguments. But, should we handle this case without crashing at runtime when the object is not used?

[klausler]

What other compilers behave differently? This is patently non-conforming code.

[eugeneepshteyn]

I agree that this is non-conforming code, but both ifx 2025.1 and gfortran 13.3 produce non-crashing code. I haven't yet checked, whether they just don't read from non-used object or whether something else is happening.

[jeanPerier]

Your example will now work because I removed the useless descriptor copy flang was making in process_data_2, however, this is dangerous/illegal usage and I highly advise fixing your source code by adding the OPTIONAL attribute to process_data_2 argument.

Flang will not support similar cases where the argument is an array, and I do not intend to pessimize valid code by adding logic that would handle getting a nullptr descriptor for such cases.

I only changed flang here because the extra descriptor copy was useless/dumb for valid code too.