/
flake.nix
362 lines (307 loc) · 10.4 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
{
description = "Expressive Python analytics at any scale.";
inputs = {
flake-compat = {
url = "github:edolstra/flake-compat";
flake = false;
};
flake-utils.url = "github:numtide/flake-utils";
gitignore = {
url = "github:hercules-ci/gitignore.nix";
inputs.nixpkgs.follows = "nixpkgs";
};
nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable-small";
poetry2nix = {
url = "github:nix-community/poetry2nix";
inputs.nixpkgs.follows = "nixpkgs";
inputs.flake-utils.follows = "flake-utils";
};
rust-overlay = {
url = "github:oxalica/rust-overlay";
inputs.nixpkgs.follows = "nixpkgs";
inputs.flake-utils.follows = "flake-utils";
};
};
outputs =
{ self
, flake-utils
, gitignore
, nixpkgs
, poetry2nix
, rust-overlay
, ...
}:
let
backends = [
"dask"
"datafusion"
"duckdb"
"pandas"
"polars"
"sqlite"
];
drv =
{ poetry2nix
, python
, lib
, gitignoreSource
, gdal
, graphviz-nox
, proj
, sqlite
, rsync
, ibisTestingData
, ...
}: poetry2nix.mkPoetryApplication rec {
inherit python;
groups = [ ];
checkGroups = [ "test" ];
projectDir = gitignoreSource ./.;
src = gitignoreSource ./.;
overrides = poetry2nix.overrides.withDefaults (
import ./poetry-overrides.nix
);
buildInputs = [ gdal graphviz-nox proj sqlite ];
checkInputs = buildInputs;
preCheck = ''
set -euo pipefail
export IBIS_TEST_DATA_DIRECTORY="$PWD/ci/ibis-testing-data"
${rsync}/bin/rsync \
--chmod=Du+rwx,Fu+rw --archive --delete \
"${ibisTestingData}/" \
"$IBIS_TEST_DATA_DIRECTORY"
'';
checkPhase = ''
set -euo pipefail
runHook preCheck
pytest --numprocesses auto --dist loadgroup -m '${lib.concatStringsSep " or " backends} or core'
runHook postCheck
'';
doCheck = true;
pythonImportsCheck = [ "ibis" ] ++ (map (backend: "ibis.backends.${backend}") backends);
};
in
{
overlays.default = nixpkgs.lib.composeManyExtensions [
gitignore.overlay
poetry2nix.overlay
rust-overlay.overlays.default
(pkgs: super: {
ibisTestingData = pkgs.fetchFromGitHub {
owner = "ibis-project";
repo = "testing-data";
rev = "master";
sha256 = "sha256-BZWi4kEumZemQeYoAtlUSw922p+R6opSWp/bmX0DjAo=";
};
rustNightly = pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.minimal);
mkPoetryEnv = groups: python: pkgs.poetry2nix.mkPoetryEnv {
inherit python groups;
projectDir = pkgs.gitignoreSource ./.;
editablePackageSources = { ibis = pkgs.gitignoreSource ./ibis; };
overrides = pkgs.poetry2nix.overrides.withDefaults (import ./poetry-overrides.nix);
};
mkPoetryDocsEnv = pkgs.mkPoetryEnv [ "docs" ];
mkPoetryDevEnv = pkgs.mkPoetryEnv [ "dev" "test" ];
mkPoetryFullDevEnv = pkgs.mkPoetryEnv [ "dev" "docs" "test" ];
prettierTOML = pkgs.writeShellScriptBin "prettier" ''
${pkgs.nodePackages.prettier}/bin/prettier \
--plugin-search-dir "${pkgs.nodePackages.prettier-plugin-toml}/lib" "$@"
'';
ibis38 = pkgs.callPackage drv { python = pkgs.python38; };
ibis39 = pkgs.callPackage drv { python = pkgs.python39; };
ibis310 = pkgs.callPackage drv { python = pkgs.python310; };
ibisDevEnv38 = pkgs.mkPoetryDevEnv pkgs.python38;
ibisDevEnv39 = pkgs.mkPoetryDevEnv pkgs.python39;
ibisDevEnv310 = pkgs.mkPoetryDevEnv pkgs.python310;
ibisDevEnv = pkgs.ibisDevEnv310;
ibisDocsEnv38 = pkgs.mkPoetryDocsEnv pkgs.python38;
ibisDocsEnv39 = pkgs.mkPoetryDocsEnv pkgs.python39;
ibisDocsEnv310 = pkgs.mkPoetryDocsEnv pkgs.python310;
ibisDocsEnv = pkgs.ibisDocsEnv310;
ibisFullDevEnv38 = pkgs.mkPoetryFullDevEnv pkgs.python38;
ibisFullDevEnv39 = pkgs.mkPoetryFullDevEnv pkgs.python39;
ibisFullDevEnv310 = pkgs.mkPoetryFullDevEnv pkgs.python310;
ibisFullDevEnv = pkgs.ibisFullDevEnv310;
changelog = pkgs.writeShellApplication {
name = "changelog";
runtimeInputs = [ pkgs.nodePackages.conventional-changelog-cli ];
text = "conventional-changelog --config ./.conventionalcommits.js";
};
arrow-cpp = (super.arrow-cpp.override {
enableS3 = !super.stdenv.isDarwin;
}).overrideAttrs
(attrs: {
# tests hang for some reason on macos with python 3.9 and 3.10
doInstallCheck = !super.stdenv.isDarwin;
buildInputs = attrs.buildInputs or [ ] ++ pkgs.lib.optionals super.stdenv.isDarwin [
pkgs.libxcrypt
pkgs.sqlite
];
});
})
];
} // flake-utils.lib.eachDefaultSystem (
localSystem:
let
pkgs = import nixpkgs {
inherit localSystem;
overlays = [ self.overlays.default ];
};
inherit (pkgs) lib;
backendDevDeps = with pkgs; [
# impala UDFs
clang_12
cmake
ninja
# snowflake
openssl
# backend test suite
docker-compose
# visualization
graphviz-nox
# duckdb
duckdb
# mysql
mariadb-client
# pyspark
openjdk11_headless
# postgres
postgresql
# geospatial
gdal
proj
# sqlite
sqlite-interactive
];
mkDevShell = env: pkgs.mkShell {
nativeBuildInputs = (with pkgs; [
# python dev environment
env
# rendering release notes
changelog
glow
# used in the justfile
jq
yj
# linting
commitlint
lychee
# release automation
nodejs
# poetry executable
env.pkgs.poetry
env.pkgs.poetry-core
# pre-commit deps
actionlint
git
just
nix-linter
nixpkgs-fmt
pre-commit
prettierTOML
shellcheck
shfmt
])
# backend development dependencies
++ backendDevDeps;
shellHook = ''
export IBIS_TEST_DATA_DIRECTORY="$PWD/ci/ibis-testing-data"
${pkgs.rsync}/bin/rsync \
--chmod=Du+rwx,Fu+rw --archive --delete \
"${pkgs.ibisTestingData}/" \
"$IBIS_TEST_DATA_DIRECTORY"
export TEMPDIR
TEMPDIR="$(python -c 'import tempfile; print(tempfile.gettempdir())')"
# necessary for mkdocs
export PYTHONPATH=''${PWD}''${PYTHONPATH:+:}''${PYTHONPATH}
'';
PGPASSWORD = "postgres";
MYSQL_PWD = "ibis";
MSSQL_SA_PASSWORD = "1bis_Testing!";
};
in
rec {
packages = rec {
ibis38 = pkgs.ibis38;
ibis39 = pkgs.ibis39;
ibis310 = pkgs.ibis310;
default = ibis310;
update-polars = pkgs.writeShellApplication {
name = "update-polars";
runtimeInputs = with pkgs; [
git
gnused
jq
rustNightly
sd
yj
];
text = ''
top="$PWD"
clone="''${1}"
tag="py-$(yj -tj < "''${top}/poetry.lock" | jq '.package[] | select(.name == "polars") | .version' -rcM)"
git -C "''${clone}" fetch
git -C "''${clone}" checkout .
git -C "''${clone}" checkout "''${tag}"
# remove patch dependencies and use thin lto to dramatically speed up builds
sed -i \
-e '/\[patch\.crates-io\]/d' \
-e '/cmake = .*/,+1d' \
-e '/codegen-units = 1/d' \
-e 's/lto = "fat"/lto = "thin"/g' \
"''${clone}/py-polars/Cargo.toml"
pushd "''${clone}/py-polars"
cargo generate-lockfile
popd
mkdir -p "''${top}/nix/patches"
git -C "''${clone}" diff | sd "py-polars/" "" > "''${top}/nix/patches/py-polars.patch"
'';
};
update-datafusion = pkgs.writeShellApplication {
name = "update-datafusion";
runtimeInputs = with pkgs; [
git
gnused
jq
rustNightly
yj
];
text = ''
top="''${PWD}"
clone="''${1}"
tag="$(yj -tj < "''${top}/poetry.lock" | jq -rcM '.package[] | select(.name == "datafusion") | .version')"
git -C "''${clone}" fetch
git -C "''${clone}" checkout .
git -C "''${clone}" checkout "''${tag}"
# use thin lto to dramatically speed up builds
sed -i \
-e '/codegen-units = 1/d' \
-e 's/lto = true/lto = "thin"/g' \
"''${clone}/Cargo.toml"
pushd "''${clone}"
cargo generate-lockfile
popd
mkdir -p "''${top}/nix/patches"
git -C "''${clone}" diff > "''${top}/nix/patches/datafusion.patch"
'';
};
update-lock-files = pkgs.writeShellApplication {
name = "update-lock-files";
runtimeInputs = with pkgs; [ poetry ];
text = ''
export PYTHONHASHSEED=0
TOP="''${PWD}"
poetry lock --no-update
poetry export --with dev --with test --with docs --without-hashes --no-ansi > "''${TOP}/requirements.txt"
'';
};
};
devShells = rec {
ibis38 = mkDevShell pkgs.ibisFullDevEnv38;
ibis39 = mkDevShell pkgs.ibisFullDevEnv39;
ibis310 = mkDevShell pkgs.ibisFullDevEnv310;
default = ibis310;
};
}
);
}