-
Notifications
You must be signed in to change notification settings - Fork 2
/
PluginEx.pas
747 lines (661 loc) · 22.6 KB
/
PluginEx.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
// Helper unit for Delphi FAR plugins.
unit PluginEx;
interface
uses
Windows, {$IFDEF UNICODE}PluginW{$ELSE}Plugin{$ENDIF};
type
{$IFNDEF UNICODE}
TFarChar = AnsiChar;
PFarChar = PAnsiChar;
FarString = AnsiString;
{$ELSE}
FarString = WideString;
{$ENDIF}
FarChar = TFarChar;
TFarStringDynArray = array of FarString;
function PToStr(P: PFarChar): FarString; inline; // work around Delphi's strict type declarations
function CharToOemStr(S: FarString): FarString;
function OemToCharStr(S: FarString): FarString;
function NullStringsToArray(P: PFarChar): TFarStringDynArray;
function ArrayToNullStrings(A: TFarStringDynArray): FarString;
procedure CopyStrToBuf(S: FarString; Buf: PFarChar; BufSize: Integer);
function IntToStr(I: Integer): FarString; inline;
function TryLoadString(FileName: FarString; var Data: FarString): Boolean;
function TryLoadText(FileName: FarString; var Data: FarString): Boolean;
function TrySaveString(FileName, Data: FarString): Boolean;
function TrySaveText(FileName, Data: FarString): Boolean;
function StrReplace(Haystack, Source, Dest: FarString): FarString;
function Trim(S: FarString): FarString;
function Split(S: FarString; Delim: FarString): TFarStringDynArray;
function SplitByAny(S, Delims: FarString): TFarStringDynArray;
function SplitLines(S: FarString): TFarStringDynArray;
function Join(S: TFarStringDynArray; Delim: FarString): FarString;
function MakeStrings(const S: array of FarString): TFarStringDynArray;
procedure AppendToStrings(var Strings: TFarStringDynArray; S: FarString);
function ConcatStrings(const S: array of TFarStringDynArray): TFarStringDynArray;
function GetTempFullFileName(PrefixString: FarString='Far'): FarString;
// ANSI/UNICODE wrappers for WinAPI functions
function RegCreateKeyExF(hKey: HKEY; lpSubKey: PFarChar; Reserved: DWORD; lpClass: PFarChar; dwOptions: DWORD; samDesired: REGSAM; lpSecurityAttributes: PSecurityAttributes; var phkResult: HKEY; lpdwDisposition: PDWORD): Longint; inline;
function RegOpenKeyExF(hKey: HKEY; lpSubKey: PFarChar; ulOptions: DWORD; samDesired: REGSAM; var phkResult: HKEY): Longint; inline;
function RegQueryValueExF(hKey: HKEY; lpValueName: PFarChar; lpReserved: Pointer; lpType: PDWORD; lpData: PByte; lpcbData: PDWORD): Longint; inline;
function RegSetValueExF(hKey: HKEY; lpValueName: PFarChar; Reserved: DWORD; dwType: DWORD; lpData: Pointer; cbData: DWORD): Longint; inline;
function RegDeleteKeyF(hKey: HKEY; lpSubKey: PFarChar): Longint; inline;
function SetEnvironmentVariableF(lpName, lpValue: PFarChar): BOOL; inline;
function GetEnvironmentStringsF: PFarChar; inline;
function FreeEnvironmentStringsF(EnvBlock: PFarChar): BOOL; inline;
function ExpandEnvironmentStringsF(lpSrc: PFarChar; lpDst: PFarChar; nSize: DWORD): DWORD; inline;
function GetTempPathF(nBufferLength: DWORD; lpBuffer: PFarChar): DWORD;
function GetTempFileNameF(lpPathName, lpPrefixString: PFarChar; uUnique: UINT; lpTempFileName: PFarChar): UINT;
function DeleteFileF(lpFileName: PFarChar): BOOL;
type
TFarDialog = class
Items: array of TFarDialogItem;
function Add(ItemType, Flags: Integer; X1, Y1, X2, Y2: Integer; InitialData: FarString; MaxLen: Integer = 0): Integer;
function Run(GUID: TGUID; W, H: Integer; HelpTopic: PFarChar = nil): Integer;
function GetData(Index: Integer): FarString;
function GetChecked(Index: Integer): Boolean;
{$IFDEF UNICODE}
destructor Destroy; override;
{$ENDIF}
private
Data: TFarStringDynArray;
{$IFDEF UNICODE}
Handle: THandle;
{$ENDIF}
end;
type
TMessage = (
{$I lang.inc}
M__Last // allow ending the list with a comma
);
function GetMsg(MsgId: TMessage): PFarChar;
function Message(GUID: TGUID; Flags: DWORD; const Lines: array of FarString; ButtonCount: Integer = 0; HelpTopic: PFarChar = nil): Integer;
function EditString(var Data: FarString; Title: FarString): Boolean;
{$IFNDEF UNICODE}
const OPEN_FROMMACRO = $10000; // not in Plugin.pas
{$ENDIF}
const DIF_NONE = 0;
var
FARAPI: TPluginStartupInfo;
{$IFDEF FAR3}
PluginGUID: TGUID;
{$ENDIF}
type
TSettings = class
function GetString (Name: FarString; Default: FarString = ''): FarString; virtual; abstract;
procedure SetString (Name: FarString; Value: FarString); virtual; abstract;
function GetStrings (Name: FarString): TFarStringDynArray; virtual; abstract;
procedure SetStrings (Name: FarString; Value: TFarStringDynArray); virtual; abstract;
function GetInt (Name: FarString): Integer; virtual; abstract;
procedure SetInt (Name: FarString; Value: Integer); virtual; abstract;
function OpenKey (Name: FarString): TSettings; virtual; abstract;
procedure DeleteKey (Name: FarString); virtual; abstract;
function ValueExists(Name: FarString): Boolean; virtual; abstract;
function KeyExists (Name: FarString): Boolean; virtual; abstract;
end;
TRegistrySettings = class(TSettings)
constructor Create(Name: FarString);
constructor CreateFrom(SubKey: HKEY);
destructor Destroy; override;
function GetString (Name: FarString; Default: FarString = ''): FarString; override;
procedure SetString (Name: FarString; Value: FarString); override;
function GetStrings(Name: FarString): TFarStringDynArray; override;
procedure SetStrings(Name: FarString; Value: TFarStringDynArray); override;
function GetInt (Name: FarString): Integer; override;
procedure SetInt (Name: FarString; Value: Integer); override;
function OpenKey (Name: FarString): TSettings; override;
procedure DeleteKey (Name: FarString); override;
function ValueExists(Name: FarString): Boolean; override;
function KeyExists (Name: FarString): Boolean; override;
private
Key: HKEY;
function GetStringRaw(Name: FarString; Default: FarString = ''): FarString;
procedure SetStringRaw(Name: FarString; Value: FarString; RegType: Cardinal);
end;
implementation
// ************************************************************************************************************************************************************
function PToStr(P: PFarChar): FarString; inline;
begin
{$IFNDEF UNICODE}
Result := PChar(P);
{$ELSE}
Result := PWideChar(P);
{$ENDIF}
end;
function CharToOemStr(S: FarString): FarString;
begin
{$IFNDEF UNICODE}
SetLength(Result, Length(S));
CharToOem(PFarChar(S), @Result[1]);
{$ELSE}
Result := S;
{$ENDIF}
end;
function OemToCharStr(S: FarString): FarString;
begin
{$IFNDEF UNICODE}
SetLength(Result, Length(S));
OemToChar(PFarChar(S), @Result[1]);
{$ELSE}
Result := S;
{$ENDIF}
end;
// Convert a zero-terminated string sequence (which itself is
// doubly-zero-terminated) to a TStringDynArray.
function NullStringsToArray(P: PFarChar): TFarStringDynArray;
var
P2: PFarChar;
begin
SetLength(Result, 0);
while P^<>#0 do
begin
P2 := P;
repeat
Inc(P2);
until P2^=#0;
SetLength(Result, Length(Result)+1);
Result[High(Result)] := Copy(P, 1, UINT_PTR(P2)-UINT_PTR(P));
P := P2;
Inc(P);
end;
end;
function ArrayToNullStrings(A: TFarStringDynArray): FarString;
var
I: Integer;
begin
Result := '';
for I:=0 to High(A) do
if Length(A[I])>0 then
Result := Result + A[I] + #0;
Result := Result + #0;
end;
procedure CopyStrToBuf(S: FarString; Buf: PFarChar; BufSize: Integer);
begin
if Length(S)>BufSize-1 then
S := Copy(S, 1, BufSize-1);
S := S+#0;
Move(S[1], Buf^, Length(S) * SizeOf(FarChar));
end;
// To avoid pulling in heavy SysUtils unit
function IntToStr(I: Integer): FarString; inline;
begin
Str(I, Result);
end;
function TryLoadString(FileName: FarString; var Data: FarString): Boolean;
var
F: File;
OldFileMode: Integer;
begin
OldFileMode := FileMode; FileMode := {fmOpenRead}0;
Assign(F, FileName);
{$I-}
Reset(F, SizeOf(FarChar));
{$I+}
FileMode := OldFileMode;
Result := False;
if IOResult<>0 then
Exit;
SetLength(Data, FileSize(F));
if FileSize(F)>0 then
BlockRead(F, Data[1], FileSize(F));
CloseFile(F);
Result := True;
end;
function TryLoadText(FileName: FarString; var Data: FarString): Boolean;
var
F: File;
OldFileMode: Integer;
RawData: AnsiString;
begin
OldFileMode := FileMode; FileMode := {fmOpenRead}0;
Assign(F, FileName);
{$I-}
Reset(F, 1);
{$I+}
FileMode := OldFileMode;
Result := False;
if IOResult<>0 then
Exit;
SetLength(RawData, FileSize(F));
if FileSize(F)>0 then
BlockRead(F, RawData[1], FileSize(F));
CloseFile(F);
{$IFDEF UNICODE}
if (Copy(RawData, 1, 2)=#$FF#$FE) and (Length(RawData) mod 2 = 0) then
begin
SetLength(Data, Length(RawData) div 2 - 1);
Move(RawData[3], Data[1], Length(RawData)-2);
end
else
{$ENDIF}
Data := RawData;
Result := True;
end;
function TrySaveString(FileName, Data: FarString): Boolean;
var
F: File;
begin
Assign(F, FileName);
{$I-}
ReWrite(F, SizeOf(FarChar));
{$I+}
Result := False;
if IOResult<>0 then
Exit;
BlockWrite(F, Data[1], Length(Data));
CloseFile(F);
Result := True;
end;
function TrySaveText(FileName, Data: FarString): Boolean;
begin
{$IFDEF UNICODE}
Data := #$FEFF + Data; // add BOM
{$ENDIF}
Result := TrySaveString(Filename, Data);
end;
function StrReplace(Haystack, Source, Dest: FarString): FarString;
var
P: Integer;
begin
Result := Haystack;
while true do
begin
P := Pos(Source, Result);
if P=0 then
Exit;
Delete(Result, P, Length(Source));
Insert(Result, Dest, P);
end;
end;
function Trim(S: FarString): FarString;
begin
while Copy(S, 1, 1)=' ' do
Delete(S, 1, 1);
while (Length(S)>0) and (Copy(S, Length(S), 1)=' ') do
Delete(S, Length(S), 1);
Result := S;
end;
function PosAny(Delims, S: FarString): Integer;
var
I, P: Integer;
begin
Result := 0;
for I := 1 to Length(Delims) do
begin
P := Pos(Delims[I], S);
if (Result=0) or ((P <> 0) and (P < Result)) then
Result := P;
end;
end;
function Split(S: FarString; Delim: FarString): TFarStringDynArray;
var
P: Integer;
begin
Result := nil;
if S='' then Exit;
S := S + Delim;
while S<>'' do
begin
SetLength(Result, Length(Result)+1);
P := Pos(Delim, S);
Result[High(Result)] := Copy(S, 1, P-1);
Delete(S, 1, P-1+Length(Delim));
end;
end;
function SplitByAny(S, Delims: FarString): TFarStringDynArray;
var
P: Integer;
begin
Result := nil;
if S='' then Exit;
S := S + Delims[1];
while S<>'' do
begin
SetLength(Result, Length(Result)+1);
P := PosAny(Delims, S);
Result[High(Result)] := Copy(S, 1, P-1);
Delete(S, 1, P);
end;
end;
function SplitLines(S: FarString): TFarStringDynArray;
var
I: Integer;
begin
Result := Split(S, #10);
for I:=0 to High(Result) do
begin
while Copy(Result[I], 1, 1)=#13 do
Delete(Result[I], 1, 1);
while Copy(Result[I], Length(Result[I]), 1)=#13 do
Delete(Result[I], Length(Result[I]), 1);
end;
end;
function Join(S: TFarStringDynArray; Delim: FarString): FarString;
var
I: Integer;
begin
Result := '';
for I:=0 to High(S) do
begin
if I>0 then
Result := Result + Delim;
Result := Result + S[I];
end;
end;
function MakeStrings(const S: array of FarString): TFarStringDynArray;
var
I: Integer;
begin
SetLength(Result, Length(S));
for I:=0 to High(S) do
Result[I] := S[I];
end;
procedure AppendToStrings(var Strings: TFarStringDynArray; S: FarString);
begin
SetLength(Strings, Length(Strings)+1);
Strings[High(Strings)] := S;
end;
function ConcatStrings(const S: array of TFarStringDynArray): TFarStringDynArray;
var
I, J, N: Integer;
begin
Result := nil;
for I:=0 to High(S) do
begin
N := Length(Result);
SetLength(Result, Length(Result)+Length(S[I]));
for J:=0 to High(S[I]) do
Result[N+J] := S[I][J];
end;
end;
function GetTempFullFileName(PrefixString: FarString='Far'): FarString;
var
Path: array[0..MAX_PATH] of FarChar;
begin
GetTempPathF(MAX_PATH, @Path[0]);
GetTempFileNameF(@Path[0], PFarChar(PrefixString), 0, @Path[0]);
Result := PFarChar(@Path[0]);
end;
// ************************************************************************************************************************************************************
function RegCreateKeyExF(hKey: HKEY; lpSubKey: PFarChar; Reserved: DWORD; lpClass: PFarChar; dwOptions: DWORD; samDesired: REGSAM; lpSecurityAttributes: PSecurityAttributes; var phkResult: HKEY; lpdwDisposition: PDWORD): Longint; inline;
begin
Result := {$IFNDEF UNICODE}RegCreateKeyExA{$ELSE}RegCreateKeyExW{$ENDIF}(hKey, lpSubKey, Reserved, lpClass, dwOptions, samDesired, lpSecurityAttributes, phkResult, lpdwDisposition);
end;
function RegOpenKeyExF(hKey: HKEY; lpSubKey: PFarChar; ulOptions: DWORD; samDesired: REGSAM; var phkResult: HKEY): Longint; inline;
begin
Result := {$IFNDEF UNICODE}RegOpenKeyExA{$ELSE}RegOpenKeyExW{$ENDIF}(hKey, lpSubKey, ulOptions, samDesired, phkResult);
end;
function RegQueryValueExF(hKey: HKEY; lpValueName: PFarChar; lpReserved: Pointer; lpType: PDWORD; lpData: PByte; lpcbData: PDWORD): Longint; inline;
begin
Result := {$IFNDEF UNICODE}RegQueryValueExA{$ELSE}RegQueryValueExW{$ENDIF}(hKey, lpValueName, lpReserved, lpType, lpData, lpcbData);
end;
function RegSetValueExF(hKey: HKEY; lpValueName: PFarChar; Reserved: DWORD; dwType: DWORD; lpData: Pointer; cbData: DWORD): Longint; inline;
begin
Result := {$IFNDEF UNICODE}RegSetValueExA{$ELSE}RegSetValueExW{$ENDIF}(hKey, lpValueName, Reserved, dwType, lpData, cbData);
end;
function RegDeleteKeyF(hKey: HKEY; lpSubKey: PFarChar): Longint; inline;
begin
Result := {$IFNDEF UNICODE}RegDeleteKeyA{$ELSE}RegDeleteKeyW{$ENDIF}(hKey, lpSubKey);
end;
function SetEnvironmentVariableF(lpName, lpValue: PFarChar): BOOL; inline;
begin
Result := {$IFNDEF UNICODE}SetEnvironmentVariableA{$ELSE}SetEnvironmentVariableW{$ENDIF}(lpName, lpValue);
end;
function GetEnvironmentStringsF: PFarChar; inline;
begin
Result := {$IFNDEF UNICODE}GetEnvironmentStringsA{$ELSE}GetEnvironmentStringsW{$ENDIF};
end;
function FreeEnvironmentStringsF(EnvBlock: PFarChar): BOOL; inline;
begin
Result := {$IFNDEF UNICODE}FreeEnvironmentStringsA{$ELSE}FreeEnvironmentStringsW{$ENDIF}(EnvBlock);
end;
function ExpandEnvironmentStringsF(lpSrc: PFarChar; lpDst: PFarChar; nSize: DWORD): DWORD; inline;
begin
Result := {$IFNDEF UNICODE}ExpandEnvironmentStringsA{$ELSE}ExpandEnvironmentStringsW{$ENDIF}(lpSrc, lpDst, nSize);
end;
function GetTempPathF(nBufferLength: DWORD; lpBuffer: PFarChar): DWORD;
begin
Result := {$IFNDEF UNICODE}GetTempPathA{$ELSE}GetTempPathW{$ENDIF}(nBufferLength, lpBuffer);
end;
function GetTempFileNameF(lpPathName, lpPrefixString: PFarChar; uUnique: UINT; lpTempFileName: PFarChar): UINT;
begin
Result := {$IFNDEF UNICODE}GetTempFileNameA{$ELSE}GetTempFileNameW{$ENDIF}(lpPathName, lpPrefixString, uUnique, lpTempFileName);
end;
function DeleteFileF(lpFileName: PFarChar): BOOL;
begin
Result := {$IFNDEF UNICODE}DeleteFileA{$ELSE}DeleteFileW{$ENDIF}(lpFileName);
end;
// ************************************************************************************************************************************************************
function TFarDialog.Add(ItemType, Flags: Integer; X1, Y1, X2, Y2: Integer; InitialData: FarString; MaxLen: Integer = 0): Integer;
var
NewItem: PFarDialogItem;
begin
SetLength(Items, Length(Items)+1);
Result := High(Items);
NewItem := @Items[Result];
FillChar(NewItem^, SizeOf(NewItem^), 0);
NewItem.ItemType := ItemType;
NewItem.Flags := Flags;
NewItem.X1 := X1;
NewItem.Y1 := Y1;
NewItem.X2 := X2;
NewItem.Y2 := Y2;
{$IFNDEF UNICODE}
if MaxLen < Length(InitialData)+1 then
MaxLen := Length(InitialData)+1;
if (MaxLen >= SizeOf(NewItem.Data.Data)) and ((ItemType=DI_COMBOBOX) or (ItemType=DI_EDIT)) then
begin
SetLength(Data, Length(Items));
Data[Result] := InitialData + #0;
SetLength(Data[Result], MaxLen);
NewItem.Data.Ptr.PtrFlags := 0;
NewItem.Data.Ptr.PtrLength := MaxLen;
NewItem.Data.Ptr.PtrData := @Data[Result][1];
NewItem.Flags := NewItem.Flags or DIF_VAREDIT;
end
else
CopyStrToBuf(InitialData, NewItem.Data.Data, SizeOf(NewItem.Data.Data));
{$ELSE}
SetLength(Data, Length(Items));
Data[Result] := InitialData;
NewItem.{$IFDEF FAR3}Data {$ELSE}PtrData{$ENDIF} := @Data[Result][1];
NewItem.{$IFDEF FAR3}MaxLength{$ELSE}MaxLen {$ENDIF} := 0;
{$ENDIF}
end;
function TFarDialog.Run(GUID: TGUID; W, H: Integer; HelpTopic: PFarChar = nil): Integer;
begin
{$IFNDEF UNICODE}
Result := FARAPI.Dialog(FARAPI.ModuleNumber, -1, -1, W, H, HelpTopic, @Items[0], Length(Items));
{$ELSE}
Handle := FARAPI.DialogInit({$IFDEF FAR3}PluginGUID, GUID{$ELSE}FARAPI.ModuleNumber{$ENDIF}, -1, -1, W, H, HelpTopic, @Items[0], Length(Items), 0, 0, nil, 0);
Result := FARAPI.DialogRun(Handle);
{$ENDIF}
end;
{$IFDEF UNICODE}
destructor TFarDialog.Destroy;
begin
FARAPI.DialogFree(Handle);
inherited;
end;
{$ENDIF}
function TFarDialog.GetData(Index: Integer): FarString;
begin
{$IFNDEF UNICODE}
if (Items[Index].Flags and DIF_VAREDIT)<>0 then
Result := PFarChar(@Data[Index][1])
else
Result := PFarChar(@Items[Index].Data.Data[0]);
{$ELSE}
Result := PFarChar(FARAPI.SendDlgMessage(Handle, DM_GETCONSTTEXTPTR, Index, {$IFDEF FAR3}nil{$ELSE}0{$ENDIF}));
{$ENDIF}
end;
function TFarDialog.GetChecked(Index: Integer): Boolean;
begin
{$IFNDEF UNICODE}
Result := Boolean(Items[Index].Param.Selected);
{$ELSE}
Result := Boolean(FARAPI.SendDlgMessage(Handle, DM_GETCHECK, Index, {$IFDEF FAR3}nil{$ELSE}0{$ENDIF}));
{$ENDIF}
end;
// ************************************************************************************************************************************************************
function GetMsg(MsgId: TMessage): PFarChar;
begin
Result := FARAPI.GetMsg({$IFDEF FAR3}PluginGUID{$ELSE}FARAPI.ModuleNumber{$ENDIF}, Integer(MsgId));
end;
function Message(GUID: TGUID; Flags: DWORD; const Lines: array of FarString; ButtonCount: Integer = 0; HelpTopic: PFarChar = nil): Integer;
begin
Result := FARAPI.Message({$IFDEF FAR3}GUID, PluginGUID{$ELSE}FARAPI.ModuleNumber{$ENDIF}, Flags, HelpTopic, PPCharArray(@Lines[0]), Length(Lines), ButtonCount);
end;
// Open an editor on a temporary file to edit given string
function EditString(var Data: FarString; Title: FarString): Boolean;
const
FileCreateErrorGUID: TGUID = '{164559c7-1bb2-497e-b6eb-bdc431c121b6}';
FileLoadErrorGUID: TGUID = '{72955220-29c1-4493-8359-b0f91bd5592a}';
var
FileName: FarString;
begin
Result := False;
FileName := GetTempFullFileName('Env');
if not TrySaveText(FileName, Data) then
begin
Message(FileCreateErrorGUID, FMSG_WARNING or FMSG_MB_OK, [GetMsg(MError), GetMsg(MFileCreateError), FileName]);
Exit;
end;
if FARAPI.Editor(PFarChar(FileName), PFarChar(Title), -1, -1, -1, -1, EF_DISABLEHISTORY, 0, 1{$IFDEF UNICODE}, CP_UNICODE{$ENDIF})=EEC_MODIFIED then
begin
Result := True;
if not TryLoadText(FileName, Data) then
begin
Message(FileLoadErrorGUID, FMSG_WARNING or FMSG_MB_OK, [GetMsg(MError), GetMsg(MFileLoadError), FileName]);
Exit;
end;
end;
DeleteFileF(PFarChar(FileName));
end;
// ************************************************************************************************************************************************************
constructor TRegistrySettings.Create(Name: FarString);
var
RegKey: FarString;
begin
{$IFDEF FAR3}
RegKey := 'Software\Far2\Plugins\' + Name;
{$ELSE}
RegKey := FARAPI.RootKey + FarString('\') + Name;
{$ENDIF}
Key := 0;
RegCreateKeyExF(HKEY_CURRENT_USER, PFarChar(RegKey), 0, nil, 0, KEY_ALL_ACCESS, nil, Key, nil);
//if Key=0 then
// raise Exception.Create('Can''t open registry key '+ RegKey);
end;
constructor TRegistrySettings.CreateFrom(SubKey: HKEY);
begin
Key := SubKey;
end;
destructor TRegistrySettings.Destroy;
begin
RegCloseKey(Key);
end;
function TRegistrySettings.GetStringRaw(Name: FarString; Default: FarString = ''): FarString;
var
R: Integer;
Size: Cardinal;
PName: PFarChar;
begin
Result := Default;
if Name='' then
PName := nil
else
PName := PFarChar(Name);
Size := 0;
R := RegQueryValueExF(Key, PName, nil, nil, nil, @Size);
if R<>ERROR_SUCCESS then
Exit;
SetLength(Result, Size div SizeOf(FarChar));
if Size=0 then
Exit;
R := RegQueryValueExF(Key, PName, nil, nil, @Result[1], @Size);
if R<>ERROR_SUCCESS then
Result := Default;
end;
function TRegistrySettings.GetString(Name: FarString; Default: FarString = ''): FarString;
begin
Result := GetStringRaw(Name, Default {+ #0});
{$IFNDEF UNICODE}
CharToOem(@Result[1], @Result[1]);
{$ENDIF}
Result := PFarChar(Result); // Reinterpret as null-terminated
end;
function TRegistrySettings.GetStrings(Name: FarString): TFarStringDynArray;
{$IFNDEF UNICODE}
var
I: Integer;
{$ENDIF}
begin
Result := NullStringsToArray(PFarChar(GetStringRaw(Name)));
{$IFNDEF UNICODE}
for I:=0 to High(Result) do
CharToOem(PFarChar(Result[I]), PFarChar(Result[I]));
{$ENDIF}
end;
function TRegistrySettings.GetInt(Name: FarString): Integer;
var
Size: Cardinal;
begin
Result := 0;
Size := SizeOf(Result);
RegQueryValueExF(Key, PFarChar(Name), nil, nil, @Result, @Size);
end;
procedure TRegistrySettings.SetStringRaw(Name: FarString; Value: FarString; RegType: Cardinal);
begin
RegSetValueExF(Key, PFarChar(Name), 0, RegType, @Value[1], Length(Value) * SizeOf(FarChar));
end;
procedure TRegistrySettings.SetString(Name: FarString; Value: FarString);
begin
{$IFNDEF UNICODE}
OemToChar(@Value[1], @Value[1]);
{$ENDIF}
SetStringRaw(Name, Value+#0, REG_SZ);
end;
procedure TRegistrySettings.SetStrings(Name: FarString; Value: TFarStringDynArray);
{$IFNDEF UNICODE}
var
I: Integer;
{$ENDIF}
begin
{$IFNDEF UNICODE}
for I:=0 to High(Value) do
OemToChar(@Value[I][1], @Value[I][1]);
{$ENDIF}
SetStringRaw(Name, ArrayToNullStrings(Value), REG_MULTI_SZ);
end;
procedure TRegistrySettings.SetInt(Name: FarString; Value: Integer);
begin
RegSetValueExF(Key, PFarChar(Name), 0, REG_DWORD, @Value, SizeOf(Value));
end;
function TRegistrySettings.OpenKey(Name: FarString): TSettings;
var
SubKey: HKEY;
begin
SubKey := 0;
RegCreateKeyExF(Key, PFarChar(Name), 0, nil, 0, KEY_ALL_ACCESS, nil, SubKey, nil);
Result := TRegistrySettings.CreateFrom(SubKey);
end;
procedure TRegistrySettings.DeleteKey(Name: FarString);
begin
RegDeleteKeyF(Key, PFarChar(Name));
end;
function TRegistrySettings.ValueExists(Name: FarString): Boolean;
begin
Result := RegQueryValueExF(Key, PFarChar(Name), nil, nil, nil, nil) = ERROR_SUCCESS;
end;
function TRegistrySettings.KeyExists(Name: FarString): Boolean;
var
SubKey: HKEY;
begin
SubKey := 0;
RegOpenKeyExF(Key, PFarChar(Name), 0, KEY_ALL_ACCESS, SubKey);
Result := SubKey <> 0;
if SubKey<>0 then
RegCloseKey(SubKey);
end;
end.