-
Notifications
You must be signed in to change notification settings - Fork 27
/
kodi_17.bb
210 lines (186 loc) · 7.11 KB
/
kodi_17.bb
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
SUMMARY = "Kodi Media Center"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://LICENSE.GPL;md5=930e2a5f63425d8dd72dbd7391c43c46"
FILESPATH =. "${FILE_DIRNAME}/kodi-17:"
DEPENDS = " \
cmake-native \
curl-native \
gperf-native \
jsonschemabuilder-native \
nasm-native \
swig-native \
unzip-native \
yasm-native \
zip-native \
avahi \
boost \
bzip2 \
curl \
dcadec \
enca \
expat \
faad2 \
ffmpeg \
fontconfig \
fribidi \
giflib \
jasper \
libass \
libcdio \
libcec \
libdvdcss \
libdvdread \
libmad \
libmicrohttpd \
libmms \
libmms \
libmodplug \
libpcre \
libplist \
libsamplerate0 \
libsdl-image \
libsdl-mixer \
libsquish \
libssh \
libtinyxml \
libusb1 \
libxinerama \
libxmu \
libxrandr \
libxslt \
libxtst \
lzo \
mpeg2dec \
python \
samba \
sqlite3 \
taglib \
virtual/egl \
virtual/libsdl \
wavpack \
yajl \
zlib \
"
SRCREV = "a234aa0cb7aaef3c417a8a3cf9712f3360c0c2ae"
# 'patch' doesn't support binary diffs
PATCHTOOL = "git"
PV = "17.3+gitr${SRCPV}"
SRC_URI = "git://github.com/xbmc/xbmc.git;branch=Krypton \
file://0001-library-tvshows-switch-genre-and-recently-added.patch \
file://0002-library-movies-switch-genre-and-recently-added.patch \
file://0003-estuary-move-recently-added-entries-to-the-top-in-ho.patch \
file://0002-configure-don-t-try-to-run-stuff-to-find-tinyxml.patch \
file://0004-add-support-to-read-frequency-output-if-using-intel-.patch \
file://0005-Revert-posix-move-libdvd-to-depends.patch \
file://0005-added-Audio-video-bitrate-info-for-video-process-dia.patch \
file://kodi-rpi-001-reduce-priority-of-python-threads.patch \
file://kodi-rpi-002-avoid-memcpy-on-every-demuxer-packet.patch \
file://kodi-rpi-003-load-OSD-dialogs-on-startup.patch \
file://kodi-rpi-004-speedup-thumb-loading.patch \
file://0006-Increase-CHUNK_SIZE-to-128-KB.patch \
file://0007-NFSFile-Return-max-chunksize-possible.patch \
file://0008-DVDDemuxFFMPEG-Increase-FFMPEG_FILE_BUFFER_SIZE-to-1.patch \
file://0009-DVDDemuxFFmpeg-Store-probe_buffer-on-heap.patch \
file://0001-smbclient-cleanup-smbclient-configuration.patch \
file://0001-SMBFile-Use-1MB-chunks.patch \
file://0001-SMBFile-Remove-year-old-workaround.patch \
"
inherit autotools-brokensep gettext python-dir
S = "${WORKDIR}/git"
# breaks compilation
CCACHE = ""
ASNEEDED = ""
CACHED_CONFIGUREVARS += " \
ac_cv_path_PYTHON="${STAGING_BINDIR_NATIVE}/python-native/python" \
"
ACCEL ?= ""
ACCEL_x86 = "vaapi vdpau"
ACCEL_x86-64 = "vaapi vdpau"
PACKAGECONFIG ??= "${ACCEL} opengl x11"
PACKAGECONFIG[opengl] = "--enable-gl,--enable-gles,glew"
PACKAGECONFIG[openglesv2] = "--enable-gles,--enable-gl,"
PACKAGECONFIG[vaapi] = "--enable-vaapi,--disable-vaapi,libva"
PACKAGECONFIG[vdpau] = "--enable-vdpau,--disable-vdpau,libvdpau"
PACKAGECONFIG[mysql] = "--enable-mysql,--disable-mysql,mysql5"
PACKAGECONFIG[x11] = "--enable-x11,--disable-x11,libxinerama libxmu libxrandr libxtst"
PACKAGECONFIG[pulseaudio] = "--enable-pulse,--disable-pulse,pulseaudio"
PACKAGECONFIG[lcms] = "--enable-lcms2,--disable-lcms2,lcms"
EXTRA_OECONF = " \
--enable-libusb \
--enable-airplay \
--disable-optical-drive \
--with-ffmpeg=shared \
--enable-texturepacker=no \
--disable-dvdcss \
"
FULL_OPTIMIZATION_armv7a = "-fexpensive-optimizations -fomit-frame-pointer -O4 -ffast-math"
BUILD_OPTIMIZATION = "${FULL_OPTIMIZATION}"
# for python modules
export HOST_SYS
export BUILD_SYS
export STAGING_LIBDIR
export STAGING_INCDIR
export PYTHON_DIR
do_configure() {
git add . || true
git commit -a -m "OE patches" || true
( for i in $(find ${S} -name "configure.*") ; do
cd $(dirname $i) && gnu-configize --force || true
autoreconf -sfi || true
done )
( cd ${S}/tools/depends && autoreconf -sfi && autoconf -f || true )
git add . || true
git commit -a -m "OE autoreconf" || true
make -C tools/depends/target/crossguid PREFIX=${STAGING_DIR_HOST}${prefix}
BOOTSTRAP_STANDALONE=1 make -f bootstrap.mk JSON_BUILDER="${STAGING_BINDIR_NATIVE}/JsonSchemaBuilder"
BOOTSTRAP_STANDALONE=1 make -f codegenerator.mk JSON_BUILDER="${STAGING_BINDIR_NATIVE}/JsonSchemaBuilder"
oe_runconf
}
do_compile_prepend() {
for i in $(find . -name "Makefile") ; do
sed -i -e 's:I/usr/include:I${STAGING_INCDIR}:g' $i
done
for i in $(find . -name "*.mak*" -o -name "Makefile") ; do
sed -i -e 's:I/usr/include:I${STAGING_INCDIR}:g' -e 's:-rpath \$(libdir):-rpath ${libdir}:g' $i
done
}
INSANE_SKIP_${PN} = "rpaths"
FILES_${PN} += "${datadir}/xsessions ${datadir}/icons ${libdir}/xbmc ${datadir}/xbmc"
FILES_${PN}-dbg += "${libdir}/kodi/.debug ${libdir}/kodi/*/.debug ${libdir}/kodi/*/*/.debug ${libdir}/kodi/*/*/*/.debug"
# kodi uses some kind of dlopen() method for libcec so we need to add it manually
# OpenGL builds need glxinfo, that's in mesa-demos
RRECOMMENDS_${PN}_append = " libcec \
python \
python-ctypes \
python-lang \
python-re \
python-netclient \
python-html \
python-difflib \
python-json \
python-zlib \
python-shell \
python-sqlite3 \
python-compression \
python-xmlrpc \
libcurl \
xdpyinfo \
xrandr \
${@bb.utils.contains('PACKAGECONFIG', 'opengl', 'mesa-demos', '', d)} \
tzdata-africa \
tzdata-americas \
tzdata-antarctica \
tzdata-arctic \
tzdata-asia \
tzdata-atlantic \
tzdata-australia \
tzdata-europe \
tzdata-pacific \
"
RRECOMMENDS_${PN}_append_libc-glibc = " glibc-charmap-ibm850 \
glibc-gconv-ibm850 \
glibc-gconv-unicode \
glibc-gconv-utf-32 \
glibc-charmap-utf-8 \
glibc-localedata-en-us \
"