Using an OLED Display (SDA = GPIO21, SCL = GPIO22) in combination with the AudioTools Library

[basementmedia2]

Hi,

first of all: i am still a beginner in using ESP's / Arduinos so please don't tear me apart right away :-)

But can it be the case that the SDA /SCL ports (GPIO21 and 22) are reserved by the audio tools library?
Because if i uncomment the USEDISPLAY boolean the display works but i get no sound anymore.
If i comment it out, sound output works

/**
 * @file player-sd-audiokit.ino
 * @brief see https://github.com/pschatzmann/arduino-audio-tools/blob/main/examples/examples-audiokit/player-sd-audiokit/README.md
 * Make sure that the pins are set to off, on, on, off, off
 * @author Phil Schatzmann
 * @copyright GPLv3
 */


//#define USEDISPLAY

#ifdef USEDISPLAY
   #include <Wire.h>
   #include <Adafruit_GFX.h>
   #include <Adafruit_SSD1306.h>
   #define SCREEN_WIDTH 128
   #define SCREEN_HEIGHT 64
   #define OLED_ADDR 0x3C  // Standard-I2C-Adresse für SSD1306 (kann auch 0x3D sein)
   Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);
#endif

#include "AudioTools.h"
#include "AudioTools/AudioLibs/AudioBoardStream.h"
#include "AudioTools/Disk/AudioSourceSD.h" // or AudioSourceIdxSD.h
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"

const char *startFilePath="/";
const char* ext="mp3";
AudioSourceSD source(startFilePath, ext, PIN_AUDIO_KIT_SD_CARD_CS);
AudioBoardStream kit(AudioKitEs8388V1);
MP3DecoderHelix decoder;  // or change to MP3DecoderMAD
AudioPlayer player(source, kit, decoder);

void next(bool, int, void*) {
   player.next();
}

void previous(bool, int, void*) {
   player.previous();
}

void startStop(bool, int, void*) {
   player.setActive(!player.isActive());
}

void setup() {
  Serial.begin(115200);

   #ifdef USEDISPLAY
      Wire.begin(21, 22);  // SDA=GPIO21, SCL=GPIO22 (für ESP32)
      
      if (!display.begin(SSD1306_SWITCHCAPVCC, OLED_ADDR)) {
         Serial.println("SSD1306 nicht gefunden!");
         while (1);
      }

      display.clearDisplay();
      display.setTextSize(1);
      display.setTextColor(WHITE);
      display.setCursor(0, 0);
      display.println("Hello, world!");
      display.println("AZDelivery OLED");
      display.display();  // Zeigt den Text tatsächlich an
   #endif

  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);

  // setup output
  auto cfg = kit.defaultConfig(TX_MODE);
  // sd_active is setting up SPI with the right SD pins by calling 
  // SPI.begin(PIN_AUDIO_KIT_SD_CARD_CLK, PIN_AUDIO_KIT_SD_CARD_MISO, PIN_AUDIO_KIT_SD_CARD_MOSI, PIN_AUDIO_KIT_SD_CARD_CS);
  cfg.sd_active = true;
  kit.begin(cfg);

  // setup additional buttons 
  kit.addDefaultActions();
  kit.addAction(kit.getKey(1), startStop);
  kit.addAction(kit.getKey(4), next);
  kit.addAction(kit.getKey(3), previous);


  // setup player
  player.setVolume(0.7);
  player.begin();

  // select file with setPath() or setIndex()
  //player.setPath("/ZZ Top/Unknown Album/Lowrider.mp3");
  //player.setIndex(1); // 2nd file

}

void loop() {
  player.copy();
  kit.processActions();

}

Thank you for your help.

Best wishes

Daniel

[pschatzmann]

Are you sure that you are using an AudioKit board ? If not you should use an I2SStream as described in the Wiki documentation.

If you check the documentation of that board you can find that GPIO 21 is used by the PA and 22 by the LED!

[basementmedia2]

Hey Phil,

I use this board:
https://amzn.eu/d/5oFMiE6

So the code I posted should work, shouldn't it?
As said the display works and the audio playback works but not in combination :-(

Can you test my code and check if it works with your Audiokit board?

Best wishes
Daniel

[pschatzmann]

You can find the pins that are used by the board in the audio-driver library

Wire is used to set up the Codec chip, so you will need to use Wire1 with some pins that do not conflict!

[pschatzmann]

If you check, GPIO 5 is used as I2S bck.
If you dont use the SD drive you might use a SD pin:

static PinsSPI ESP32PinsSD{PinFunction::SD, 14, 2, 15, 13, SPI};

[basementmedia2]

Ok, means also: if I use the SD drive (what I do) there are no pins free for my Midi In and my OLED, right?

[pschatzmann]

Maybe you can use a pin from the JTAG header ?

[basementmedia2]

With DIP 1 off, DIP2-5 ON it works to use the MTD0 (GPIO 15) as SDA and the MTCK (GPIO13) as SCL
OLED and Audio-Playback works now :-)

Do you have a last tip, which pin would be ok to use for my midi in?
What is the risk to use GPIO23? As i see it is connected to a key (4), isn't it?
So receiving a MIDI signal could trigger the key 4 function?
But if i do not assign a function to it...is it ok then?

[pschatzmann]

I think it should be ok if you don't use this key; it is GPIO 32 and not 23 !