/
config_test.pri
50 lines (41 loc) · 1.42 KB
/
config_test.pri
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Let deployers know this is only a test app.
CONFIG += deng_testapp
include(../config.pri)
include(../dep_core.pri)
mod.files = \
$$DENG_MODULES_DIR/Config.de \
$$DENG_MODULES_DIR/Log.de \
$$DENG_MODULES_DIR/recutil.de
macx {
mod.path = Contents/Resources/modules
defineTest(deployTest) {
contDir = $${OUT_PWD}/$${1}.app/Contents
fwDir = \"$$contDir/Frameworks\"
# Quite a hack: directly use the client's Frameworks folder.
doPostLink("rm -rf $$fwDir")
doPostLink("ln -s \"$$OUT_PWD/../../client/Doomsday.app/Contents/Frameworks\" $$fwDir")
doPostLink("ln -sf \"$$OUT_PWD/../../client/Doomsday.app/Contents/PlugIns\" \"$$contDir/\"")
doPostLink("ln -sf \"$$OUT_PWD/../../client/Doomsday.app/Contents/Resources/qt.conf\" \"$$contDir/Resources/qt.conf\"")
# Fix the dynamic linker paths so they point to ../Frameworks/ inside the bundle.
fixInstallName($${1}.app/Contents/MacOS/$${1}, libdeng_core.2.dylib, ..)
QMAKE_BUNDLE_DATA += mod
export(QMAKE_BUNDLE_DATA)
}
}
else:win32 {
CONFIG += console
target.path = $$DENG_BIN_DIR
mod.path = $$DENG_DATA_DIR/modules
defineTest(deployTest) {
INSTALLS += mod target
export(INSTALLS)
}
}
else {
target.path = $$DENG_BIN_DIR
mod.path = $$DENG_DATA_DIR/modules
defineTest(deployTest) {
INSTALLS += mod target
export(INSTALLS)
}
}