-
Notifications
You must be signed in to change notification settings - Fork 14
/
IR_TO_XLSX.pkb
2432 lines (2296 loc) · 102 KB
/
IR_TO_XLSX.pkb
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
create or replace PACKAGE BODY IR_TO_XLSX
as
-- general: displayed / not displayed columns - can be sow/hidden by user
-- hidden columns - column with type "hidden"
CURSOR cur_highlight(
p_report_id in APEX_APPLICATION_PAGE_IR_RPT.REPORT_ID%TYPE,
p_delimetered_column_list IN VARCHAR2
)
IS
SELECT rez.* ,
rownum cond_number,
'HIGHLIGHT_'||rownum cond_name
FROM (
SELECT report_id,
CASE
WHEN condition_operator in ('not in', 'in') THEN
ir_to_xlsx.get_highlight_in_cond_sql(condition_expression,condition_sql,condition_column_name)
ELSE
REPLACE(REPLACE(REPLACE(REPLACE(condition_sql,'#APXWS_EXPR#',''''||condition_expression||''''),'#APXWS_EXPR2#',''''||condition_expression2||''''),'#APXWS_HL_ID#','1'),'#APXWS_CC_EXPR#','"'||condition_column_name||'"')
END condition_sql,
condition_column_name,
condition_enabled,
highlight_row_color,
highlight_row_font_color,
highlight_cell_color,
highlight_cell_font_color
FROM apex_application_page_ir_cond
WHERE condition_type = 'Highlight'
AND report_id = p_report_id
AND instr(':'||p_delimetered_column_list||':',':'||condition_column_name||':') > 0
AND condition_enabled = 'Yes'
ORDER BY --rows highlights first
nvl2(highlight_row_color,1,0) DESC,
nvl2(highlight_row_font_color,1,0) DESC,
highlight_sequence
) rez;
SUBTYPE t_color IS VARCHAR2(7);
SUBTYPE t_style_string IS VARCHAR2(300);
SUBTYPE t_format_mask IS VARCHAR2(100);
SUBTYPE t_font IS VARCHAR2(50);
SUBTYPE t_large_varchar2 IS VARCHAR2(32767);
SUBTYPE largevarchar2 IS VARCHAR2(32767);
SUBTYPE columntype IS VARCHAR2(15);
SUBTYPE t_formatmask IS VARCHAR2(100);
TYPE t_date_table IS TABLE OF DATE INDEX BY BINARY_INTEGER;
TYPE t_number_table IS TABLE OF NUMBER INDEX BY BINARY_INTEGER;
TYPE t_styles IS TABLE OF BINARY_INTEGER INDEX BY t_style_string;
TYPE t_fill_list IS TABLE OF BINARY_INTEGER INDEX BY t_color;
TYPE t_font_list IS TABLE OF BINARY_INTEGER INDEX BY t_font;
TYPE t_format_mask_list IS TABLE OF BINARY_INTEGER INDEX BY t_format_mask;
TYPE t_col_names IS TABLE OF apex_application_page_ir_col.report_label%TYPE INDEX BY apex_application_page_ir_col.column_alias%TYPE;
TYPE t_col_format_mask IS TABLE OF apex_application_page_ir_comp.computation_format_mask%TYPE INDEX BY apex_application_page_ir_col.column_alias%TYPE;
TYPE t_header_alignment IS TABLE OF apex_application_page_ir_col.heading_alignment%TYPE INDEX BY apex_application_page_ir_col.column_alias%TYPE;
TYPE t_column_alignment IS TABLE OF apex_application_page_ir_col.column_alignment%TYPE INDEX BY apex_application_page_ir_col.column_alias%TYPE;
TYPE t_column_data_types IS TABLE OF apex_application_page_ir_col.column_type%TYPE INDEX BY BINARY_INTEGER;
TYPE t_highlight IS TABLE OF cur_highlight%rowtype INDEX BY BINARY_INTEGER;
TYPE t_column_links IS TABLE OF apex_application_page_ir_col.column_link%TYPE INDEX BY apex_application_page_ir_col.column_alias%TYPE;
TYPE t_all_columns IS TABLE OF BINARY_INTEGER INDEX BY VARCHAR2(32767);
TYPE ir_report IS RECORD
(
report apex_ir.t_report,
ir_data APEX_APPLICATION_PAGE_IR_RPT%ROWTYPE,
displayed_columns APEX_APPLICATION_GLOBAL.VC_ARR2,
break_on APEX_APPLICATION_GLOBAL.VC_ARR2,
break_really_on APEX_APPLICATION_GLOBAL.VC_ARR2, -- "break on" except hidden columns
sum_columns_on_break APEX_APPLICATION_GLOBAL.VC_ARR2,
avg_columns_on_break APEX_APPLICATION_GLOBAL.VC_ARR2,
max_columns_on_break APEX_APPLICATION_GLOBAL.VC_ARR2,
min_columns_on_break APEX_APPLICATION_GLOBAL.VC_ARR2,
median_columns_on_break APEX_APPLICATION_GLOBAL.VC_ARR2,
count_columns_on_break APEX_APPLICATION_GLOBAL.VC_ARR2,
count_distnt_col_on_break APEX_APPLICATION_GLOBAL.VC_ARR2,
skipped_columns BINARY_INTEGER default 0, -- when scpecial columns like apxws_row_pk is used
start_with BINARY_INTEGER default 0, -- position of first displayed column in query
end_with BINARY_INTEGER default 0, -- position of last displayed column in query
agg_cols_cnt BINARY_INTEGER default 0,
sql_query_columns_cnt BINARY_INTEGER default 0, -- columns count in SQL query
column_header_labels t_col_names, -- column names in report header
col_format_mask t_col_format_mask, -- format like $3849,56
row_highlight t_highlight,
col_highlight t_highlight,
header_alignment t_header_alignment,
column_alignment t_column_alignment,
column_data_types t_column_data_types,
column_link t_column_links,
desc_tab DBMS_SQL.DESC_TAB2, -- information about columns from final sql query
all_columns t_all_columns -- list of all columns from final sql query
);
TYPE t_cell_data IS RECORD
(
VALUE VARCHAR2(100),
text largevarchar2,
datatype VARCHAR2(50)
);
-- EXCEPTIONS
format_error EXCEPTION;
PRAGMA EXCEPTION_INIT(format_error, -01830);
date_format_error EXCEPTION;
PRAGMA EXCEPTION_INIT(date_format_error, -01821);
conversion_error EXCEPTION;
PRAGMA EXCEPTION_INIT(conversion_error,-06502);
l_report ir_report;
-- these plSQL tables are used ONLY to identify that unique entity
-- was already used,not to keep the XML content.
g_styles t_styles;
g_fills t_fill_list;
g_fonts t_font_list;
g_number_formats t_format_mask_list;
-- the unique XML content is saved in these text variables
g_fonts_xml t_large_varchar2;
g_back_xml t_large_varchar2;
v_styles_xml CLOB;
v_format_mask_xml CLOB;
-- CONSTANT
STRING_HEIGHT CONSTANT NUMBER DEFAULT 14.4;
WIDTH_COEFFICIENT CONSTANT NUMBER DEFAULT 6;
LOG_PREFIX VARCHAR2(9) DEFAULT 'GPV_XLSX:';
BACK_COLOR CONSTANT t_color DEFAULT '#C6E0B4';
-- Excel-template should have some pre-defined
-- fonts, format masks, fills, styles etc. to format column headers.
-- They are hardcoded in constants below (BOLD_FONT,UNDERLINE_FONT etc.).
-- One should keep this entities by adding new one.
-- Constatns below define an amount of this hardcoded entities
FONTS_CNT CONSTANT BINARY_INTEGER DEFAULT 3;
FORMAT_MASK_CNT CONSTANT BINARY_INTEGER DEFAULT 1;
DEFAULT_FILL_CNT CONSTANT BINARY_INTEGER DEFAULT 2;
DEFAULT_STYLES_CNT CONSTANT BINARY_INTEGER DEFAULT 1;
FORMAT_MASK_START_WITH CONSTANT BINARY_INTEGER DEFAULT 164;
------------------------------------------------------------------------------
t_sheet_rels CLOB DEFAULT '<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<Relationships xmlns="http://schemas.openxmlformats.org/package/2006/relationships">
<Relationship Id="rId3" Type="http://schemas.openxmlformats.org/officeDocument/2006/relationships/styles" Target="styles.xml"/>
<Relationship Id="rId2" Type="http://schemas.openxmlformats.org/officeDocument/2006/relationships/theme" Target="theme/theme1.xml"/>
<Relationship Id="rId1" Type="http://schemas.openxmlformats.org/officeDocument/2006/relationships/worksheet" Target="worksheets/sheet1.xml"/>
<Relationship Id="rId4" Type="http://schemas.openxmlformats.org/officeDocument/2006/relationships/sharedStrings" Target="sharedStrings.xml"/>
</Relationships>';
t_workbook CLOB DEFAULT '<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<workbook xmlns="http://schemas.openxmlformats.org/spreadsheetml/2006/main" xmlns:r="http://schemas.openxmlformats.org/officeDocument/2006/relationships">
<fileVersion appName="xl" lastEdited="4" lowestEdited="4" rupBuild="4506"/>
<workbookPr filterPrivacy="1" defaultThemeVersion="124226"/>
<bookViews>
<workbookView xWindow="120" yWindow="120" windowWidth="24780" windowHeight="12150"/>
</bookViews>
<sheets>
<sheet name="Sheet1" sheetId="1" r:id="rId1"/>
</sheets>
<definedNames><definedName name="_xlnm._FilterDatabase" localSheetId="0" hidden="1">Sheet1!$A$1:$H$1</definedName></definedNames>
<calcPr calcId="125725"/>
<fileRecoveryPr repairLoad="1"/>
</workbook>';
t_style_template CLOB DEFAULT '<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<styleSheet xmlns="http://schemas.openxmlformats.org/spreadsheetml/2006/main" xmlns:mc="http://schemas.openxmlformats.org/markup-compatibility/2006" mc:Ignorable="x14ac" xmlns:x14ac="http://schemas.microsoft.com/office/spreadsheetml/2009/9/ac">
#FORMAT_MASKS#
#FONTS#
#FILLS#
<borders count="2">
<border>
<left/>
<right/>
<top/>
<bottom/>
<diagonal/>
</border>
<border>
<left/>
<right/>
<top style="thin">
<color indexed="64"/>
</top>
<bottom/>
<diagonal/>
</border>
</borders>
<cellStyleXfs count="2">
<xf numFmtId="0" fontId="0" fillId="0" borderId="0" />
<xf numFmtId="0" fontId="2" fillId="0" borderId="0" applyNumberFormat="0" applyFill="0" applyBorder="0" applyAlignment="0" applyProtection="0" />
</cellStyleXfs>
#STYLES#
<cellStyles count="2">
<cellStyle name="Link" xfId="1" builtinId="8" />
<cellStyle name="Standard" xfId="0" builtinId="0" />
</cellStyles>
<dxfs count="0"/>
<tableStyles count="0" defaultTableStyle="TableStyleMedium9" defaultPivotStyle="PivotStyleLight16"/>
<extLst>
<ext uri="{EB79DEF2-80B8-43e5-95BD-54CBDDF9020C}" xmlns:x14="http://schemas.microsoft.com/office/spreadsheetml/2009/9/main">
<x14:slicerStyles defaultSlicerStyle="SlicerStyleLight1"/>
</ext>
</extLst>
</styleSheet>';
DEFAULT_FONT CONSTANT VARCHAR2(200) DEFAULT '
<font>
<sz val="11" />
<color theme="1" />
<name val="Calibri" />
<family val="2" />
<scheme val="minor" />
</font>';
BOLD_FONT CONSTANT VARCHAR2(200) DEFAULT '
<font>
<b />
<sz val="11" />
<color theme="1" />
<name val="Calibri" />
<family val="2" />
<scheme val="minor" />
</font>';
UNDERLINE_FONT CONSTANT VARCHAR2(200) DEFAULT '
<font>
<u />
<sz val="11" />
<color theme="10" />
<name val="Calibri" />
<family val="2" />
<scheme val="minor" />
</font>';
DEFAULT_FILL CONSTANT VARCHAR2(200) DEFAULT '
<fill>
<patternFill patternType="none" />
</fill>
<fill>
<patternFill patternType="gray125" />
</fill>';
DEFAULT_STYLE CONSTANT VARCHAR2(200) DEFAULT '
<xf numFmtId="0" fontId="0" fillId="0" borderId="0" xfId="0"/>';
AGGREGATE_STYLE CONSTANT VARCHAR2(250) DEFAULT '
<xf numFmtId="#FMTID#" borderId="1" fillId="0" fontId="1" xfId="0" applyAlignment="1" applyFont="1" applyBorder="1">
<alignment wrapText="1" horizontal="right" vertical="top"/>
</xf>';
HEADER_STYLE CONSTANT VARCHAR2(200) DEFAULT '
<xf numFmtId="0" borderId="0" #FILL# fontId="1" xfId="0" applyAlignment="1" applyFont="1" >
<alignment wrapText="0" horizontal="#ALIGN#"/>
</xf>';
FORMAT_MASK CONSTANT VARCHAR2(100) DEFAULT '
<numFmt numFmtId="'||FORMAT_MASK_START_WITH||'" formatCode="dd.mm.yyyy"/>';
------------------------------------------------------------------------------
/**
* http://mk-commi.blogspot.co.at/2014/11/concatenating-varchar2-values-into-clob.html
* Procedure concatenates a VARCHAR2 to a CLOB.
* It uses another VARCHAR2 as a buffer until it reaches 32767 characters.
* Then it flushes the current buffer to the CLOB and resets the buffer using
* the actual VARCHAR2 to add.
* Your final call needs to be done setting p_eof to TRUE in order to
* flush everything to the CLOB.
*
* @param p_clob The CLOB buffer.
* @param p_vc_buffer The intermediate VARCHAR2 buffer. (must be VARCHAR2(32767))
* @param p_vc_addition The VARCHAR2 value you want to append.
* @param p_eof Indicates if complete buffer should be flushed to CLOB.
*/
PROCEDURE add(
p_clob IN OUT NOCOPY CLOB
,p_vc_buffer IN OUT NOCOPY VARCHAR2
,p_vc_addition IN VARCHAR2
,p_eof IN BOOLEAN DEFAULT false
) AS
BEGIN
-- Standard Flow
IF nvl(lengthb(p_vc_buffer), 0) + nvl(lengthb(p_vc_addition), 0) < (32767/2) THEN
p_vc_buffer := p_vc_buffer || convert(p_vc_addition,'utf8');
ELSE
IF p_clob IS NULL THEN
dbms_lob.createtemporary(p_clob, true);
END IF;
dbms_lob.writeappend(p_clob, length(p_vc_buffer), p_vc_buffer);
p_vc_buffer := convert(p_vc_addition,'utf8');
END IF;
-- Full Flush requested
IF p_eof THEN
IF p_clob IS NULL THEN
p_clob := p_vc_buffer;
ELSE
dbms_lob.writeappend(p_clob, length(p_vc_buffer), p_vc_buffer);
END IF;
p_vc_buffer := NULL;
END IF;
END add;
------------------------------------------------------------------------------
PROCEDURE log(p_message IN VARCHAR2)
IS
BEGIN
apex_debug_message.log_message(p_message => log_prefix||substr(p_message,1,32758),
p_enabled => false,
p_level => 4);
END log;
------------------------------------------------------------------------------
-- convert date format string from ORACLE-style to MS Excel style
FUNCTION convert_date_format(p_format IN VARCHAR2)
RETURN VARCHAR2
IS
v_str VARCHAR2(100);
BEGIN
v_str := apex_plugin_util.replace_substitutions(p_format);
v_str := upper(v_str);
--date
v_str := replace(v_str,'DAY','DDDD');
v_str := replace(v_str,'MONTH','MMMM');
v_str := replace(v_str,'MON','MMM');
v_str := replace(v_str,'R','Y');
v_str := replace(v_str,'FM','');
v_str := replace(v_str,'PM',' AM/PM');
--time
v_str := replace(v_str,'MI','mm');
v_str := replace(v_str,'SS','ss');
v_str := replace(v_str,'HH24','hh');
v_str := regexp_replace(v_str,'HH12([^ ]+)','h\1 AM/PM');
v_str := replace(v_str,'AM\/PM',' AM/PM');
RETURN v_str;
END convert_date_format;
------------------------------------------------------------------------------
-- convert number format string from ORACLE-style to MS Excel style
FUNCTION convert_number_format(p_format IN VARCHAR2)
RETURN VARCHAR2
IS
v_str VARCHAR2(100);
BEGIN
v_str := apex_plugin_util.replace_substitutions(p_format);
v_str := upper(v_str);
--number
v_str := replace(v_str,'9','#');
v_str := replace(v_str,'D','.');
v_str := replace(v_str,'G',',');
v_str := replace(v_str,'FM','');
-- plus/minus sign
IF instr(v_str,'S') > 0 THEN
v_str := replace(v_str,'S','');
v_str := '+'||v_str||';-'||v_str;
END IF;
--currency
v_str := replace(v_str,'L',convert('"'||rtrim(TO_CHAR(0,'FML0'),'0')||'"','UTF8'));
v_str := regexp_substr(v_str,'.G?[^G]+$');
RETURN v_str;
END convert_number_format;
------------------------------------------------------------------------------
-- get current date/time format used in DB session for given date or time type
-- this format is used if date/time format in APEX is not defined
FUNCTION get_current_format(p_data_type IN BINARY_INTEGER)
RETURN VARCHAR2
IS
v_format t_formatmask;
v_parameter VARCHAR2(50);
BEGIN
IF p_data_type IN (dbms_types.typecode_timestamp_tz,181) THEN
v_parameter := 'NLS_TIMESTAMP_TZ_FORMAT';
ELSIF p_data_type IN (dbms_types.typecode_timestamp_ltz,231) THEN
v_parameter := 'NLS_TIMESTAMP_TZ_FORMAT';
ELSIF p_data_type IN (dbms_types.typecode_timestamp,180) THEN
v_parameter := 'NLS_TIMESTAMP_FORMAT';
ELSIF p_data_type = dbms_types.typecode_date THEN
v_parameter := 'NLS_DATE_FORMAT';
ELSE
RETURN 'dd.mm.yyyy';
END IF;
SELECT value
INTO v_format
FROM v$nls_parameters
WHERE parameter = v_parameter;
RETURN v_format;
END get_current_format;
------------------------------------------------------------------------------
-- convert date format from ORACLE-style to MS Excel Style
-- for given date/time datatype
FUNCTION convert_date_format(
p_datatype IN VARCHAR2,
p_format IN VARCHAR2
)
RETURN VARCHAR2
IS
v_str VARCHAR2(100);
v_24h_format BOOLEAN DEFAULT true;
BEGIN
IF p_format IS NULL THEN
IF p_datatype = 'TIMESTAMP_TZ' THEN
v_str := get_current_format(dbms_types.typecode_timestamp_tz);
ELSIF p_datatype = 'TIMESTAMP_LTZ' THEN
v_str := get_current_format(dbms_types.typecode_timestamp_ltz);
ELSIF p_datatype = 'TIMESTAMP' THEN
v_str := get_current_format(dbms_types.typecode_timestamp);
ELSIF p_datatype = 'DATE' THEN
v_str := get_current_format(dbms_types.typecode_date);
ELSE
v_str := get_current_format('');
END IF;
ELSE
v_str := p_format;
END IF;
RETURN convert_date_format(p_format => v_str);
END convert_date_format;
------------------------------------------------------------------------------
-- convert date format from ORACLE-style to format used in JavaScript
-- for given date/time datatype
FUNCTION convert_date_format_js(
p_datatype IN VARCHAR2,
p_format IN VARCHAR2
)
RETURN VARCHAR2
IS
v_str VARCHAR2(100);
v_24h_format BOOLEAN DEFAULT true;
BEGIN
IF p_format IS NULL THEN
IF p_datatype = 'TIMESTAMP_TZ' THEN
v_str := get_current_format(dbms_types.typecode_timestamp_tz);
ELSIF p_datatype = 'TIMESTAMP_LTZ' THEN
v_str := get_current_format(dbms_types.typecode_timestamp_ltz);
ELSIF p_datatype = 'TIMESTAMP' THEN
v_str := get_current_format(dbms_types.typecode_timestamp);
ELSIF p_datatype = 'DATE' THEN
v_str := get_current_format(dbms_types.typecode_date);
ELSE
v_str := get_current_format('');
END IF;
ELSE
v_str := p_format;
END IF;
v_str := upper(apex_plugin_util.replace_substitutions(v_str));
--date
v_str := replace(v_str,'DAY','ddd');
v_str := replace(v_str,'MONTH','MMMM');
v_str := replace(v_str,'MON','MMM');
v_str := replace(v_str,'R','Y');
v_str := replace(v_str,'FM','');
IF instr(v_str,'PM') > 0 THEN
v_24h_format := false;
END IF;
v_str := replace(v_str,'AM/PM','');
v_str := replace(v_str,'PM','');
--time
v_str := replace(v_str,'MI','mm');
v_str := replace(v_str,'SS','ss');
v_str := replace(v_str,'HH24','HH');
v_str := replace(v_str,'HH12','hh');
IF NOT v_24h_format THEN
v_str := replace(v_str,'HH','hh');
END IF;
RETURN v_str;
END convert_date_format_js;
------------------------------------------------------------------------------
-- to set a font-color in Excel one need to define a Font
-- add_font function:
-- return an index of the Font based on the combination (font-color + has link property)
-- create a new Font if Font not exists and return an id
FUNCTION add_font(
p_font_color IN t_color,
p_is_link IN BOOLEAN
)
RETURN BINARY_INTEGER
IS
v_index t_font;
BEGIN
IF p_is_link THEN
v_index := p_font_color||'L';
ELSIF p_font_color IS NOT NULL THEN
v_index := p_font_color;
ELSE
raise_application_error(-20001,'Font is null and Link is null!');
END IF;
IF NOT g_fonts.EXISTS(v_index) THEN
g_fonts(v_index) := g_fonts.count + 1;
g_fonts_xml := g_fonts_xml||
'<font>'||chr(10)||
CASE WHEN p_is_link THEN
' <u />'||chr(10)
ELSE ''||
' <sz val="11" />'||chr(10)
END ||
CASE WHEN p_font_color IS NOT NULL THEN
' <color rgb="'||ltrim(p_font_color,'#')||'" />'||chr(10)
ELSE -- link
' <color theme="10" />'||chr(10)
END ||
' <name val="Calibri" />'||chr(10)||
' <family val="2" />'||chr(10)||
' <scheme val="minor" />'||
'</font>'||chr(10);
RETURN g_fonts.count + FONTS_CNT - 1; --start with 0
ELSE
RETURN g_fonts(v_index) + FONTS_CNT - 1;
END IF;
END add_font;
------------------------------------------------------------------------------
-- to set a background-color in Excel one need create a Fill
-- add_fill function:
-- return an index of the Fill based on the background-color
-- create a new Fill if Fill not exists and return an id
FUNCTION add_fill(p_back_color IN t_color)
RETURN BINARY_INTEGER
IS
BEGIN
IF NOT g_fills.EXISTS(p_back_color) THEN
g_fills(p_back_color) := g_fills.count + 1;
g_back_xml := g_back_xml||
'<fill>'||chr(10)||
' <patternFill patternType="solid">'||chr(10)||
' <fgColor rgb="'||ltrim(p_back_color,'#')||'" />'||chr(10)||
' <bgColor indexed="64" />'||chr(10)||
' </patternFill>'||
'</fill>'||chr(10);
RETURN g_fills.count + DEFAULT_FILL_CNT - 1; --start with 0
ELSE
RETURN g_fills(p_back_color) + DEFAULT_FILL_CNT - 1;
END IF;
END add_fill;
------------------------------------------------------------------------------
-- to set a Number-Format in Excel one need create them
-- add_number_format function:
-- return an index of the Number-Format based on the format mask
-- create a new Number-Format if Number-Format not exists and return an id
FUNCTION add_number_format(p_mask IN VARCHAR2)
RETURN BINARY_INTEGER
IS
BEGIN
IF NOT g_number_formats.EXISTS(p_mask) THEN
g_number_formats(p_mask) := g_number_formats.count + 1;
v_format_mask_xml := v_format_mask_xml||
'<numFmt numFmtId="'||(FORMAT_MASK_START_WITH + g_number_formats.count)||'" formatCode="'||p_mask||'"/>'||chr(10);
RETURN g_number_formats.count + FORMAT_MASK_CNT + FORMAT_MASK_START_WITH - 1;
ELSE
RETURN g_number_formats(p_mask) + FORMAT_MASK_CNT + FORMAT_MASK_START_WITH - 1;
END IF;
END add_number_format;
------------------------------------------------------------------------------
-- build a Fonts: XML-list of Font-elements
FUNCTION get_fonts_xml
RETURN CLOB
IS
BEGIN
RETURN to_clob('<fonts count="'||(g_fonts.count + FONTS_CNT)||'" x14ac:knownFonts="1">'||
DEFAULT_FONT||chr(10)||
BOLD_FONT||chr(10)||
UNDERLINE_FONT||chr(10)||
g_fonts_xml||chr(10)||
'</fonts>'||chr(10));
END get_fonts_xml;
------------------------------------------------------------------------------
-- build a Fills: XML-list of Fill-elements
FUNCTION get_fills_xml
RETURN CLOB
IS
BEGIN
RETURN to_clob('<fills count="'||(g_fills.count + DEFAULT_FILL_CNT)||'">'||
default_fill||
g_back_xml||chr(10)||
'</fills>'||chr(10));
END get_fills_xml;
------------------------------------------------------------------------------
-- build a numFmts: XML-list of numFmt-elements
FUNCTION get_numFmts_xml
RETURN CLOB
IS
BEGIN
RETURN to_clob('<numFmts count="'||(g_number_formats.count + FORMAT_MASK_CNT)||'">'||
FORMAT_MASK||
v_format_mask_xml||chr(10)||
'</numFmts>'||chr(10));
END get_numFmts_xml;
------------------------------------------------------------------------------
-- build a cellXfs: XML-list of cell styles
FUNCTION get_cellxfs_xml
RETURN CLOB
IS
BEGIN
RETURN to_clob('<cellXfs count="'||(g_styles.count + default_styles_cnt)||'">'||
DEFAULT_STYLE||chr(10)||
v_styles_xml||chr(10)||
'</cellXfs>'||chr(10));
END get_cellxfs_xml;
------------------------------------------------------------------------------
-- get an index of existent Numer- or Date- Format
-- create the new Format if not exist
FUNCTION get_num_fmt_id(p_data_type IN VARCHAR2,
p_format_mask IN VARCHAR2)
RETURN BINARY_INTEGER
IS
v_format_mask VARCHAR2(100);
BEGIN
v_format_mask := apex_plugin_util.replace_substitutions(p_format_mask);
IF p_data_type = 'NUMBER' THEN
IF v_format_mask IS NULL THEN
RETURN 0; -- default number format in Excel
ELSE
RETURN add_number_format(convert_number_format(v_format_mask));
END IF;
ELSIF p_data_type = 'DATE' THEN
IF v_format_mask IS NULL THEN
RETURN FORMAT_MASK_START_WITH; -- default date format
ELSE
RETURN add_number_format(convert_date_format(v_format_mask));
END IF;
ELSE
RETURN 2; -- default string format in Excel
END IF;
END get_num_fmt_id;
------------------------------------------------------------------------------
-- get style_id for existent styles or
-- add new style and return style_id
FUNCTION get_style_id(
p_font_color IN t_color,
p_back_color IN t_color,
p_data_type IN VARCHAR2,
p_format_mask IN VARCHAR2,
p_align IN VARCHAR2,
p_is_link IN BOOLEAN
)
RETURN BINARY_INTEGER
IS
v_style t_style_string;
v_font_color_id BINARY_INTEGER;
v_back_color_id BINARY_INTEGER;
v_style_xml t_large_varchar2;
BEGIN
-- generate unique style name based on cell format
v_style := nvl(p_font_color,' ')
||nvl(p_back_color,' ')
||p_data_type
||p_format_mask
||p_align
||CASE WHEN p_is_link THEN 'LINK' ELSE '' END;
IF g_styles.EXISTS(v_style) THEN
RETURN g_styles(v_style) - 1 + default_styles_cnt;
ELSE
g_styles(v_style) := g_styles.count + 1;
IF p_is_link THEN
v_style_xml := '<xf borderId="0" xfId="0" ';
ELSE
v_style_xml := '<xf borderId="0" xfId="1" ';
END IF;
v_style_xml := v_style_xml||replace(' numFmtId="#FMTID#" ','#FMTID#',get_num_fmt_id(p_data_type,p_format_mask));
IF p_font_color IS NOT NULL OR p_is_link THEN
v_font_color_id := add_font(p_font_color,p_is_link);
v_style_xml := v_style_xml||' fontId="'||v_font_color_id||'" applyFont="1" ';
ELSE
v_style_xml := v_style_xml||' fontId="0" '; --default font
END IF;
IF p_back_color IS NOT NULL THEN
v_back_color_id := add_fill(p_back_color);
v_style_xml := v_style_xml||' fillId="'||v_back_color_id||'" applyFill="1" ';
ELSE
v_style_xml := v_style_xml||' fillId="0" '; --default fill
END IF;
v_style_xml := v_style_xml||'>'||chr(10);
v_style_xml := v_style_xml||'<alignment wrapText="1"';
IF p_align IS NOT NULL THEN
v_style_xml := v_style_xml||' horizontal="'||lower(p_align)||'" ';
END IF;
v_style_xml := v_style_xml||'/>'||chr(10);
v_style_xml := v_style_xml||'</xf>'||chr(10);
v_styles_xml := v_styles_xml||to_clob(v_style_xml);
RETURN g_styles.count - 1 + DEFAULT_STYLES_CNT;
END IF;
END get_style_id;
------------------------------------------------------------------------------
-- analog of get_style_id for aggregate functions of Interactive Report
FUNCTION get_aggregate_style_id(
p_font IN t_color,
p_back IN t_color,
p_data_type IN VARCHAR2,
p_format_mask IN VARCHAR2
)
RETURN BINARY_INTEGER
IS
v_style t_style_string;
v_style_xml t_large_varchar2;
v_num_fmt_id BINARY_INTEGER;
BEGIN
-- generate unique style name based on cell format
v_style := nvl(p_font,' ')||nvl(p_back,' ')||p_data_type||p_format_mask||'AGGREGATE';
--
IF g_styles.exists(v_style) THEN
RETURN g_styles(v_style) - 1 + DEFAULT_STYLES_CNT;
ELSE
g_styles(v_style) := g_styles.count + 1;
v_style_xml := replace(AGGREGATE_STYLE,'#FMTID#',get_num_fmt_id(p_data_type,p_format_mask)) ||chr(10);
v_styles_xml := v_styles_xml||v_style_xml;
RETURN g_styles.count - 1 + DEFAULT_STYLES_CNT;
END IF;
END get_aggregate_style_id;
------------------------------------------------------------------------------
-- analog of get_style_id for report headers
FUNCTION get_header_style_id(
p_back IN t_color DEFAULT BACK_COLOR,
p_align IN VARCHAR2,
p_border IN BOOLEAN DEFAULT FALSE
)
RETURN BINARY_INTEGER
IS
v_style t_style_string;
v_style_xml t_large_varchar2;
v_num_fmt_id BINARY_INTEGER;
v_fill_id BINARY_INTEGER;
BEGIN
-- generate unique style name based on cell format
v_style := ' '||nvl(p_back,' ')||'CHARHEADER'||p_align;
--
IF g_styles.exists(v_style) THEN
RETURN g_styles(v_style) - 1 + DEFAULT_STYLES_CNT;
ELSE
g_styles(v_style) := g_styles.count + 1;
IF p_back IS NOT NULL THEN
v_fill_id := add_fill(p_back);
v_style_xml := replace(HEADER_STYLE,'#FILL#',' fillId="'||v_fill_id||'" applyFill="1" ' );
ELSE
v_style_xml := replace(HEADER_STYLE,'#FILL#',' fillId="0" '); --default fill
END IF;
v_style_xml := replace(v_style_xml,'#ALIGN#',lower(p_align))||chr(10);
v_styles_xml := v_styles_xml||v_style_xml;
RETURN g_styles.count - 1 + DEFAULT_STYLES_CNT;
END IF;
END get_header_style_id;
------------------------------------------------------------------------------
-- build a final XML containing all styles
FUNCTION get_styles_xml
RETURN CLOB
IS
v_template CLOB;
BEGIN
v_template := replace(t_style_template,'#FORMAT_MASKS#',get_numfmts_xml);
v_template := replace(v_template,'#FONTS#',get_fonts_xml);
v_template := replace(v_template,'#FILLS#',get_fills_xml);
v_template := replace(v_template,'#STYLES#',get_cellxfs_xml);
RETURN v_template;
END get_styles_xml;
------------------------------------------------------------------------------
-- get cell name in Excel Format (like A11 ob B5)
FUNCTION get_cell_name(
p_col IN BINARY_INTEGER,
p_row IN BINARY_INTEGER
)
RETURN VARCHAR2
IS
BEGIN
/*
Author: Moritz Klein (https://github.com/commi235)
https://github.com/commi235/xlsx_builder/blob/master/xlsx_builder_pkg.pkb
*/
RETURN CASE
WHEN p_col > 702
THEN
CHR (64 + TRUNC ( (p_col - 27) / 676))
|| CHR (65 + MOD (TRUNC ( (p_col - 1) / 26) - 1, 26))
|| CHR (65 + MOD (p_col - 1, 26))
WHEN p_col > 26
THEN
CHR (64 + TRUNC ( (p_col - 1) / 26)) || CHR (65 + MOD (p_col - 1, 26))
ELSE
CHR (64 + p_col)
END||p_row;
END get_cell_name;
-----------------------------------------------------------
FUNCTION get_column_header_label(p_column_alias IN apex_application_page_ir_col.column_alias%TYPE)
RETURN apex_application_page_ir_col.report_label%TYPE
IS
BEGIN
-- https://github.com/glebovpavel/IR_to_MSExcel/issues/9
-- Thanks HeavyS
RETURN apex_plugin_util.replace_substitutions(p_value => l_report.column_header_labels(p_column_alias));
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_column_header_label: p_column_alias='||p_column_alias||' '||SQLERRM);
END get_column_header_label;
------------------------------------------------------------------------------
FUNCTION get_col_format_mask(p_column_alias IN apex_application_page_ir_col.column_alias%TYPE)
RETURN t_formatmask
IS
BEGIN
RETURN apex_plugin_util.replace_substitutions(
p_value => replace(l_report.col_format_mask(p_column_alias),'"',''),
p_escape => false);
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_col_format_mask: p_column_alias='||p_column_alias||' '||SQLERRM);
END get_col_format_mask;
------------------------------------------------------------------------------
FUNCTION get_col_link(p_column_alias IN apex_application_page_ir_col.column_alias%TYPE)
RETURN t_formatmask
IS
BEGIN
RETURN replace(l_report.column_link(p_column_alias),'"','');
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_col_link: p_column_alias='||p_column_alias||' '||SQLERRM);
END get_col_link;
------------------------------------------------------------------------------
PROCEDURE set_col_format_mask(
p_column_alias IN apex_application_page_ir_col.column_alias%TYPE,
p_format_mask IN t_formatmask
)
IS
BEGIN
l_report.col_format_mask(p_column_alias) := p_format_mask;
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'set_col_format_mask: p_column_alias='||p_column_alias||' '||sqlerrm);
END set_col_format_mask;
------------------------------------------------------------------------------
FUNCTION get_header_alignment(p_column_alias IN apex_application_page_ir_col.column_alias%TYPE)
RETURN apex_application_page_ir_col.heading_alignment%TYPE
IS
BEGIN
RETURN l_report.header_alignment(p_column_alias);
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_header_alignment: p_column_alias='||p_column_alias||' '||sqlerrm);
END get_header_alignment;
------------------------------------------------------------------------------
FUNCTION get_column_alignment(p_column_alias IN apex_application_page_ir_col.column_alias%TYPE)
RETURN apex_application_page_ir_col.column_alignment%TYPE
IS
BEGIN
RETURN l_report.column_alignment(p_column_alias);
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_column_alignment: p_column_alias='||p_column_alias||' '||sqlerrm);
END get_column_alignment;
------------------------------------------------------------------------------
FUNCTION get_column_data_type(p_num IN BINARY_INTEGER)
RETURN apex_application_page_ir_col.column_type%TYPE
IS
BEGIN
RETURN l_report.column_data_types(p_num);
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_column_data_type: p_num='||p_num||' '||sqlerrm);
END get_column_data_type;
------------------------------------------------------------------------------
FUNCTION get_column_alias(p_num IN BINARY_INTEGER)
RETURN VARCHAR2
IS
BEGIN
RETURN l_report.displayed_columns(p_num);
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_column_alias: p_num='||p_num||' '||sqlerrm);
END get_column_alias;
------------------------------------------------------------------------------
-- get column alias by column number from SQL-Query
FUNCTION get_column_alias_sql(p_num IN BINARY_INTEGER) -- column number in sql-query
RETURN VARCHAR2
IS
BEGIN
RETURN l_report.displayed_columns(p_num - l_report.start_with + 1);
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_column_alias_sql: p_num='||p_num||' '||sqlerrm);
END get_column_alias_sql;
------------------------------------------------------------------------------
-- get value from varchar2-table by position
FUNCTION get_current_row(
p_current_row IN apex_application_global.vc_arr2,
p_position IN BINARY_INTEGER
)
RETURN largevarchar2
IS
BEGIN
RETURN p_current_row(p_position);
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_current_row: string: p_id='||p_position||' '||sqlerrm);
END get_current_row;
------------------------------------------------------------------------------
-- get value from date2-table by position
FUNCTION get_current_row(
p_current_row IN t_date_table,
p_position IN BINARY_INTEGER
)
RETURN DATE
IS
BEGIN
IF p_current_row.EXISTS(p_position) THEN
RETURN p_current_row(p_position);
ELSE
RETURN NULL;
END IF;
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_current_row:date: p_id='||p_position||' '||sqlerrm);
END get_current_row;
------------------------------------------------------------------------------
-- get value from numbers-table by position
FUNCTION get_current_row(
p_current_row IN t_number_table,
p_position IN BINARY_INTEGER
)
RETURN NUMBER
IS
BEGIN
IF p_current_row.EXISTS(p_position) THEN
RETURN p_current_row(p_position);
ELSE
RETURN NULL;
END IF;
EXCEPTION
WHEN OTHERS THEN
raise_application_error(-20001,'get_current_row:number: p_id='||p_position||' '||sqlerrm);
END get_current_row;
------------------------------------------------------------------------------
-- replace multiple occurences of ":" to the one
-- :::: -> :
FUNCTION rr(p_str IN VARCHAR2)
RETURN VARCHAR2
IS
BEGIN
RETURN ltrim(rtrim(regexp_replace(p_str,'[:]+',':'),':'),':');
END rr;
------------------------------------------------------------------------------
-- remove HTML-tags (only simple cases are supported),
-- special invisible characters like \t, \n ets
-- and conver them to the xml
FUNCTION get_xmlval(p_str IN VARCHAR2)
RETURN VARCHAR2
IS
v_tmp largevarchar2;
BEGIN
-- p_str can be encoded html-string
-- wee need first convert to text
v_tmp := regexp_replace(p_str,'<(BR)\s*/*>',chr(13)||chr(10),1,0,'i');
v_tmp := regexp_replace(v_tmp,'<[^<>]+>',' ',1,0,'i');
-- https://community.oracle.com/message/14074217#14074217
v_tmp := regexp_replace(v_tmp, '[^[:print:]'||chr(13)||chr(10)||chr(9)||']', ' ');
v_tmp := utl_i18n.unescape_reference(v_tmp);
-- and finally encode them
--v_tmp := substr(v_tmp,1,32000);
v_tmp := dbms_xmlgen.convert( substr( v_tmp, 1, 32000 ) );
RETURN v_tmp;
END get_xmlval;
------------------------------------------------------------------------------
FUNCTION intersect_arrays(p_one IN apex_application_global.vc_arr2,
p_two IN apex_application_global.vc_arr2)
RETURN apex_application_global.vc_arr2
IS
v_ret apex_application_global.vc_arr2;
BEGIN
FOR i IN 1..p_one.count LOOP
FOR b IN 1..p_two.count LOOP
IF p_one(i) = p_two(b) THEN
v_ret(v_ret.count + 1) := p_one(i);
EXIT;
END IF;
END LOOP;
END LOOP;
RETURN v_ret;
END intersect_arrays;
------------------------------------------------------------------------------
-- get list of column-aliases from
-- report's SQL-Query
FUNCTION get_query_column_list
RETURN apex_application_global.vc_arr2
IS
v_cur INTEGER;
v_colls_count BINARY_INTEGER;
v_columns apex_application_global.vc_arr2;
v_desc_tab dbms_sql.desc_tab2;
v_sql largevarchar2;