/
CanvasDrag.pbi
424 lines (375 loc) · 12.4 KB
/
CanvasDrag.pbi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
; +------------+
; | CanvasDrag |
; +------------+
; | 2019-04-25 : Creation
; | 2019-11-03 : Added L/R/M mouse button handling
; | 2019-11-04 : Added Start/Stop/Change custom EventTypes, threshold/clamp
; | 2019-11-05 : Added CanvasClickWasDragStop() to avoid double-handling
; | 2019-11-26 : Added LockXY(), ScaleX(), ScaleY(), demo text instructions
; | 2019-11-27 : Get real parent window (WindowFromGadget.pbi required)
; TODO
; release drag on MouseLeave ? depends on OS ?
;-
CompilerIf (Not Defined(_CanvasDrag_Included, #PB_Constant))
#_CanvasDrag_Included = #True
CompilerIf (#PB_Compiler_IsMainFile)
EnableExplicit
CompilerEndIf
;- Constants
Enumeration
#CanvasDrag_Start = #PB_EventType_FirstCustomValue
#CanvasDrag_Stop
#CanvasDrag_Change
EndEnumeration
;-
;- Includes
XIncludeFile "WindowFromGadget.pbi"
;-
;- Globals
Global _CanvasDown.i = #False
Global _CanvasDragging.i = #False
Global _CanvasClamp.i = #False
Global _CanvasWindow.i = 0
Global _CanvasDragThreshold.i = 3
Global _CanvasDragGadget.i
Global _CanvasClickWasDrag.i = #False
Global _CanvasButton.i
Global _CanvasAnchorX.i
Global _CanvasAnchorY.i
Global _CanvasPreviousSelX.i
Global _CanvasPreviousSelY.i
Global _CanvasSelX.i
Global _CanvasSelY.i
Global _CanvasLeftX.i
Global _CanvasRightX.i
Global _CanvasTopY.i
Global _CanvasBottomY.i
Global _CanvasDragX.i
Global _CanvasDragY.i
Global _CanvasDragWidth.i
Global _CanvasDragHeight.i
Global _CanvasDirX.i
Global _CanvasDirY.i
Global _CanvasUserX.d
Global _CanvasUserY.d
;-
;- Procedures
Declare _CanvasDragCallback()
Procedure.i IsCanvasDragging()
ProcedureReturn (_CanvasDragging)
EndProcedure
Procedure.i CanvasDragGadget()
ProcedureReturn (_CanvasDragGadget)
EndProcedure
Procedure.i CanvasDragButton()
ProcedureReturn (_CanvasButton)
EndProcedure
Procedure.i CanvasClickWasDragStop()
Protected Result.i = _CanvasClickWasDrag
_CanvasClickWasDrag = #False
ProcedureReturn (Result)
EndProcedure
Procedure.i CanvasDragAnchorX()
ProcedureReturn (_CanvasAnchorX)
EndProcedure
Procedure.i CanvasDragAnchorY()
ProcedureReturn (_CanvasAnchorY)
EndProcedure
Procedure.i CanvasDragCursorX()
ProcedureReturn (_CanvasSelX)
EndProcedure
Procedure.i CanvasDragCursorY()
ProcedureReturn (_CanvasSelY)
EndProcedure
Procedure.i CanvasDragDeltaX()
Protected Result.i = _CanvasSelX - _CanvasPreviousSelX
_CanvasPreviousSelX = _CanvasSelX
ProcedureReturn (Result)
EndProcedure
Procedure.i CanvasDragDeltaY()
Protected Result.i = _CanvasSelY - _CanvasPreviousSelY
_CanvasPreviousSelY = _CanvasSelY
ProcedureReturn (Result)
EndProcedure
Procedure.i CanvasDragRelativeX()
ProcedureReturn (_CanvasDragX)
EndProcedure
Procedure.i CanvasDragRelativeY()
ProcedureReturn (_CanvasDragY)
EndProcedure
Procedure.i CanvasDragDirX()
ProcedureReturn (_CanvasDirX)
EndProcedure
Procedure.i CanvasDragDirY()
ProcedureReturn (_CanvasDirY)
EndProcedure
Procedure.i CanvasDragLeftX()
ProcedureReturn (_CanvasLeftX)
EndProcedure
Procedure.i CanvasDragRightX()
ProcedureReturn (_CanvasRightX)
EndProcedure
Procedure.i CanvasDragTopY()
ProcedureReturn (_CanvasTopY)
EndProcedure
Procedure.i CanvasDragBottomY()
ProcedureReturn (_CanvasBottomY)
EndProcedure
Procedure.i CanvasDragWidth()
ProcedureReturn (_CanvasDragWidth)
EndProcedure
Procedure.i CanvasDragHeight()
ProcedureReturn (_CanvasDragHeight)
EndProcedure
Procedure CanvasDragLockXY(UserX.d, UserY.d)
_CanvasUserX = UserX
_CanvasUserY = UserY
EndProcedure
Procedure.d CanvasDragScaleX(ScaleX.d = 1.0)
ProcedureReturn (ScaleX * _CanvasDragX + _CanvasUserX)
EndProcedure
Procedure.d CanvasDragScaleY(ScaleY.d = 1.0)
ProcedureReturn (ScaleY * _CanvasDragY + _CanvasUserY)
EndProcedure
Procedure.i CanvasDragContainsPoint(x.i, y.i)
Protected Result.i = #False
If (_CanvasDragging)
If ((x >= _CanvasLeftX) And (x <= _CanvasRightX))
If ((y >= _CanvasTopY) And (y <= _CanvasBottomY))
Result = #True
EndIf
EndIf
EndIf
ProcedureReturn (Result)
EndProcedure
Procedure.i CanvasDragContainsBox(x.i, y.i, Width.i, Height.i)
Protected Result.i = #False
If (_CanvasDragging)
If ((x >= _CanvasLeftX) And (x + Width <= _CanvasRightX))
If ((y >= _CanvasTopY) And (y + Height <= _CanvasBottomY))
Result = #True
EndIf
EndIf
EndIf
ProcedureReturn (Result)
EndProcedure
Procedure.i CanvasDragIntersectsBox(x.i, y.i, Width.i, Height.i)
Protected Result.i = #False
If (_CanvasDragging)
If ((x <= _CanvasRightX) And (x + Width >= _CanvasLeftX))
If ((y <= _CanvasBottomY) And (y + Height >= _CanvasTopY))
Result = #True
EndIf
EndIf
EndIf
ProcedureReturn (Result)
EndProcedure
Procedure SetCanvasDragThreshold(Pixels.i)
If (Pixels >= 0)
_CanvasDragThreshold = Pixels
EndIf
EndProcedure
Procedure SetCanvasDragClamp(State.i)
_CanvasClamp = Bool(State)
EndProcedure
Procedure CancelCanvasDrag()
If (_CanvasDragging)
_CanvasDown = #False
_CanvasDragging = #False
EndIf
EndProcedure
Procedure.i TrackCanvasDrag(Gadget.i)
BindGadgetEvent(Gadget, @_CanvasDragCallback())
EndProcedure
Procedure.i UntrackCanvasDrag(Gadget.i)
UnbindGadgetEvent(Gadget, @_CanvasDragCallback())
EndProcedure
;-
Procedure _CanvasDragCallback()
If ((Not _CanvasDown) Or (_CanvasDragGadget = EventGadget()))
Select (EventType())
Case #PB_EventType_LeftButtonDown, #PB_EventType_RightButtonDown, #PB_EventType_MiddleButtonDown
If (Not _CanvasDown)
_CanvasDown = #True
_CanvasDragGadget = EventGadget()
_CanvasAnchorX = GetGadgetAttribute(EventGadget(), #PB_Canvas_MouseX)
_CanvasAnchorY = GetGadgetAttribute(EventGadget(), #PB_Canvas_MouseY)
_CanvasPreviousSelX = _CanvasAnchorX
_CanvasPreviousSelY = _CanvasAnchorY
Select (EventType())
Case #PB_EventType_LeftButtonDown
_CanvasButton = #PB_Canvas_LeftButton
Case #PB_EventType_RightButtonDown
_CanvasButton = #PB_Canvas_RightButton
Case #PB_EventType_MiddleButtonDown
_CanvasButton = #PB_Canvas_MiddleButton
EndSelect
EndIf
Case #PB_EventType_LeftButtonUp, #PB_EventType_RightButtonUp, #PB_EventType_MiddleButtonUp
If (_CanvasDown)
If (((EventType() = #PB_EventType_LeftButtonUp) And (_CanvasButton = #PB_Canvas_LeftButton)) Or
((EventType() = #PB_EventType_RightButtonUp) And (_CanvasButton = #PB_Canvas_RightButton)) Or
((EventType() = #PB_EventType_MiddleButtonUp) And (_CanvasButton = #PB_Canvas_MiddleButton)))
_CanvasDown = #False
If (_CanvasDragging)
_CanvasDragging = #False
PostEvent(#PB_Event_Gadget, _CanvasWindow, EventGadget(), #CanvasDrag_Stop)
EndIf
EndIf
EndIf
Case #PB_EventType_MouseLeave
;
Case #PB_EventType_MouseMove
If (_CanvasDown)
_CanvasSelX = GetGadgetAttribute(EventGadget(), #PB_Canvas_MouseX)
_CanvasSelY = GetGadgetAttribute(EventGadget(), #PB_Canvas_MouseY)
If (_CanvasClamp)
If (_CanvasSelX < 0)
_CanvasSelX = 0
ElseIf (_CanvasSelX >= GadgetWidth(EventGadget()))
_CanvasSelX = GadgetWidth(EventGadget()) - 1
EndIf
If (_CanvasSelY < 0)
_CanvasSelY = 0
ElseIf (_CanvasSelY >= GadgetHeight(EventGadget()))
_CanvasSelY = GadgetHeight(EventGadget()) - 1
EndIf
EndIf
If (Not _CanvasDragging)
If ((Abs(_CanvasSelX - _CanvasAnchorX) + Abs(_CanvasSelY - _CanvasAnchorY)) >= _CanvasDragThreshold)
_CanvasClickWasDrag = #True
_CanvasDragging = #True
_CanvasWindow = GetWindowFromGadget(_CanvasDragGadget)
PostEvent(#PB_Event_Gadget, _CanvasWindow, EventGadget(), #CanvasDrag_Start)
EndIf
EndIf
If (_CanvasDragging)
If (_CanvasSelX > _CanvasAnchorX)
_CanvasLeftX = _CanvasAnchorX
_CanvasRightX = _CanvasSelX
_CanvasDirX = 1
Else
_CanvasLeftX = _CanvasSelX
_CanvasRightX = _CanvasAnchorX
_CanvasDirX = -1
EndIf
If (_CanvasSelY > _CanvasAnchorY)
_CanvasTopY = _CanvasAnchorY
_CanvasBottomY = _CanvasSelY
_CanvasDirY = 1
Else
_CanvasTopY = _CanvasSelY
_CanvasBottomY = _CanvasAnchorY
_CanvasDirY = -1
EndIf
_CanvasDragX = _CanvasSelX - _CanvasAnchorX
_CanvasDragY = _CanvasSelY - _CanvasAnchorY
_CanvasDragWidth = _CanvasRightX - _CanvasLeftX
_CanvasDragHeight = _CanvasBottomY - _CanvasTopY
PostEvent(#PB_Event_Gadget, _CanvasWindow, EventGadget(), #CanvasDrag_Change)
EndIf
EndIf
EndSelect
EndIf
EndProcedure
;-
;-
;- Demo Program
CompilerIf (#PB_Compiler_IsMainFile)
DisableExplicit
Global CameraX.i
Global CameraY.i
Procedure DemoRedraw()
Protected Selecting.i = Bool(IsCanvasDragging() And (CanvasDragButton() <> #PB_Canvas_MiddleButton))
If StartVectorDrawing(CanvasVectorOutput(0))
; Clear background
If (Selecting And CanvasDragContainsPoint(CameraX + VectorOutputWidth()/2, CameraY + VectorOutputHeight()/2))
VectorSourceColor($FFC0FFFF)
Else
VectorSourceColor($FFFFFFFF)
EndIf
FillVectorOutput()
; Draw dot to select
VectorSourceColor($FF000000)
AddPathCircle(CameraX + 320, CameraY + 240,1)
FillPath()
; Draw box to select
VectorSourceColor($FFc0c0c0)
If (Selecting)
If (CanvasDragDirX() > 0) And CanvasDragContainsBox(CameraX + 100, CameraY + 100, 50, 50)
VectorSourceColor($FFff0000)
ElseIf (CanvasDragDirX() < 0) And CanvasDragIntersectsBox(CameraX + 100, CameraY + 100, 50, 50)
VectorSourceColor($FF00ff00)
EndIf
EndIf
AddPathBox(CameraX + 100, CameraY + 100, 50, 50)
FillPath()
; Draw text instructions
VectorSourceColor($FFf0d0d0)
VectorFont(FontID(0))
MovePathCursor(CameraX + 200, CameraY + 100)
DrawVectorText("Drag rightward for contain select")
MovePathCursor(CameraX + 200, CameraY + 100 + VectorTextHeight(" "))
DrawVectorText("Drag leftward for intersect select")
MovePathCursor(CameraX + 200, CameraY + 100 + 2*VectorTextHeight(" "))
DrawVectorText("Pan with the Middle mouse button")
; Draw selection box
If (Selecting)
If (CanvasDragDirX() > 0)
Color = #Blue
Else
Color = #Green
EndIf
Color | $FF000000
AddPathBox(CanvasDragLeftX(), CanvasDragTopY(), CanvasDragWidth() + 1, CanvasDragHeight() + 1)
VectorSourceColor(Color)
If (CanvasDragDirX() > 0)
StrokePath(1)
Else
DashPath(1, 10)
EndIf
EndIf
StopVectorDrawing()
EndIf
EndProcedure
Procedure DemoCallback()
If (EventType() = #CanvasDrag_Start)
Debug "Start dragging"
CanvasDragLockXY(CameraX, CameraY)
ElseIf (EventType() = #CanvasDrag_Stop)
Debug "Stop"
ElseIf (EventType() = #CanvasDrag_Change)
;Debug "Change"
If (CanvasDragButton() = #PB_Canvas_MiddleButton)
CameraX = CanvasDragScaleX()
CameraY = CanvasDragScaleY()
EndIf
ElseIf ((EventType() = #PB_EventType_LeftClick) Or
(EventType() = #PB_EventType_RightClick))
If (Not CanvasClickWasDragStop())
Debug "Click without drag"
EndIf
EndIf
DemoRedraw()
EndProcedure
Procedure DemoCancel()
CancelCanvasDrag()
DemoRedraw()
EndProcedure
#Win = 0
LoadFont(0, "Arial", 14)
OpenWindow(#Win, 0, 0, 640, 480, "CanvasDrag", #PB_Window_ScreenCentered | #PB_Window_SystemMenu)
CanvasGadget(0, 0, 0, 640, 480)
TrackCanvasDrag(0)
;SetCanvasDragThreshold(40)
;SetCanvasDragClamp(#True)
BindGadgetEvent(0, @DemoCallback())
AddKeyboardShortcut(#Win, #PB_Shortcut_Escape, 1)
BindEvent(#PB_Event_Menu, @DemoCancel(), #Win, 1)
DemoRedraw()
Repeat
;
Until (WaitWindowEvent() = #PB_Event_CloseWindow)
CompilerEndIf
CompilerEndIf
;-