/
servlet.clj
200 lines (187 loc) · 8.62 KB
/
servlet.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
;; Copyright 2014-2015 Red Hat, Inc, and individual contributors.
;;
;; Licensed under the Apache License, Version 2.0 (the "License");
;; you may not use this file except in compliance with the License.
;; You may obtain a copy of the License at
;;
;; http://www.apache.org/licenses/LICENSE-2.0
;;
;; Unless required by applicable law or agreed to in writing, software
;; distributed under the License is distributed on an "AS IS" BASIS,
;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
;; See the License for the specific language governing permissions and
;; limitations under the License.
(ns ^{:no-doc true} immutant.web.internal.servlet
(:require [immutant.web.internal.ring :as ring]
[immutant.web.internal.headers :as hdr]
[immutant.web.async :as async])
(:import [org.projectodd.wunderboss.web.async Channel
Channel$OnOpen Channel$OnClose Channel$OnError
ServletHttpChannel Util]
[org.projectodd.wunderboss.web.async.websocket DelegatingJavaxEndpoint
JavaxWebsocketChannel WebSocketHelpyHelpersonFilter
WebsocketChannel WebsocketChannel$OnMessage]
[java.util LinkedHashMap]
[javax.servlet.http HttpServlet HttpServletRequest HttpServletResponse HttpSession]
[javax.servlet Servlet ServletConfig ServletContext]
[javax.websocket Session Endpoint EndpointConfig MessageHandler$Whole CloseReason]
[javax.websocket.server ServerContainer
ServerEndpointConfig ServerEndpointConfig$Builder ServerEndpointConfig$Configurator]))
(defn- get-or-create-session
([servlet-request]
(get-or-create-session servlet-request nil))
([^HttpServletRequest servlet-request timeout]
(let [session (.getSession servlet-request)]
(if timeout
(ring/set-session-expiry session timeout)
session))))
(defn wrap-servlet-session
"Ring middleware to insert a :session entry into the request, its
value stored in the possibly-replicated HttpSession from the
associated servlet"
[handler {:keys [timeout]}]
(fn [request]
(let [^HttpServletRequest servlet-request (:servlet-request request)
response (handler
(assoc request
;; we assume the request map automatically derefs delays
:session (delay (-> servlet-request (get-or-create-session timeout) ring/ring-session))))]
(when (contains? response :session)
(if-let [data (:session response)]
(ring/set-ring-session! (get-or-create-session servlet-request) data)
(when-let [session (.getSession servlet-request false)]
(.invalidate session))))
response)))
(extend-type HttpSession
ring/Session
(attribute [session key]
(.getAttribute session key))
(set-attribute! [session key value]
(.setAttribute session key value))
(get-expiry [session]
(.getMaxInactiveInterval session))
(set-expiry [session timeout]
(.setMaxInactiveInterval session timeout)))
(extend-type HttpServletRequest
ring/RingRequest
(server-port [request] (.getServerPort request))
(server-name [request] (.getServerName request))
(remote-addr [request] (.getRemoteAddr request))
(uri [request] (.getRequestURI request))
(query-string [request] (.getQueryString request))
(scheme [request] (-> request .getScheme keyword))
(request-method [request] (-> request .getMethod .toLowerCase keyword))
(content-type [request] (.getContentType request))
(content-length [request] (.getContentLength request))
(character-encoding [request] (.getCharacterEncoding request))
(headers [request] (hdr/headers->map request))
(body [request] (.getInputStream request))
(context [request] (str (.getContextPath request) (.getServletPath request)))
(path-info [request] (or (.getPathInfo request) "/"))
(ssl-client-cert [request] (first (.getAttribute request "javax.servlet.request.X509Certificate")))
hdr/Headers
(get-names [request] (enumeration-seq (.getHeaderNames request)))
(get-values [request key] (enumeration-seq (.getHeaders request key))))
(extend-type HttpServletResponse
ring/RingResponse
(set-status [response status] (.setStatus response status))
(header-map [response] response)
(output-stream [response] (.getOutputStream response))
hdr/Headers
(get-value [response key] (.getHeader response key))
(set-header [response key value] (.setHeader response key value))
(add-header [response key value] (.addHeader response key value)))
(defn ^ServerContainer server-container [^ServletContext context]
(.getAttribute context "javax.websocket.server.ServerContainer"))
(defn add-endpoint
"Adds an endpoint to a container obtained from the servlet-context"
[^Endpoint endpoint ^ServletContext servlet-context {:keys [path handshake] :or {path "/"}}]
(.addEndpoint (server-container servlet-context)
(.. ServerEndpointConfig$Builder
(create (class endpoint) path)
(configurator (proxy [ServerEndpointConfig$Configurator] []
(getEndpointInstance [c] endpoint)
(modifyHandshake [^ServerEndpointConfig config _ response]
(when handshake
(handshake config
(.get (WebSocketHelpyHelpersonFilter/requestTL))
response)))))
build)))
(defn handshake-ring-invoker [handler]
(fn [^ServerEndpointConfig config request response]
(let [body (:body (handler (ring/ring-request-map request
[:handler-type :servlet]
[:servlet-request request]
[:websocket? true])))]
(when (instance? WebsocketChannel body)
(-> config
.getUserProperties
(.put DelegatingJavaxEndpoint/ENDPOINT_KEY
(.endpoint ^WebsocketChannel body)))))))
(defn ^Servlet create-servlet
"Encapsulate a ring handler within a servlet"
[handler]
(proxy [HttpServlet] []
(service [^HttpServletRequest request ^HttpServletResponse response]
(let [ring-map (-> request
(ring/ring-request-map
[:handler-type :servlet]
[:servlet this]
[:servlet-request request]
[:servlet-response response]
[:servlet-context (delay (.getServletContext ^HttpServlet this))]))]
(if-let [result (if handler (handler ring-map) {:status 404})]
(ring/write-response response result)
(throw (NullPointerException. "Ring handler returned nil")))))
(init [^ServletConfig config]
(let [^HttpServlet this this]
(proxy-super init config)
(let [context (.getServletContext config)
mapping (-> context (.getServletRegistration (.getServletName this)) .getMappings first)
path (apply str (take (- (count mapping) 2) mapping))
path (if (empty? path) "/" path)]
(add-endpoint (DelegatingJavaxEndpoint.) context
{:path path :handshake (handshake-ring-invoker handler)}))))))
(defmethod async/initialize-stream :servlet
[request {:keys [on-open on-error on-close]}]
(ServletHttpChannel.
(:servlet-request request)
(:servlet-response request)
(reify Channel$OnOpen
(handle [_ ch _]
(.setOriginatingRequest ^Channel ch request)
(when on-open
(on-open ch))))
(when on-error
(reify Channel$OnError
(handle [_ ch error]
(on-error ch error))))
(when on-close
(reify Channel$OnClose
(handle [_ ch code reason]
(on-close ch {:code code
:reason reason}))))))
(defmethod async/initialize-websocket :servlet
[request {:keys [on-open on-error on-close on-message on-error]}]
(JavaxWebsocketChannel.
(reify Channel$OnOpen
(handle [_ ch config]
(.setOriginatingRequest ^Channel ch request)
(when on-open
(on-open ch))))
(reify Channel$OnError
(handle [_ ch error]
(when on-error
(on-error ch error))))
(reify Channel$OnClose
(handle [_ ch code reason]
(when on-close
(on-close ch {:code code
:reason reason}))))
(reify WebsocketChannel$OnMessage
(handle [_ ch message]
(when on-message
(on-message ch message))))))
(defn websocket-servlet-filter-map []
(doto (LinkedHashMap.)
(.put "ws-helper" (WebSocketHelpyHelpersonFilter.))))