BiDO Ontology Extension

These graphs and table explain the extension to the BiDO Standard Bibliometric Measures Module from SPAR Ontology Network.

Where C = Class; OP = Object Property; DP = Data Property; NI = Name Individual

Quering with SPARQL

The competency questions and the queries is presented in this section. You can click in the play button to execute the query.
For publishing the RDF, we employed the triple database OpenLink Virtuoso. The URI to access our endpoint to do any query to our data is http://spar.linkeddata.es/sparql, and the graph URI is http://spar.linkeddata.es/graph/bido.

CQ1. How many publications does a researcher have?

prefix bido: <http://purl.org/spar/bido-core/>  
prefix frbr: <http://purl.org/vocab/frbr/core/>  
prefix dcterms: <http://purl.org/dc/terms/>  

SELECT DISTINCT ?numDocs ?name AS ?authorName  (group_concat(?orgName; separator="; ") as ?affils)  
WHERE  
{  
 {
  SELECT DISTINCT ?numDocs ?name ?orgName WHERE 
  {
   ?author bido:holdsBibliometricDataInTime ?authorMeasure ;   
             foaf:name ?name .  
   ?org foaf:member ?author ;  
        foaf:name ?orgName .  
   ?authorMeasure bido:withBibliometricData ?authorDocNumber .  
   ?authorDocNumber bido:hasMeasure <http://purl.org/spar/bido/author-number-documents> ;  
            bido:hasNumericValue ?numDocs2.  
  bind(xsd:int(?numDocs2) as ?numDocs )  
  }  
 }
} 
GROUP BY ?name ?numDocs  
ORDER BY DESC(?numDocs) ?authorName  

CQ2. How many citations does a publication have?

prefix fabio:<http://purl.org/spar/fabio/>  
prefix bido: <http://purl.org/spar/bido-core/>  
prefix frbr: <http://purl.org/vocab/frbr/core/>      
prefix dcterms: <http://purl.org/dc/terms/>  
  
SELECT DISTINCT ?numCitations ?paperTitle  
WHERE  
{  
 ?paper bido:holdsBibliometricDataInTime ?paperMeasure .  
 ?biblio frbr:realization ?paper ;  
        dcterms:title ?paperTitle .  
 ?paperMeasure bido:withBibliometricData ?paperCitations .  
 ?paperCitations bido:hasMeasure <http://purl.org/spar/bido/paper-citation-count> ;  
                 bido:hasNumericValue ?numCitations2.  
 bind(xsd:int(?numCitations2) as ?numCitations )  
}  
ORDER BY DESC(?numCitations)  

CQ3. Which is the h-index of the journal?

prefix fabio:<http://purl.org/spar/fabio/>  
prefix bido: <http://purl.org/spar/bido-core/>  
prefix frbr: <http://purl.org/vocab/frbr/core/>     
prefix dcterms: <http://purl.org/dc/terms/>  
  
SELECT DISTINCT ?hindex ?nameSource  
WHERE  
{  
 ?source bido:holdsBibliometricDataInTime ?SMY ;  
        foaf:name ?nameSource .      
 ?SMY bido:withBibliometricData ?FI ;  
     bido:accordingTo  "SJR".  
 ?FI bido:hasMeasure <http://purl.org/spar/bido/h-index> .  
 ?FI bido:hasNumericValue ?hindex2 .  
 bind(xsd:int(?hindex2) as ?hindex )  
}  
ORDER BY  DESC(?hindex)  

CQ4. How many publications have been published in journals indexed in SJR or JCR?

prefix fabio:<http://purl.org/spar/fabio/>  
prefix bido: <http://purl.org/spar/bido-core/>  
prefix frbr: <http://purl.org/vocab/frbr/core/>      
prefix dcterms: <http://purl.org/dc/terms/>  
  
SELECT DISTINCT (count(?paper) as ?num) ?kind  
WHERE  
{  
 ?paper rdf:type ?kind ;  
       frbr:partOf ?source .  
 ?source bido:holdsBibliometricDataInTime ?SMY .        
 ?SMY bido:withBibliometricData ?FI ;  
     bido:accordingTo  "SJR".  
     OPTIONAL  
    { ?SMY bido:accordingTo "JCR" . }  
 ?FI bido:hasMeasure <http://purl.org/spar/bido/journal-impact-factor> .  
 ?FI bido:hasNumericValue ?sjr .  
}  

CQ5. How many publications have been published in a specific quartile and in which area and discipline?

prefix fabio:<http://purl.org/spar/fabio/>  
prefix bido: <http://purl.org/spar/bido-core/>  
prefix frbr: <http://purl.org/vocab/frbr/core/>      
prefix dcterms: <http://purl.org/dc/terms/>  
  
SELECT DISTINCT (count(?paper) AS ?numPaper) ?nameDisc ?nameArea ?Q  
WHERE  
{  
 ?paper frbr:partOf ?source .  
 ?source bido:holdsBibliometricDataInTime ?SMY .  
 ?SMY bido:withBibliometricData ?SYAD .  
 ?SYAD bido:relatesToSubjectCategory ?disc ;  
      bido:hasQuartile ?Q .  
 ?disc skos:prefLabel ?nameDisc ;  
      skos:broader ?area .  
 ?area skos:prefLabel ?nameArea .  
}  
ORDER BY ?Q DESC(?numPaper)  

Publications by researcher

  
prefix fabio:<http://purl.org/spar/fabio/>  
prefix bido: <http://purl.org/spar/bido-core/>  
prefix frbr: <http://purl.org/vocab/frbr/core/>      
prefix dcterms: <http://purl.org/dc/terms/>  
  
SELECT DISTINCT  ?authorName (count(?paper) AS ?numPaper) ?nameDisc ?nameArea ?Q ?author  
WHERE  
{  
 ?author foaf:name ?authorName ;  
        dcterms:creator ?paper .  
 ?paper frbr:partOf ?source .  
 ?source bido:holdsBibliometricDataInTime ?SMY .  
 ?SMY bido:withBibliometricData ?SYAD .  
 ?SYAD bido:relatesToSubjectCategory ?disc ;  
      bido:hasQuartile ?Q .  
 ?disc skos:prefLabel ?nameDisc ;  
      skos:broader ?area .  
 ?area skos:prefLabel ?nameArea .  
}  
ORDER BY DESC(?numPaper) ?authorName  

CQ6. Which is the rank of the journal?

prefix fabio:<http://purl.org/spar/fabio/>  
prefix bido: <http://purl.org/spar/bido-core/>  
prefix frbr: <http://purl.org/vocab/frbr/core/>      
prefix dcterms: <http://purl.org/dc/terms/>  
  
SELECT DISTINCT  ?rank ?Q ?nameSource  
WHERE  
{  
 ?source foaf:name ?nameSource ;  
        bido:holdsBibliometricDataInTime ?SMY .  
 ?SMY bido:withBibliometricData ?SYAD .  
 ?SYAD bido:relatesToSubjectCategory ?disc ;  
      bido:hasQuartile ?Q ;  
      bido:rankInQuartile ?rank .  
 ?disc skos:prefLabel ?nameDisc ;  
      skos:broader ?area .  
 ?area skos:prefLabel ?nameArea .  
}  
ORDER BY (xsd:integer(?rank))